bin/mplayer.pl

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5
   6 use IPC::Open3 qw(open3);
   7 use IO::Epoll;
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use YAML;
  11 use JSON;
  12
  13
  14 my $movie = shift @ARGV
  15         || 'www/media/video.ogv';
  16 #       || die "usage: $0 path/to/movie.ogv\n";
  17
  18 my $edl = "/dev/shm/edl";
  19 my $subtitles = $movie;
  20 $subtitles =~ s{\.\w+$}{.srt};
  21
  22 my $preroll = 3;
  23
  24 our $to_mplayer;
  25 our $from_mplayer;
  26 our $err_mplayer;
  27 our $prop = {};
  28
  29 my $pid = open3( $to_mplayer, $from_mplayer, $err_mplayer,
  30          'mplayer',
  31                 '-slave', '-idle',
  32                 '-quiet',
  33                 '-edlout', $edl,
  34                 '-osdlevel', 3,
  35 );
  36
  37 my $epfd = epoll_create(10);
  38
  39 epoll_ctl($epfd, EPOLL_CTL_ADD, fileno STDIN         , EPOLLIN  ) >= 0 || die $!;
  40 epoll_ctl($epfd, EPOLL_CTL_ADD, fileno $from_mplayer , EPOLLIN  ) >= 0 || die $!;
  41 #epoll_ctl($epfd, EPOLL_CTL_ADD, fileno $to_mplayer   , EPOLLOUT ) >= 0 || die $!;
  42
  43 sub load_movie {
  44         warn "$movie ", -s $movie, " bytes $edl\n";
  45         print $to_mplayer qq|loadfile "$movie"\n|;
  46         print $to_mplayer "get_property $_\n" foreach ( qw/metadata video_codec video_bitrate width height fps length/ );
  47 }
  48
  49
  50 my $term_id = `xdotool getwindowfocus`;
  51 our $mplayer_id;
  52
  53
  54 sub focus_mplayer {
  55         $mplayer_id ||= `xdotool search mplayer`;
  56         warn "focus_mplayer $mplayer_id\n";
  57         system "xdotool windowactivate $mplayer_id"
  58 }
  59
  60 sub focus_term {
  61         warn "focus_term $term_id\n";
  62         system "xdotool windowactivate $term_id";
  63 }
  64
  65 sub preroll {
  66         my ( $pos, $osd ) = @_;
  67         $osd =~ s{\W+}{ }gs;
  68         warn "PREROLL $pos $osd\n";
  69         print $to_mplayer "osd_show_text \"PREROLL $osd\" ", $preroll * 1000, "\n";
  70         my $to = $pos - $preroll;
  71         $to = 0 if $to < 0;
  72         print $to_mplayer "set_property time_pos $to\n";
  73         print $to_mplayer "get_property time_pos\n";
  74         print $to_mplayer "play\n";
  75 }
  76
  77
  78 $|=1;
  79
  80 my $line;
  81 my $repl;
  82
  83 sub repl {
  84         print "> ";
  85         my $cmd = <STDIN>;
  86         warn ">>> $cmd\n";
  87         print $to_mplayer $cmd;
  88 }
  89
  90
  91 our @subtitles;
  92
  93 sub html5tv {
  94         my $sync;
  95
  96         foreach my $s ( @subtitles ) {
  97                 push @{ $sync->{htmlEvents}->{'#subtitle'} }, {
  98                         startTime => $s->[0],
  99                         endTime => $s->[1],
 100                         html => $s->[2],
 101                 };
 102                 next unless $s->[2] =~ m{\[(\d+)\]};
 103
 104                 my $res = ( $prop->{width} / 4 ) . 'x' . ( $prop->{height} / 4 );
 105
 106                 push @{ $sync->{customEvents} }, {
 107                         startTime => $s->[0],
 108                         endTime => $s->[1],
 109                         action => 'chapterChange',
 110                         args => {
 111                                 carousel => 'theCarousel',
 112                                 id => "chapter$1",
 113                                 index => $1,
 114                                 title => $s->[2],
 115                                 description => $s->[2],
 116                                 src => sprintf('media/s/%s/p%08d.jpg', $res, $1),
 117                                 href => '',
 118                         },
 119                 }
 120         }
 121
 122         my $html5tv = {
 123                 sync => $sync,
 124                 video => $prop,
 125         };
 126
 127         if ( $prop->{width} && $prop->{height} ) {
 128                 foreach my $factor ( 4, 2, 1 ) {
 129                         my $w = $prop->{width}  / $factor;
 130                         my $h = $prop->{height} / $factor;
 131
 132                         $html5tv->{slide} ||= {
 133                                 width  => $w,
 134                                 height => $h,
 135                         };
 136
 137                         my $path = "www/media/s/${w}x${h}";
 138                         if ( ! -d $path ) {
 139                                 mkdir $path;
 140                                 warn "created $path\n";
 141                         }
 142                 }
 143         }
 144
 145         warn "html5tv ", dump $html5tv;
 146
 147         my $sync_path = 'www/media/video.js';
 148         write_file $sync_path, "var html5tv = " . to_json($html5tv) . " ;\n";
 149         warn "sync $sync_path ", -s $sync_path, " bytes\n";
 150
 151
 152 }
 153
 154
 155 sub t_srt {
 156         my $t = shift;
 157         my $hh = int( $t / 3600 );
 158         $t -= $hh * 3600;
 159         my $mm = int( $t / 60 );
 160         $t -= $mm * 60;
 161         my $srt = sprintf "%02d:%02d:%04.1f", $hh, $mm, $t;
 162         $srt =~ s{\.}{,};
 163         return $srt;
 164 }
 165
 166 sub save_subtitles {
 167         my $nr = 0;
 168         my $srt = "\n";
 169         foreach my $s ( @subtitles ) {
 170                 $srt .= $nr++ . "\n"
 171                         . t_srt( $s->[0] ) . " --> " . t_srt( $s->[1] ) . "\n"
 172                         . $s->[2] . "\n\n"
 173                         ;
 174         }
 175         warn $srt;
 176
 177         write_file $subtitles, $srt;
 178         YAML::DumpFile "$subtitles.yaml", sort { $a->[0] <=> $b->[0] } @subtitles;
 179
 180         print $to_mplayer "sub_remove\n";
 181         print $to_mplayer qq|sub_load "$subtitles"\n|;
 182         print $to_mplayer "sub_select 1\n";
 183
 184         html5tv;
 185 }
 186
 187 sub load_subtitles {
 188         @subtitles = YAML::LoadFile "$subtitles.yaml";
 189         warn "subtitles ", dump @subtitles;
 190         save_subtitles;
 191 }
 192
 193 load_subtitles if -e "$subtitles.yaml";
 194
 195 sub edit_subtitles {
 196         print $to_mplayer qq|pause\n|;
 197         focus_term;
 198         system( qq|vi "$subtitles.yaml"| ) == 0 and load_subtitles;
 199         focus_mplayer;
 200 }
 201
 202 sub add_subtitle {
 203         print $to_mplayer qq|pause\n|;
 204
 205         focus_term;
 206
 207         warn "subtitles ", dump( @subtitles );
 208         print "## ";
 209         my $line = <STDIN>;
 210         $subtitles[ $#subtitles ]->[2] = $line if defined $line;
 211
 212         save_subtitles;
 213
 214         focus_mplayer;
 215
 216         preroll $subtitles[ $#subtitles ]->[0], $line;
 217 }
 218
 219 sub time_pos {
 220         print $to_mplayer qq|get_property time_pos\n|;
 221         my $pos = <$from_mplayer>;
 222         if ( $pos =~ m{^ANS_time_pos=(\d+\.\d+)} ) {
 223                 warn "# time_pos $1\n";
 224                 return $1;
 225         }
 226 }
 227
 228 sub sub_fmt {
 229         my $s = shift;
 230         sprintf "%1.5f - %1.5f %s %s\n", @$s, join(' | ',@_);
 231 }
 232
 233 sub prev_subtitle {
 234         my $pos = time_pos;
 235         my $s = ( grep { $_->[0] < $pos } @subtitles )[0];
 236         warn "<<<< subtitle ", sub_fmt $s;
 237         preroll $s->[0], $s->[2];
 238 #       print $to_mplayer "set_property time_pos $s->[0]\n";
 239 }
 240
 241 sub next_subtitle {
 242         my $pos = time_pos + $preroll;
 243         my $s = ( grep { $_->[0] > $pos } @subtitles )[0];
 244         warn ">>>> subtitle ", sub_fmt $s;
 245         preroll $s->[0], $s->[2];
 246 #       print $to_mplayer "set_property time_pos $s->[0]\n";
 247 }
 248
 249 sub current_subtitle {
 250         my $callback = shift;
 251         my $pos = time_pos;
 252         my $visible;
 253         foreach my $nr ( 0 .. $#subtitles ) {
 254                 my $s = $subtitles[$nr];
 255                 if ( $s->[0] <= $pos && $s->[1] >= $pos ) {
 256                         warn sub_fmt $s, $pos;
 257                         $visible = $nr;
 258                         $callback->( $visible, $pos ) if $callback;
 259                         return ( $visible, $pos );
 260                 }
 261         }
 262         warn "# $pos no visible subtitle\n";
 263 }
 264
 265 sub move_subtitle {
 266         my $offset = shift;
 267         current_subtitle( sub {
 268                 my ( $nr, $pos ) = @_;
 269                 my $new_start = $subtitles[$nr]->[0] += $offset;
 270                 warn "subtitle $nr $pos $offset $new_start\n";
 271                 save_subtitles;
 272                 preroll $new_start, "$pos $offset $new_start";
 273         } );
 274 }
 275
 276
 277
 278 # XXX main epool loop
 279
 280 load_movie;
 281
 282 while ( my $events = epoll_wait($epfd, 10, 1000) ) { # Max 10 events returned, 1s timeout
 283
 284         warn "no events" unless $events;
 285
 286         foreach my $e ( @$events ) {
 287 #               warn "# event: ", dump($e), $/;
 288
 289                 my $fileno = $e->[0];
 290
 291                 if ( $fileno == fileno STDIN ) {
 292                         my $chr;
 293                         sysread STDIN, $chr, 1;
 294                         print $chr;
 295                 } elsif ( $fileno == fileno $from_mplayer ) {
 296                         my $chr;
 297                         sysread $from_mplayer, $chr, 1;
 298                         print $chr;
 299
 300                         if ( $chr =~ m{[\n\r]} ) {
 301
 302                                 exit if $line =~ m{Exiting};
 303
 304                                 if ( $line =~ m{ANS_(\w+)=(\S+)} ) {
 305                                         $prop->{$1} = $2;
 306                                         warn "prop $1 = $2\n";
 307                                 } elsif ( $line =~ m{No bind found for key '(.+)'} ) {
 308
 309                                           $1 eq 'c'  ? repl
 310                                         : $1 eq ','  ? add_subtitle
 311                                         : $1 eq 'F1' ? prev_subtitle
 312                                         : $1 eq 'F2' ? move_subtitle( -0.3 )
 313                                         : $1 eq 'F3' ? move_subtitle( +0.3 )
 314                                         : $1 eq 'F4' ? next_subtitle
 315                                         : $1 eq 'F2' ? move_subtitle( -0.3 )
 316                                         : $1 eq 'F3' ? move_subtitle( +0.3 )
 317                                         : $1 eq 'F9' ? add_subtitle
 318                                         : $1 eq 'F12' ? edit_subtitles
 319                                         : warn "CUSTOM $1\n"
 320                                         ;
 321
 322                                 } elsif ( $line =~ m{EDL}i ) {
 323
 324                                         print $to_mplayer qq|osd_show_text "$line"\n|;
 325
 326                                         if ( my $pos = time_pos ) {
 327                                                 if ( $line =~ m{start}i ) {
 328                                                         push @subtitles, [ $pos, $pos, '-' ];
 329                                                 } else {
 330                                                         $subtitles[ $#subtitles ]->[1] = $pos;
 331                                                 }
 332                                         }
 333                                 }
 334
 335                                 $line = '';
 336                         } else {
 337                                 $line .= $chr;
 338                         }
 339
 340
 341                 } elsif ( $fileno == fileno $to_mplayer ) {
 342 #                       warn "command";
 343                 } else {
 344                         die "invalid fileno $fileno";
 345                 }
 346         }
 347
 348 }
 349