circ/waitingreserves.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # parts copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use strict;
  22 use warnings;
  23 use CGI qw ( -utf8 );
  24 use C4::Context;
  25 use C4::Output;
  26 use C4::Auth;
  27 use C4::Circulation;
  28 use C4::Members;
  29 use C4::Biblio;
  30 use C4::Items;
  31 use Date::Calc qw(
  32   Today
  33   Add_Delta_Days
  34   Date_to_Days
  35 );
  36 use C4::Reserves;
  37 use C4::Koha;
  38 use Koha::DateUtils;
  39 use Koha::BiblioFrameworks;
  40
  41 my $input = new CGI;
  42
  43 my $item           = $input->param('itemnumber');
  44 my $borrowernumber = $input->param('borrowernumber');
  45 my $fbr            = $input->param('fbr') || '';
  46 my $tbr            = $input->param('tbr') || '';
  47 my $all_branches   = $input->param('allbranches') || '';
  48 my $cancelall      = $input->param('cancelall');
  49 my $tab            = $input->param('tab');
  50
  51 my ( $template, $loggedinuser, $cookie, $flags ) = get_template_and_user(
  52     {
  53         template_name   => "circ/waitingreserves.tt",
  54         query           => $input,
  55         type            => "intranet",
  56         authnotrequired => 0,
  57         flagsrequired   => { circulate => "circulate_remaining_permissions" },
  58         debug           => 1,
  59     }
  60 );
  61
  62 my $default = C4::Context->userenv->{'branch'};
  63
  64 my $transfer_when_cancel_all = C4::Context->preference('TransferWhenCancelAllWaitingHolds');
  65 $template->param( TransferWhenCancelAllWaitingHolds => 1 ) if $transfer_when_cancel_all;
  66
  67 my @cancel_result;
  68 # if we have a return from the form we launch the subroutine CancelReserve
  69 if ($item) {
  70     my $res = cancel( $item, $borrowernumber, $fbr, $tbr );
  71     push @cancel_result, $res if $res;
  72 }
  73
  74 if ( C4::Context->preference('IndependentBranches') ) {
  75     undef $all_branches;
  76 } else {
  77     $template->param( all_branches_link => '/cgi-bin/koha/circ/waitingreserves.pl' . '?allbranches=1' )
  78       unless $all_branches;
  79 }
  80 $template->param( all_branches => 1 ) if $all_branches;
  81
  82 my (@reservloop, @overloop);
  83 my ($reservcount, $overcount);
  84 my @getreserves = $all_branches ? GetReservesForBranch() : GetReservesForBranch($default);
  85 # get reserves for the branch we are logged into, or for all branches
  86
  87 my $today = Date_to_Days(&Today);
  88 my $max_pickup_delay = C4::Context->preference('ReservesMaxPickUpDelay');
  89 $max_pickup_delay-- if C4::Context->preference('ExpireReservesMaxPickUpDelay');
  90
  91 foreach my $num (@getreserves) {
  92     next unless ($num->{'waitingdate'} && $num->{'waitingdate'} ne '0000-00-00');
  93
  94     my $itemnumber = $num->{'itemnumber'};
  95     my $gettitle     = GetBiblioFromItemNumber( $itemnumber );
  96     my $borrowernum = $num->{'borrowernumber'};
  97     my $holdingbranch = $gettitle->{'holdingbranch'};
  98     my $homebranch = $gettitle->{'homebranch'};
  99
 100     my %getreserv = (
 101         itemnumber => $itemnumber,
 102         borrowernum => $borrowernum,
 103     );
 104
 105     # fix up item type for display
 106     $gettitle->{'itemtype'} = C4::Context->preference('item-level_itypes') ? $gettitle->{'itype'} : $gettitle->{'itemtype'};
 107     my $getborrower = GetMember(borrowernumber => $num->{'borrowernumber'});
 108     my $itemtypeinfo = getitemtypeinfo( $gettitle->{'itemtype'} );  # using the fixed up itype/itemtype
 109     $getreserv{'waitingdate'} = $num->{'waitingdate'};
 110     my ( $waiting_year, $waiting_month, $waiting_day ) = split (/-/, $num->{'waitingdate'});
 111
 112     ( $waiting_year, $waiting_month, $waiting_day ) =
 113       Add_Delta_Days( $waiting_year, $waiting_month, $waiting_day,
 114         $max_pickup_delay);
 115     my $calcDate = Date_to_Days( $waiting_year, $waiting_month, $waiting_day );
 116
 117     $getreserv{'itemtype'}       = $itemtypeinfo->{'description'};
 118     $getreserv{'title'}          = $gettitle->{'title'};
 119     $getreserv{'subtitle'}       = GetRecordValue('subtitle', GetMarcBiblio($gettitle->{'biblionumber'}), GetFrameworkCode($gettitle->{'biblionumber'}));
 120     $getreserv{'biblionumber'}   = $gettitle->{'biblionumber'};
 121     $getreserv{'barcode'}        = $gettitle->{'barcode'};
 122     $getreserv{'homebranch'}     = $gettitle->{'homebranch'};
 123     $getreserv{'holdingbranch'}  = $gettitle->{'holdingbranch'};
 124     $getreserv{'itemcallnumber'} = $gettitle->{'itemcallnumber'};
 125     $getreserv{'enumchron'}      = $gettitle->{'enumchron'};
 126     $getreserv{'copynumber'}     = $gettitle->{'copynumber'};
 127     if ( $homebranch ne $holdingbranch ) {
 128         $getreserv{'dotransfer'} = 1;
 129     }
 130     $getreserv{'borrowername'}      = $getborrower->{'surname'};
 131     $getreserv{'borrowerfirstname'} = $getborrower->{'firstname'};
 132     $getreserv{'borrowerphone'}     = $getborrower->{'phone'};
 133
 134     my $borEmail = GetFirstValidEmailAddress( $borrowernum );
 135
 136     if ( $borEmail ) {
 137         $getreserv{'borrowermail'}  = $borEmail;
 138     }
 139
 140     if ($today > $calcDate) {
 141         if ($cancelall) {
 142             my $res = cancel( $itemnumber, $borrowernum, $holdingbranch, $homebranch, !$transfer_when_cancel_all );
 143             push @cancel_result, $res if $res;
 144             next;
 145         } else {
 146             push @overloop,   \%getreserv;
 147             $overcount++;
 148         }
 149     }else{
 150         push @reservloop, \%getreserv;
 151         $reservcount++;
 152     }
 153
 154 }
 155
 156 $template->param(cancel_result => \@cancel_result) if @cancel_result;
 157 $template->param(
 158     reserveloop => \@reservloop,
 159     reservecount => $reservcount,
 160     overloop    => \@overloop,
 161     overcount   => $overcount,
 162     show_date   => output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 }),
 163     ReservesMaxPickUpDelay => $max_pickup_delay,
 164     tab => $tab,
 165 );
 166
 167 # Checking if there is a Fast Cataloging Framework
 168 $template->param( fast_cataloging => 1 ) if Koha::BiblioFrameworks->find( 'FA' );
 169
 170 # Checking if the transfer page needs to be displayed
 171 $template->param( display_transfer => 1 ) if ( ($flags->{'superlibrarian'} == 1) || (C4::Context->preference("IndependentBranches") == 0) );
 172
 173 if ($item && $tab eq 'holdsover' && !@cancel_result) {
 174     print $input->redirect("/cgi-bin/koha/circ/waitingreserves.pl#holdsover");
 175 } elsif ($cancelall) {
 176     print $input->redirect("/cgi-bin/koha/circ/waitingreserves.pl");
 177 } else {
 178     output_html_with_http_headers $input, $cookie, $template->output;
 179 }
 180
 181 exit;
 182
 183 sub cancel {
 184     my ($item, $borrowernumber, $fbr, $tbr, $skip_transfers ) = @_;
 185
 186     my $transfer = $fbr ne $tbr; # XXX && !$nextreservinfo;
 187
 188     return if $transfer && $skip_transfers;
 189
 190     my ( $messages, $nextreservinfo ) = ModReserveCancelAll( $item, $borrowernumber );
 191
 192 #       if the document is not in his homebranch location and there is not reservation after, we transfer it
 193     if ($transfer && !$nextreservinfo) {
 194         ModItemTransfer( $item, $fbr, $tbr );
 195     }
 196     # if we have a result
 197     if ($nextreservinfo) {
 198         my %res;
 199         my $borrowerinfo = C4::Members::GetMember( borrowernumber => $nextreservinfo );
 200         my $iteminfo = GetBiblioFromItemNumber($item);
 201         if ( $messages->{'transfert'} ) {
 202             $res{messagetransfert} = $messages->{'transfert'};
 203             $res{branchcode}       = $messages->{'transfert'};
 204         }
 205
 206         $res{message}             = 1;
 207         $res{nextreservnumber}    = $nextreservinfo;
 208         $res{nextreservsurname}   = $borrowerinfo->{'surname'};
 209         $res{nextreservfirstname} = $borrowerinfo->{'firstname'};
 210         $res{nextreservitem}      = $item;
 211         $res{nextreservtitle}     = $iteminfo->{'title'};
 212         $res{waiting}             = $messages->{'waiting'} ? 1 : 0;
 213
 214         return \%res;
 215     }
 216
 217     return;
 218 }