arch/arm/lib/csumpartial.S

   1 /*
   2  *  linux/arch/arm/lib/csumpartial.S
   3  *
   4  *  Copyright (C) 1995-1998 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 #include <linux/linkage.h>
  11 #include <asm/assembler.h>
  12
  13                 .text
  14
  15 /*
  16  * Function: __u32 csum_partial(const char *src, int len, __u32 sum)
  17  * Params  : r0 = buffer, r1 = len, r2 = checksum
  18  * Returns : r0 = new checksum
  19  */
  20
  21 buf     .req    r0
  22 len     .req    r1
  23 sum     .req    r2
  24 td0     .req    r3
  25 td1     .req    r4      @ save before use
  26 td2     .req    r5      @ save before use
  27 td3     .req    lr
  28
  29 .zero:          mov     r0, sum
  30                 add     sp, sp, #4
  31                 ldr     pc, [sp], #4
  32
  33                 /*
  34                  * Handle 0 to 7 bytes, with any alignment of source and
  35                  * destination pointers.  Note that when we get here, C = 0
  36                  */
  37 .less8:         teq     len, #0                 @ check for zero count
  38                 beq     .zero
  39
  40                 /* we must have at least one byte. */
  41                 tst     buf, #1                 @ odd address?
  42                 ldrneb  td0, [buf], #1
  43                 subne   len, len, #1
  44                 adcnes  sum, sum, td0, lsl #8
  45
  46 .less4:         tst     len, #6
  47                 beq     .less8_byte
  48
  49                 /* we are now half-word aligned */
  50
  51 .less8_wordlp:
  52 #if __LINUX_ARM_ARCH__ >= 4
  53                 ldrh    td0, [buf]
  54                 add     buf, buf, #2
  55                 sub     len, len, #2
  56 #else
  57                 ldrb    td0, [buf], #1
  58                 ldrb    td3, [buf], #1
  59                 sub     len, len, #2
  60                 orr     td0, td0, td3, lsl #8
  61 #endif
  62                 adcs    sum, sum, td0
  63                 tst     len, #6
  64                 bne     .less8_wordlp
  65
  66 .less8_byte:    tst     len, #1                 @ odd number of bytes
  67                 ldrneb  td0, [buf], #1          @ include last byte
  68                 adcnes  sum, sum, td0           @ update checksum
  69
  70 .done:          adc     r0, sum, #0             @ collect up the last carry
  71                 ldr     td0, [sp], #4
  72                 tst     td0, #1                 @ check buffer alignment
  73                 movne   td0, r0, lsl #8         @ rotate checksum by 8 bits
  74                 orrne   r0, td0, r0, lsr #24
  75                 ldr     pc, [sp], #4            @ return
  76
  77 .not_aligned:   tst     buf, #1                 @ odd address
  78                 ldrneb  td0, [buf], #1          @ make even
  79                 subne   len, len, #1
  80                 adcnes  sum, sum, td0, lsl #8   @ update checksum
  81
  82                 tst     buf, #2                 @ 32-bit aligned?
  83 #if __LINUX_ARM_ARCH__ >= 4
  84                 ldrneh  td0, [buf]              @ make 32-bit aligned
  85                 add     buf, buf, #2
  86                 subne   len, len, #2
  87 #else
  88                 ldrneb  td0, [buf], #1
  89                 ldrneb  ip, [buf], #1
  90                 subne   len, len, #2
  91                 orrne   td0, td0, ip, lsl #8
  92 #endif
  93                 adcnes  sum, sum, td0           @ update checksum
  94                 mov     pc, lr
  95
  96 ENTRY(csum_partial)
  97                 stmfd   sp!, {buf, lr}
  98                 cmp     len, #8                 @ Ensure that we have at least
  99                 blo     .less8                  @ 8 bytes to copy.
 100
 101                 adds    sum, sum, #0            @ C = 0
 102                 tst     buf, #3                 @ Test destination alignment
 103                 blne    .not_aligned            @ aligh destination, return here
 104
 105 1:              bics    ip, len, #31
 106                 beq     3f
 107
 108                 stmfd   sp!, {r4 - r5}
 109 2:              ldmia   buf!, {td0, td1, td2, td3}
 110                 adcs    sum, sum, td0
 111                 adcs    sum, sum, td1
 112                 adcs    sum, sum, td2
 113                 adcs    sum, sum, td3
 114                 ldmia   buf!, {td0, td1, td2, td3}
 115                 adcs    sum, sum, td0
 116                 adcs    sum, sum, td1
 117                 adcs    sum, sum, td2
 118                 adcs    sum, sum, td3
 119                 sub     ip, ip, #32
 120                 teq     ip, #0
 121                 bne     2b
 122                 ldmfd   sp!, {r4 - r5}
 123
 124 3:              tst     len, #0x1c              @ should not change C
 125                 beq     .less4
 126
 127 4:              ldr     td0, [buf], #4
 128                 sub     len, len, #4
 129                 adcs    sum, sum, td0
 130                 tst     len, #0x1c
 131                 bne     4b
 132                 b       .less4