lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14 use Storable;
  15 use Time::HiRes qw(time);
  16
  17 our $loaded;
  18 our $filters;
  19
  20 sub index {
  21         my $self = shift;
  22
  23         my $path = $self->app->home->rel_dir('data');
  24         die "no data dir $path" unless -d $path;
  25
  26         my @files;
  27         my $edits;
  28         find( sub {
  29                 my $file = $File::Find::name;
  30                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  31                         $file =~ s/$path\/*//;
  32                         push @files, $file;
  33                 } elsif ( -f $file && $file =~ m/([^\/]+)\.edits\/(\d+\.\d+.+)/ ) {
  34                         push @{ $edits->{$1} }, $2
  35                 } else {
  36                         warn "IGNORE: $file\n";
  37                 }
  38         }, $path);
  39
  40         @files = sort { lc $a cmp lc $b } @files;
  41         my $size;
  42         $size->{$_} = -s "$path/$_" foreach @files;
  43
  44         if ( my $save_path = $self->session('save_path') ) {
  45                 $self->session( 'save_path' => 0 )
  46                 if ! defined $loaded->{$save_path};
  47         }
  48
  49         $self->render(
  50                 files => [ @files ],
  51                 size => $size,
  52                 loaded => $loaded,
  53                 filters => $filters,
  54                 dump_path => { map { $_ => $self->_dump_path($_) } @files },
  55                 edits => $edits,
  56         );
  57 }
  58
  59 sub _dump_path {
  60         my ( $self, $name ) = @_;
  61         my $dir = $self->app->home->rel_dir('data');
  62         $name =~ s/^$dir//;
  63         $name =~ s/\/+/_/g;
  64         return '/tmp/mojo_facets.' . $name . '.storable';
  65 }
  66
  67 sub _save {
  68         my ( $self, $path ) = @_;
  69
  70         my $dump_path = $self->_dump_path( $path );
  71         my $first_load = ! -e $dump_path;
  72         warn "save loaded to $dump_path";
  73         my $info = $loaded->{$path};
  74         store $info, $dump_path;
  75
  76         if ( $first_load ) {
  77                 my $mtime = $loaded->{$path}->{mtime};
  78                 utime $mtime, $mtime, $dump_path;
  79                 warn "sync time to $path at $mtime\n";
  80         }
  81
  82         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  83         return $dump_path;
  84 }
  85
  86
  87 sub __stats {
  88
  89         my $stats;
  90
  91         my $nr_items = $#{ $_[0] } + 1;
  92
  93         foreach my $e ( @{ $_[0] } ) {
  94                 foreach my $n ( keys %$e ) {
  95                         $stats->{$n}->{count}++;
  96                         my @v;
  97                         if ( ref $e->{$n} eq 'ARRAY' ) {
  98                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
  99                                 @v = @{ $e->{$n} };
 100                         } else {
 101                                 @v = ( $e->{$n} );
 102                         }
 103
 104                         foreach my $x ( @v ) {
 105                                 $stats->{$n}->{numeric}++
 106                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 107                                 $stats->{$n}->{empty}++
 108                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 109                         }
 110
 111                 }
 112         }
 113
 114         foreach my $n ( keys %$stats ) {
 115                 my $s = $stats->{$n};
 116                 next unless defined $s->{array};
 117                 if ( $s->{array} == $s->{count} ) {
 118                         delete $s->{array};
 119                         if ( $s->{count} == $nr_items ) {
 120                                 warn "check $n for uniqeness\n";
 121                                 my $unique;
 122                                 foreach my $e ( @{ $_[0] } ) {
 123                                         if ( ++$unique->{ $e->{$n}->[0] } == 2 ) {
 124                                                 $unique = 0;
 125                                                 last;
 126                                         }
 127                                 }
 128                                 if ( $unique ) {
 129                                         $stats->{$n}->{unique} = 1;
 130                                         warn "# $n unique ",dump( $unique );
 131                                 }
 132                         }
 133                 }
 134         }
 135
 136         warn "# __stats ",dump($stats);
 137
 138         return $stats;
 139 }
 140
 141
 142
 143 sub _load_path {
 144         my ( $self, $path ) = @_;
 145
 146         my $full_path = $self->app->home->rel_file( 'data/' . $path );
 147         die "$full_path $!" unless -r $full_path;
 148
 149         my $dump_path = $self->_dump_path( $path );
 150
 151         if ( defined $loaded->{$path}->{data} ) {
 152                 my $mtime = (stat($full_path))[9];
 153                 return if $loaded->{$path}->{mtime} == $mtime;
 154                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
 155         } elsif ( -e $dump_path ) {
 156                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
 157                 my $info = retrieve $dump_path;
 158                 $loaded->{ $path } = $info;
 159                 return;
 160         }
 161
 162         # we could use Mojo::JSON here, but it's too slow
 163 #       $data = from_json read_file $path;
 164         my $data = read_file $full_path;
 165         warn "# data snippet: ", substr($data,0,200);
 166         my @header;
 167         if ( $path =~ m/\.js/ ) {
 168                 Encode::_utf8_on($data);
 169                 $data = from_json $data;
 170         } elsif ( $path =~ m/\.txt/ ) {
 171                 my @lines = split(/\r?\n/, $data);
 172                 $data = { items => [] };
 173
 174                 my $header_line = shift @lines;
 175                 my $multiline = $header_line =~ s/\^//g;
 176                 @header = split(/\|/, $header_line );
 177                 warn "# header ", dump( @header );
 178                 while ( my $line = shift @lines ) {
 179                         $line =~ s/\^//g;
 180                         chomp $line;
 181                         my @v = split(/\|/, $line);
 182                         while ( @lines && $#v < $#header ) {
 183                                 $line = $lines[0];
 184                                 $line =~ s/\^//g;
 185                                 chomp $line;
 186                                 my @more_v = split(/\|/, $line);
 187                                 if ( $#v + $#more_v > $#header ) {
 188                                         warn "short line: ",dump( @v );
 189                                         last;
 190                                 }
 191                                 shift @lines;
 192                                 $v[ $#v ] .= shift @more_v if @more_v;
 193                                 push @v, @more_v if @more_v;
 194
 195                                 if ( $#v > $#header ) {
 196                                         die "# splice $#header ", dump( @v );
 197                                         @v = splice @v, 0, $#header;
 198                                 }
 199                         }
 200                         my $item;
 201                         foreach my $i ( 0 .. $#v ) {
 202                                 $item->{ $header[$i] || "f_$i" } = [ $v[$i] ];
 203                         }
 204                         push @{ $data->{items} }, $item;
 205                 }
 206         } else {
 207                 warn "file format unknown $path";
 208         }
 209
 210         my $stats = __stats( $data->{items} );
 211
 212         if ( ! @header ) {
 213                 if ( defined $data->{header} ) {
 214                         if ( ref $data->{header} eq 'ARRAY' ) {
 215                                 @header = @{ $data->{header} };
 216                         } else {
 217                                 warn "header not array ", dump( $data->{header} );
 218                         }
 219                 }
 220         }
 221
 222         @header =
 223                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 224                 grep { defined $stats->{$_}->{count} } keys %$stats
 225                 unless @header;
 226
 227         my $info = {
 228                 header => [ @header ],
 229                 stats  => $stats,
 230                 full_path => $full_path,
 231                 size => -s $full_path,
 232                 mtime => (stat($full_path))[9],
 233                 data => $data,
 234         };
 235
 236         $loaded->{ $path } = $info;
 237         $self->_save( $path );
 238
 239 }
 240
 241
 242 sub load {
 243         my $self = shift;
 244
 245         my @paths = $self->param('paths');
 246         warn "# paths ", dump @paths;
 247         $self->_load_path( $_ ) foreach @paths;
 248
 249         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 250         warn "# path $path\n";
 251         $self->session('path' => $path);
 252         $self->_load_path( $path );
 253
 254         $self->session( 'header' => $loaded->{$path}->{header} );
 255         if ( ! defined $loaded->{$path}->{columns} ) {
 256                 $self->session( 'columns' => $loaded->{$path}->{header} );
 257                 $self->session( 'order'   => $loaded->{$path}->{header}->[0] );
 258                 $self->redirect_to( '/data/columns' );
 259         } else {
 260                 $self->session( 'columns' => $loaded->{$path}->{columns} );
 261                 $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 262                 $self->redirect_to( '/data/items' );
 263         }
 264 }
 265
 266
 267 sub _loaded {
 268         my ( $self, $name ) = @_;
 269         my $path = $self->session('path') || $self->param('path');
 270         $self->redirect_to('/data/index') unless $path;
 271         if ( ! defined $loaded->{$path}->{$name} ) {
 272                 warn "$path $name isn't loaded\n";
 273                 $self->_load_path( $path );
 274                 $self->redirect_to('/data/index')
 275                         unless defined $loaded->{$path}->{$name};
 276         }
 277         return $loaded->{$path}->{$name};
 278 }
 279
 280
 281 sub _checked {
 282         my $self = shift;
 283         my $checked;
 284         $checked->{$_}++ foreach @_;
 285 #       warn "# _checked ",dump($checked);
 286         return $checked;
 287 }
 288
 289
 290 sub columns {
 291     my $self = shift;
 292
 293         if ( $self->param('columns') ) {
 294                 $self->_perm_array('columns');
 295                 $self->redirect_to('/data/items');
 296         }
 297
 298         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 299
 300         my @columns;
 301         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 302
 303         foreach my $c ( @{ $self->session( 'header' ) } ) {
 304                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 305         }
 306
 307     $self->render(
 308                 message => 'Select columns to display',
 309                 stats => $stats,
 310                 columns => \@columns,
 311                 checked => $self->_checked( $self->_perm_array('columns') ),
 312         );
 313 }
 314
 315 sub _perm_array {
 316     my ($self,$name) = @_;
 317
 318         my @array = $self->param($name);
 319         my $path  = $self->session('path');
 320
 321         if ( @array ) {
 322                 $self->session($name => [ @array ]);
 323                 $loaded->{$path}->{$name} = [ @array ];
 324         } elsif ( my $session = $self->session($name) ) {
 325                 if ( ref $session eq 'ARRAY' ) {
 326                         @array = @$session;
 327                 } else {
 328                         die "$name not array ",dump($session);
 329                 }
 330         }
 331         #warn "# $name ",dump @array;
 332         return @array;
 333 }
 334
 335 sub _perm_scalar {
 336     my ($self,$name,$default) = @_;
 337
 338         my $scalar = $self->param($name);
 339
 340         if ( defined $scalar ) {
 341                 $self->session($name => $scalar);
 342         } else {
 343                 $scalar = $self->session($name);
 344         }
 345
 346         if ( ! defined $scalar ) {
 347                 $scalar = $default;
 348                 die "no default for $name" unless defined $scalar;
 349                 $self->session($name => $scalar);
 350         }
 351
 352         warn "# _perm_scalar $name ",dump $scalar;
 353         return $scalar;
 354 }
 355
 356 sub filter {
 357         my $self = shift;
 358
 359         my $name = $self->param('filter_name') || die "name?";
 360         my @vals = $self->param('filter_vals');
 361
 362         $self->_remove_filter( $name );
 363         $self->_filter_on_data( $name, @vals ) if @vals;
 364
 365         $self->session( 'offset' => 0 );
 366
 367         $self->redirect_to('/data/items');
 368 }
 369
 370 sub _filter_on_data {
 371         my ( $self, $name, @vals ) = @_;
 372
 373         my $path = $self->session('path');
 374
 375         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 376                 warn "filter $name not found in data set";
 377                 return;
 378         }
 379
 380         $filters->{$name} = [ @vals ];
 381         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 382
 383         my $filter_hash;
 384         $filter_hash->{$_}++ foreach @vals;
 385
 386         #warn "# filter_hash ",dump( $filter_hash );
 387
 388         my $items = $self->_loaded('data')->{items};
 389
 390         my $include_missing = defined $filter_hash->{_missing};
 391         my $filtered_items;
 392
 393         foreach my $i ( 0 .. $#$items ) {
 394
 395                 if ( defined $items->[$i]->{$name} ) {
 396                         foreach my $v ( @{ $items->[$i]->{$name} } ) {
 397                                 if ( defined $filter_hash->{ $v } ) {
 398                                         $filtered_items->{$i}++;
 399                                 }
 400                         }
 401                 } elsif ( $include_missing ) {
 402                         $filtered_items->{$i}++;
 403                 }
 404         }
 405
 406         #warn "# filter $name ",dump($filtered_items);
 407
 408         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 409         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 410 }
 411
 412 sub _data_items {
 413         my ( $self, $all ) = @_;
 414         my $data = $self->_loaded( 'data' );
 415
 416         return @{ $data->{items} } if $all == 1;
 417
 418         my $filters = $self->_current_filters;
 419         my $filter_value;
 420         foreach my $f ( keys %$filters ) {
 421                 foreach my $n ( @{ $filters->{$f} } ) {
 422                         $filter_value->{$f}->{$n} = 1;
 423                 }
 424         }
 425         my @items = @{ $data->{items} };
 426         @items = grep {
 427                 my $i = $_;
 428                 my $pass = 1;
 429                 foreach my $n ( keys %$filter_value ) {
 430                         if ( ! exists $i->{$n} ) {
 431                                 if ( defined $filter_value->{$n}->{_missing} ) {
 432                                         $pass = 1;
 433                                         next;
 434                                 } else {
 435                                         $pass = 0;
 436                                         last;
 437                                 }
 438                         }
 439                         # and match any of values in element
 440                         my $have_values = 0;
 441                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 442                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 443                         }
 444                         if ( ! $have_values ) {
 445                                 $pass = 0;
 446                                 last;
 447                         }
 448                 }
 449                 $pass;
 450         } @items if $filter_value;
 451         return @items;
 452 }
 453
 454
 455 sub _current_filters {
 456         my $self = shift;
 457         my $current_filters;
 458         $current_filters->{ $_ } = $filters->{ $_ }
 459                 foreach (
 460                         grep { defined $filters->{ $_ } }
 461                         @{ $self->_loaded('header') }
 462                 );
 463         #warn "# current_filters ",dump($current_filters);
 464         return $current_filters;
 465 }
 466
 467 sub _data_sorted_by {
 468         my ( $self, $order ) = @_;
 469
 470         my $path = $self->session('path');
 471
 472         warn "_data_sorted_by $order from $path";
 473
 474         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 475                 return $loaded->{$path}->{sorted}->{$order};
 476         }
 477
 478         my $data = $self->_loaded( 'data' );
 479         my $numeric = $self->_is_numeric($order);
 480         my $missing = $numeric ? 0 : '';
 481         no warnings qw(numeric);
 482         my $nr = 0;
 483         my @sorted = map {
 484                 $_->[0]
 485         } sort {
 486                 if ( $numeric ) {
 487                         $a->[1] <=> $b->[1]
 488                 } else {
 489                         $a->[1] cmp $b->[1]
 490                 }
 491         } map {
 492                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 493         } @{ $data->{items} }
 494         ;
 495
 496         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 497         #warn "# sorted ",dump( @sorted );
 498
 499         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 500 }
 501
 502
 503 sub items {
 504         my $self = shift;
 505
 506         my $path = $self->session('path');
 507         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 508
 509         my @columns = $self->_perm_array('columns');
 510         $self->redirect_to('/data/columns') unless @columns;
 511         my $order   = $self->_perm_scalar('order', $columns[0]);
 512         my $sort    = $self->_perm_scalar('sort', 'a');
 513         my $offset  = $self->_perm_scalar('offset', 0);
 514         my $limit   = $self->_perm_scalar('limit', 20);
 515         $self->_perm_scalar('show', 'table');
 516
 517         # fix offset when changing limit
 518         $offset = int( $offset / $limit ) * $limit;
 519
 520         my $sorted = $self->_data_sorted_by( $order );
 521
 522         my @filter_names;
 523         if ( $filters ) {
 524                 foreach my $name ( keys %$filters ) {
 525                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 526                                 warn "skip filter $name not found in $path\n";
 527                                 next;
 528                         }
 529                         push @filter_names, $name;
 530                 }
 531                 warn "filter_names ",dump( @filter_names );
 532                 foreach my $name ( @filter_names ) {
 533                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 534                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 535                 }
 536         }
 537
 538         my $all_filters = join(' ',sort @filter_names,'order:',$order);
 539
 540 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 541
 542         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 543
 544                 my $path_filters = $loaded->{$path}->{filters};
 545
 546                 warn "create combined filter for $all_filters\n";
 547
 548                 my @filtered;
 549                 foreach my $i ( 0 .. $#$sorted ) {
 550                         my $pos = $sorted->[$i];
 551
 552                         if ( $#filter_names == -1 ) {
 553                                 push @filtered, $pos;
 554                                 next;
 555                         }
 556
 557                         my $skip = 0;
 558                         foreach ( @filter_names ) {
 559                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 560                         }
 561                         next if $skip;
 562
 563                         push @filtered, $pos;
 564                 }
 565
 566                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 567         }
 568
 569         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 570                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 571
 572         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 573
 574         my $sorted_items;
 575         my $data = $self->_loaded('data');
 576         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 577         foreach ( 0 .. $limit ) {
 578                 my $i = $_ + $offset;
 579                 last unless defined $filtered->[$i];
 580                 $i = $from_end - $i if $from_end;
 581                 my $id = $filtered->[$i];
 582                 push @$sorted_items,
 583                 my $item = $data->{items}->[ $id ];
 584                 $item->{_row_id} ||= $id;
 585         }
 586
 587         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 588
 589         $self->render(
 590                 order => $order,
 591                 offset => $offset,
 592                 limit => $limit,
 593                 sorted => $sorted_items,
 594                 columns => [ @columns ],
 595                 rows => $#$filtered + 1,
 596                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 597                 filters => $self->_current_filters,
 598         );
 599
 600 }
 601
 602
 603 sub order {
 604         my $self = shift;
 605         $self->session('order', $self->param('order'));
 606         $self->session('sort', $self->param('sort'));
 607         $self->redirect_to('/data/items');
 608 }
 609
 610 sub _is_numeric {
 611         my ( $self, $name ) = @_;
 612
 613         my $stats = $self->_loaded( 'stats' );
 614
 615         # sort facet numerically if more >50% elements are numeric
 616         my $count = $stats->{$name}->{count};
 617         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 618         defined $stats->{$name}->{numeric} &&
 619                 $stats->{$name}->{numeric} > $count / 2;
 620 }
 621
 622 sub _remove_filter {
 623         my ($self,$name) = @_;
 624         warn "_remove_filter $name\n";
 625
 626         my $path = $self->session('path');
 627
 628         delete $filters->{$name};
 629         delete $loaded->{$path}->{filters}->{$name};
 630         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 631
 632         foreach (
 633                         grep { /\b$name\b/ }
 634                         keys %{ $loaded->{$path}->{filtered} }
 635         ) {
 636                 delete $loaded->{$path}->{filtered}->{$_};
 637                 warn "remove filtered cache $_";
 638         }
 639 }
 640
 641 sub facet {
 642         my $self = shift;
 643
 644         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 645
 646         if ( my $name = $self->param('remove') ) {
 647                 $self->_remove_filter( $name );
 648                 $self->redirect_to( '/data/items' );
 649         }
 650
 651         my $facet;
 652         my $name = $self->param('name') || die "no name";
 653
 654         my $all = $self->_perm_scalar('all', 1);
 655         my $data = $self->_loaded('data');
 656
 657         my $filters = $self->_current_filters;
 658         my $all_filters = join(' ',sort keys %$filters,'order:',$self->session('order'));
 659         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 660                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 661
 662         if ( ! $filtered || $all ) {
 663                 $filtered = [ 0 .. $#{ $data->{items} } ];
 664                 warn "filter all values\n";
 665         } else {
 666                 warn "filter using $all_filters\n";
 667         }
 668
 669         foreach my $i ( @$filtered ) {
 670                 my $item = $data->{items}->[$i];
 671                 if ( ! exists $item->{$name} ) {
 672                         $facet->{ _missing }++;
 673                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 674                         $facet->{$_}++ foreach @{ $item->{$name} };
 675                 } else {
 676                         $facet->{ $item->{$name} }++;
 677                 }
 678         }
 679
 680 #       warn "# facet $name ",dump $facet;
 681
 682         my $checked;
 683         my @facet_names =
 684                   $all                      ? keys %$facet
 685                 : defined $filters->{$name} ? @{ $filters->{$name} }
 686                 : keys %$facet;
 687
 688         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 689
 690         my $numeric = $self->_is_numeric($name);
 691
 692         my $sort = $self->param('sort');
 693         # sort numeric facets with more than 5 values ascending
 694         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 695
 696         @facet_names = sort {
 697                 my $result;
 698                 if ( $sort eq 'a' ) {
 699                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 700                 } elsif ( $sort eq 'd' ) {
 701                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 702                 } elsif ( $sort eq 'c' ) {
 703                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 704                 } else {
 705                         warn "unknown sort: $sort";
 706                         $result = $a cmp $b;
 707                 }
 708                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 709                 $result;
 710         } @facet_names;
 711
 712         $self->render( name => $name, facet => $facet, checked => $checked,
 713                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 714         );
 715 }
 716
 717 sub edit {
 718         my $self = shift;
 719         my $content = $self->param('content');
 720
 721         my $i = $self->param('_row_id');
 722         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
 723         my $path = $self->param('path') || die "no path";
 724         my $name = $self->param('name') || die "no name";
 725         my $status = 200; # 200 = OK, 201 = Created
 726
 727         my $data = $self->_loaded('data');
 728
 729         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
 730                 $content =~ s/^\s+//s;
 731                 $content =~ s/\s+$//s;
 732                 my $v;
 733                 if ( $content =~ /\xB6/ ) {     # para
 734                         $v = [ split(/\s*\xB6\s*/, $content) ];
 735                 } else {
 736                         $v = [ $content ];
 737                 }
 738
 739                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
 740                 my $new = dump $v;
 741                 if ( $old ne $new
 742                         && ! ( $old eq 'undef' && length($content) == 0 ) # new value empty, previous undef
 743                 ) {
 744                         my $edit = {
 745                                 path => $path,
 746                                 column => $name,
 747                                 pos => $i,
 748                                 old => $loaded->{$path}->{data}->{items}->[$i]->{$name},
 749                                 new => $v,
 750                                 time => $self->param('time') || time(),
 751                                 user => $self->param('user') || $ENV{'LOGNAME'},
 752                                 unique => {
 753                                         map { $_ => $loaded->{$path}->{data}->{items}->[$i]->{$_}->[0] }
 754                                         grep { defined $loaded->{$path}->{stats}->{$_}->{unique} }
 755                                         keys %{ $loaded->{$path}->{stats} }
 756                                 },
 757                         };
 758                         my $edit_path = $self->app->home->rel_dir('data') . '/' . $path . '.edits';
 759                         mkdir $edit_path unless -d $edit_path;
 760                         $edit_path .= '/' . $edit->{time};
 761                         store $edit, $edit_path;
 762                         utime $edit->{time}, $edit->{time}, $edit_path;
 763                         warn "# $edit_path ", dump($edit);
 764
 765                         warn "# edit $path $i $old -> $new\n";
 766                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
 767
 768                         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
 769                             delete $loaded->{$path}->{sorted}->{$name};
 770                                 warn "# invalidate $path sorted $name\n";
 771                         }
 772
 773                         foreach ( grep { m/$name/ } keys %{ $loaded->{$path}->{filtered} } ) {
 774                             delete $loaded->{$path}->{filtered}->{$_};
 775                                 warn "# invalidate $path filtered $_\n";
 776                         }
 777
 778                         $status = 201; # created
 779                         $self->session('save_path' => $path);
 780
 781                 } else {
 782                         warn "# unchanged $path $i $old\n";
 783                         $status = 304;
 784                 }
 785         } else {
 786                 $content = "$path $i $name doesn't exist\n";
 787                 $status = 404;
 788         }
 789
 790         warn "# edit $status $content";
 791
 792         $self->render(
 793                 status => $status,
 794                 content => $content,
 795         );
 796 }
 797
 798
 799 sub save {
 800         my $self = shift;
 801         my $path = $self->param('path');
 802         $path  ||= $self->session('path');
 803
 804         my $dump_path = $self->_save( $path );
 805         $self->session('save_path' => 0);
 806
 807         $self->redirect_to( '/data/items' );
 808 }
 809
 810 1;