arch/ia64/vmlinux.lds.S

   1 #include <linux/config.h>
   2
   3 #include <asm/cache.h>
   4 #include <asm/page.h>
   5 #include <asm/system.h>
   6
   7 OUTPUT_FORMAT("elf64-ia64-little")
   8 OUTPUT_ARCH(ia64)
   9 ENTRY(phys_start)
  10 SECTIONS
  11 {
  12   /* Sections to be discarded */
  13   /DISCARD/ : {
  14         *(.text.exit)
  15         *(.data.exit)
  16         *(*.text.exit)
  17         *(*.data.exit)
  18         *(.exitcall.exit)
  19         *(.IA_64.unwind.text.exit)
  20         *(.IA_64.unwind_info.text.exit)
  21         }
  22
  23   v = PAGE_OFFSET;      /* this symbol is here to make debugging easier... */
  24   phys_start = _start - PAGE_OFFSET;
  25
  26   . = KERNEL_START;
  27
  28   _text = .;
  29   _stext = .;
  30   .text : AT(ADDR(.text) - PAGE_OFFSET)
  31     {
  32         *(.text.ivt)
  33         *(.text)
  34     }
  35   .text2 : AT(ADDR(.text2) - PAGE_OFFSET)
  36         { *(.text2) }
  37 #ifdef CONFIG_SMP
  38   .text.lock : AT(ADDR(.text.lock) - PAGE_OFFSET)
  39         { *(.text.lock) }
  40 #endif
  41   _etext = .;
  42
  43   /* Read-only data */
  44
  45   /* Global data */
  46   _data = .;
  47
  48   /* Exception table */
  49   . = ALIGN(16);
  50   __start___ex_table = .;
  51   __ex_table : AT(ADDR(__ex_table) - PAGE_OFFSET)
  52         { *(__ex_table) }
  53   __stop___ex_table = .;
  54
  55 #if defined(CONFIG_IA64_GENERIC)
  56   /* Machine Vector */
  57   . = ALIGN(16);
  58   machvec_start = .;
  59   .machvec : AT(ADDR(.machvec) - PAGE_OFFSET)
  60         { *(.machvec) }
  61   machvec_end = .;
  62 #endif
  63
  64   __start___ksymtab = .;        /* Kernel symbol table */
  65   __ksymtab : AT(ADDR(__ksymtab) - PAGE_OFFSET)
  66         { *(__ksymtab) }
  67   __stop___ksymtab = .;
  68
  69   __start___kallsyms = .;       /* All kernel symbols for debugging */
  70   __kallsyms : AT(ADDR(__kallsyms) - PAGE_OFFSET)
  71         { *(__kallsyms) }
  72   __stop___kallsyms = .;
  73
  74   /* Unwind info & table: */
  75   . = ALIGN(8);
  76   .IA_64.unwind_info : AT(ADDR(.IA_64.unwind_info) - PAGE_OFFSET)
  77         { *(.IA_64.unwind_info*) }
  78   ia64_unw_start = .;
  79   .IA_64.unwind : AT(ADDR(.IA_64.unwind) - PAGE_OFFSET)
  80         { *(.IA_64.unwind*) }
  81   ia64_unw_end = .;
  82
  83   .rodata : AT(ADDR(.rodata) - PAGE_OFFSET)
  84         { *(.rodata) *(.rodata.*) }
  85   .kstrtab : AT(ADDR(.kstrtab) - PAGE_OFFSET)
  86         { *(.kstrtab) }
  87   .opd : AT(ADDR(.opd) - PAGE_OFFSET)
  88         { *(.opd) }
  89
  90   /* Initialization code and data: */
  91
  92   . = ALIGN(PAGE_SIZE);
  93   __init_begin = .;
  94   .text.init : AT(ADDR(.text.init) - PAGE_OFFSET)
  95         { *(.text.init) }
  96
  97   .data.init : AT(ADDR(.data.init) - PAGE_OFFSET)
  98         { *(.data.init) }
  99    . = ALIGN(16);
 100   __setup_start = .;
 101   .setup.init : AT(ADDR(.setup.init) - PAGE_OFFSET)
 102         { *(.setup.init) }
 103   __setup_end = .;
 104   __initcall_start = .;
 105   .initcall.init : AT(ADDR(.initcall.init) - PAGE_OFFSET)
 106         { *(.initcall.init) }
 107   __initcall_end = .;
 108   . = ALIGN(PAGE_SIZE);
 109   __init_end = .;
 110
 111   /* The initial task and kernel stack */
 112   init_task : AT(ADDR(init_task) - PAGE_OFFSET)
 113         { *(init_task) }
 114
 115   .data.page_aligned : AT(ADDR(.data.page_aligned) - PAGE_OFFSET)
 116         { *(__special_page_section)
 117           __start_gate_section = .;
 118           *(.text.gate)
 119           __stop_gate_section = .;
 120         }
 121
 122   . = ALIGN(SMP_CACHE_BYTES);
 123   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - PAGE_OFFSET)
 124         { *(.data.cacheline_aligned) }
 125
 126   /* Kernel symbol names for modules: */
 127   .kstrtab : AT(ADDR(.kstrtab) - PAGE_OFFSET)
 128         { *(.kstrtab) }
 129
 130   .data : AT(ADDR(.data) - PAGE_OFFSET)
 131         { *(.data) *(.gnu.linkonce.d*) CONSTRUCTORS }
 132
 133
 134   . = ALIGN(16);
 135   __gp = . + 0x200000;  /* gp must be 16-byte aligned for exc. table */
 136
 137   .got : AT(ADDR(.got) - PAGE_OFFSET)
 138         { *(.got.plt) *(.got) }
 139   /* We want the small data sections together, so single-instruction offsets
 140      can access them all, and initialized data all before uninitialized, so
 141      we can shorten the on-disk segment size.  */
 142   .sdata : AT(ADDR(.sdata) - PAGE_OFFSET)
 143         { *(.sdata) }
 144   _edata  =  .;
 145   _bss = .;
 146   .sbss : AT(ADDR(.sbss) - PAGE_OFFSET)
 147         { *(.sbss) *(.scommon) }
 148   .bss : AT(ADDR(.bss) - PAGE_OFFSET)
 149         { *(.bss) *(COMMON) }
 150   . = ALIGN(64 / 8);
 151   _end = .;
 152
 153   /* Stabs debugging sections.  */
 154   .stab 0 : { *(.stab) }
 155   .stabstr 0 : { *(.stabstr) }
 156   .stab.excl 0 : { *(.stab.excl) }
 157   .stab.exclstr 0 : { *(.stab.exclstr) }
 158   .stab.index 0 : { *(.stab.index) }
 159   .stab.indexstr 0 : { *(.stab.indexstr) }
 160   /* DWARF debug sections.
 161      Symbols in the DWARF debugging sections are relative to the beginning
 162      of the section so we begin them at 0.  */
 163   /* DWARF 1 */
 164   .debug          0 : { *(.debug) }
 165   .line           0 : { *(.line) }
 166   /* GNU DWARF 1 extensions */
 167   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 168   .debug_sfnames  0 : { *(.debug_sfnames) }
 169   /* DWARF 1.1 and DWARF 2 */
 170   .debug_aranges  0 : { *(.debug_aranges) }
 171   .debug_pubnames 0 : { *(.debug_pubnames) }
 172   /* DWARF 2 */
 173   .debug_info     0 : { *(.debug_info) }
 174   .debug_abbrev   0 : { *(.debug_abbrev) }
 175   .debug_line     0 : { *(.debug_line) }
 176   .debug_frame    0 : { *(.debug_frame) }
 177   .debug_str      0 : { *(.debug_str) }
 178   .debug_loc      0 : { *(.debug_loc) }
 179   .debug_macinfo  0 : { *(.debug_macinfo) }
 180   /* SGI/MIPS DWARF 2 extensions */
 181   .debug_weaknames 0 : { *(.debug_weaknames) }
 182   .debug_funcnames 0 : { *(.debug_funcnames) }
 183   .debug_typenames 0 : { *(.debug_typenames) }
 184   .debug_varnames  0 : { *(.debug_varnames) }
 185   /* These must appear regardless of  .  */
 186   /* Discard them for now since Intel SoftSDV cannot handle them.
 187   .comment 0 : { *(.comment) }
 188   .note 0 : { *(.note) }
 189   */
 190   /DISCARD/ : { *(.comment) }
 191   /DISCARD/ : { *(.note) }
 192 }