catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # $Header$
   6 #
   7 # Copyright 2006 LibLime
   8 #
   9 # This file is part of Koha
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along with
  21 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  22 # Suite 330, Boston, MA  02111-1307 USA
  23
  24 =head1 NAME
  25
  26 search - a search script for finding records in a Koha system (Version 3)
  27
  28 =head1 OVERVIEW
  29
  30 This script utilizes a new search API for Koha 3. It is designed to be
  31 simple to use and configure, yet capable of performing feats like stemming,
  32 field weighting, relevance ranking, support for multiple  query language
  33 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  34 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  35 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  36
  37 The API as represented in this script is mostly sound, even if the individual
  38 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  39 free to disagree :-)
  40
  41 I will attempt to describe what is happening at each part of this script.
  42 -- Joshua Ferraro <jmf AT liblime DOT com>
  43
  44 =head2 INTRO
  45
  46 This script performs two functions:
  47
  48 =over
  49
  50 =item 1. interacts with Koha to retrieve and display the results of a search
  51
  52 =item 2. loads the advanced search page
  53
  54 =back
  55
  56 These two functions share many of the same variables and modules, so the first
  57 task is to load what they have in common and determine which template to use.
  58 Once determined, proceed to only load the variables and procedures necessary
  59 for that function.
  60
  61 =head2 LOADING ADVANCED SEARCH PAGE
  62
  63 This is fairly straightforward, and I won't go into detail ;-)
  64
  65 =head2 PERFORMING A SEARCH
  66
  67 If we're performing a search, this script  performs three primary
  68 operations:
  69
  70 =over
  71
  72 =item 1. builds query strings (yes, plural)
  73
  74 =item 2. perform the search and return the results array
  75
  76 =item 3. build the HTML for output to the template
  77
  78 =back
  79
  80 There are several additional secondary functions performed that I will
  81 not cover in detail.
  82
  83 =head3 1. Building Query Strings
  84
  85 There are several types of queries needed in the process of search and retrieve:
  86
  87 =over
  88
  89 =item 1 $query - the fully-built query passed to zebra
  90
  91 This is the most complex query that needs to be built. The original design goal
  92 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  93 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  94 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  95 I'll try to flesh out this section to better explain.
  96
  97 This query incorporates query profiles that aren't compatible with most non-Zebra
  98 Z39.50 targets to acomplish the field weighting and relevance ranking.
  99
 100 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 101 stemming, etc., suitable to pass off to other search targets
 102
 103 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 104 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 105
 106 =item 3 $query_cgi - passed to the template / saved for future refinements of
 107 the query (by user)
 108
 109 This is a simple string that completely expresses the query as a CGI string that
 110 can be used for future refinements of the query or as a part of a history feature.
 111
 112 =item 4 $query_desc - Human search description - what the user sees in search
 113 feedback area
 114
 115 This is a simple string that is human readable. It will contain '=', ',', etc.
 116
 117 =back
 118
 119 =head3 2. Perform the Search
 120
 121 This section takes the query strings and performs searches on the named servers,
 122 including the Koha Zebra server, stores the results in a deeply nested object,
 123 builds 'faceted results', and returns these objects.
 124
 125 =head3 3. Build HTML
 126
 127 The final major section of this script takes the objects collected thusfar and
 128 builds the HTML for output to the template and user.
 129
 130 =head3 Additional Notes
 131
 132 Not yet completed...
 133
 134 =cut
 135
 136 use strict;            # always use
 137
 138 ## STEP 1. Load things that are used in both search page and
 139 # results page and decide which template to load, operations
 140 # to perform, etc.
 141
 142 ## load Koha modules
 143 use C4::Context;
 144 use C4::Output;
 145 use C4::Auth;
 146 use C4::Search;
 147 use C4::Languages; # getAllLanguages
 148 use C4::Koha;
 149 use POSIX qw(ceil floor);
 150 use C4::Branch; # GetBranches
 151
 152 # create a new CGI object
 153 # FIXME: no_undef_params needs to be tested
 154 use CGI qw('-no_undef_params');
 155 my $cgi = new CGI;
 156
 157 my ($template,$borrowernumber,$cookie);
 158
 159 # decide which template to use
 160 my $template_name;
 161 my $template_type;
 162 my @params = $cgi->param("limit");
 163 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 164     $template_name = 'catalogue/results.tmpl';
 165 }
 166 else {
 167     $template_name = 'catalogue/advsearch.tmpl';
 168     $template_type = 'advsearch';
 169 }
 170 # load the template
 171 ($template, $borrowernumber, $cookie) = get_template_and_user({
 172     template_name => $template_name,
 173     query => $cgi,
 174     type => "intranet",
 175     authnotrequired => 0,
 176     flagsrequired   => { catalogue => 1 },
 177     }
 178 );
 179 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 180     $template->param('UNIMARC' => 1);
 181 }
 182
 183 ## URI Re-Writing
 184 # Deprecated, but preserved because it's interesting :-)
 185 # The same thing can be accomplished with mod_rewrite in
 186 # a more elegant way
 187 #
 188 #my $rewrite_flag;
 189 #my $uri = $cgi->url(-base => 1);
 190 #my $relative_url = $cgi->url(-relative=>1);
 191 #$uri.="/".$relative_url."?";
 192 #warn "URI:$uri";
 193 #my @cgi_params_list = $cgi->param();
 194 #my $url_params = $cgi->Vars;
 195 #
 196 #for my $each_param_set (@cgi_params_list) {
 197 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 198 #}
 199 #warn "New URI:$uri";
 200 # Only re-write a URI if there are params or if it already hasn't been re-written
 201 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 202 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 203 #                            -cookie => $cookie);
 204 #    exit;
 205 #}
 206
 207 # load the branches
 208 my $branches = GetBranches();
 209 my @branch_loop;
 210
 211 for my $branch_hash (sort keys %$branches) {
 212     push @branch_loop, {value => "$branch_hash" , branchname => $branches->{$branch_hash}->{'branchname'}, };
 213 }
 214
 215 my $categories = GetBranchCategories(undef,'searchdomain');
 216
 217 $template->param(branchloop => \@branch_loop, searchdomainloop => $categories);
 218
 219 # load the itemtypes
 220 my $itemtypes = GetItemTypes;
 221 my @itemtypesloop;
 222 my $selected=1;
 223 my $cnt;
 224 my $imgdir = getitemtypeimagesrc();
 225 foreach my $thisitemtype ( sort {$itemtypes->{$a}->{'description'} cmp $itemtypes->{$b}->{'description'} } keys %$itemtypes ) {
 226     my %row =(  number=>$cnt++,
 227                 imageurl=> $itemtypes->{$thisitemtype}->{'imageurl'}?($imgdir."/".$itemtypes->{$thisitemtype}->{'imageurl'}):"",
 228                 code => $thisitemtype,
 229                 selected => $selected,
 230                 description => $itemtypes->{$thisitemtype}->{'description'},
 231                 count5 => $cnt % 4,
 232             );
 233     $selected = 0 if ($selected) ;
 234     push @itemtypesloop, \%row;
 235 }
 236 $template->param(itemtypeloop => \@itemtypesloop);
 237
 238 # load the ccodes
 239 # my ($ccodecount,@ccode_loop) = GetCcodes();
 240 # $template->param(ccodeloop=>\@ccode_loop,);
 241
 242 # load the languages ( for switching from one template to another )
 243 $template->param(languages_loop => getTranslatedLanguages('intranet','prog'));
 244
 245 # The following should only be loaded if we're bringing up the advanced search template
 246 if ( $template_type eq 'advsearch' ) {
 247
 248     # load the servers (used for searching -- to do federated searching, etc.)
 249     my $primary_servers_loop;# = displayPrimaryServers();
 250     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 251
 252     my $secondary_servers_loop;# = displaySecondaryServers();
 253     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 254
 255     # determine what to display next to the search boxes (ie, boolean option
 256     # shouldn't appear on the first one, scan indexes should, adding a new
 257     # box should only appear on the last, etc.
 258     my @search_boxes_array;
 259     my $search_boxes_count = C4::Context->preference("OPACAdvSearchInputCount") | 3; # FIXME: should be a syspref
 260     for (my $i=1;$i<=$search_boxes_count;$i++) {
 261         # if it's the first one, don't display boolean option, but show scan indexes
 262         if ($i==1) {
 263             push @search_boxes_array,
 264                 {
 265                 scan_index => 1,
 266                 };
 267
 268         }
 269         # if it's the last one, show the 'add field' box
 270         elsif ($i==$search_boxes_count) {
 271             push @search_boxes_array,
 272                 {
 273                 boolean => 1,
 274                 add_field => 1,
 275                 };
 276         }
 277         else {
 278             push @search_boxes_array,
 279                 {
 280                 boolean => 1,
 281                 };
 282         }
 283
 284     }
 285     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 286                       search_boxes_loop => \@search_boxes_array);
 287
 288     # load the language limits (for search)
 289     my $languages_limit_loop = getAllLanguages();
 290     $template->param(search_languages_loop => $languages_limit_loop,);
 291
 292     # use the global setting by default
 293     if ( C4::Context->preference("expandedSearchOption") == 1) {
 294         $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 295     }
 296     # but let the user override it
 297     if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 298         $template->param( expanded_options => $cgi->param('expanded_options'));
 299     }
 300
 301     output_html_with_http_headers $cgi, $cookie, $template->output;
 302     exit;
 303 }
 304
 305 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 306
 307 # Fetch the paramater list as a hash in scalar context:
 308 #  * returns paramater list as tied hash ref
 309 #  * we can edit the values by changing the key
 310 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 311 my $params = $cgi->Vars;
 312
 313 # Params that can have more than one value
 314 # sort by is used to sort the query
 315 # in theory can have more than one but generally there's just one
 316 my @sort_by;
 317 my $default_sort_by = C4::Context->preference('defaultSortField')."_".C4::Context->preference('defaultSortOrder')
 318     if (C4::Context->preference('defaultSortField') && C4::Context->preference('defaultSortOrder'));
 319
 320 @sort_by = split("\0",$params->{'sort_by'}) if $params->{'sort_by'};
 321 $sort_by[0] = $default_sort_by unless $sort_by[0];
 322 foreach my $sort (@sort_by) {
 323     $template->param($sort => 1);
 324 }
 325 $template->param('sort_by' => $sort_by[0]);
 326
 327 # Use the servers defined, or just search our local catalog(default)
 328 my @servers;
 329 @servers = split("\0",$params->{'server'}) if $params->{'server'};
 330 unless (@servers) {
 331     #FIXME: this should be handled using Context.pm
 332     @servers = ("biblioserver");
 333     # @servers = C4::Context->config("biblioserver");
 334 }
 335 # operators include boolean and proximity operators and are used
 336 # to evaluate multiple operands
 337 my @operators;
 338 @operators = split("\0",$params->{'op'}) if $params->{'op'};
 339
 340 # indexes are query qualifiers, like 'title', 'author', etc. They
 341 # can be single or multiple parameters separated by comma: kw,right-Truncation
 342 my @indexes;
 343 @indexes = split("\0",$params->{'idx'});
 344
 345 # an operand can be a single term, a phrase, or a complete ccl query
 346 my @operands;
 347 @operands = split("\0",$params->{'q'}) if $params->{'q'};
 348
 349 # limits are use to limit to results to a pre-defined category such as branch or language
 350 my @limits;
 351 @limits = split("\0",$params->{'limit'}) if $params->{'limit'};
 352
 353 if($params->{'multibranchlimit'}) {
 354 push @limits, join(" or ", map { "branch: $_ "}  @{GetBranchesInCategory($params->{'multibranchlimit'})}) ;
 355 }
 356
 357 my $available;
 358 foreach my $limit(@limits) {
 359     if ($limit =~/available/) {
 360         $available = 1;
 361     }
 362 }
 363 $template->param(available => $available);
 364
 365 # append year limits if they exist
 366 my $limit_yr;
 367 my $limit_yr_value;
 368 if ($params->{'limit-yr'}) {
 369     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 370         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 371         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 372         $limit_yr_value = "$yr1-$yr2";
 373     }
 374     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 375         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 376         $limit_yr_value = $params->{'limit-yr'};
 377     }
 378     push @limits,$limit_yr;
 379     #FIXME: Should return a error to the user, incorect date format specified
 380 }
 381
 382 # Params that can only have one value
 383 my $scan = $params->{'scan'};
 384 my $count = C4::Context->preference('numSearchResults') || 20;
 385 my $results_per_page = $params->{'count'} || $count;
 386 my $offset = $params->{'offset'} || 0;
 387 my $page = $cgi->param('page') || 1;
 388 #my $offset = ($page-1)*$results_per_page;
 389 my $hits;
 390 my $expanded_facet = $params->{'expand'};
 391
 392 # Define some global variables
 393 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 394
 395 my @results;
 396
 397 ## I. BUILD THE QUERY
 398 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by,$scan);
 399
 400 ## parse the query_cgi string and put it into a form suitable for <input>s
 401 my @query_inputs;
 402 for my $this_cgi ( split('&',$query_cgi) ) {
 403     next unless $this_cgi;
 404     $this_cgi =~ m/(.*=)(.*)/;
 405     my $input_name = $1;
 406     my $input_value = $2;
 407     $input_name =~ s/=$//;
 408     push @query_inputs, { input_name => $input_name, input_value => $input_value };
 409 }
 410 $template->param ( QUERY_INPUTS => \@query_inputs );
 411
 412 ## parse the limit_cgi string and put it into a form suitable for <input>s
 413 my @limit_inputs;
 414 for my $this_cgi ( split('&',$limit_cgi) ) {
 415     next unless $this_cgi;
 416     # handle special case limit-yr
 417     if ($this_cgi =~ /yr,st-numeric/) {
 418         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 419         next;
 420     }
 421     $this_cgi =~ m/(.*=)(.*)/;
 422     my $input_name = $1;
 423     my $input_value = $2;
 424     $input_name =~ s/=$//;
 425     push @limit_inputs, { input_name => $input_name, input_value => $input_value };
 426 }
 427 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 428
 429 ## II. DO THE SEARCH AND GET THE RESULTS
 430 my $total; # the total results for the whole set
 431 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 432 my @results_array;
 433 my $results_hashref;
 434
 435 if (C4::Context->preference('NoZebra')) {
 436     $query=~s/yr(:|=)\s*([\d]{1,4})-([\d]{1,4})/(yr>=$2 and yr<=$3)/g;
 437     $simple_query=~s/yr\s*(:|=)([\d]{1,4})-([\d]{1,4})/(yr>=$2 and yr<=$3)/g;
 438     warn $query;
 439     eval {
 440         ($error, $results_hashref, $facets) = NZgetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 441     };
 442 } else {
 443     eval {
 444         ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 445     };
 446 }
 447 if ($@ || $error) {
 448     $template->param(query_error => $error.$@);
 449
 450     output_html_with_http_headers $cgi, $cookie, $template->output;
 451     exit;
 452 }
 453
 454 # FIXME: This belongs in tools/ not in the primary search results page
 455 my $op=$cgi->param("operation");
 456 if ($op eq "bulkedit"){
 457     my ($countchanged,$listunchanged)=
 458     ModBiblios($results_hashref->{'biblioserver'}->{"RECORDS"},
 459                       $params->{"tagsubfield"},
 460                       $params->{"inputvalue"},
 461                       $params->{"targetvalue"},
 462                       $params->{"test"}
 463                       );
 464     $template->param(bulkeditresults=>1,
 465                       tagsubfield=>$params->{"tagsubfield"},
 466                       inputvalue=>$params->{"inputvalue"},
 467                       targetvalue=>$params->{"targetvalue"},
 468                       countchanged=>$countchanged,
 469                       countunchanged=>scalar(@$listunchanged),
 470                       listunchanged=>$listunchanged);
 471
 472     if (C4::Context->userenv->{'flags'}==1 ||(C4::Context->userenv->{'flags'} & ( 2**9 ) )){
 473     #Edit Catalogue Permissions
 474         my $editable_subfields = GetManagedTagSubfields();
 475         # change '--' to '&mdash;' to avoid escaping issues
 476         for (my $i = 0; $i <= $#{$editable_subfields}; $i++) {
 477             $editable_subfields->[$i]->{subfielddesc} =~ s/--/&mdash;/g;
 478             $editable_subfields->[$i]->{tagdesc} =~ s/--/&mdash;/g;
 479         }
 480         $template->param(bulkedit => 1);
 481         $template->param(tagsubfields=>$editable_subfields);
 482     }
 483 }
 484
 485 # At this point, each server has given us a result set
 486 # now we build that set for template display
 487 my @sup_results_array;
 488 for (my $i=0;$i<@servers;$i++) {
 489     my $server = $servers[$i];
 490     if ($server =~/biblioserver/) { # this is the local bibliographic server
 491         $hits = $results_hashref->{$server}->{"hits"};
 492         my $page = $cgi->param('page') || 0;
 493         my @newresults = searchResults( $query_desc,$hits,$results_per_page,$offset,@{$results_hashref->{$server}->{"RECORDS"}});
 494         $total = $total + $results_hashref->{$server}->{"hits"};
 495         if ($hits) {
 496             $template->param(total => $hits);
 497             my $limit_cgi_not_availablity = $limit_cgi;
 498             $limit_cgi_not_availablity =~ s/&limit=available//g;
 499             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 500             $template->param(limit_cgi => $limit_cgi);
 501             $template->param(query_cgi => $query_cgi);
 502             $template->param(query_desc => $query_desc);
 503             $template->param(limit_desc => $limit_desc);
 504             if ($query_desc || $limit_desc) {
 505                 $template->param(searchdesc => 1);
 506             }
 507             $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 508             $template->param(results_per_page =>  $results_per_page);
 509             $template->param(SEARCH_RESULTS => \@newresults);
 510
 511             ## FIXME: add a global function for this, it's better than the current global one
 512             ## Build the page numbers on the bottom of the page
 513             my @page_numbers;
 514             # total number of pages there will be
 515             my $pages = ceil($hits / $results_per_page);
 516             # default page number
 517             my $current_page_number = 1;
 518             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 519             my $previous_page_offset = $offset - $results_per_page unless ($offset - $results_per_page <0);
 520             my $next_page_offset = $offset + $results_per_page;
 521             # If we're within the first 10 pages, keep it simple
 522             #warn "current page:".$current_page_number;
 523             if ($current_page_number < 10) {
 524                 # just show the first 10 pages
 525                 # Loop through the pages
 526                 my $pages_to_show = 10;
 527                 $pages_to_show = $pages if $pages<10;
 528                 for (my $i=1; $i<=$pages_to_show;$i++) {
 529                     # the offset for this page
 530                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 531                     # the page number for this page
 532                     my $this_page_number = $i;
 533                     # it should only be highlighted if it's the current page
 534                     my $highlight = 1 if ($this_page_number == $current_page_number);
 535                     # put it in the array
 536                     push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 537
 538                 }
 539
 540             }
 541             # now, show twenty pages, with the current one smack in the middle
 542             else {
 543                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 544                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 545                     my $this_page_number = $i-9;
 546                     my $highlight = 1 if ($this_page_number == $current_page_number);
 547                     if ($this_page_number <= $pages) {
 548                         push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 549                     }
 550                 }
 551
 552             }
 553             # FIXME: no previous_page_offset when pages < 2
 554             $template->param(   PAGE_NUMBERS => \@page_numbers,
 555                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 556             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 557         }
 558         # no hits
 559         else {
 560             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 561         }
 562     } # end of the if local
 563
 564     # asynchronously search the authority server
 565     elsif ($server =~/authorityserver/) { # this is the local authority server
 566         my @inner_sup_results_array;
 567         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 568             my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 569             # warn "Authority Found: ".$marc_record_object->as_formatted();
 570             push @inner_sup_results_array, {
 571                 'title' => $marc_record_object->field(100)->subfield('a'),
 572                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 573             };
 574         }
 575         my $servername = $server;
 576         push @sup_results_array, {  servername => $servername,
 577                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 578     }
 579     # FIXME: can add support for other targets as needed here
 580     $template->param(           outer_sup_results_loop => \@sup_results_array);
 581 } #/end of the for loop
 582 #$template->param(FEDERATED_RESULTS => \@results_array);
 583
 584
 585 $template->param(
 586             #classlist => $classlist,
 587             total => $total,
 588             opacfacets => 1,
 589             facets_loop => $facets,
 590             scan => $scan,
 591             search_error => $error,
 592 );
 593
 594 if ($query_desc || $limit_desc) {
 595     $template->param(searchdesc => 1);
 596 }
 597
 598 ## Now let's find out if we have any supplemental data to show the user
 599 #  and in the meantime, save the current query for statistical purposes, etc.
 600 my $koha_spsuggest; # a flag to tell if we've got suggestions coming from Koha
 601 my @koha_spsuggest; # place we store the suggestions to be returned to the template as LOOP
 602 my $phrases = $query_desc;
 603 my $ipaddress;
 604
 605 if ( C4::Context->preference("kohaspsuggest") ) {
 606         my ($suggest_host, $suggest_dbname, $suggest_user, $suggest_pwd) = split(':', C4::Context->preference("kohaspsuggest"));
 607         eval {
 608             my $koha_spsuggest_dbh;
 609             # FIXME: this needs to be moved to Context.pm
 610             eval {
 611                 $koha_spsuggest_dbh=DBI->connect("DBI:mysql:$suggest_dbname:$suggest_host","$suggest_user","$suggest_pwd");
 612             };
 613             if ($@) {
 614                 warn "can't connect to spsuggest db";
 615             }
 616             else {
 617                 my $koha_spsuggest_insert = "INSERT INTO phrase_log(phr_phrase,phr_resultcount,phr_ip) VALUES(?,?,?)";
 618                 my $koha_spsuggest_query = "SELECT display FROM distincts WHERE strcmp(soundex(suggestion), soundex(?)) = 0 order by soundex(suggestion) limit 0,5";
 619                 my $koha_spsuggest_sth = $koha_spsuggest_dbh->prepare($koha_spsuggest_query);
 620                 $koha_spsuggest_sth->execute($phrases);
 621                 while (my $spsuggestion = $koha_spsuggest_sth->fetchrow_array) {
 622                     $spsuggestion =~ s/(:|\/)//g;
 623                     my %line;
 624                     $line{spsuggestion} = $spsuggestion;
 625                     push @koha_spsuggest,\%line;
 626                     $koha_spsuggest = 1;
 627                 }
 628
 629                 # Now save the current query
 630                 $koha_spsuggest_sth=$koha_spsuggest_dbh->prepare($koha_spsuggest_insert);
 631                 #$koha_spsuggest_sth->execute($phrases,$results_per_page,$ipaddress);
 632                 $koha_spsuggest_sth->finish;
 633
 634                 $template->param( koha_spsuggest => $koha_spsuggest ) unless $hits;
 635                 $template->param( SPELL_SUGGEST => \@koha_spsuggest,
 636                 );
 637             }
 638     };
 639     if ($@) {
 640             warn "Kohaspsuggest failure:".$@;
 641     }
 642 }
 643
 644 # VI. BUILD THE TEMPLATE
 645 output_html_with_http_headers $cgi, $cookie, $template->output;