lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use Encode;
  11 use locale;
  12 use File::Find;
  13 use Storable;
  14 use Time::HiRes qw(time);
  15 use File::Path qw(mkpath);
  16 use Text::Unaccent::PurePerl;
  17 use Digest::MD5;
  18
  19 use MojoFacets::Import::File;
  20 use MojoFacets::Import::HTMLTable;
  21 use MojoFacets::Import::CSV;
  22 use MojoFacets::Import::CouchDB;
  23
  24 our $loaded;
  25 our $filters;
  26
  27 sub index {
  28         my $self = shift;
  29
  30         my $data_dir = $self->app->home->rel_dir('data');
  31         die "no data dir $data_dir" unless -d $data_dir;
  32
  33         my @files;
  34         my $changes;
  35         find( sub {
  36                 my $file = $File::Find::name;
  37                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  38                         $file =~ s/$data_dir\/*//;
  39                         push @files, $file;
  40                 } elsif ( -f $file && $file =~ m/([^\/]+)\.changes\/(\d+\.\d+.+)/ ) {
  41                         push @{ $changes->{$1} }, $2
  42                 } elsif ( -d $file && $file =~ m/\.html$/ ) {
  43                         $file =~ s/$data_dir\/*//;
  44                         push @files, $file;
  45                 } elsif ( -f $file && $file =~ m/\.(csv|storabe|couchdb)$/i ) {
  46                         $file =~ s/$data_dir\/*//;
  47                         push @files, $file;
  48                 } else {
  49                         #warn "IGNORE: $file\n";
  50                 }
  51         }, $data_dir);
  52
  53         no warnings qw(uninitialized); # mtime
  54         @files = sort { $loaded->{$b}->{mtime} <=> $loaded->{$a}->{mtime} || lc $a cmp lc $b } @files,
  55                         grep { defined $loaded->{$_}->{generated} } keys %$loaded;
  56         my $size;
  57         $size->{$_} = -s "$data_dir/$_" foreach @files;
  58
  59         $self->render(
  60                 files => [ @files ],
  61                 size => $size,
  62                 loaded => $loaded,
  63                 filters => $filters,
  64                 dump_path => { map { $_ => $self->_dump_path($_) } @files },
  65                 changes => $changes,
  66         );
  67 }
  68
  69 sub _dump_path {
  70         my ( $self, $name ) = @_;
  71         my $dir = $self->app->home->rel_dir('data');
  72         $name =~ s/^$dir//;
  73         $name =~ s/\/+/_/g;
  74         return '/tmp/mojo_facets.' . $name . '.storable';
  75 }
  76
  77 sub _save {
  78         my ( $self, $path ) = @_;
  79
  80         my $dump_path = $self->_dump_path( $path );
  81         my $first_load = ! -e $dump_path;
  82         warn "save loaded to $dump_path";
  83         my $info = $loaded->{$path};
  84         store $info, $dump_path;
  85
  86         if ( $first_load ) {
  87                 my $mtime = $loaded->{$path}->{mtime};
  88                 utime $mtime, $mtime, $dump_path;
  89                 warn "sync time to $path at $mtime\n";
  90         }
  91
  92         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  93         return $dump_path;
  94 }
  95
  96
  97 sub __stats {
  98
  99         my $stats;
 100
 101         my $nr_items = $#{ $_[0] } + 1;
 102
 103         warn "__stats $nr_items\n";
 104
 105         foreach my $e ( @{ $_[0] } ) {
 106                 foreach my $n ( keys %$e ) {
 107                         $stats->{$n}->{count}++;
 108                         my @v;
 109                         if ( ref $e->{$n} eq 'ARRAY' ) {
 110                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 111                                 @v = @{ $e->{$n} };
 112                         } else {
 113                                 @v = ( $e->{$n} );
 114                         }
 115
 116                         foreach my $x ( @v ) {
 117                                 $stats->{$n}->{numeric}++
 118                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 119                                 $stats->{$n}->{empty}++
 120                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 121                         }
 122
 123                 }
 124         }
 125
 126         foreach my $n ( keys %$stats ) {
 127                 my $s = $stats->{$n};
 128                 next unless defined $s->{array};
 129                 if ( $s->{array} == $s->{count} ) {
 130                         delete $s->{array};
 131                         if ( $s->{count} == $nr_items ) {
 132                                 warn "check $n for uniqeness\n";
 133                                 my $unique;
 134                                 foreach my $e ( @{ $_[0] } ) {
 135                                         if ( ++$unique->{ $e->{$n}->[0] } == 2 ) {
 136                                                 $unique = 0;
 137                                                 last;
 138                                         }
 139                                 }
 140                                 if ( $unique ) {
 141                                         $stats->{$n}->{unique} = 1;
 142                                         #warn "# $n unique ",dump( $unique );
 143                                 }
 144                         }
 145                 }
 146         }
 147
 148         warn "# __stats ",dump($stats);
 149
 150         return $stats;
 151 }
 152
 153 sub _param_or_session {
 154         $_[0]->param( $_[1] ) || $_[0]->session( $_[1] )
 155 }
 156
 157 sub stats {
 158         my $self = shift;
 159         my $path = $self->_param_or_session('path');
 160         warn "stats $path\n";
 161         delete $loaded->{$path}->{stats};
 162         return $self->redirect_to( '/data/columns' );
 163 }
 164
 165
 166 sub _load_path {
 167         my ( $self, $path ) = @_;
 168
 169         return if defined $loaded->{$path}->{generated};
 170
 171         my $full_path = $self->app->home->rel_file( 'data/' . $path );
 172         return $self->redirect_to('/data/index') unless -r $full_path;
 173
 174         my $dump_path = $self->_dump_path( $path );
 175
 176         if ( defined $loaded->{$path}->{data} ) {
 177                 my $mtime = (stat($full_path))[9];
 178                 return if $loaded->{$path}->{mtime} == $mtime;
 179                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
 180         } elsif ( -e $dump_path ) {
 181                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
 182                 my $info = retrieve $dump_path;
 183                 $loaded->{ $path } = $info;
 184                 return;
 185         }
 186
 187         my $data;
 188         if ( -f $full_path ) {
 189                 if ( $full_path =~ m/.csv/i ) {
 190                         $data = MojoFacets::Import::CSV->new( full_path => $full_path )->data;
 191                 } elsif ( $full_path =~ m/.couchdb/i ) {
 192                         $data = MojoFacets::Import::CouchDB->new( full_path => $full_path )->data;
 193                 } elsif ( $full_path =~ m/.storable/ ) {
 194                         warn "open $full_path ", -s $full_path, " bytes";
 195                         open(my $pipe, "<", $full_path) || die $!;
 196                         while ( my $o = eval { Storable::fd_retrieve $pipe } ) {
 197                                 if ( defined $o->{item} ) {
 198                                         push @{ $data->{items} }, $o->{item};
 199                                 } else {
 200                                         warn "SKIP ",dump($o);
 201                                 }
 202                         }
 203                         close($pipe);
 204                         warn "loaded ", $#{ $data->{items} } + 1, " items from $full_path\n";
 205                         $data->{generated}++;
 206                 } else {
 207                         $data = MojoFacets::Import::File->new( full_path => $full_path, path => $path )->data;
 208                 }
 209         } elsif ( -d $full_path && $full_path =~ m/.html/ ) {
 210                 $data = MojoFacets::Import::HTMLTable->new( dir => $full_path )->data;
 211         } else {
 212                 die "can't load $full_path";
 213         }
 214
 215         my @header;
 216
 217         if ( defined $data->{header} ) {
 218                 if ( ref $data->{header} eq 'ARRAY' ) {
 219                         @header = @{ $data->{header} };
 220                 } else {
 221                         warn "header not array ", dump( $data->{header} );
 222                 }
 223         }
 224
 225         my $stats = __stats( $data->{items} );
 226
 227         @header =
 228                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 229                 grep { defined $stats->{$_}->{count} } keys %$stats
 230                 unless @header;
 231
 232         my $info = {
 233                 header => [ @header ],
 234                 stats  => $stats,
 235                 full_path => $full_path,
 236                 size => -s $full_path,
 237                 mtime => (stat($full_path))[9],
 238                 data => $data,
 239                 defined $data->{generated} ? ( generated => 1 ) : (),
 240         };
 241
 242         $loaded->{ $path } = $info;
 243         $self->_save( $path ) unless $info->{generated};
 244
 245 }
 246
 247
 248 sub load {
 249         my $self = shift;
 250
 251         my $path = $self->param('path') || return $self->redirect_to( '/data/index' );
 252
 253         my @paths = $self->param('paths');
 254         warn "# paths ", dump @paths;
 255
 256         foreach my $p ( keys %$loaded ) {
 257                 next if grep { /^\Q$p\E$/ } @paths;
 258                 warn "remove $p from memory\n";
 259                 delete $loaded->{$p};
 260         }
 261
 262         $self->_load_path( $_ ) foreach @paths;
 263
 264         warn "# path $path\n";
 265         $self->_load_path( $path );
 266
 267         $self->session( 'path' => $path );
 268
 269         my $redirect_to = '/data/items';
 270
 271         $self->session( 'header' => $loaded->{$path}->{header} );
 272         if ( ! defined $loaded->{$path}->{columns} ) {
 273                 my $columns_path = $self->_permanent_path( 'columns' );
 274                 if ( -e $columns_path ) {
 275                         my @columns = map { s/[\r\n]+$//; $_ } read_file $columns_path, binmode => ':utf8';
 276                         $loaded->{$path}->{columns} = [ @columns ];
 277                         warn "# columns_path $columns_path ",dump(@columns);
 278                 } else {
 279                         $loaded->{$path}->{columns} = $loaded->{$path}->{header}
 280                 }
 281
 282                 $redirect_to = '/data/columns';
 283         }
 284         $self->session( 'columns' => $loaded->{$path}->{columns} );
 285         $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 286         return $self->redirect_to( $redirect_to );
 287 }
 288
 289
 290 sub _loaded {
 291         my ( $self, $name ) = @_;
 292         my $path = $self->session('path') || $self->param('path');
 293         return $self->redirect_to('/data/index') unless $path;
 294
 295         if ( defined $loaded->{$path}->{modified} && $loaded->{$path}->{modified} > 1 ) {
 296                 my $caller = (caller(1))[3];
 297                 if ( $caller =~ m/::edit/ ) {
 298                         warn "rebuild stats for $path ignored caller $caller\n";
 299                 } else {
 300                         warn "rebuild stats for $path FORCED by modified caller $caller\n";
 301 #                       $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 302                         $loaded->{$path}->{rebuild_stats} = 1;
 303                         $loaded->{$path}->{modified} = 1;
 304                 }
 305         }
 306
 307         if ( defined $loaded->{$path}->{rebuild_stats} ) {
 308                 warn "rebuild_stats $path";
 309                 $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 310                 delete $loaded->{$path}->{rebuild_stats};
 311         }
 312
 313         if ( ! defined $loaded->{$path}->{$name} ) {
 314                 warn "$path $name isn't loaded\n";
 315                 $self->_load_path( $path );
 316                 if ( ! defined $loaded->{$path}->{stats} ) {
 317                         warn "rebuild stats for $path\n";
 318                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 319                 }
 320                 if ( ! defined $loaded->{$path}->{$name} ) {
 321                         warn "MISSING $name for $path\n";
 322                         return $self->redirect_to('/data/index')
 323                 }
 324         }
 325
 326         $self->session( 'modified' => $loaded->{$path}->{modified} );
 327
 328         return $loaded->{$path}->{$name};
 329 }
 330
 331
 332 sub _checked {
 333         my $self = shift;
 334         my $checked;
 335         $checked->{$_}++ foreach @_;
 336 #       warn "# _checked ",dump($checked);
 337         return $checked;
 338 }
 339
 340 sub _permanent_path {
 341         my $self = shift;
 342         my $path = $self->_param_or_session('path');
 343         $self->app->home->rel_dir('data') . '/' . join('.', $path, @_);
 344 }
 345
 346 sub __unac {
 347         my $n = shift;
 348         $n = unac_string($n);
 349         $n =~ s/\W+/_/g;
 350         return $n;
 351 }
 352
 353 sub _column_from_unac {
 354         my ($self,$name) = @_;
 355
 356         my $stats = $self->_loaded('stats');
 357         my $cols_norm = { map { __unac( $_ ) => $_ } keys %$stats };
 358
 359         $cols_norm->{$name} || die "can't find column $name in ", dump($cols_norm);
 360 }
 361
 362 sub _export_path {
 363         my $self = shift;
 364         my $path = $self->_param_or_session('path');
 365         if ( ! $path ) {
 366                 warn "no path in param or session";
 367                 return;
 368         }
 369         my $dir = $self->app->home->rel_dir('public') . "/export/$path";
 370         mkpath $dir unless -e $dir;
 371         my $name = __export_path_name( $path, @_ );
 372         my $full = $dir . '/' . $name;
 373         $full =~ s/\/+$// if -d $full; # strip trailing slash for dirs
 374         return $full;
 375 }
 376
 377 sub __export_path_name {
 378         my $max_length = 80;
 379
 380         my $path = shift;
 381         my $name = join('.', map { __unac($_) } @_ );
 382         if ( length($name) > $max_length ) {
 383                 $name = substr($name,0,$max_length) . Digest::MD5::md5_hex substr($name,$max_length);
 384         }
 385         return $name;
 386 }
 387
 388 sub columns {
 389     my $self = shift;
 390
 391         my $view_path = $self->_permanent_path( 'views' );
 392
 393         if ( $self->param('columns') ) {
 394                 my @columns = $self->_param_array('columns');
 395                 write_file( $self->_permanent_path( 'columns' ), { binmode => ':utf8' }, map { "$_\n" } @columns );
 396                 if ( my $view = $self->param('view') ) {
 397                         mkdir $view_path unless -e $view_path;
 398                         write_file( "$view_path/$view", { binmode => ':utf8' }, map { "$_\n" } @columns );
 399                         warn "view $view_path/$view ", -s "$view_path/$view", " bytes\n";
 400                 }
 401
 402                 return $self->redirect_to('/data/items');
 403
 404         } elsif ( ! $self->session('header') ) {
 405                 return $self->redirect_to('/data/load');
 406         }
 407
 408         if ( my $id = $self->param('id') ) {
 409                 my $view_full = "$view_path/$id";
 410                 if ( -f $view_full ) {
 411                         my @columns = map { chomp; $_ } read_file $view_full, binmode => ':utf8';
 412                         warn "view $view_full loaded ", dump @columns;
 413                         $self->session( 'columns' => [ @columns ] );
 414                         return $self->redirect_to('/data/items');
 415                 }
 416         }
 417
 418         my $stats = $self->_loaded( 'stats' );
 419
 420         my @columns;
 421         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 422
 423         foreach my $c ( @{ $self->session( 'header' ) } ) {
 424                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 425         }
 426
 427         my @views;
 428         if ( -d $view_path ) {
 429                 @views = map { s{^\Q$view_path\E/*}{}; $_ } glob "$view_path/*";
 430                 warn "# views ",dump @views;
 431         }
 432
 433     $self->render(
 434                 message => 'Select columns to display',
 435                 stats => $stats,
 436                 columns => \@columns,
 437                 checked => $self->_checked( $self->_param_array('columns') ),
 438                 views => \@views,
 439         );
 440 }
 441
 442 sub _param_array {
 443     my ($self,$name) = @_;
 444
 445         my @array = $self->param($name);
 446         my $path  = $self->session('path');
 447
 448         if ( @array ) {
 449                 $self->session($name => [ @array ]);
 450                 $loaded->{$path}->{$name} = [ @array ];
 451         } elsif ( my $session = $self->session($name) ) {
 452                 if ( ref $session eq 'ARRAY' ) {
 453                         @array = @$session;
 454                 } else {
 455                         die "$name not array ",dump($session);
 456                 }
 457         }
 458         #warn "# $name ",dump @array;
 459         return @array;
 460 }
 461
 462 sub _param_scalar {
 463     my ($self,$name,$default) = @_;
 464
 465         my $scalar = $self->param($name);
 466
 467         if ( defined $scalar ) {
 468                 $self->session($name => $scalar);
 469         } else {
 470                 $scalar = $self->session($name);
 471         }
 472
 473         if ( ! defined $scalar ) {
 474                 $scalar = $default;
 475                 die "no default for $name" unless defined $scalar;
 476                 $self->session($name => $scalar);
 477         }
 478
 479         warn "# _param_scalar $name ",dump $scalar;
 480         return $scalar;
 481 }
 482
 483 sub filter {
 484         my $self = shift;
 485
 486         my $name = $self->param('filter_name') || die "name?";
 487         my @vals = $self->param('filter_vals');
 488
 489         $self->_remove_filter( $name );
 490         if ( @vals ) {
 491                 $self->_filter_on_data( $name, @vals );
 492                 if ( my $permanent = $self->param('_permanent') ) {
 493                         my $permanent_path = $self->_export_path( 'filter', $name, $permanent );
 494                         write_file $permanent_path, { binmode => ':utf8' }, map { "$_\n" } @vals;
 495                         warn "permanent filter $permanent_path ", -s $permanent_path;
 496                 }
 497         }
 498
 499         $self->session( 'offset' => 0 );
 500
 501         return $self->redirect_to('/data/items');
 502 }
 503
 504 sub _filter_on_data {
 505         my ( $self, $name, @vals ) = @_;
 506
 507         my $path = $self->session('path');
 508
 509         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 510                 warn "filter $name not found in data set";
 511                 return;
 512         }
 513
 514         $filters->{$name} = [ @vals ];
 515         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 516
 517         my $filter_hash;
 518         $filter_hash->{$_}++ foreach @vals;
 519
 520         #warn "# filter_hash ",dump( $filter_hash );
 521
 522         my $items = $self->_loaded('data')->{items};
 523
 524         my $include_missing = defined $filter_hash->{_missing};
 525         my $filtered_items;
 526
 527         foreach my $i ( 0 .. $#$items ) {
 528
 529                 if ( defined $items->[$i]->{$name} ) {
 530                         my $row = $items->[$i]->{$name};
 531                         $row = [ $row ] unless ref $row eq 'ARRAY'; # FIXME probably wrong place
 532                         foreach my $v ( @$row ) {
 533                                 if ( defined $filter_hash->{ $v } ) {
 534                                         $filtered_items->{$i}++;
 535                                 }
 536                         }
 537                 } elsif ( $include_missing ) {
 538                         $filtered_items->{$i}++;
 539                 }
 540         }
 541
 542         #warn "# filter $name ",dump($filtered_items);
 543
 544         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 545         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 546 }
 547
 548
 549 sub _current_filters {
 550         my $self = shift;
 551         my $current_filters;
 552         my $stats = $self->_loaded('stats');
 553
 554         $current_filters->{ $_ } = $filters->{ $_ }
 555                 foreach ( grep { defined $filters->{ $_ } } keys %$stats )
 556         ;
 557         warn "# _current_filters ",dump( keys %$current_filters );
 558         return $current_filters;
 559 }
 560
 561 sub _data_sorted_by {
 562         my ( $self, $order ) = @_;
 563
 564         my $path = $self->session('path');
 565
 566         warn "_data_sorted_by $order from $path";
 567
 568         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 569                 return $loaded->{$path}->{sorted}->{$order};
 570         }
 571
 572         my $data = $self->_loaded( 'data' );
 573         my $numeric = $self->_is_numeric($order);
 574         my $missing = $numeric ? 0 : '';
 575         no warnings qw(numeric);
 576         my $nr = 0;
 577         my @sorted = map {
 578                 $_->[0]
 579         } sort {
 580                 if ( $numeric ) {
 581                         $a->[1] <=> $b->[1]
 582                 } else {
 583                         $a->[1] cmp $b->[1]
 584                 }
 585         } map {
 586                 my $v;
 587                 if ( ! exists $_->{$order} ) {
 588                         $v = $missing;
 589                 } elsif ( ref $_->{$order} eq 'ARRAY' ) {
 590                         $v = join('', @{$_->{$order}});
 591                 } else {
 592                         $v = $_->{$order};
 593                 }
 594                 [ $nr++, $v ]
 595         } @{ $data->{items} }
 596         ;
 597
 598         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 599         #warn "# sorted ",dump( @sorted );
 600
 601         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 602 }
 603
 604
 605 sub __all_filters {
 606         my $order = pop @_;
 607         join(',', sort(@_), 'order', $order);
 608 }
 609
 610 our ($out, $key,$value);
 611
 612 sub __commit_path_code {
 613         my ( $path, $i, $code, $commit_changed ) = @_;
 614
 615         my $items = $loaded->{$path}->{data}->{items} || die "no items for $path";
 616         my $row = $items->[$i];
 617         my $update;
 618         eval $code;
 619         foreach ( keys %$update ) {
 620                 $$commit_changed->{$_}++;
 621                 $loaded->{$path}->{data}->{items}->[$i]->{$_} = $update->{$_};
 622         }
 623         #warn "__commit_path_code $path $i ",dump( $update );
 624 }
 625
 626 sub items {
 627         my $self = shift;
 628
 629         if ( my $show = $self->param('id') ) {
 630                 $self->param('show', $show);
 631                 warn "show $show\n";
 632         }
 633
 634         my $path = $self->_param_scalar('path');
 635
 636         my @columns = $self->_param_array('columns');
 637         return $self->redirect_to('/data/columns') unless @columns;
 638         my $order   = $self->_param_scalar('order', $columns[0]);
 639         my $sort    = $self->_param_scalar('sort', 'a');
 640         my $offset  = $self->_param_scalar('offset', 0);
 641         my $limit   = $self->_param_scalar('limit', 20);
 642         $self->_param_scalar('show', 'table');
 643
 644         # fix offset when changing limit
 645         $offset = int( $offset / $limit ) * $limit;
 646
 647         if ( ! grep { /^\Q$order\E$/ } @columns ) {
 648                 $order = $columns[0];
 649                 $self->session( order => $order );
 650         }
 651         my $sorted = $self->_data_sorted_by( $order );
 652
 653         my @filter_names;
 654         if ( $filters ) {
 655                 foreach my $name ( keys %$filters ) {
 656                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 657                                 warn "skip filter $name not found in $path\n";
 658                                 next;
 659                         }
 660                         push @filter_names, $name;
 661                 }
 662                 warn "filter_names ",dump( @filter_names );
 663                 foreach my $name ( @filter_names ) {
 664                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 665                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 666                 }
 667         }
 668
 669         my $all_filters = __all_filters( @filter_names,$order );
 670
 671 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 672
 673         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 674
 675                 my $path_filters = $loaded->{$path}->{filters};
 676
 677                 warn "create combined filter for $all_filters from ", $#$sorted + 1, " items\n";
 678
 679                 my @filtered;
 680                 foreach my $i ( 0 .. $#$sorted ) {
 681                         my $pos = $sorted->[$i];
 682
 683                         if ( $#filter_names == -1 ) {
 684                                 push @filtered, $pos;
 685                                 next;
 686                         }
 687
 688                         my $skip = 0;
 689                         foreach ( @filter_names ) {
 690                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 691                         }
 692                         next if $skip;
 693
 694                         push @filtered, $pos;
 695                 }
 696
 697                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 698         }
 699
 700         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 701                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 702
 703         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 704
 705         my $data = $self->_loaded('data');
 706
 707         my $code = $self->_param_scalar('code','');
 708         $code =~ s{\r}{}gs;
 709         $code =~ s{\n+$}{\n}s;
 710
 711         my $commit = $self->param('commit');
 712         my $test = $self->param('test');
 713
 714         my $commit_changed;
 715
 716         if ( $code && ( $test || $commit ) ) {
 717                 # XXX find columns used in code snippet and show them to user
 718                 my $order = 0;
 719                 foreach my $column ( $code =~ m/\$row->{([^}]+)}/g ) {
 720                         if ( $column =~ s/^(['"])// ) {
 721                                 $column =~ s/$1$//;
 722                         }
 723                         next if $column =~ m/\$/; # hide columns with vars in them
 724                         $commit_changed->{$column} = 0;
 725                 }
 726         }
 727
 728         my $code_path = $self->app->home->rel_dir('public') . "/code";
 729         if ( $commit ) {
 730
 731                 warn "# commit on ", $#$filtered + 1, " items:\n$code\n";
 732                 ( $key, $value, $out ) = ( 'key', 'value' );
 733                 foreach ( 0 .. $#$filtered ) {
 734                         my $i = $filtered->[$_];
 735                         __commit_path_code( $path, $i, $code, \$commit_changed );
 736                 }
 737
 738                 # this might move before $out to recalculate stats on source dataset?
 739                 __path_rebuild_stats( $path );
 740                 my $c = { map { $_ => 1 } @columns };
 741                 my @added_columns = sort grep { ! $c->{$_} } keys %$commit_changed;
 742                 warn "# added_columns ",dump( @added_columns );
 743                 unshift @columns, @added_columns;
 744
 745                 $loaded->{$path}->{columns} = [ @columns ];
 746                 warn "# new columns ",dump( @columns );
 747
 748                 __invalidate_path_column( $path, $_ ) foreach keys %$commit_changed;
 749
 750                 $self->_save_change({
 751                         path => $path,
 752                         time => $self->param('time') || time(),
 753                         user => $self->param('user') || $ENV{'LOGNAME'},
 754                         code => $code,
 755                         commit_changed => $commit_changed,
 756                 });
 757
 758                 if ( my $description = $self->param('code_description') ) {
 759                         my $depends = $self->param('code_depends') || die "no code_depends?";
 760                         my $path = "$code_path/$depends.$description.pl";
 761                         if ( -e $path && ! $self->param('overwrite') ) {
 762                                 warn "# code $path not saved\n";
 763                         } else {
 764                                 write_file(  $path, { binmode => ':utf8' }, "$code\n" );
 765                                 warn "code $path ", -s $path, " bytes saved\n";
 766                         }
 767                 }
 768
 769                 # remove console
 770                 $code = '';
 771                 if ( $out ) {
 772                         my $commit_dataset = join('.'
 773                                 , $self->param('code_depends')
 774                                 , $self->param('code_description')
 775                                 , time()
 776                         );
 777                         $key ||= 'key';
 778                         $value ||= 'value';
 779                         warn "key $key value $value";
 780                         my $items;
 781                         foreach my $n ( keys %$out ) {
 782                                 my $i = { $key => [ $n ] };
 783                                 my $ref = ref $out->{$n};
 784                                 if ( $ref eq 'HASH' ) {
 785                                         $i->{$_} = [ $out->{$n}->{$_} ] foreach keys %{ $out->{$n} };
 786                                 } elsif ( $ref eq 'ARRAY' ) {
 787                                         $i->{$_} = $out->{$n};
 788                                 } elsif ( ! $ref ) {
 789                                         $i->{$value} = [ $out->{$n} ];
 790                                 } else {
 791                                         $i->{_error} = [ dump($out->{$n}) ];
 792                                 }
 793                                 push @$items, $i;
 794                         };
 795                         undef $out;
 796                         my $stats = __stats( $items );
 797                         my @columns = grep { ! m/^\Q$key\E$/ } sort keys %$stats;
 798                         unshift @columns, $key;
 799
 800                         $loaded->{$commit_dataset} = {
 801                                 header => [ @columns ],
 802                                 columns => [ @columns ],
 803                                 mtime => time(),
 804                                 data => { items => $items },
 805                                 stats => $stats,
 806                                 generated => 1,
 807                         };
 808                         warn "# loaded out ", dump( $loaded->{$commit_dataset} );
 809                         $self->session('path', $commit_dataset);
 810                         $self->session('columns', [ @columns ]);
 811                         $self->session('order', $key);
 812                         return $self->redirect_to('/data/items');
 813                 }
 814
 815                 $self->session('columns', [ @columns ]);
 816         }
 817
 818         my $sorted_items;
 819         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 820         my $test_changed;
 821         my ( $key, $value, $out ) = ( 'key', 'value' ); # XXX make local
 822         foreach ( 0 .. $limit ) {
 823                 my $i = $_ + $offset;
 824                 last unless defined $filtered->[$i];
 825                 $i = $from_end - $i if $from_end;
 826                 my $id = $filtered->[$i];
 827                 my $row = Storable::dclone $data->{items}->[ $id ];
 828                 if ( $code && $test ) {
 829                         my $update;
 830                         eval $code;
 831                         if ( $@ ) {
 832                                 warn "ERROR evaling $@", dump($code);
 833                                 $self->stash('eval_error', $@) if $@;
 834                         } else {
 835                                 warn "EVAL ",dump($update);
 836                                 foreach ( keys %$update ) {
 837                                         $test_changed->{$_}++;
 838                                         $row->{$_} = $update->{$_};
 839                                 }
 840                         }
 841                 }
 842                 $row->{_row_id} ||= $id;
 843                 push @$sorted_items, $row;
 844         }
 845
 846         if ( $self->param('export') ) {
 847                 my $export_path = $self->_export_path( 'items', @columns);
 848                 open(my $fh, '>', $export_path) || die "ERROR: can't open $export_path: $!";
 849                 print $fh "#",join("\t",@columns),"\n";
 850                 foreach my $f ( 0 .. $#$filtered ) {
 851                         print $fh join("\t", map {
 852                                 my $i = $data->{items}->[ $filtered->[$f] ];
 853                                 my $v = '\N';
 854                                 if ( ! defined $i->{$_} ) {
 855                                         # nop
 856                                 } elsif ( ref $i->{$_} eq 'ARRAY' ) {
 857                                         $v =join(',', @{ $i->{$_} });
 858                                         $v = '\N' if length($v) == 0;
 859                                 } elsif ( ! ref $i->{$_} ) {
 860                                         $v = $i->{$_};
 861                                 } else {
 862                                         $v = dump $i->{$_};
 863                                 }
 864                                 $v;
 865                         } @columns),"\n";
 866                 }
 867                 close($fh);
 868                 warn "export $export_path ", -s $export_path, " bytes\n";
 869         }
 870
 871         warn "# test_changed ",dump( $test_changed );
 872         my $c = { map { $_ => 1 } @columns };
 873         my @added_columns = sort grep { ! $c->{$_} } keys %$test_changed;
 874         unshift @columns, @added_columns;
 875
 876         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 877
 878         my $code_depends = $self->param('code_depends')||
 879         join(',', sort grep { $test_changed->{$_} == 0 } keys %$test_changed );
 880         my $code_description = $self->param('code_description') ||
 881         join(',', @added_columns);
 882
 883         $code_depends ||= $code_description; # self-modifing
 884         if ( ! $code_depends && $out ) {
 885                 $code_depends = $key;
 886                 $code_description = $value;
 887         }
 888
 889         warn "# test_changed ",dump( $test_changed, $code_depends, $code_description );
 890
 891         $self->render(
 892                 order => $order,
 893                 offset => $offset,
 894                 limit => $limit,
 895                 sorted => $sorted_items,
 896                 columns => [ @columns ],
 897                 rows => $#$filtered + 1,
 898                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 899                 unique  => { map { $_, $self->_is_unique( $_) } @columns },
 900                 filters => $self->_current_filters,
 901                 code => $code,
 902                 cols_changed => $commit ? $commit_changed : $test_changed,
 903                 code_depends => $code_depends,
 904                 code_description => $code_description,
 905                 code_path => $code_path,
 906                 out => $out,
 907         );
 908
 909 }
 910
 911
 912 sub order {
 913         my $self = shift;
 914         $self->session('order', $self->param('order'));
 915         $self->session('sort', $self->param('sort'));
 916         return $self->redirect_to('/data/items');
 917 }
 918
 919 sub _is_numeric {
 920         my ( $self, $name ) = @_;
 921
 922         my $stats = $self->_loaded( 'stats' );
 923
 924         # sort facet numerically if more >50% elements are numeric
 925         my $count = $stats->{$name}->{count};
 926         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 927         defined $stats->{$name}->{numeric} &&
 928                 $stats->{$name}->{numeric} > $count / 2;
 929 }
 930
 931 sub _is_unique {
 932         my ( $self, $name ) = @_;
 933         my $stats = $self->_loaded( 'stats' );
 934         defined $stats->{$name}->{unique};
 935 }
 936
 937 sub _remove_filter {
 938         my ($self,$name) = @_;
 939         warn "_remove_filter $name\n";
 940
 941         my $path = $self->session('path');
 942
 943         delete $filters->{$name};
 944         delete $loaded->{$path}->{filters}->{$name};
 945         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 946
 947         foreach (
 948                         grep { /\Q$name\E/ }
 949                         keys %{ $loaded->{$path}->{filtered} }
 950         ) {
 951                 delete $loaded->{$path}->{filtered}->{$_};
 952                 warn "remove filtered cache $_";
 953         }
 954 }
 955
 956 sub facet {
 957         my $self = shift;
 958
 959         my $path = $self->session('path') || return $self->redirect_to( '/data/index' );
 960
 961         if ( my $name = $self->param('remove') ) {
 962                 $self->_remove_filter( $name );
 963                 return $self->redirect_to( '/data/items' );
 964         }
 965
 966         my $facet;
 967         my $name = $self->param('name') || die "no name";
 968
 969         my $all = $self->_param_scalar('all', 1);
 970         my $data = $self->_loaded('data');
 971
 972         my $filters = $self->_current_filters;
 973         my $all_filters = __all_filters( keys %$filters,$self->session('order') );
 974         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 975                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 976
 977         if ( ! $filtered || $all ) {
 978                 $filtered = [ 0 .. $#{ $data->{items} } ];
 979                 warn "filter all values\n";
 980         } else {
 981                 warn "filter using $all_filters\n";
 982         }
 983
 984         foreach my $i ( @$filtered ) {
 985                 my $item = $data->{items}->[$i];
 986                 if ( ! exists $item->{$name} ) {
 987                         $facet->{ _missing }++;
 988                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 989                         $facet->{$_}++ foreach @{ $item->{$name} };
 990                 } else {
 991                         $facet->{ $item->{$name} }++;
 992                 }
 993         }
 994
 995         my $checked_values = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 996
 997         if ( my $code = $self->param('code') ) {
 998                 my $out;
 999                 foreach my $value ( keys %$facet ) {
1000                         my $count = $facet->{$value};
1001                         my $checked = $checked_values->{$value};
1002                         eval $code;
1003                         if ( $@ ) {
1004                                 $out = $@;
1005                                 warn "ERROR: $@\n$code\n";
1006                                 last;
1007                         } elsif ( $checked != $checked_values->{$value} ) {
1008                                 warn "checked $value $count -> $checked\n";
1009                                 $checked_values->{$value} = $checked;
1010                         }
1011                 }
1012                 warn "out ",dump( $out );
1013                 $self->stash( out => $out );
1014         }
1015
1016 #       warn "# facet $name ",dump $facet;
1017
1018         my @facet_names =
1019                   $all                      ? keys %$facet
1020                 : defined $filters->{$name} ? @{ $filters->{$name} }
1021                 : keys %$facet;
1022
1023         my $numeric = $self->_is_numeric($name);
1024
1025         my $sort = $self->param('sort');
1026         # sort numeric facets with more than 5 values ascending
1027         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
1028
1029         @facet_names = sort {
1030                 my $result;
1031                 if ( $sort eq 'a' ) {
1032                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
1033                 } elsif ( $sort eq 'd' ) {
1034                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
1035                 } elsif ( $sort eq 'c' ) {
1036                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
1037                 } else {
1038                         warn "unknown sort: $sort";
1039                         $result = $a cmp $b;
1040                 }
1041                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
1042                 $result;
1043         } @facet_names;
1044
1045         $self->render( name => $name, facet => $facet, checked => $checked_values,
1046                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
1047         );
1048 }
1049
1050
1051 sub __invalidate_path_column {
1052         my ( $path, $name ) = @_;
1053
1054         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
1055                 delete $loaded->{$path}->{sorted}->{$name};
1056                 warn "# invalidate $path sorted $name\n";
1057         }
1058
1059         foreach ( grep { m/\Q$name\E/ } keys %{ $loaded->{$path}->{filtered} } ) {
1060                 delete $loaded->{$path}->{filtered}->{$_};
1061                 warn "# invalidate $path filtered $_\n";
1062         }
1063 }
1064
1065 sub __path_modified {
1066         my ( $path, $value ) = @_;
1067         $value = 1 unless defined $value;
1068
1069         $loaded->{$path}->{modified}  = $value;
1070
1071         warn "# __path_modified $path $value\n";
1072 }
1073
1074 sub __path_rebuild_stats { $loaded->{ $_[0] }->{rebuild_stats} = 1 };
1075
1076 sub _save_change {
1077         my ($self,$change) = @_;
1078
1079         my $change_path = $self->_permanent_path( 'changes' );
1080         mkdir $change_path unless -d $change_path;
1081         $change_path .= '/' . $change->{time};
1082         store $change, $change_path;
1083         utime $change->{time}, $change->{time}, $change_path;
1084         warn "_save_change $change_path ", dump($change);
1085 }
1086
1087 sub edit {
1088         my $self = shift;
1089         my $new_content = $self->param('new_content');
1090         $new_content  ||= $self->param('content'); # backward compatibility with old actions
1091
1092         my $i = $self->param('_row_id');
1093         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
1094         my $path = $self->param('path') || die "no path";
1095         my $name = $self->param('name') || die "no name";
1096         my $status = 200; # 200 = OK, 201 = Created
1097
1098         my $data = $self->_loaded('data');
1099
1100         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
1101                 $new_content =~ s/^\s+//s;
1102                 $new_content =~ s/\s+$//s;
1103                 my $v;
1104                 if ( $new_content =~ /\xB6/ ) { # para
1105                         $v = [ split(/\s*\xB6\s*/, $new_content) ];
1106                 } else {
1107                         $v = [ $new_content ];
1108                 }
1109
1110                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
1111                 my $new = dump $v;
1112                 if ( $old ne $new
1113                         && ! ( $old eq 'undef' && length($new_content) == 0 ) # new value empty, previous undef
1114                 ) {
1115                         $self->_save_change({
1116                                 path => $path,
1117                                 column => $name,
1118                                 pos => $i,
1119                                 old => $loaded->{$path}->{data}->{items}->[$i]->{$name},
1120                                 new => $v,
1121                                 time => $self->param('time') || time(),
1122                                 user => $self->param('user') || $ENV{'LOGNAME'},
1123                                 unique => {
1124                                         map { $_ => $loaded->{$path}->{data}->{items}->[$i]->{$_}->[0] }
1125                                         grep { defined $loaded->{$path}->{stats}->{$_}->{unique} }
1126                                         keys %{ $loaded->{$path}->{stats} }
1127                                 },
1128                         });
1129
1130                         warn "# change $path $i $old -> $new\n";
1131                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
1132
1133                         __invalidate_path_column( $path, $name );
1134
1135                         $status = 201; # created
1136                         __path_rebuild_stats( $path );
1137
1138                         $new_content = join("\xB6",@$v);
1139
1140                 } else {
1141                         warn "# unchanged $path $i $old\n";
1142                         $status = 304;
1143                 }
1144         } else {
1145                 $new_content = "$path $i $name doesn't exist\n";
1146                 $status = 404;
1147         }
1148
1149         warn "# edit $status ", dump $new_content;
1150
1151         $self->render(
1152                 status => $status,
1153                 new_content => scalar $new_content,
1154         );
1155 }
1156
1157
1158 sub save {
1159         my $self = shift;
1160         my $path = $self->_param_or_session('path');
1161         my $dump_path = $self->_save( $path );
1162         __path_modified( $path, 0 );
1163
1164         return $self->redirect_to( '/data/items' );
1165 }
1166
1167 sub export {
1168         my $self = shift;
1169
1170         my $dir = $self->app->home->rel_dir('public');
1171
1172         if ( my $import = $self->param('import') ) {
1173
1174                 if ( $import =~ m{/filter\.(.+?)\..+} ) {
1175                         my $name = $self->_column_from_unac( $1 );
1176
1177                         my @vals = map { chomp; $_ }
1178                                 read_file "$dir/export/$import", binmode => ':utf8';
1179
1180                         $self->_remove_filter( $name );
1181                         $self->_filter_on_data( $name, @vals );
1182                         $self->session( 'offset' => 0 );
1183                         return $self->redirect_to('/data/items');
1184                 } else {
1185                         warn "UNKNOWN IMPORT $import";
1186                 }
1187         }
1188
1189         if ( my $remove = $self->param('remove') ) {
1190                 my $path = "$dir/export/$remove";
1191                 unlink $path if -e $path;
1192                 $path .= '.png';
1193                 unlink $path if -e $path;
1194         }
1195
1196         my $path = $self->_export_path || return $self->redirect_to('/data/index');
1197
1198         my @files = grep { ! /\.png$/ } glob "$path/*";
1199         my $mtime = { map { $_ => (stat($_))[9] } @files };
1200         @files = sort { $mtime->{$b} <=> $mtime->{$a} } @files;
1201         $self->render( export => [ @files ] );
1202 }
1203
1204 sub __loaded_paths {
1205         return
1206                 grep { defined $loaded->{$_}->{data} }
1207                 keys %$loaded;
1208 }
1209
1210 sub unlink {
1211         my $self = shift;
1212         my $path = $self->param('path');
1213         if ( $path =~ m{^/tmp/mojo_facets.} ) {
1214                 unlink $path;
1215                 warn "# unlink $path";
1216         } else {
1217                 warn "WARNING: $path unlink ignored";
1218         }
1219         return $self->redirect_to( '/data/load' );
1220 }
1221
1222 1;