bin/mplayer.pl

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5
   6 use IPC::Open3 qw(open3);
   7 use IO::Epoll;
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use YAML;
  11 use JSON;
  12
  13
  14 my $movie = shift @ARGV
  15         || 'media/lpc-2009-network-namespaces/Pavel Emelyanov.ogg';
  16 #       || die "usage: $0 path/to/movie.ogv\n";
  17
  18 my $edl = "/dev/shm/edl";
  19 my $subtitles = $movie;
  20 $subtitles =~ s{\.\w+$}{.srt};
  21
  22 my $preroll = 3;
  23
  24 our $to_mplayer;
  25 our $from_mplayer;
  26 our $err_mplayer;
  27
  28 my $pid = open3( $to_mplayer, $from_mplayer, $err_mplayer,
  29          'mplayer',
  30                 '-slave', '-idle',
  31                 '-quiet',
  32                 '-edlout', $edl,
  33                 '-osdlevel', 3,
  34 );
  35
  36 my $epfd = epoll_create(10);
  37
  38 epoll_ctl($epfd, EPOLL_CTL_ADD, fileno STDIN         , EPOLLIN  ) >= 0 || die $!;
  39 epoll_ctl($epfd, EPOLL_CTL_ADD, fileno $from_mplayer , EPOLLIN  ) >= 0 || die $!;
  40 #epoll_ctl($epfd, EPOLL_CTL_ADD, fileno $to_mplayer   , EPOLLOUT ) >= 0 || die $!;
  41
  42 sub load_movie {
  43         warn "$movie ", -s $movie, " bytes $edl\n";
  44         print $to_mplayer qq|loadfile "$movie"\n|;
  45         print $to_mplayer "get_property $_\n" foreach ( qw/metadata video_codec video_bitrate width height fps/ );
  46 }
  47
  48
  49 my $term_id = `xdotool getwindowfocus`;
  50 our $mplayer_id;
  51
  52
  53 sub focus_mplayer {
  54         $mplayer_id ||= `xdotool search mplayer`;
  55         warn "focus_mplayer $mplayer_id\n";
  56         system "xdotool windowactivate $mplayer_id"
  57 }
  58
  59 sub focus_term {
  60         warn "focus_term $term_id\n";
  61         system "xdotool windowactivate $term_id";
  62 }
  63
  64 sub preroll {
  65         my $pos = shift;
  66         my $to = $pos - $preroll;
  67         $to = 0 if $to < 0;
  68         warn "$pos PREROLL $to\n";
  69         print $to_mplayer "set_property time_pos $to\n";
  70         print $to_mplayer "play\n";
  71 }
  72
  73
  74 $|=1;
  75
  76 my $line;
  77 my $repl;
  78
  79 sub repl {
  80         print "> ";
  81         my $cmd = <STDIN>;
  82         warn ">>> $cmd\n";
  83         print $to_mplayer $cmd;
  84 }
  85
  86
  87 our $prop;
  88 our @subtitles;
  89
  90 sub html5tv {
  91         my $sync;
  92
  93         foreach my $s ( @subtitles ) {
  94                 push @{ $sync->{htmlEvents}->{'#subtitle'} }, {
  95                         startTime => $s->[0],
  96                         endTime => $s->[1],
  97                         html => $s->[2],
  98                 };
  99                 next unless $s->[2] =~ m{\[(\d+)\]};
 100
 101                 push @{ $sync->{customEvents} }, {
 102                         startTime => $s->[0],
 103                         endTime => $s->[1],
 104                         action => 'chapterChange',
 105                         args => {
 106                                 carousel => 'theCarousel',
 107                                 id => "chapter$1",
 108                                 index => $1,
 109                                 title => $s->[2],
 110                                 description => $s->[2],
 111                                 src => sprintf('s/117x66/p%08d.jpg', $1),
 112                                 href => '',
 113                         },
 114                 }
 115         }
 116
 117         warn "# sync ", dump $sync;
 118
 119         my $json = to_json $sync;
 120         my $sync_path = 'www/video.js';
 121         write_file $sync_path, "var video_sync = $json;\n";
 122         warn "sync $sync_path ", -s $sync_path, " bytes\n";
 123
 124         warn "prop ", dump $prop;
 125 }
 126
 127
 128 sub t_srt {
 129         my $t = shift;
 130         my $hh = int( $t / 3600 );
 131         $t -= $hh * 3600;
 132         my $mm = int( $t / 60 );
 133         $t -= $mm * 60;
 134         my $srt = sprintf "%02d:%02d:%04.1f", $hh, $mm, $t;
 135         $srt =~ s{\.}{,};
 136         return $srt;
 137 }
 138
 139 sub save_subtitles {
 140         my $nr = 0;
 141         my $srt = "\n";
 142         foreach my $s ( @subtitles ) {
 143                 $srt .= $nr++ . "\n"
 144                         . t_srt( $s->[0] ) . " --> " . t_srt( $s->[1] ) . "\n"
 145                         . $s->[2] . "\n\n"
 146                         ;
 147         }
 148         warn $srt;
 149
 150         write_file $subtitles, $srt;
 151         YAML::DumpFile "$subtitles.yaml", @subtitles;
 152
 153         print $to_mplayer "sub_remove\n";
 154         print $to_mplayer qq|sub_load "$subtitles"\n|;
 155         print $to_mplayer "sub_select 1\n";
 156
 157         html5tv;
 158 }
 159
 160 sub load_subtitles {
 161         @subtitles = YAML::LoadFile "$subtitles.yaml";
 162         warn "subtitles ", dump @subtitles;
 163         save_subtitles;
 164 }
 165
 166 load_subtitles if -e "$subtitles.yaml";
 167
 168 sub edit_subtitles {
 169         print $to_mplayer qq|pause\n|;
 170         focus_term;
 171         system( qq|vi "$subtitles.yaml"| ) == 0 and load_subtitles;
 172         focus_mplayer;
 173 }
 174
 175 sub add_subtitle {
 176         print $to_mplayer qq|pause\n|;
 177
 178         focus_term;
 179
 180         warn "subtitles ", dump( @subtitles );
 181         print "## ";
 182         my $line = <STDIN>;
 183         $subtitles[ $#subtitles ]->[2] = $line if defined $line;
 184
 185         save_subtitles;
 186
 187         focus_mplayer;
 188
 189         preroll $subtitles[ $#subtitles ]->[0];
 190 }
 191
 192 sub time_pos {
 193         print $to_mplayer qq|get_property time_pos\n|;
 194         my $pos = <$from_mplayer>;
 195         if ( $pos =~ m{^ANS_time_pos=(\d+\.\d+)} ) {
 196                 warn "# time_pos $1\n";
 197                 return $1;
 198         }
 199 }
 200
 201 sub sub_fmt {
 202         my $s = shift;
 203         sprintf "%1.5f - %1.5f %s %s\n", @$s, join(' | ',@_);
 204 }
 205
 206 sub prev_subtitle {
 207         my $pos = time_pos;
 208         my $s = ( grep { $_->[0] < $pos } @subtitles )[0];
 209         warn "<<<< subtitle ", sub_fmt $s;
 210         preroll $s->[0];
 211 #       print $to_mplayer "set_property time_pos $s->[0]\n";
 212 }
 213
 214 sub next_subtitle {
 215         my $pos = time_pos;
 216         my $s = ( grep { $_->[0] > $pos } @subtitles )[0];
 217         warn ">>>> subtitle ", sub_fmt $s;
 218         preroll $s->[0];
 219 #       print $to_mplayer "set_property time_pos $s->[0]\n";
 220 }
 221
 222 sub current_subtitle {
 223         my $callback = shift;
 224         my $pos = time_pos;
 225         my $visible;
 226         foreach my $nr ( 0 .. $#subtitles ) {
 227                 my $s = $subtitles[$nr];
 228                 if ( $s->[0] <= $pos && $s->[1] >= $pos ) {
 229                         warn sub_fmt $s, $pos;
 230                         $visible = $nr;
 231                         $callback->( $visible, $pos ) if $callback;
 232                         return ( $visible, $pos );
 233                 }
 234         }
 235         warn "# $pos no visible subtitle\n";
 236 }
 237
 238 sub move_subtitle {
 239         my $offset = shift;
 240         current_subtitle( sub {
 241                 my ( $nr, $pos ) = @_;
 242                 my $new_start = $subtitles[$nr]->[0] += $offset;
 243                 warn "subtitle $nr $pos $offset $new_start\n";
 244                 save_subtitles;
 245                 preroll $new_start;
 246         } );
 247 }
 248
 249
 250
 251 # XXX main epool loop
 252
 253 our $prop;
 254 load_movie;
 255
 256 while ( my $events = epoll_wait($epfd, 10, 1000) ) { # Max 10 events returned, 1s timeout
 257
 258         warn "no events" unless $events;
 259
 260         foreach my $e ( @$events ) {
 261 #               warn "# event: ", dump($e), $/;
 262
 263                 my $fileno = $e->[0];
 264
 265                 if ( $fileno == fileno STDIN ) {
 266                         my $chr;
 267                         sysread STDIN, $chr, 1;
 268                         print $chr;
 269                 } elsif ( $fileno == fileno $from_mplayer ) {
 270                         my $chr;
 271                         sysread $from_mplayer, $chr, 1;
 272                         print $chr;
 273
 274                         if ( $chr =~ m{[\n\r]} ) {
 275
 276                                 exit if $line =~ m{Exiting};
 277
 278                                 if ( $line =~ m{ANS_(\w+)=(\S+)} ) {
 279                                         $prop->{$1} = $2;
 280                                         warn "prop $1 = $2\n";
 281                                 } elsif ( $line =~ m{No bind found for key '(.+)'} ) {
 282
 283                                           $1 eq 'c'  ? repl
 284                                         : $1 eq ','  ? add_subtitle
 285                                         : $1 eq 'F1' ? prev_subtitle
 286                                         : $1 eq 'F2' ? move_subtitle( -0.3 )
 287                                         : $1 eq 'F3' ? move_subtitle( +0.3 )
 288                                         : $1 eq 'F4' ? next_subtitle
 289                                         : $1 eq 'F2' ? move_subtitle( -0.3 )
 290                                         : $1 eq 'F3' ? move_subtitle( +0.3 )
 291                                         : $1 eq 'F9' ? add_subtitle
 292                                         : $1 eq 'F12' ? edit_subtitles
 293                                         : warn "CUSTOM $1\n"
 294                                         ;
 295
 296                                 } elsif ( $line =~ m{EDL}i ) {
 297
 298                                         print $to_mplayer qq|osd_show_text "$line"\n|;
 299
 300                                         if ( my $pos = time_pos ) {
 301                                                 if ( $line =~ m{start}i ) {
 302                                                         push @subtitles, [ $pos, $pos, '-' ];
 303                                                 } else {
 304                                                         $subtitles[ $#subtitles ]->[1] = $pos;
 305                                                 }
 306                                         }
 307                                 }
 308
 309                                 $line = '';
 310                         } else {
 311                                 $line .= $chr;
 312                         }
 313
 314
 315                 } elsif ( $fileno == fileno $to_mplayer ) {
 316 #                       warn "command";
 317                 } else {
 318                         die "invalid fileno $fileno";
 319                 }
 320         }
 321
 322 }
 323