arch/x86_64/lib/copy_page.S

   1 /* Written 2003 by Andi Kleen, based on a kernel by Evandro Menezes */
   2
   3 #include <linux/config.h>
   4
   5 /* Don't use streaming store because it's better when the target
   6    ends up in cache. */
   7
   8 /* Could vary the prefetch distance based on SMP/UP */
   9
  10         .globl copy_page
  11         .p2align 4
  12 copy_page:
  13
  14     prefetcht0 (%rsi)
  15     prefetcht0 1*64(%rsi)
  16 #ifdef CONFIG_MK8
  17         prefetchw (%rdi)
  18         prefetchw 1*64(%rdi)
  19 #endif
  20
  21         subq    $3*8,%rsp
  22         movq    %rbx,(%rsp)
  23         movq    %r12,1*8(%rsp)
  24         movq    %r13,2*8(%rsp)
  25
  26         movl    $(4096/64)-5,%ecx
  27         .p2align 4
  28 .Loop64:
  29         dec     %rcx
  30
  31         movq        (%rsi), %rax
  32         movq      8 (%rsi), %rbx
  33         movq     16 (%rsi), %rdx
  34         movq     24 (%rsi), %r8
  35         movq     32 (%rsi), %r9
  36         movq     40 (%rsi), %r10
  37         movq     48 (%rsi), %r11
  38         movq     56 (%rsi), %r12
  39
  40         prefetcht0 5*64(%rsi)
  41
  42         movq     %rax,    (%rdi)
  43         movq     %rbx,  8 (%rdi)
  44         movq     %rdx, 16 (%rdi)
  45         movq     %r8,  24 (%rdi)
  46         movq     %r9,  32 (%rdi)
  47         movq     %r10, 40 (%rdi)
  48         movq     %r11, 48 (%rdi)
  49         movq     %r12, 56 (%rdi)
  50
  51 #ifdef CONFIG_MK8
  52         prefetchw 5*64(%rdi)
  53 #endif
  54
  55         leaq    64 (%rsi), %rsi
  56         leaq    64 (%rdi), %rdi
  57
  58         jnz     .Loop64
  59
  60         movl    $5,%ecx
  61         .p2align 4
  62 .Loop2:
  63         decl   %ecx
  64
  65         movq        (%rsi), %rax
  66         movq      8 (%rsi), %rbx
  67         movq     16 (%rsi), %rdx
  68         movq     24 (%rsi), %r8
  69         movq     32 (%rsi), %r9
  70         movq     40 (%rsi), %r10
  71         movq     48 (%rsi), %r11
  72         movq     56 (%rsi), %r12
  73
  74         movq     %rax,    (%rdi)
  75         movq     %rbx,  8 (%rdi)
  76         movq     %rdx, 16 (%rdi)
  77         movq     %r8,  24 (%rdi)
  78         movq     %r9,  32 (%rdi)
  79         movq     %r10, 40 (%rdi)
  80         movq     %r11, 48 (%rdi)
  81         movq     %r12, 56 (%rdi)
  82
  83         leaq    64(%rdi),%rdi
  84         leaq    64(%rsi),%rsi
  85
  86         jnz     .Loop2
  87
  88         movq    (%rsp),%rbx
  89         movq    1*8(%rsp),%r12
  90         movq    2*8(%rsp),%r13
  91         addq    $3*8,%rsp
  92         ret