bin/mplayer.pl

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5
   6 use IPC::Open3 qw(open3);
   7 use IO::Epoll;
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use YAML;
  11 use JSON;
  12
  13
  14 my $movie = shift @ARGV
  15         || 'www/media/video.ogv';
  16 #       || die "usage: $0 path/to/movie.ogv\n";
  17
  18 my $edl = "/dev/shm/edl";
  19 my $subtitles = $movie;
  20 $subtitles =~ s{\.\w+$}{.srt};
  21
  22 my $preroll = 3;
  23
  24 our $to_mplayer;
  25 our $from_mplayer;
  26 our $err_mplayer;
  27 our $prop = {};
  28
  29 my $pid = open3( $to_mplayer, $from_mplayer, $err_mplayer,
  30          'mplayer',
  31                 '-slave', '-idle',
  32                 '-quiet',
  33                 '-edlout', $edl,
  34                 '-osdlevel', 3,
  35 );
  36
  37 my $epfd = epoll_create(10);
  38
  39 epoll_ctl($epfd, EPOLL_CTL_ADD, fileno STDIN         , EPOLLIN  ) >= 0 || die $!;
  40 epoll_ctl($epfd, EPOLL_CTL_ADD, fileno $from_mplayer , EPOLLIN  ) >= 0 || die $!;
  41 #epoll_ctl($epfd, EPOLL_CTL_ADD, fileno $to_mplayer   , EPOLLOUT ) >= 0 || die $!;
  42
  43 sub load_movie {
  44         warn "$movie ", -s $movie, " bytes $edl\n";
  45         print $to_mplayer qq|loadfile "$movie"\n|;
  46         print $to_mplayer "get_property $_\n" foreach ( qw/metadata video_codec video_bitrate width height fps length/ );
  47 }
  48
  49
  50 my $term_id = `xdotool getwindowfocus`;
  51 our $mplayer_id;
  52
  53
  54 sub focus_mplayer {
  55         $mplayer_id ||= `xdotool search mplayer`;
  56         warn "focus_mplayer $mplayer_id\n";
  57         system "xdotool windowactivate $mplayer_id"
  58 }
  59
  60 sub focus_term {
  61         warn "focus_term $term_id\n";
  62         system "xdotool windowactivate $term_id";
  63 }
  64
  65 sub preroll {
  66         my ( $pos, $osd ) = @_;
  67         $osd =~ s{\W+}{ }gs;
  68         warn "PREROLL $pos $osd\n";
  69         print $to_mplayer "osd_show_text \"PREROLL $osd\" ", $preroll * 1000, "\n";
  70         my $to = $pos - $preroll;
  71         $to = 0 if $to < 0;
  72         print $to_mplayer "set_property time_pos $to\n";
  73         print $to_mplayer "get_property time_pos\n";
  74         print $to_mplayer "play\n";
  75 }
  76
  77
  78 $|=1;
  79
  80 my $line;
  81 my $repl;
  82
  83 sub repl {
  84         print "> ";
  85         my $cmd = <STDIN>;
  86         warn ">>> $cmd\n";
  87         print $to_mplayer $cmd;
  88 }
  89
  90
  91 our @subtitles;
  92
  93 sub html5tv {
  94         my $sync;
  95
  96         my @slide_t;
  97
  98         my @videos;
  99
 100         foreach my $s ( @subtitles ) {
 101                 push @{ $sync->{htmlEvents}->{'#subtitle'} }, {
 102                         startTime => $s->[0],
 103                         endTime   => $s->[1],
 104                         html      => $s->[2],
 105                 };
 106
 107                 if ( $s->[2] =~ m{video:(.+)} ) {
 108                         my $video = $1;
 109                         my $path = "www/media/$video";
 110                         if ( ! -e $path ) {
 111                                 warn "MISSING $path: $!\n";
 112                         } else {
 113                                 push @videos, $video;
 114                         }
 115                 }
 116
 117                 next unless $s->[2] =~ m{\[(\d+)\]};
 118
 119                 my $res = ( $prop->{width} / 4 ) . 'x' . ( $prop->{height} / 4 );
 120
 121                 push @{ $sync->{customEvents} }, {
 122                         startTime => $s->[0],
 123                         endTime   => $s->[1],
 124                         action    => 'chapterChange',
 125                         args => {
 126                                 carousel => 'theCarousel',
 127                                 id => "chapter$1",
 128                                 index => $1,
 129                                 title => $s->[2],
 130                                 description => $s->[2],
 131                                 src => sprintf('media/s/%s/p%03d.jpg', $res, $1),
 132                                 href => '',
 133                         },
 134                 };
 135
 136                 push @slide_t, $s->[0];
 137         }
 138
 139         my $res = $prop->{width} . 'x' . $prop->{height};
 140
 141         foreach ( 0 .. $#slide_t ) {
 142                 push @{ $sync->{htmlEvents}->{'#slide'} }, {
 143                         startTime => $slide_t[$_],
 144                         endTime   => $slide_t[$_ + 1] || $prop->{length},
 145                         html      => sprintf( '<img src=media/s/%s/p%03d.jpg>', $res, $_ + 1 ),
 146                 };
 147         }
 148
 149         my $html5tv = {
 150                 sync => $sync,
 151                 video => $prop,
 152         };
 153
 154         if ( $prop->{width} && $prop->{height} ) {
 155                 foreach my $factor ( 4, 2, 1 ) {
 156                         my $w = $prop->{width}  / $factor;
 157                         my $h = $prop->{height} / $factor;
 158
 159                         $html5tv->{slide} ||= {
 160                                 width  => $w,
 161                                 height => $h,
 162                         };
 163
 164                         my $path = "www/media/s/${w}x${h}";
 165                         if ( ! -d $path ) {
 166                                 mkdir $path;
 167                                 warn "created $path\n";
 168                         }
 169                 }
 170         }
 171
 172         $html5tv->{video_tags} =
 173                 join("\n",
 174                         map {
 175                                 qq|
 176                                         <div id="$_">
 177                                                 <video controls="controls" width="$html5tv->{slide}->{width}px" height="$html5tv->{slide}->{height}px">
 178                                                 <source src="media/$_" />
 179                                                 </video>
 180                                         </div>
 181                                 |
 182                         } @videos
 183                 )
 184         ;
 185
 186         warn "html5tv ", dump $html5tv;
 187
 188         my $sync_path = 'www/media/video.js';
 189         write_file $sync_path, "var html5tv = " . to_json($html5tv) . " ;\n";
 190         warn "sync $sync_path ", -s $sync_path, " bytes\n";
 191
 192         my $html = read_file 'www/tv.html';
 193         $html =~ s|{([^}]+)}|my $n = $1; $n =~ s(\.)(}->{)g; eval "\$html5tv->{$n}"|egs ||
 194                 warn "no interpolation in template!";
 195
 196         write_file 'www/media.html', $html;
 197
 198 }
 199
 200
 201 sub t_srt {
 202         my $t = shift;
 203         my $hh = int( $t / 3600 );
 204         $t -= $hh * 3600;
 205         my $mm = int( $t / 60 );
 206         $t -= $mm * 60;
 207         my $srt = sprintf "%02d:%02d:%04.1f", $hh, $mm, $t;
 208         $srt =~ s{\.}{,};
 209         return $srt;
 210 }
 211
 212 sub save_subtitles {
 213         my $nr = 0;
 214         my $srt = "\n";
 215         foreach my $s ( @subtitles ) {
 216                 $srt .= $nr++ . "\n"
 217                         . t_srt( $s->[0] ) . " --> " . t_srt( $s->[1] ) . "\n"
 218                         . $s->[2] . "\n\n"
 219                         ;
 220         }
 221         warn $srt;
 222
 223         write_file $subtitles, $srt;
 224         YAML::DumpFile "$subtitles.yaml", sort { $a->[0] <=> $b->[0] } @subtitles;
 225
 226         print $to_mplayer "sub_remove\n";
 227         print $to_mplayer qq|sub_load "$subtitles"\n|;
 228         print $to_mplayer "sub_select 1\n";
 229
 230         html5tv;
 231 }
 232
 233 sub load_subtitles {
 234         @subtitles = YAML::LoadFile "$subtitles.yaml";
 235         warn "subtitles ", dump @subtitles;
 236         save_subtitles;
 237 }
 238
 239 load_subtitles if -e "$subtitles.yaml";
 240
 241 sub edit_subtitles {
 242         print $to_mplayer qq|pause\n|;
 243         focus_term;
 244         system( qq|vi "$subtitles.yaml"| ) == 0 and load_subtitles;
 245         focus_mplayer;
 246 }
 247
 248 sub add_subtitle {
 249         print $to_mplayer qq|pause\n|;
 250
 251         focus_term;
 252
 253         warn "subtitles ", dump( @subtitles );
 254         print "## ";
 255         my $line = <STDIN>;
 256         $subtitles[ $#subtitles ]->[2] = $line if defined $line;
 257
 258         save_subtitles;
 259
 260         focus_mplayer;
 261
 262         preroll $subtitles[ $#subtitles ]->[0], $line;
 263 }
 264
 265 sub time_pos {
 266         print $to_mplayer qq|get_property time_pos\n|;
 267         my $pos = <$from_mplayer>;
 268         if ( $pos =~ m{^ANS_time_pos=(\d+\.\d+)} ) {
 269                 warn "# time_pos $1\n";
 270                 return $1;
 271         }
 272 }
 273
 274 sub sub_fmt {
 275         my $s = shift;
 276         sprintf "%1.5f - %1.5f %s %s\n", @$s, join(' | ',@_);
 277 }
 278
 279 sub prev_subtitle {
 280         my $pos = time_pos;
 281         my $s = ( grep { $_->[0] < $pos } @subtitles )[0];
 282         warn "<<<< subtitle ", sub_fmt $s;
 283         preroll $s->[0], $s->[2];
 284 #       print $to_mplayer "set_property time_pos $s->[0]\n";
 285 }
 286
 287 sub next_subtitle {
 288         my $pos = time_pos + $preroll;
 289         my $s = ( grep { $_->[0] > $pos } @subtitles )[0];
 290         warn ">>>> subtitle ", sub_fmt $s;
 291         preroll $s->[0], $s->[2];
 292 #       print $to_mplayer "set_property time_pos $s->[0]\n";
 293 }
 294
 295 sub current_subtitle {
 296         my $callback = shift;
 297         my $pos = time_pos;
 298         my $visible;
 299         foreach my $nr ( 0 .. $#subtitles ) {
 300                 my $s = $subtitles[$nr];
 301                 if ( $s->[0] <= $pos && $s->[1] >= $pos ) {
 302                         warn sub_fmt $s, $pos;
 303                         $visible = $nr;
 304                         $callback->( $visible, $pos ) if $callback;
 305                         return ( $visible, $pos );
 306                 }
 307         }
 308         warn "# $pos no visible subtitle\n";
 309 }
 310
 311 sub move_subtitle {
 312         my $offset = shift;
 313         current_subtitle( sub {
 314                 my ( $nr, $pos ) = @_;
 315                 my $new_start = $subtitles[$nr]->[0] += $offset;
 316                 warn "subtitle $nr $pos $offset $new_start\n";
 317                 save_subtitles;
 318                 preroll $new_start, "$pos $offset $new_start";
 319         } );
 320 }
 321
 322
 323
 324 # XXX main epool loop
 325
 326 load_movie;
 327
 328 while ( my $events = epoll_wait($epfd, 10, 1000) ) { # Max 10 events returned, 1s timeout
 329
 330         warn "no events" unless $events;
 331
 332         foreach my $e ( @$events ) {
 333 #               warn "# event: ", dump($e), $/;
 334
 335                 my $fileno = $e->[0];
 336
 337                 if ( $fileno == fileno STDIN ) {
 338                         my $chr;
 339                         sysread STDIN, $chr, 1;
 340                         print $chr;
 341                 } elsif ( $fileno == fileno $from_mplayer ) {
 342                         my $chr;
 343                         sysread $from_mplayer, $chr, 1;
 344                         print $chr;
 345
 346                         if ( $chr =~ m{[\n\r]} ) {
 347
 348                                 exit if $line =~ m{Exiting};
 349
 350                                 if ( $line =~ m{ANS_(\w+)=(\S+)} ) {
 351                                         $prop->{$1} = $2;
 352                                         warn "prop $1 = $2\n";
 353                                 } elsif ( $line =~ m{No bind found for key '(.+)'} ) {
 354
 355                                         # XXX keyboard shortcuts
 356
 357                                           $1 eq 'c'  ? repl
 358                                         : $1 eq ','  ? add_subtitle
 359                                         : $1 eq 'F1' ? prev_subtitle
 360                                         : $1 eq 'F2' ? move_subtitle( -0.3 )
 361                                         : $1 eq 'F3' ? move_subtitle( +0.3 )
 362                                         : $1 eq 'F4' ? next_subtitle
 363                                         : $1 eq 'F2' ? move_subtitle( -0.3 )
 364                                         : $1 eq 'F3' ? move_subtitle( +0.3 )
 365                                         : $1 eq 'F9' ? add_subtitle
 366                                         : $1 eq 'F12' ? edit_subtitles
 367                                         : warn "CUSTOM $1\n"
 368                                         ;
 369
 370                                 } elsif ( $line =~ m{EDL}i ) {
 371
 372                                         print $to_mplayer qq|osd_show_text "$line"\n|;
 373
 374                                         if ( my $pos = time_pos ) {
 375                                                 if ( $line =~ m{start}i ) {
 376                                                         push @subtitles, [ $pos, $pos, '-' ];
 377                                                 } else {
 378                                                         $subtitles[ $#subtitles ]->[1] = $pos;
 379                                                 }
 380                                         }
 381                                 }
 382
 383                                 $line = '';
 384                         } else {
 385                                 $line .= $chr;
 386                         }
 387
 388
 389                 } elsif ( $fileno == fileno $to_mplayer ) {
 390 #                       warn "command";
 391                 } else {
 392                         die "invalid fileno $fileno";
 393                 }
 394         }
 395
 396 }
 397