bin/mplayer.pl

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5
   6 use IPC::Open3 qw(open3);
   7 use IO::Epoll;
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use YAML;
  11 use JSON;
  12
  13
  14 my $movie = shift @ARGV
  15         || 'www/media/video.ogv';
  16 #       || die "usage: $0 path/to/movie.ogv\n";
  17
  18 my $edl = "/dev/shm/edl";
  19 my $subtitles = $movie;
  20 $subtitles =~ s{\.\w+$}{.srt};
  21
  22 my $preroll = 3;
  23
  24 our $to_mplayer;
  25 our $from_mplayer;
  26 our $err_mplayer;
  27 our $prop = {};
  28
  29 my $pid = open3( $to_mplayer, $from_mplayer, $err_mplayer,
  30          'mplayer',
  31                 '-slave', '-idle',
  32                 '-quiet',
  33                 '-edlout', $edl,
  34                 '-osdlevel', 3,
  35 );
  36
  37 my $epfd = epoll_create(10);
  38
  39 epoll_ctl($epfd, EPOLL_CTL_ADD, fileno STDIN         , EPOLLIN  ) >= 0 || die $!;
  40 epoll_ctl($epfd, EPOLL_CTL_ADD, fileno $from_mplayer , EPOLLIN  ) >= 0 || die $!;
  41 #epoll_ctl($epfd, EPOLL_CTL_ADD, fileno $to_mplayer   , EPOLLOUT ) >= 0 || die $!;
  42
  43 sub load_movie {
  44         warn "$movie ", -s $movie, " bytes $edl\n";
  45         print $to_mplayer qq|loadfile "$movie"\n|;
  46         print $to_mplayer "get_property $_\n" foreach ( qw/metadata video_codec video_bitrate width height fps length/ );
  47 }
  48
  49
  50 my $term_id = `xdotool getwindowfocus`;
  51 our $mplayer_id;
  52
  53
  54 sub focus_mplayer {
  55         $mplayer_id ||= `xdotool search mplayer`;
  56         warn "focus_mplayer $mplayer_id\n";
  57         system "xdotool windowactivate $mplayer_id"
  58 }
  59
  60 sub focus_term {
  61         warn "focus_term $term_id\n";
  62         system "xdotool windowactivate $term_id";
  63 }
  64
  65 sub preroll {
  66         my ( $pos, $osd ) = @_;
  67         $osd =~ s{\W+}{ }gs;
  68         warn "PREROLL $pos $osd\n";
  69         print $to_mplayer "osd_show_text \"PREROLL $osd\" ", $preroll * 1000, "\n";
  70         my $to = $pos - $preroll;
  71         $to = 0 if $to < 0;
  72         print $to_mplayer "set_property time_pos $to\n";
  73         print $to_mplayer "get_property time_pos\n";
  74         print $to_mplayer "play\n";
  75 }
  76
  77
  78 $|=1;
  79
  80 my $line;
  81 my $repl;
  82
  83 sub repl {
  84         print "> ";
  85         my $cmd = <STDIN>;
  86         warn ">>> $cmd\n";
  87         print $to_mplayer $cmd;
  88 }
  89
  90
  91 our @subtitles;
  92
  93 sub html5tv {
  94         my $sync;
  95
  96         my @slide_t;
  97
  98         my @videos;
  99
 100         foreach my $s ( @subtitles ) {
 101                 push @{ $sync->{htmlEvents}->{'#subtitle'} }, {
 102                         startTime => $s->[0],
 103                         endTime   => $s->[1],
 104                         html      => $s->[2],
 105                 };
 106
 107                 if ( $s->[2] =~ m{video:(.+)} ) {
 108                         my $video = $1;
 109                         my $path = "www/media/$video";
 110                         if ( ! -e $path ) {
 111                                 warn "MISSING $path: $!\n";
 112                         } else {
 113                                 push @videos, [ @$s, $video ];
 114                         }
 115                 }
 116
 117                 next unless $s->[2] =~ m{\[(\d+)\]};
 118
 119                 my $res = ( $prop->{width} / 4 ) . 'x' . ( $prop->{height} / 4 );
 120
 121                 push @{ $sync->{customEvents} }, {
 122                         startTime => $s->[0],
 123                         endTime   => $s->[1],
 124                         action    => 'chapterChange',
 125                         args => {
 126                                 carousel => 'theCarousel',
 127                                 id => "chapter$1",
 128                                 index => $1,
 129                                 title => $s->[2],
 130                                 description => $s->[2],
 131                                 src => sprintf('media/s/%s/p%03d.jpg', $res, $1),
 132                                 href => '',
 133                         },
 134                 };
 135
 136                 push @slide_t, $s->[0];
 137         }
 138
 139         my $res = $prop->{width} . 'x' . $prop->{height};
 140
 141         foreach ( 0 .. $#slide_t ) {
 142                 push @{ $sync->{htmlEvents}->{'#slide'} }, {
 143                         startTime => $slide_t[$_],
 144                         endTime   => $slide_t[$_ + 1] || $prop->{length},
 145                         html      => sprintf( '<img src=media/s/%s/p%03d.jpg>', $res, $_ + 1 ),
 146                 };
 147         }
 148
 149         my $html5tv = {
 150                 sync => $sync,
 151                 video => $prop,
 152         };
 153
 154         if ( $prop->{width} && $prop->{height} ) {
 155                 foreach my $factor ( 4, 2, 1 ) {
 156                         my $w = $prop->{width}  / $factor;
 157                         my $h = $prop->{height} / $factor;
 158
 159                         $html5tv->{slide} = {
 160                                 width  => $w,
 161                                 height => $h,
 162                         } if $factor == 4;
 163
 164                         my $path = "www/media/s/${w}x${h}";
 165                         if ( ! -d $path ) {
 166                                 mkdir $path;
 167                                 warn "created $path\n";
 168                         }
 169                 }
 170         }
 171
 172         $html5tv->{video_tags} =
 173                 join("\n",
 174                         map {
 175                                 my $id = $_->[3];
 176                                 $id =~ s{\W+}{_}g;
 177
 178                                 push @{ $html5tv->{sync}->{customEvents} }, {
 179                                         startTime => $_->[0],
 180                                         endTime   => $_->[1],
 181                                         action    => 'additional_video',
 182                                         args => {
 183                                                 video => $_[3],
 184                                                 id => $id,
 185                                         },
 186                                 };
 187
 188                                 qq|
 189                                         <video id="$id" style="display: none" controls="controls" width="$html5tv->{video}->{width}px" height="$html5tv->{video}->{height}px">
 190                                         <source src="media/$_->[3]" />
 191                                         </video>
 192                                 |
 193                         } @videos
 194                 )
 195         ;
 196
 197         warn "html5tv ", dump $html5tv;
 198
 199         my $sync_path = 'www/media/video.js';
 200         write_file $sync_path, "var html5tv = " . to_json($html5tv) . " ;\n";
 201         warn "sync $sync_path ", -s $sync_path, " bytes\n";
 202
 203         my $html = read_file 'www/tv.html';
 204         $html =~ s|{([^}]+)}|my $n = $1; $n =~ s(\.)(}->{)g; eval "\$html5tv->{$n}"|egs ||
 205                 warn "no interpolation in template!";
 206
 207         write_file 'www/media.html', $html;
 208
 209         write_file 'www/media/video.css', qq|
 210
 211 .jcarousel-skin-ie7 .jcarousel-container-horizontal,
 212 .jcarousel-skin-ie7 .jcarousel-clip-horizontal {
 213         width: $html5tv->{video}->{width}px;
 214         height: $html5tv->{slide}->{height}px;
 215 }
 216
 217 .jcarousel-skin-ie7 .jcarousel-item {
 218         width: $html5tv->{slide}->{width}px;
 219         height: $html5tv->{slide}->{height}px;
 220 }
 221
 222         |;
 223
 224 }
 225
 226
 227 sub t_srt {
 228         my $t = shift;
 229         my $hh = int( $t / 3600 );
 230         $t -= $hh * 3600;
 231         my $mm = int( $t / 60 );
 232         $t -= $mm * 60;
 233         my $srt = sprintf "%02d:%02d:%04.1f", $hh, $mm, $t;
 234         $srt =~ s{\.}{,};
 235         return $srt;
 236 }
 237
 238 sub save_subtitles {
 239         my $nr = 0;
 240         my $srt = "\n";
 241         foreach my $s ( @subtitles ) {
 242                 $srt .= $nr++ . "\n"
 243                         . t_srt( $s->[0] ) . " --> " . t_srt( $s->[1] ) . "\n"
 244                         . $s->[2] . "\n\n"
 245                         ;
 246         }
 247         warn $srt;
 248
 249         write_file $subtitles, $srt;
 250         YAML::DumpFile "$subtitles.yaml", sort { $a->[0] <=> $b->[0] } @subtitles;
 251
 252         print $to_mplayer "sub_remove\n";
 253         print $to_mplayer qq|sub_load "$subtitles"\n|;
 254         print $to_mplayer "sub_select 1\n";
 255
 256         html5tv;
 257 }
 258
 259 sub load_subtitles {
 260         @subtitles = YAML::LoadFile "$subtitles.yaml";
 261         warn "subtitles ", dump @subtitles;
 262         save_subtitles;
 263 }
 264
 265 load_subtitles if -e "$subtitles.yaml";
 266
 267 sub edit_subtitles {
 268         print $to_mplayer qq|pause\n|;
 269         focus_term;
 270         system( qq|vi "$subtitles.yaml"| ) == 0 and load_subtitles;
 271         focus_mplayer;
 272 }
 273
 274 sub add_subtitle {
 275         print $to_mplayer qq|pause\n|;
 276
 277         focus_term;
 278
 279         warn "subtitles ", dump( @subtitles );
 280         print "## ";
 281         my $line = <STDIN>;
 282         $subtitles[ $#subtitles ]->[2] = $line if defined $line;
 283
 284         save_subtitles;
 285
 286         focus_mplayer;
 287
 288         preroll $subtitles[ $#subtitles ]->[0], $line;
 289 }
 290
 291 sub time_pos {
 292         print $to_mplayer qq|get_property time_pos\n|;
 293         my $pos = <$from_mplayer>;
 294         if ( $pos =~ m{^ANS_time_pos=(\d+\.\d+)} ) {
 295                 warn "# time_pos $1\n";
 296                 return $1;
 297         }
 298 }
 299
 300 sub sub_fmt {
 301         my $s = shift;
 302         sprintf "%1.5f - %1.5f %s %s\n", @$s, join(' | ',@_);
 303 }
 304
 305 sub prev_subtitle {
 306         my $pos = time_pos;
 307         my $s = ( grep { $_->[0] < $pos } @subtitles )[0];
 308         warn "<<<< subtitle ", sub_fmt $s;
 309         preroll $s->[0], $s->[2];
 310 #       print $to_mplayer "set_property time_pos $s->[0]\n";
 311 }
 312
 313 sub next_subtitle {
 314         my $pos = time_pos + $preroll;
 315         my $s = ( grep { $_->[0] > $pos } @subtitles )[0];
 316         warn ">>>> subtitle ", sub_fmt $s;
 317         preroll $s->[0], $s->[2];
 318 #       print $to_mplayer "set_property time_pos $s->[0]\n";
 319 }
 320
 321 sub current_subtitle {
 322         my $callback = shift;
 323         my $pos = time_pos;
 324         my $visible;
 325         foreach my $nr ( 0 .. $#subtitles ) {
 326                 my $s = $subtitles[$nr];
 327                 if ( $s->[0] <= $pos && $s->[1] >= $pos ) {
 328                         warn sub_fmt $s, $pos;
 329                         $visible = $nr;
 330                         $callback->( $visible, $pos ) if $callback;
 331                         return ( $visible, $pos );
 332                 }
 333         }
 334         warn "# $pos no visible subtitle\n";
 335 }
 336
 337 sub move_subtitle {
 338         my $offset = shift;
 339         current_subtitle( sub {
 340                 my ( $nr, $pos ) = @_;
 341                 my $new_start = $subtitles[$nr]->[0] += $offset;
 342                 warn "subtitle $nr $pos $offset $new_start\n";
 343                 save_subtitles;
 344                 preroll $new_start, "$pos $offset $new_start";
 345         } );
 346 }
 347
 348
 349
 350 # XXX main epool loop
 351
 352 load_movie;
 353
 354 while ( my $events = epoll_wait($epfd, 10, 1000) ) { # Max 10 events returned, 1s timeout
 355
 356         warn "no events" unless $events;
 357
 358         foreach my $e ( @$events ) {
 359 #               warn "# event: ", dump($e), $/;
 360
 361                 my $fileno = $e->[0];
 362
 363                 if ( $fileno == fileno STDIN ) {
 364                         my $chr;
 365                         sysread STDIN, $chr, 1;
 366                         print $chr;
 367                 } elsif ( $fileno == fileno $from_mplayer ) {
 368                         my $chr;
 369                         sysread $from_mplayer, $chr, 1;
 370                         print $chr;
 371
 372                         if ( $chr =~ m{[\n\r]} ) {
 373
 374                                 exit if $line =~ m{Exiting};
 375
 376                                 if ( $line =~ m{ANS_(\w+)=(\S+)} ) {
 377                                         $prop->{$1} = $2;
 378                                         warn "prop $1 = $2\n";
 379                                 } elsif ( $line =~ m{No bind found for key '(.+)'} ) {
 380
 381                                         # XXX keyboard shortcuts
 382
 383                                           $1 eq 'c'  ? repl
 384                                         : $1 eq ','  ? add_subtitle
 385                                         : $1 eq 'F1' ? prev_subtitle
 386                                         : $1 eq 'F2' ? move_subtitle( -0.3 )
 387                                         : $1 eq 'F3' ? move_subtitle( +0.3 )
 388                                         : $1 eq 'F4' ? next_subtitle
 389                                         : $1 eq 'F5' ? save_subtitles
 390                                         : $1 eq 'F9' ? add_subtitle
 391                                         : $1 eq 'F12' ? edit_subtitles
 392                                         : warn "CUSTOM $1\n"
 393                                         ;
 394
 395                                 } elsif ( $line =~ m{EDL}i ) {
 396
 397                                         print $to_mplayer qq|osd_show_text "$line"\n|;
 398
 399                                         if ( my $pos = time_pos ) {
 400                                                 if ( $line =~ m{start}i ) {
 401                                                         push @subtitles, [ $pos, $pos, '-' ];
 402                                                 } else {
 403                                                         $subtitles[ $#subtitles ]->[1] = $pos;
 404                                                 }
 405                                         }
 406                                 }
 407
 408                                 $line = '';
 409                         } else {
 410                                 $line .= $chr;
 411                         }
 412
 413
 414                 } elsif ( $fileno == fileno $to_mplayer ) {
 415 #                       warn "command";
 416                 } else {
 417                         die "invalid fileno $fileno";
 418                 }
 419         }
 420
 421 }
 422