catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # $Header$
   6 #
   7 # Copyright 2006 LibLime
   8 #
   9 # This file is part of Koha
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along with
  21 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  22 # Suite 330, Boston, MA  02111-1307 USA
  23
  24 =head1 NAME
  25
  26 search - a search script for finding records in a Koha system (Version 3)
  27
  28 =head1 OVERVIEW
  29
  30 This script utilizes a new search API for Koha 3. It is designed to be
  31 simple to use and configure, yet capable of performing feats like stemming,
  32 field weighting, relevance ranking, support for multiple  query language
  33 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  34 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  35 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  36
  37 The API as represented in this script is mostly sound, even if the individual
  38 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  39 free to disagree :-)
  40
  41 I will attempt to describe what is happening at each part of this script.
  42 -- Joshua Ferraro <jmf AT liblime DOT com>
  43
  44 =head2 INTRO
  45
  46 This script performs two functions:
  47
  48 =over
  49
  50 =item 1. interacts with Koha to retrieve and display the results of a search
  51
  52 =item 2. loads the advanced search page
  53
  54 =back
  55
  56 These two functions share many of the same variables and modules, so the first
  57 task is to load what they have in common and determine which template to use.
  58 Once determined, proceed to only load the variables and procedures necessary
  59 for that function.
  60
  61 =head2 LOADING ADVANCED SEARCH PAGE
  62
  63 This is fairly straightforward, and I won't go into detail ;-)
  64
  65 =head2 PERFORMING A SEARCH
  66
  67 If we're performing a search, this script  performs three primary
  68 operations:
  69
  70 =over
  71
  72 =item 1. builds query strings (yes, plural)
  73
  74 =item 2. perform the search and return the results array
  75
  76 =item 3. build the HTML for output to the template
  77
  78 =back
  79
  80 There are several additional secondary functions performed that I will
  81 not cover in detail.
  82
  83 =head3 1. Building Query Strings
  84
  85 There are several types of queries needed in the process of search and retrieve:
  86
  87 =over
  88
  89 =item 1 $query - the fully-built query passed to zebra
  90
  91 This is the most complex query that needs to be built. The original design goal
  92 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  93 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  94 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  95 I'll try to flesh out this section to better explain.
  96
  97 This query incorporates query profiles that aren't compatible with most non-Zebra
  98 Z39.50 targets to acomplish the field weighting and relevance ranking.
  99
 100 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 101 stemming, etc., suitable to pass off to other search targets
 102
 103 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 104 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 105
 106 =item 3 $query_cgi - passed to the template / saved for future refinements of
 107 the query (by user)
 108
 109 This is a simple string that completely expresses the query as a CGI string that
 110 can be used for future refinements of the query or as a part of a history feature.
 111
 112 =item 4 $query_desc - Human search description - what the user sees in search
 113 feedback area
 114
 115 This is a simple string that is human readable. It will contain '=', ',', etc.
 116
 117 =back
 118
 119 =head3 2. Perform the Search
 120
 121 This section takes the query strings and performs searches on the named servers,
 122 including the Koha Zebra server, stores the results in a deeply nested object,
 123 builds 'faceted results', and returns these objects.
 124
 125 =head3 3. Build HTML
 126
 127 The final major section of this script takes the objects collected thusfar and
 128 builds the HTML for output to the template and user.
 129
 130 =head3 Additional Notes
 131
 132 Not yet completed...
 133
 134 =cut
 135
 136 use strict;            # always use
 137
 138 ## STEP 1. Load things that are used in both search page and
 139 # results page and decide which template to load, operations
 140 # to perform, etc.
 141
 142 ## load Koha modules
 143 use C4::Context;
 144 use C4::Output;
 145 use C4::Auth;
 146 use C4::Search;
 147 use C4::Languages qw(getAllLanguages);
 148 use C4::Koha;
 149 use POSIX qw(ceil floor);
 150 use C4::Branch; # GetBranches
 151
 152 # create a new CGI object
 153 # FIXME: no_undef_params needs to be tested
 154 use CGI qw('-no_undef_params');
 155 my $cgi = new CGI;
 156
 157 my ($template,$borrowernumber,$cookie);
 158
 159 # decide which template to use
 160 my $template_name;
 161 my $template_type;
 162 my @params = $cgi->param("limit");
 163 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 164     $template_name = 'catalogue/results.tmpl';
 165 }
 166 else {
 167     $template_name = 'catalogue/advsearch.tmpl';
 168     $template_type = 'advsearch';
 169 }
 170 # load the template
 171 ($template, $borrowernumber, $cookie) = get_template_and_user({
 172     template_name => $template_name,
 173     query => $cgi,
 174     type => "intranet",
 175     authnotrequired => 0,
 176     flagsrequired   => { catalogue => 1 },
 177     }
 178 );
 179 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 180     $template->param('UNIMARC' => 1);
 181 }
 182
 183 ## URI Re-Writing
 184 # Deprecated, but preserved because it's interesting :-)
 185 # The same thing can be accomplished with mod_rewrite in
 186 # a more elegant way
 187 #
 188 #my $rewrite_flag;
 189 #my $uri = $cgi->url(-base => 1);
 190 #my $relative_url = $cgi->url(-relative=>1);
 191 #$uri.="/".$relative_url."?";
 192 #warn "URI:$uri";
 193 #my @cgi_params_list = $cgi->param();
 194 #my $url_params = $cgi->Vars;
 195 #
 196 #for my $each_param_set (@cgi_params_list) {
 197 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 198 #}
 199 #warn "New URI:$uri";
 200 # Only re-write a URI if there are params or if it already hasn't been re-written
 201 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 202 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 203 #                            -cookie => $cookie);
 204 #    exit;
 205 #}
 206
 207 # load the branches
 208 my $branches = GetBranches();
 209 my @branch_loop;
 210
 211 # we need to know the borrower branch code to set a default branch
 212 my $borrowerbranchcode = C4::Context->userenv->{'branch'};
 213
 214 for my $branch_hash (sort { $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname} } keys %$branches) {
 215     # if independantbranches is activated, set the default branch to the borrower branch
 216     my $selected = (C4::Context->preference("independantbranches") and ($borrowerbranchcode eq $branch_hash)) ? 1 : undef;
 217     push @branch_loop, {value => "$branch_hash" , branchname => $branches->{$branch_hash}->{'branchname'}, selected => $selected};
 218 }
 219
 220 my $categories = GetBranchCategories(undef,'searchdomain');
 221
 222 $template->param(branchloop => \@branch_loop, searchdomainloop => $categories);
 223
 224 # load the Type stuff
 225 # load the Type stuff
 226 my $itemtypes = GetItemTypes;
 227 # the index parameter is different for item-level itemtypes
 228 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 229 my @itemtypesloop;
 230 my $selected=1;
 231 my $cnt;
 232 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes");
 233
 234 if (!$advanced_search_types or $advanced_search_types eq 'itemtypes') {                                                                 foreach my $thisitemtype ( sort {$itemtypes->{$a}->{'description'} cmp $itemtypes->{$b}->{'description'} } keys %$itemtypes ) {
 235     my %row =(  number=>$cnt++,
 236                 ccl => $itype_or_itemtype,
 237                 code => $thisitemtype,
 238                 selected => $selected,
 239                 description => $itemtypes->{$thisitemtype}->{'description'},
 240                 count5 => $cnt % 4,
 241                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 242             );
 243         $selected = 0 if ($selected) ;
 244         push @itemtypesloop, \%row;
 245     }
 246     $template->param(itemtypeloop => \@itemtypesloop);
 247 } else {
 248     my $advsearchtypes = GetAuthorisedValues($advanced_search_types);
 249     for my $thisitemtype (@$advsearchtypes) {
 250         my %row =(
 251                 number=>$cnt++,
 252                 ccl => $advanced_search_types,
 253                 code => $thisitemtype->{authorised_value},
 254                 selected => $selected,
 255                 description => $thisitemtype->{'lib'},
 256                 count5 => $cnt % 4,
 257                 imageurl=> getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 258             );
 259         push @itemtypesloop, \%row;
 260     }
 261     $template->param(itemtypeloop => \@itemtypesloop);
 262 }
 263
 264 # The following should only be loaded if we're bringing up the advanced search template
 265 if ( $template_type eq 'advsearch' ) {
 266
 267     # load the servers (used for searching -- to do federated searching, etc.)
 268     my $primary_servers_loop;# = displayPrimaryServers();
 269     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 270
 271     my $secondary_servers_loop;# = displaySecondaryServers();
 272     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 273
 274     # set the default sorting
 275     my $default_sort_by = C4::Context->preference('defaultSortField')."_".C4::Context->preference('defaultSortOrder')
 276         if (C4::Context->preference('OPACdefaultSortField') && C4::Context->preference('OPACdefaultSortOrder'));
 277     $template->param($default_sort_by => 1);
 278
 279     # determine what to display next to the search boxes (ie, boolean option
 280     # shouldn't appear on the first one, scan indexes should, adding a new
 281     # box should only appear on the last, etc.
 282     my @search_boxes_array;
 283     my $search_boxes_count = C4::Context->preference("OPACAdvSearchInputCount") | 3; # FIXME: should be a syspref
 284     for (my $i=1;$i<=$search_boxes_count;$i++) {
 285         # if it's the first one, don't display boolean option, but show scan indexes
 286         if ($i==1) {
 287             push @search_boxes_array,
 288                 {
 289                 scan_index => 1,
 290                 };
 291
 292         }
 293         # if it's the last one, show the 'add field' box
 294         elsif ($i==$search_boxes_count) {
 295             push @search_boxes_array,
 296                 {
 297                 boolean => 1,
 298                 add_field => 1,
 299                 };
 300         }
 301         else {
 302             push @search_boxes_array,
 303                 {
 304                 boolean => 1,
 305                 };
 306         }
 307
 308     }
 309     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 310                       search_boxes_loop => \@search_boxes_array);
 311
 312     # load the language limits (for search)
 313     my $languages_limit_loop = getAllLanguages();
 314     $template->param(search_languages_loop => $languages_limit_loop,);
 315
 316     # use the global setting by default
 317     if ( C4::Context->preference("expandedSearchOption") == 1) {
 318         $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 319     }
 320     # but let the user override it
 321     if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 322         $template->param( expanded_options => $cgi->param('expanded_options'));
 323     }
 324
 325     output_html_with_http_headers $cgi, $cookie, $template->output;
 326     exit;
 327 }
 328
 329 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 330
 331 # Fetch the paramater list as a hash in scalar context:
 332 #  * returns paramater list as tied hash ref
 333 #  * we can edit the values by changing the key
 334 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 335 my $params = $cgi->Vars;
 336
 337 # Params that can have more than one value
 338 # sort by is used to sort the query
 339 # in theory can have more than one but generally there's just one
 340 my @sort_by;
 341 my $default_sort_by = C4::Context->preference('defaultSortField')."_".C4::Context->preference('defaultSortOrder')
 342     if (C4::Context->preference('defaultSortField') && C4::Context->preference('defaultSortOrder'));
 343
 344 @sort_by = split("\0",$params->{'sort_by'}) if $params->{'sort_by'};
 345 $sort_by[0] = $default_sort_by unless $sort_by[0];
 346 foreach my $sort (@sort_by) {
 347     $template->param($sort => 1);
 348 }
 349 $template->param('sort_by' => $sort_by[0]);
 350
 351 # Use the servers defined, or just search our local catalog(default)
 352 my @servers;
 353 @servers = split("\0",$params->{'server'}) if $params->{'server'};
 354 unless (@servers) {
 355     #FIXME: this should be handled using Context.pm
 356     @servers = ("biblioserver");
 357     # @servers = C4::Context->config("biblioserver");
 358 }
 359 # operators include boolean and proximity operators and are used
 360 # to evaluate multiple operands
 361 my @operators;
 362 @operators = split("\0",$params->{'op'}) if $params->{'op'};
 363
 364 # indexes are query qualifiers, like 'title', 'author', etc. They
 365 # can be single or multiple parameters separated by comma: kw,right-Truncation
 366 my @indexes;
 367 @indexes = split("\0",$params->{'idx'});
 368
 369 # if a simple index (only one)  display the index used in the top search box
 370 if ($indexes[0] && !$indexes[1]) {
 371     $template->param("ms_".$indexes[0] => 1);}
 372
 373
 374 # an operand can be a single term, a phrase, or a complete ccl query
 375 my @operands;
 376 @operands = split("\0",$params->{'q'}) if $params->{'q'};
 377
 378 # limits are use to limit to results to a pre-defined category such as branch or language
 379 my @limits;
 380 @limits = split("\0",$params->{'limit'}) if $params->{'limit'};
 381
 382 if($params->{'multibranchlimit'}) {
 383 push @limits, join(" or ", map { "branch: $_ "}  @{GetBranchesInCategory($params->{'multibranchlimit'})}) ;
 384 }
 385
 386 my $available;
 387 foreach my $limit(@limits) {
 388     if ($limit =~/available/) {
 389         $available = 1;
 390     }
 391 }
 392 $template->param(available => $available);
 393
 394 # append year limits if they exist
 395 my $limit_yr;
 396 my $limit_yr_value;
 397 if ($params->{'limit-yr'}) {
 398     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 399         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 400         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 401         $limit_yr_value = "$yr1-$yr2";
 402     }
 403     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 404         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 405         $limit_yr_value = $params->{'limit-yr'};
 406     }
 407     push @limits,$limit_yr;
 408     #FIXME: Should return a error to the user, incorect date format specified
 409 }
 410
 411 # convert indexes and operands to corresponding parameter names for the z3950 search
 412 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 413 my $z3950par;
 414 my $indexes2z3950 = {
 415         kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 416         'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 417         ti=>'title', 'ti,phr'=>'title', se=>'title'
 418 };
 419 for (my $ii = 0; $ii < @operands; ++$ii)
 420 {
 421         my $name = $indexes2z3950->{$indexes[$ii]};
 422         if (defined $name && defined $operands[$ii])
 423         {
 424                 $z3950par ||= {};
 425                 $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 426         }
 427 }
 428
 429
 430 # Params that can only have one value
 431 my $scan = $params->{'scan'};
 432 my $count = C4::Context->preference('numSearchResults') || 20;
 433 my $results_per_page = $params->{'count'} || $count;
 434 my $offset = $params->{'offset'} || 0;
 435 my $page = $cgi->param('page') || 1;
 436 #my $offset = ($page-1)*$results_per_page;
 437 my $hits;
 438 my $expanded_facet = $params->{'expand'};
 439
 440 # Define some global variables
 441 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 442
 443 my @results;
 444
 445 ## I. BUILD THE QUERY
 446 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by,$scan);
 447
 448 ## parse the query_cgi string and put it into a form suitable for <input>s
 449 my @query_inputs;
 450 my $scan_index_to_use;
 451
 452 for my $this_cgi ( split('&',$query_cgi) ) {
 453     next unless $this_cgi;
 454     $this_cgi =~ m/(.*=)(.*)/;
 455     my $input_name = $1;
 456     my $input_value = $2;
 457     $input_name =~ s/=$//;
 458     push @query_inputs, { input_name => $input_name, input_value => $input_value };
 459         if ($input_name eq 'idx') {
 460         $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 461         }
 462 }
 463 $template->param ( QUERY_INPUTS => \@query_inputs,
 464                    scan_index_to_use => $scan_index_to_use );
 465
 466 ## parse the limit_cgi string and put it into a form suitable for <input>s
 467 my @limit_inputs;
 468 for my $this_cgi ( split('&',$limit_cgi) ) {
 469     next unless $this_cgi;
 470     # handle special case limit-yr
 471     if ($this_cgi =~ /yr,st-numeric/) {
 472         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 473         next;
 474     }
 475     $this_cgi =~ m/(.*=)(.*)/;
 476     my $input_name = $1;
 477     my $input_value = $2;
 478     $input_name =~ s/=$//;
 479     push @limit_inputs, { input_name => $input_name, input_value => $input_value };
 480 }
 481 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 482
 483 ## II. DO THE SEARCH AND GET THE RESULTS
 484 my $total; # the total results for the whole set
 485 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 486 my @results_array;
 487 my $results_hashref;
 488
 489 if (C4::Context->preference('NoZebra')) {
 490     $query=~s/yr(:|=)\s*([\d]{1,4})-([\d]{1,4})/(yr>=$2 and yr<=$3)/g;
 491     $simple_query=~s/yr\s*(:|=)([\d]{1,4})-([\d]{1,4})/(yr>=$2 and yr<=$3)/g;
 492     warn $query;
 493     eval {
 494         ($error, $results_hashref, $facets) = NZgetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 495     };
 496 } else {
 497     eval {
 498         ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 499     };
 500 }
 501 if ($@ || $error) {
 502     $template->param(query_error => $error.$@);
 503
 504     output_html_with_http_headers $cgi, $cookie, $template->output;
 505     exit;
 506 }
 507
 508 # At this point, each server has given us a result set
 509 # now we build that set for template display
 510 my @sup_results_array;
 511 for (my $i=0;$i<@servers;$i++) {
 512     my $server = $servers[$i];
 513     if ($server =~/biblioserver/) { # this is the local bibliographic server
 514         $hits = $results_hashref->{$server}->{"hits"};
 515         my $page = $cgi->param('page') || 0;
 516         my @newresults = searchResults( $query_desc,$hits,$results_per_page,$offset,$scan,@{$results_hashref->{$server}->{"RECORDS"}});
 517         $total = $total + $results_hashref->{$server}->{"hits"};
 518         ## If there's just one result, redirect to the detail page
 519         if ($total == 1) {
 520             my $biblionumber=@newresults[0]->{biblionumber};
 521                         my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 522                         my $views = { C4::Search::enabled_staff_search_views };
 523             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 524                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 525             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 526                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 527             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 528                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 529             } else {
 530                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 531             }
 532             exit;
 533         }
 534
 535
 536
 537         if ($hits) {
 538             $template->param(total => $hits);
 539             my $limit_cgi_not_availablity = $limit_cgi;
 540             $limit_cgi_not_availablity =~ s/&limit=available//g;
 541             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 542             $template->param(limit_cgi => $limit_cgi);
 543             $template->param(query_cgi => $query_cgi);
 544             $template->param(query_desc => $query_desc);
 545             $template->param(limit_desc => $limit_desc);
 546                         $template->param (z3950_search_params => C4::Search::z3950_search_args($query_desc));
 547             if ($query_desc || $limit_desc) {
 548                 $template->param(searchdesc => 1);
 549             }
 550             $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 551             $template->param(results_per_page =>  $results_per_page);
 552             $template->param(SEARCH_RESULTS => \@newresults);
 553
 554             ## FIXME: add a global function for this, it's better than the current global one
 555             ## Build the page numbers on the bottom of the page
 556             my @page_numbers;
 557             # total number of pages there will be
 558             my $pages = ceil($hits / $results_per_page);
 559             # default page number
 560             my $current_page_number = 1;
 561             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 562             my $previous_page_offset = $offset - $results_per_page unless ($offset - $results_per_page <0);
 563             my $next_page_offset = $offset + $results_per_page;
 564             # If we're within the first 10 pages, keep it simple
 565             #warn "current page:".$current_page_number;
 566             if ($current_page_number < 10) {
 567                 # just show the first 10 pages
 568                 # Loop through the pages
 569                 my $pages_to_show = 10;
 570                 $pages_to_show = $pages if $pages<10;
 571                 for (my $i=1; $i<=$pages_to_show;$i++) {
 572                     # the offset for this page
 573                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 574                     # the page number for this page
 575                     my $this_page_number = $i;
 576                     # it should only be highlighted if it's the current page
 577                     my $highlight = 1 if ($this_page_number == $current_page_number);
 578                     # put it in the array
 579                     push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 580
 581                 }
 582
 583             }
 584
 585
 586
 587             # now, show twenty pages, with the current one smack in the middle
 588             else {
 589                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 590                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 591                     my $this_page_number = $i-9;
 592                     my $highlight = 1 if ($this_page_number == $current_page_number);
 593                     if ($this_page_number <= $pages) {
 594                         push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 595                     }
 596                 }
 597
 598             }
 599             # FIXME: no previous_page_offset when pages < 2
 600             $template->param(   PAGE_NUMBERS => \@page_numbers,
 601                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 602             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 603         }
 604
 605
 606
 607
 608
 609         # no hits
 610         else {
 611             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 612                         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 613         }
 614
 615
 616
 617
 618
 619     } # end of the if local
 620
 621     # asynchronously search the authority server
 622     elsif ($server =~/authorityserver/) { # this is the local authority server
 623         my @inner_sup_results_array;
 624         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 625             my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 626             # warn "Authority Found: ".$marc_record_object->as_formatted();
 627             push @inner_sup_results_array, {
 628                 'title' => $marc_record_object->field(100)->subfield('a'),
 629                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 630             };
 631         }
 632         my $servername = $server;
 633         push @sup_results_array, {  servername => $servername,
 634                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 635     }
 636     # FIXME: can add support for other targets as needed here
 637     $template->param(           outer_sup_results_loop => \@sup_results_array);
 638 } #/end of the for loop
 639 #$template->param(FEDERATED_RESULTS => \@results_array);
 640
 641
 642 $template->param(
 643             #classlist => $classlist,
 644             total => $total,
 645             opacfacets => 1,
 646             facets_loop => $facets,
 647             scan => $scan,
 648             search_error => $error,
 649 );
 650
 651 if ($query_desc || $limit_desc) {
 652     $template->param(searchdesc => 1);
 653 }
 654
 655 ## Now let's find out if we have any supplemental data to show the user
 656 #  and in the meantime, save the current query for statistical purposes, etc.
 657 my $koha_spsuggest; # a flag to tell if we've got suggestions coming from Koha
 658 my @koha_spsuggest; # place we store the suggestions to be returned to the template as LOOP
 659 my $phrases = $query_desc;
 660 my $ipaddress;
 661
 662 if ( C4::Context->preference("kohaspsuggest") ) {
 663         my ($suggest_host, $suggest_dbname, $suggest_user, $suggest_pwd) = split(':', C4::Context->preference("kohaspsuggest"));
 664         eval {
 665             my $koha_spsuggest_dbh;
 666             # FIXME: this needs to be moved to Context.pm
 667             eval {
 668                 $koha_spsuggest_dbh=DBI->connect("DBI:mysql:$suggest_dbname:$suggest_host","$suggest_user","$suggest_pwd");
 669             };
 670             if ($@) {
 671                 warn "can't connect to spsuggest db";
 672             }
 673             else {
 674                 my $koha_spsuggest_insert = "INSERT INTO phrase_log(phr_phrase,phr_resultcount,phr_ip) VALUES(?,?,?)";
 675                 my $koha_spsuggest_query = "SELECT display FROM distincts WHERE strcmp(soundex(suggestion), soundex(?)) = 0 order by soundex(suggestion) limit 0,5";
 676                 my $koha_spsuggest_sth = $koha_spsuggest_dbh->prepare($koha_spsuggest_query);
 677                 $koha_spsuggest_sth->execute($phrases);
 678                 while (my $spsuggestion = $koha_spsuggest_sth->fetchrow_array) {
 679                     $spsuggestion =~ s/(:|\/)//g;
 680                     my %line;
 681                     $line{spsuggestion} = $spsuggestion;
 682                     push @koha_spsuggest,\%line;
 683                     $koha_spsuggest = 1;
 684                 }
 685
 686                 # Now save the current query
 687                 $koha_spsuggest_sth=$koha_spsuggest_dbh->prepare($koha_spsuggest_insert);
 688                 #$koha_spsuggest_sth->execute($phrases,$results_per_page,$ipaddress);
 689                 $koha_spsuggest_sth->finish;
 690
 691                 $template->param( koha_spsuggest => $koha_spsuggest ) unless $hits;
 692                 $template->param( SPELL_SUGGEST => \@koha_spsuggest,
 693                 );
 694             }
 695     };
 696     if ($@) {
 697             warn "Kohaspsuggest failure:".$@;
 698     }
 699 }
 700
 701 # VI. BUILD THE TEMPLATE
 702 output_html_with_http_headers $cgi, $cookie, $template->output;