lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14 use Storable;
  15
  16 our $loaded;
  17 our $filters;
  18
  19 sub index {
  20         my $self = shift;
  21
  22         my $path = $self->app->home->rel_dir('data');
  23         die "no data dir $path" unless -d $path;
  24
  25         my @files;
  26         find( sub {
  27                 my $file = $File::Find::name;
  28                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  29                         $file =~ s/$path\/*//;
  30                         push @files, $file;
  31                 } else {
  32                         warn "IGNORE: $file\n";
  33                 }
  34         }, $path);
  35
  36         @files = sort { lc $a cmp lc $b } @files;
  37         my $size;
  38         $size->{$_} = -s "$path/$_" foreach @files;
  39
  40         my $dump_path;
  41         $dump_path->{$_} = $self->_dump_path( $_ ) foreach @files;
  42
  43         $self->render(
  44                 files => [ @files ],
  45                 size => $size,
  46                 loaded => $loaded,
  47                 filters => $filters,
  48                 dump_path => $dump_path,
  49         );
  50 }
  51
  52 sub _dump_path {
  53         my ( $self, $name ) = @_;
  54         my $dir = $self->app->home->rel_dir('data');
  55         $name =~ s/^$dir//;
  56         $name =~ s/\/+/_/g;
  57         return '/tmp/mojo_facets.' . $name . '.storable';
  58 }
  59
  60 sub _save {
  61         my ( $self, $path ) = @_;
  62
  63         my $dump_path = $self->_dump_path( $path );
  64         warn "save loaded to $dump_path";
  65         my $info = $loaded->{$path};
  66         store $info, $dump_path;
  67
  68         # sync timestamp
  69         my $mtime = $loaded->{$path}->{mtime};
  70         utime $mtime, $mtime, $dump_path;
  71
  72         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  73         return $dump_path;
  74 }
  75
  76 sub _load_path {
  77         my ( $self, $path ) = @_;
  78
  79         my $full_path = $self->app->home->rel_file( 'data/' . $path );
  80         die "$full_path $!" unless -r $full_path;
  81
  82         my $dump_path = $self->_dump_path( $path );
  83
  84         if ( defined $loaded->{$path}->{data} ) {
  85                 my $mtime = (stat($full_path))[9];
  86                 return if $loaded->{$path}->{mtime} == $mtime;
  87                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
  88         } elsif ( -e $dump_path ) {
  89                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
  90                 my $info = retrieve $dump_path;
  91                 $loaded->{ $path } = $info;
  92                 return;
  93         }
  94
  95         # we could use Mojo::JSON here, but it's too slow
  96 #       $data = from_json read_file $path;
  97         my $data = read_file $full_path;
  98         warn "# data snippet: ", substr($data,0,200);
  99         my @header;
 100         if ( $path =~ m/\.js/ ) {
 101                 Encode::_utf8_on($data);
 102                 $data = from_json $data;
 103         } elsif ( $path =~ m/\.txt/ ) {
 104                 my @lines = split(/\r?\n/, $data);
 105                 $data = { items => [] };
 106
 107                 my $header_line = shift @lines;
 108                 my $multiline = $header_line =~ s/\^//g;
 109                 @header = split(/\|/, $header_line );
 110                 warn "# header ", dump( @header );
 111                 while ( my $line = shift @lines ) {
 112                         $line =~ s/\^//g;
 113                         chomp $line;
 114                         my @v = split(/\|/, $line);
 115                         while ( @lines && $#v < $#header ) {
 116                                 $line = $lines[0];
 117                                 $line =~ s/\^//g;
 118                                 chomp $line;
 119                                 my @more_v = split(/\|/, $line);
 120                                 if ( $#v + $#more_v > $#header ) {
 121                                         warn "short line: ",dump( @v );
 122                                         last;
 123                                 }
 124                                 shift @lines;
 125                                 $v[ $#v ] .= shift @more_v if @more_v;
 126                                 push @v, @more_v if @more_v;
 127
 128                                 if ( $#v > $#header ) {
 129                                         die "# splice $#header ", dump( @v );
 130                                         @v = splice @v, 0, $#header;
 131                                 }
 132                         }
 133                         my $item;
 134                         foreach my $i ( 0 .. $#v ) {
 135                                 $item->{ $header[$i] || "f_$i" } = [ $v[$i] ];
 136                         }
 137                         push @{ $data->{items} }, $item;
 138                 }
 139         } else {
 140                 warn "file format unknown $path";
 141         }
 142
 143         my $stats;
 144
 145         foreach my $e ( @{ $data->{items} } ) {
 146                 foreach my $n ( keys %$e ) {
 147                         $stats->{$n}->{count}++;
 148                         my @v;
 149                         if ( ref $e->{$n} eq 'ARRAY' ) {
 150                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 151                                 @v = @{ $e->{$n} };
 152                         } else {
 153                                 @v = ( $e->{$n} );
 154                         }
 155
 156                         foreach my $x ( @v ) {
 157                                 $stats->{$n}->{numeric}++
 158                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 159                                 $stats->{$n}->{empty}++
 160                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 161                         }
 162
 163                 }
 164         }
 165
 166         foreach my $n ( keys %$stats ) {
 167                 next unless defined $stats->{$n}->{array};
 168                 delete $stats->{$n}->{array}
 169                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 170         }
 171
 172         if ( ! @header ) {
 173                 if ( defined $data->{header} ) {
 174                         if ( ref $data->{header} eq 'ARRAY' ) {
 175                                 @header = @{ $data->{header} };
 176                         } else {
 177                                 warn "header not array ", dump( $data->{header} );
 178                         }
 179                 }
 180         }
 181
 182         @header =
 183                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 184                 grep { defined $stats->{$_}->{count} } keys %$stats
 185                 unless @header;
 186
 187         warn dump($stats);
 188
 189         my $info = {
 190                 header => [ @header ],
 191                 stats  => $stats,
 192                 full_path => $full_path,
 193                 size => -s $full_path,
 194                 mtime => (stat($full_path))[9],
 195                 data => $data,
 196         };
 197
 198         $loaded->{ $path } = $info;
 199         $self->_save( $path );
 200
 201 }
 202
 203
 204 sub load {
 205         my $self = shift;
 206
 207         my @paths = $self->param('paths');
 208         warn "# paths ", dump @paths;
 209         $self->_load_path( $_ ) foreach @paths;
 210
 211         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 212         warn "# path $path\n";
 213         $self->session('path' => $path);
 214         $self->_load_path( $path );
 215
 216         $self->session( 'header' => $loaded->{$path}->{header} );
 217         if ( ! defined $loaded->{$path}->{columns} ) {
 218                 $self->session( 'columns' => $loaded->{$path}->{header} );
 219                 $self->session( 'order'   => $loaded->{$path}->{header}->[0] );
 220                 $self->redirect_to( '/data/columns' );
 221         } else {
 222                 $self->session( 'columns' => $loaded->{$path}->{columns} );
 223                 $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 224                 $self->redirect_to( '/data/items' );
 225         }
 226 }
 227
 228
 229 sub _loaded {
 230         my ( $self, $name ) = @_;
 231         my $path = $self->session('path');
 232         $self->redirect_to('/data/index') unless $path;
 233         if ( ! defined $loaded->{$path}->{$name} ) {
 234                 warn "$path $name doesn't exist in loaded ",dump( $loaded );
 235                 $self->redirect_to('/data/index');
 236         }
 237         return $loaded->{$path}->{$name};
 238 }
 239
 240
 241 sub _checked {
 242         my $self = shift;
 243         my $checked;
 244         $checked->{$_}++ foreach @_;
 245 #       warn "# _checked ",dump($checked);
 246         return $checked;
 247 }
 248
 249
 250 sub columns {
 251     my $self = shift;
 252
 253         if ( $self->param('columns') ) {
 254                 $self->_perm_array('columns');
 255                 $self->redirect_to('/data/items');
 256         }
 257
 258         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 259
 260         my @columns;
 261         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 262
 263         foreach my $c ( @{ $self->session( 'header' ) } ) {
 264                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 265         }
 266
 267     $self->render(
 268                 message => 'Select columns to display',
 269                 stats => $stats,
 270                 columns => \@columns,
 271                 checked => $self->_checked( $self->_perm_array('columns') ),
 272         );
 273 }
 274
 275 sub _perm_array {
 276     my ($self,$name) = @_;
 277
 278         my @array = $self->param($name);
 279         my $path  = $self->session('path');
 280
 281         if ( @array ) {
 282                 $self->session($name => [ @array ]);
 283                 $loaded->{$path}->{$name} = [ @array ];
 284         } elsif ( my $session = $self->session($name) ) {
 285                 if ( ref $session eq 'ARRAY' ) {
 286                         @array = @$session;
 287                 } else {
 288                         die "$name not array ",dump($session);
 289                 }
 290         }
 291         #warn "# $name ",dump @array;
 292         return @array;
 293 }
 294
 295 sub _perm_scalar {
 296     my ($self,$name,$default) = @_;
 297
 298         my $scalar = $self->param($name);
 299
 300         if ( defined $scalar ) {
 301                 $self->session($name => $scalar);
 302         } else {
 303                 $scalar = $self->session($name);
 304         }
 305
 306         if ( ! defined $scalar ) {
 307                 $scalar = $default;
 308                 die "no default for $name" unless defined $scalar;
 309                 $self->session($name => $scalar);
 310         }
 311
 312         warn "# _perm_scalar $name ",dump $scalar;
 313         return $scalar;
 314 }
 315
 316 sub filter {
 317         my $self = shift;
 318
 319         my $name = $self->param('filter_name') || die "name?";
 320         my @vals = $self->param('filter_vals');
 321
 322         $self->_remove_filter( $name );
 323         $self->_filter_on_data( $name, @vals ) if @vals;
 324
 325         $self->session( 'offset' => 0 );
 326
 327         $self->redirect_to('/data/items');
 328 }
 329
 330 sub _filter_on_data {
 331         my ( $self, $name, @vals ) = @_;
 332
 333         my $path = $self->session('path');
 334
 335         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 336                 warn "filter $name not found in data set";
 337                 return;
 338         }
 339
 340         $filters->{$name} = [ @vals ];
 341         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 342
 343         my $filter_hash;
 344         $filter_hash->{$_}++ foreach @vals;
 345
 346         #warn "# filter_hash ",dump( $filter_hash );
 347
 348         my $items = $self->_loaded('data')->{items};
 349
 350         my $include_missing = defined $filter_hash->{_missing};
 351         my $filtered_items;
 352
 353         foreach my $i ( 0 .. $#$items ) {
 354
 355                 if ( defined $items->[$i]->{$name} ) {
 356                         foreach my $v ( @{ $items->[$i]->{$name} } ) {
 357                                 if ( defined $filter_hash->{ $v } ) {
 358                                         $filtered_items->{$i}++;
 359                                 }
 360                         }
 361                 } elsif ( $include_missing ) {
 362                         $filtered_items->{$i}++;
 363                 }
 364         }
 365
 366         #warn "# filter $name ",dump($filtered_items);
 367
 368         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 369         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 370 }
 371
 372 sub _data_items {
 373         my ( $self, $all ) = @_;
 374         my $data = $self->_loaded( 'data' );
 375
 376         return @{ $data->{items} } if $all == 1;
 377
 378         my $filters = $self->_current_filters;
 379         my $filter_value;
 380         foreach my $f ( keys %$filters ) {
 381                 foreach my $n ( @{ $filters->{$f} } ) {
 382                         $filter_value->{$f}->{$n} = 1;
 383                 }
 384         }
 385         my @items = @{ $data->{items} };
 386         @items = grep {
 387                 my $i = $_;
 388                 my $pass = 1;
 389                 foreach my $n ( keys %$filter_value ) {
 390                         if ( ! exists $i->{$n} ) {
 391                                 if ( defined $filter_value->{$n}->{_missing} ) {
 392                                         $pass = 1;
 393                                         next;
 394                                 } else {
 395                                         $pass = 0;
 396                                         last;
 397                                 }
 398                         }
 399                         # and match any of values in element
 400                         my $have_values = 0;
 401                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 402                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 403                         }
 404                         if ( ! $have_values ) {
 405                                 $pass = 0;
 406                                 last;
 407                         }
 408                 }
 409                 $pass;
 410         } @items if $filter_value;
 411         return @items;
 412 }
 413
 414
 415 sub _current_filters {
 416         my $self = shift;
 417         my $current_filters;
 418         $current_filters->{ $_ } = $filters->{ $_ }
 419                 foreach (
 420                         grep { defined $filters->{ $_ } }
 421                         @{ $self->_loaded('header') }
 422                 );
 423         #warn "# current_filters ",dump($current_filters);
 424         return $current_filters;
 425 }
 426
 427 sub _data_sorted_by {
 428         my ( $self, $order ) = @_;
 429
 430         my $path = $self->session('path');
 431
 432         warn "_data_sorted_by $order from $path";
 433
 434         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 435                 return $loaded->{$path}->{sorted}->{$order};
 436         }
 437
 438         my $data = $self->_loaded( 'data' );
 439         my $numeric = $self->_is_numeric($order);
 440         my $missing = $numeric ? 0 : '';
 441         no warnings qw(numeric);
 442         my $nr = 0;
 443         my @sorted = map {
 444                 $_->[0]
 445         } sort {
 446                 if ( $numeric ) {
 447                         $a->[1] <=> $b->[1]
 448                 } else {
 449                         $a->[1] cmp $b->[1]
 450                 }
 451         } map {
 452                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 453         } @{ $data->{items} }
 454         ;
 455
 456         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 457         #warn "# sorted ",dump( @sorted );
 458
 459         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 460 }
 461
 462
 463 sub items {
 464         my $self = shift;
 465
 466         my $path = $self->session('path');
 467         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 468
 469         my @columns = $self->_perm_array('columns');
 470         $self->redirect_to('/data/columns') unless @columns;
 471         my $order   = $self->_perm_scalar('order', $columns[0]);
 472         my $sort    = $self->_perm_scalar('sort', 'a');
 473         my $offset  = $self->_perm_scalar('offset', 0);
 474         my $limit   = $self->_perm_scalar('limit', 20);
 475         $self->_perm_scalar('show', 'table');
 476
 477         # fix offset when changing limit
 478         $offset = int( $offset / $limit ) * $limit;
 479
 480         my $sorted = $self->_data_sorted_by( $order );
 481
 482         my @filter_names;
 483         if ( $filters ) {
 484                 foreach my $name ( keys %$filters ) {
 485                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 486                                 warn "skip filter $name not found in $path\n";
 487                                 next;
 488                         }
 489                         push @filter_names, $name;
 490                 }
 491                 warn "filter_names ",dump( @filter_names );
 492                 foreach my $name ( @filter_names ) {
 493                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 494                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 495                 }
 496         }
 497
 498         my $all_filters = join(' ',sort @filter_names,'order:',$order);
 499
 500 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 501
 502         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 503
 504                 my $path_filters = $loaded->{$path}->{filters};
 505
 506                 warn "create combined filter for $all_filters\n";
 507
 508                 my @filtered;
 509                 foreach my $i ( 0 .. $#$sorted ) {
 510                         my $pos = $sorted->[$i];
 511
 512                         if ( $#filter_names == -1 ) {
 513                                 push @filtered, $pos;
 514                                 next;
 515                         }
 516
 517                         my $skip = 0;
 518                         foreach ( @filter_names ) {
 519                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 520                         }
 521                         next if $skip;
 522
 523                         push @filtered, $pos;
 524                 }
 525
 526                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 527         }
 528
 529         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 530                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 531
 532         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 533
 534         my $sorted_items;
 535         my $data = $self->_loaded('data');
 536         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 537         foreach ( 0 .. $limit ) {
 538                 my $i = $_ + $offset;
 539                 last unless defined $filtered->[$i];
 540                 $i = $from_end - $i if $from_end;
 541                 my $id = $filtered->[$i];
 542                 push @$sorted_items,
 543                 my $item = $data->{items}->[ $id ];
 544                 $item->{_row_id} ||= $id;
 545         }
 546
 547         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 548
 549         $self->render(
 550                 order => $order,
 551                 offset => $offset,
 552                 limit => $limit,
 553                 sorted => $sorted_items,
 554                 columns => [ @columns ],
 555                 rows => $#$filtered + 1,
 556                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 557                 filters => $self->_current_filters,
 558         );
 559
 560 }
 561
 562
 563 sub order {
 564         my $self = shift;
 565         $self->session('order', $self->param('order'));
 566         $self->session('sort', $self->param('sort'));
 567         $self->redirect_to('/data/items');
 568 }
 569
 570 sub _is_numeric {
 571         my ( $self, $name ) = @_;
 572
 573         my $stats = $self->_loaded( 'stats' );
 574
 575         # sort facet numerically if more >50% elements are numeric
 576         my $count = $stats->{$name}->{count};
 577         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 578         defined $stats->{$name}->{numeric} &&
 579                 $stats->{$name}->{numeric} > $count / 2;
 580 }
 581
 582 sub _remove_filter {
 583         my ($self,$name) = @_;
 584         warn "_remove_filter $name\n";
 585
 586         my $path = $self->session('path');
 587
 588         delete $filters->{$name};
 589         delete $loaded->{$path}->{filters}->{$name};
 590         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 591
 592         foreach (
 593                         grep { /\b$name\b/ }
 594                         keys %{ $loaded->{$path}->{filtered} }
 595         ) {
 596                 delete $loaded->{$path}->{filtered}->{$_};
 597                 warn "remove filtered cache $_";
 598         }
 599 }
 600
 601 sub facet {
 602         my $self = shift;
 603
 604         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 605
 606         if ( my $name = $self->param('remove') ) {
 607                 $self->_remove_filter( $name );
 608                 $self->redirect_to( '/data/items' );
 609         }
 610
 611         my $facet;
 612         my $name = $self->param('name') || die "no name";
 613
 614         my $all = $self->_perm_scalar('all', 1);
 615         my $data = $self->_loaded('data');
 616
 617         my $filters = $self->_current_filters;
 618         my $all_filters = join(' ',sort keys %$filters,'order:',$self->session('order'));
 619         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 620                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 621
 622         if ( ! $filtered || $all ) {
 623                 $filtered = [ 0 .. $#{ $data->{items} } ];
 624                 warn "filter all values\n";
 625         } else {
 626                 warn "filter using $all_filters\n";
 627         }
 628
 629         foreach my $i ( @$filtered ) {
 630                 my $item = $data->{items}->[$i];
 631                 if ( ! exists $item->{$name} ) {
 632                         $facet->{ _missing }++;
 633                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 634                         $facet->{$_}++ foreach @{ $item->{$name} };
 635                 } else {
 636                         $facet->{ $item->{$name} }++;
 637                 }
 638         }
 639
 640 #       warn "# facet $name ",dump $facet;
 641
 642         my $checked;
 643         my @facet_names =
 644                   $all                      ? keys %$facet
 645                 : defined $filters->{$name} ? @{ $filters->{$name} }
 646                 : keys %$facet;
 647
 648         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 649
 650         my $numeric = $self->_is_numeric($name);
 651
 652         my $sort = $self->param('sort');
 653         # sort numeric facets with more than 5 values ascending
 654         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 655
 656         @facet_names = sort {
 657                 my $result;
 658                 if ( $sort eq 'a' ) {
 659                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 660                 } elsif ( $sort eq 'd' ) {
 661                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 662                 } elsif ( $sort eq 'c' ) {
 663                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 664                 } else {
 665                         warn "unknown sort: $sort";
 666                         $result = $a cmp $b;
 667                 }
 668                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 669                 $result;
 670         } @facet_names;
 671
 672         $self->render( name => $name, facet => $facet, checked => $checked,
 673                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 674         );
 675 }
 676
 677 sub edit {
 678         my $self = shift;
 679         my $content = $self->param('content');
 680
 681         my $i = $self->param('_row_id');
 682         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
 683         my $path = $self->param('path') || die "no path";
 684         my $name = $self->param('name') || die "no name";
 685         my $status = 200; # 200 = OK, 201 = Created
 686
 687         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
 688                 $content =~ s/^\s+//s;
 689                 $content =~ s/\s+$//s;
 690                 my $v;
 691                 if ( $content =~ /\xB6/ ) {     # para
 692                         $v = [ split(/\s*\xB6\s*/, $content) ];
 693                 } else {
 694                         $v = [ $content ];
 695                 }
 696
 697                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
 698                 my $new = dump $v;
 699                 if ( $old ne $new ) {
 700                         warn "# update $path $i $old -> $new\n";
 701                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
 702
 703                         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
 704                             delete $loaded->{$path}->{sorted}->{$name};
 705                                 warn "# invalidate $path sorted $name\n";
 706                         }
 707
 708                         foreach ( grep { m/$name/ } keys %{ $loaded->{$path}->{filtered} } ) {
 709                             delete $loaded->{$path}->{filtered}->{$_};
 710                                 warn "# invalidate $path filtered $_\n";
 711                         }
 712
 713                         $status = 201; # created
 714                         $self->session('save_path' => $path);
 715
 716                 } else {
 717                         warn "# unchanged $path $i $old\n";
 718                         $status = 304;
 719                 }
 720         } else {
 721                 $content = "$path $i $name doesn't exist\n";
 722                 $status = 404;
 723         }
 724
 725         warn "# edit $status $content";
 726
 727         $self->render(
 728                 status => $status,
 729                 content => $content,
 730         );
 731 }
 732
 733
 734 sub save {
 735         my $self = shift;
 736         my $path = $self->param('path');
 737         $path  ||= $self->session('path');
 738
 739         my $dump_path = $self->_save( $path );
 740         $self->session('save_path' => 0);
 741
 742         $self->redirect_to( '/data/items' );
 743 }
 744
 745 1;