lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use Encode;
  11 use locale;
  12 use File::Find;
  13 use Storable;
  14 use Time::HiRes qw(time);
  15
  16 use MojoFacets::Import::File;
  17 use MojoFacets::Import::HTMLTable;
  18
  19 our $loaded;
  20 our $filters;
  21
  22 sub index {
  23         my $self = shift;
  24
  25         my $data_dir = $self->app->home->rel_dir('data');
  26         die "no data dir $data_dir" unless -d $data_dir;
  27
  28         my @files;
  29         my $changes;
  30         find( sub {
  31                 my $file = $File::Find::name;
  32                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  33                         $file =~ s/$data_dir\/*//;
  34                         push @files, $file;
  35                 } elsif ( -f $file && $file =~ m/([^\/]+)\.changes\/(\d+\.\d+.+)/ ) {
  36                         push @{ $changes->{$1} }, $2
  37                 } elsif ( -d $file && $file =~ m/\.html$/ ) {
  38                         $file =~ s/$data_dir\/*//;
  39                         push @files, $file;
  40                 } else {
  41                         warn "IGNORE: $file\n";
  42                 }
  43         }, $data_dir);
  44
  45         @files = sort { lc $a cmp lc $b } @files;
  46         my $size;
  47         $size->{$_} = -s "$data_dir/$_" foreach @files;
  48
  49         $self->render(
  50                 files => [ @files ],
  51                 size => $size,
  52                 loaded => $loaded,
  53                 filters => $filters,
  54                 dump_path => { map { $_ => $self->_dump_path($_) } @files },
  55                 changes => $changes,
  56         );
  57 }
  58
  59 sub _dump_path {
  60         my ( $self, $name ) = @_;
  61         my $dir = $self->app->home->rel_dir('data');
  62         $name =~ s/^$dir//;
  63         $name =~ s/\/+/_/g;
  64         return '/tmp/mojo_facets.' . $name . '.storable';
  65 }
  66
  67 sub _save {
  68         my ( $self, $path ) = @_;
  69
  70         my $dump_path = $self->_dump_path( $path );
  71         my $first_load = ! -e $dump_path;
  72         warn "save loaded to $dump_path";
  73         my $info = $loaded->{$path};
  74         store $info, $dump_path;
  75
  76         if ( $first_load ) {
  77                 my $mtime = $loaded->{$path}->{mtime};
  78                 utime $mtime, $mtime, $dump_path;
  79                 warn "sync time to $path at $mtime\n";
  80         }
  81
  82         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  83         return $dump_path;
  84 }
  85
  86
  87 sub __stats {
  88
  89         my $stats;
  90
  91         my $nr_items = $#{ $_[0] } + 1;
  92
  93         warn "__stats $nr_items\n";
  94
  95         foreach my $e ( @{ $_[0] } ) {
  96                 foreach my $n ( keys %$e ) {
  97                         $stats->{$n}->{count}++;
  98                         my @v;
  99                         if ( ref $e->{$n} eq 'ARRAY' ) {
 100                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 101                                 @v = @{ $e->{$n} };
 102                         } else {
 103                                 @v = ( $e->{$n} );
 104                         }
 105
 106                         foreach my $x ( @v ) {
 107                                 $stats->{$n}->{numeric}++
 108                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 109                                 $stats->{$n}->{empty}++
 110                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 111                         }
 112
 113                 }
 114         }
 115
 116         foreach my $n ( keys %$stats ) {
 117                 my $s = $stats->{$n};
 118                 next unless defined $s->{array};
 119                 if ( $s->{array} == $s->{count} ) {
 120                         delete $s->{array};
 121                         if ( $s->{count} == $nr_items ) {
 122                                 warn "check $n for uniqeness\n";
 123                                 my $unique;
 124                                 foreach my $e ( @{ $_[0] } ) {
 125                                         if ( ++$unique->{ $e->{$n}->[0] } == 2 ) {
 126                                                 $unique = 0;
 127                                                 last;
 128                                         }
 129                                 }
 130                                 if ( $unique ) {
 131                                         $stats->{$n}->{unique} = 1;
 132                                         warn "# $n unique ",dump( $unique );
 133                                 }
 134                         }
 135                 }
 136         }
 137
 138         warn "# __stats ",dump($stats);
 139
 140         return $stats;
 141 }
 142
 143 sub _param_or_session {
 144         $_[0]->param( $_[1] ) || $_[0]->session( $_[1] )
 145 }
 146
 147 sub stats {
 148         my $self = shift;
 149         my $path = $self->_param_or_session('path');
 150         warn "stats $path\n";
 151         delete $loaded->{$path}->{stats};
 152         $self->redirect_to( '/data/columns' );
 153 }
 154
 155
 156 sub _load_path {
 157         my ( $self, $path ) = @_;
 158
 159         my $full_path = $self->app->home->rel_file( 'data/' . $path );
 160         die "$full_path $!" unless -r $full_path;
 161
 162         my $dump_path = $self->_dump_path( $path );
 163
 164         if ( defined $loaded->{$path}->{data} ) {
 165                 my $mtime = (stat($full_path))[9];
 166                 return if $loaded->{$path}->{mtime} == $mtime;
 167                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
 168         } elsif ( -e $dump_path ) {
 169                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
 170                 my $info = retrieve $dump_path;
 171                 $loaded->{ $path } = $info;
 172                 return;
 173         }
 174
 175         my $data;
 176         if ( -f $full_path ) {
 177                 $data = MojoFacets::Import::File->new( full_path => $full_path, path => $path )->data;
 178         } elsif ( -d $full_path && $full_path =~ m/.html/ ) {
 179                 $data = MojoFacets::Import::HTMLTable->new( dir => $full_path )->data;
 180         } else {
 181                 die "can't load $full_path";
 182         }
 183
 184         my @header;
 185
 186         if ( defined $data->{header} ) {
 187                 if ( ref $data->{header} eq 'ARRAY' ) {
 188                         @header = @{ $data->{header} };
 189                 } else {
 190                         warn "header not array ", dump( $data->{header} );
 191                 }
 192         }
 193
 194         my $stats = __stats( $data->{items} );
 195
 196         @header =
 197                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 198                 grep { defined $stats->{$_}->{count} } keys %$stats
 199                 unless @header;
 200
 201         my $info = {
 202                 header => [ @header ],
 203                 stats  => $stats,
 204                 full_path => $full_path,
 205                 size => -s $full_path,
 206                 mtime => (stat($full_path))[9],
 207                 data => $data,
 208         };
 209
 210         $loaded->{ $path } = $info;
 211         $self->_save( $path );
 212
 213 }
 214
 215
 216 sub load {
 217         my $self = shift;
 218
 219         my @paths = $self->param('paths');
 220         warn "# paths ", dump @paths;
 221         $self->_load_path( $_ ) foreach @paths;
 222
 223         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 224         warn "# path $path\n";
 225         $self->_load_path( $path );
 226
 227         $self->session( 'path' => $path );
 228         $self->session( 'modified' => $loaded->{$path}->{modified} );
 229
 230         my $redirect_to = '/data/items';
 231
 232         $self->session( 'header' => $loaded->{$path}->{header} );
 233         if ( ! defined $loaded->{$path}->{columns} ) {
 234                 my $columns_path = $self->_permanent_path( 'columns' );
 235                 if ( -e $columns_path ) {
 236                         my @columns = map { s/[\r\n]+$//; $_ } read_file $columns_path;
 237                         $loaded->{$path}->{columns} = [ @columns ];
 238                         warn "# columns_path $columns_path ",dump(@columns);
 239                 } else {
 240                         $loaded->{$path}->{columns} = $loaded->{$path}->{header}
 241                 }
 242
 243                 $redirect_to = '/data/columns';
 244         }
 245         $self->session( 'columns' => $loaded->{$path}->{columns} );
 246         $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 247         $self->redirect_to( $redirect_to );
 248 }
 249
 250
 251 sub _loaded {
 252         my ( $self, $name ) = @_;
 253         my $path = $self->session('path') || $self->param('path');
 254         $self->redirect_to('/data/index') unless $path;
 255
 256         if ( $loaded->{$path}->{modified} > 1 ) {
 257                 warn "rebuild stats for $path forced by modified\n";
 258                 $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 259                 $loaded->{$path}->{modified} = 1;
 260         }
 261
 262         if ( ! defined $loaded->{$path}->{$name} ) {
 263                 warn "$path $name isn't loaded\n";
 264                 $self->_load_path( $path );
 265                 $self->redirect_to('/data/index')
 266                         unless defined $loaded->{$path}->{$name};
 267                 if ( ! defined $loaded->{$path}->{stats} ) {
 268                         warn "rebuild stats for $path\n";
 269                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 270                 }
 271         }
 272         return $loaded->{$path}->{$name};
 273 }
 274
 275
 276 sub _checked {
 277         my $self = shift;
 278         my $checked;
 279         $checked->{$_}++ foreach @_;
 280 #       warn "# _checked ",dump($checked);
 281         return $checked;
 282 }
 283
 284 sub _permanent_path {
 285         my $self = shift;
 286         my $path = $self->_param_or_session('path');
 287         $self->app->home->rel_dir('data') . '/' . join('.', $path, @_);
 288 }
 289
 290 sub _export_path {
 291         my $self = shift;
 292         my $path = $self->_param_or_session('path');
 293         my $dir = $self->app->home->rel_dir('public') . '/export/';
 294         mkdir $dir unless -e $dir;
 295         $dir .= $path;
 296         mkdir $dir unless -e $dir;
 297         $dir . '/' . join('.', @_);
 298 }
 299
 300 sub columns {
 301     my $self = shift;
 302
 303         if ( $self->param('columns') ) {
 304                 my @columns = $self->_param_array('columns');
 305                 write_file( $self->_permanent_path( 'columns' ), map { "$_\n" } @columns );
 306                 $self->redirect_to('/data/items');
 307         }
 308
 309         my $stats = $self->_loaded( 'stats' );
 310
 311         my @columns;
 312         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 313
 314         foreach my $c ( @{ $self->session( 'header' ) } ) {
 315                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 316         }
 317
 318     $self->render(
 319                 message => 'Select columns to display',
 320                 stats => $stats,
 321                 columns => \@columns,
 322                 checked => $self->_checked( $self->_param_array('columns') ),
 323         );
 324 }
 325
 326 sub _param_array {
 327     my ($self,$name) = @_;
 328
 329         my @array = $self->param($name);
 330         my $path  = $self->session('path');
 331
 332         if ( @array ) {
 333                 $self->session($name => [ @array ]);
 334                 $loaded->{$path}->{$name} = [ @array ];
 335         } elsif ( my $session = $self->session($name) ) {
 336                 if ( ref $session eq 'ARRAY' ) {
 337                         @array = @$session;
 338                 } else {
 339                         die "$name not array ",dump($session);
 340                 }
 341         }
 342         #warn "# $name ",dump @array;
 343         return @array;
 344 }
 345
 346 sub _param_scalar {
 347     my ($self,$name,$default) = @_;
 348
 349         my $scalar = $self->param($name);
 350
 351         if ( defined $scalar ) {
 352                 $self->session($name => $scalar);
 353         } else {
 354                 $scalar = $self->session($name);
 355         }
 356
 357         if ( ! defined $scalar ) {
 358                 $scalar = $default;
 359                 die "no default for $name" unless defined $scalar;
 360                 $self->session($name => $scalar);
 361         }
 362
 363         warn "# _perm_scalar $name ",dump $scalar;
 364         return $scalar;
 365 }
 366
 367 sub filter {
 368         my $self = shift;
 369
 370         my $name = $self->param('filter_name') || die "name?";
 371         my @vals = $self->param('filter_vals');
 372
 373         $self->_remove_filter( $name );
 374         if ( @vals ) {
 375                 $self->_filter_on_data( $name, @vals );
 376                 if ( my $permanent = $self->param('_permanent') ) {
 377                         my $permanent_path = $self->_export_path( 'filter', $name, $permanent );
 378                         write_file $permanent_path, map { "$_\n" } @vals;
 379                         warn "permanent filter $permanent_path ", -s $permanent_path;
 380                 }
 381         }
 382
 383         $self->session( 'offset' => 0 );
 384
 385         $self->redirect_to('/data/items');
 386 }
 387
 388 sub _filter_on_data {
 389         my ( $self, $name, @vals ) = @_;
 390
 391         my $path = $self->session('path');
 392
 393         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 394                 warn "filter $name not found in data set";
 395                 return;
 396         }
 397
 398         $filters->{$name} = [ @vals ];
 399         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 400
 401         my $filter_hash;
 402         $filter_hash->{$_}++ foreach @vals;
 403
 404         #warn "# filter_hash ",dump( $filter_hash );
 405
 406         my $items = $self->_loaded('data')->{items};
 407
 408         my $include_missing = defined $filter_hash->{_missing};
 409         my $filtered_items;
 410
 411         foreach my $i ( 0 .. $#$items ) {
 412
 413                 if ( defined $items->[$i]->{$name} ) {
 414                         foreach my $v ( @{ $items->[$i]->{$name} } ) {
 415                                 if ( defined $filter_hash->{ $v } ) {
 416                                         $filtered_items->{$i}++;
 417                                 }
 418                         }
 419                 } elsif ( $include_missing ) {
 420                         $filtered_items->{$i}++;
 421                 }
 422         }
 423
 424         #warn "# filter $name ",dump($filtered_items);
 425
 426         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 427         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 428 }
 429
 430 sub _data_items {
 431         my ( $self, $all ) = @_;
 432         my $data = $self->_loaded( 'data' );
 433
 434         return @{ $data->{items} } if $all == 1;
 435
 436         my $filters = $self->_current_filters;
 437         my $filter_value;
 438         foreach my $f ( keys %$filters ) {
 439                 foreach my $n ( @{ $filters->{$f} } ) {
 440                         $filter_value->{$f}->{$n} = 1;
 441                 }
 442         }
 443         my @items = @{ $data->{items} };
 444         @items = grep {
 445                 my $i = $_;
 446                 my $pass = 1;
 447                 foreach my $n ( keys %$filter_value ) {
 448                         if ( ! exists $i->{$n} ) {
 449                                 if ( defined $filter_value->{$n}->{_missing} ) {
 450                                         $pass = 1;
 451                                         next;
 452                                 } else {
 453                                         $pass = 0;
 454                                         last;
 455                                 }
 456                         }
 457                         # and match any of values in element
 458                         my $have_values = 0;
 459                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 460                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 461                         }
 462                         if ( ! $have_values ) {
 463                                 $pass = 0;
 464                                 last;
 465                         }
 466                 }
 467                 $pass;
 468         } @items if $filter_value;
 469         return @items;
 470 }
 471
 472
 473 sub _current_filters {
 474         my $self = shift;
 475         my $current_filters;
 476         $current_filters->{ $_ } = $filters->{ $_ }
 477                 foreach (
 478                         grep { defined $filters->{ $_ } }
 479                         @{ $self->_loaded('header') }
 480                 );
 481         #warn "# current_filters ",dump($current_filters);
 482         return $current_filters;
 483 }
 484
 485 sub _data_sorted_by {
 486         my ( $self, $order ) = @_;
 487
 488         my $path = $self->session('path');
 489
 490         warn "_data_sorted_by $order from $path";
 491
 492         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 493                 return $loaded->{$path}->{sorted}->{$order};
 494         }
 495
 496         my $data = $self->_loaded( 'data' );
 497         my $numeric = $self->_is_numeric($order);
 498         my $missing = $numeric ? 0 : '';
 499         no warnings qw(numeric);
 500         my $nr = 0;
 501         my @sorted = map {
 502                 $_->[0]
 503         } sort {
 504                 if ( $numeric ) {
 505                         $a->[1] <=> $b->[1]
 506                 } else {
 507                         $a->[1] cmp $b->[1]
 508                 }
 509         } map {
 510                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 511         } grep { ref $_->{$order} eq 'ARRAY' } @{ $data->{items} }
 512         ;
 513
 514         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 515         #warn "# sorted ",dump( @sorted );
 516
 517         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 518 }
 519
 520
 521 sub items {
 522         my $self = shift;
 523
 524         my $path = $self->session('path');
 525         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 526
 527         my @columns = $self->_param_array('columns');
 528         $self->redirect_to('/data/columns') unless @columns;
 529         my $order   = $self->_param_scalar('order', $columns[0]);
 530         my $sort    = $self->_param_scalar('sort', 'a');
 531         my $offset  = $self->_param_scalar('offset', 0);
 532         my $limit   = $self->_param_scalar('limit', 20);
 533         $self->_param_scalar('show', 'table');
 534
 535         # fix offset when changing limit
 536         $offset = int( $offset / $limit ) * $limit;
 537
 538         my $sorted = $self->_data_sorted_by( $order );
 539
 540         my @filter_names;
 541         if ( $filters ) {
 542                 foreach my $name ( keys %$filters ) {
 543                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 544                                 warn "skip filter $name not found in $path\n";
 545                                 next;
 546                         }
 547                         push @filter_names, $name;
 548                 }
 549                 warn "filter_names ",dump( @filter_names );
 550                 foreach my $name ( @filter_names ) {
 551                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 552                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 553                 }
 554         }
 555
 556         my $all_filters = join(' ',sort @filter_names,'order:',$order);
 557
 558 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 559
 560         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 561
 562                 my $path_filters = $loaded->{$path}->{filters};
 563
 564                 warn "create combined filter for $all_filters\n";
 565
 566                 my @filtered;
 567                 foreach my $i ( 0 .. $#$sorted ) {
 568                         my $pos = $sorted->[$i];
 569
 570                         if ( $#filter_names == -1 ) {
 571                                 push @filtered, $pos;
 572                                 next;
 573                         }
 574
 575                         my $skip = 0;
 576                         foreach ( @filter_names ) {
 577                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 578                         }
 579                         next if $skip;
 580
 581                         push @filtered, $pos;
 582                 }
 583
 584                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 585         }
 586
 587         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 588                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 589
 590         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 591
 592         my $sorted_items;
 593         my $data = $self->_loaded('data');
 594         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 595         foreach ( 0 .. $limit ) {
 596                 my $i = $_ + $offset;
 597                 last unless defined $filtered->[$i];
 598                 $i = $from_end - $i if $from_end;
 599                 my $id = $filtered->[$i];
 600                 push @$sorted_items,
 601                 my $item = $data->{items}->[ $id ];
 602                 $item->{_row_id} ||= $id;
 603         }
 604
 605         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 606
 607         $self->render(
 608                 order => $order,
 609                 offset => $offset,
 610                 limit => $limit,
 611                 sorted => $sorted_items,
 612                 columns => [ @columns ],
 613                 rows => $#$filtered + 1,
 614                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 615                 filters => $self->_current_filters,
 616         );
 617
 618 }
 619
 620
 621 sub order {
 622         my $self = shift;
 623         $self->session('order', $self->param('order'));
 624         $self->session('sort', $self->param('sort'));
 625         $self->redirect_to('/data/items');
 626 }
 627
 628 sub _is_numeric {
 629         my ( $self, $name ) = @_;
 630
 631         my $stats = $self->_loaded( 'stats' );
 632
 633         # sort facet numerically if more >50% elements are numeric
 634         my $count = $stats->{$name}->{count};
 635         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 636         defined $stats->{$name}->{numeric} &&
 637                 $stats->{$name}->{numeric} > $count / 2;
 638 }
 639
 640 sub _remove_filter {
 641         my ($self,$name) = @_;
 642         warn "_remove_filter $name\n";
 643
 644         my $path = $self->session('path');
 645
 646         delete $filters->{$name};
 647         delete $loaded->{$path}->{filters}->{$name};
 648         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 649
 650         foreach (
 651                         grep { /\b$name\b/ }
 652                         keys %{ $loaded->{$path}->{filtered} }
 653         ) {
 654                 delete $loaded->{$path}->{filtered}->{$_};
 655                 warn "remove filtered cache $_";
 656         }
 657 }
 658
 659 sub facet {
 660         my $self = shift;
 661
 662         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 663
 664         if ( my $name = $self->param('remove') ) {
 665                 $self->_remove_filter( $name );
 666                 $self->redirect_to( '/data/items' );
 667         }
 668
 669         my $facet;
 670         my $name = $self->param('name') || die "no name";
 671
 672         my $all = $self->_param_scalar('all', 1);
 673         my $data = $self->_loaded('data');
 674
 675         my $filters = $self->_current_filters;
 676         my $all_filters = join(' ',sort keys %$filters,'order:',$self->session('order'));
 677         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 678                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 679
 680         if ( ! $filtered || $all ) {
 681                 $filtered = [ 0 .. $#{ $data->{items} } ];
 682                 warn "filter all values\n";
 683         } else {
 684                 warn "filter using $all_filters\n";
 685         }
 686
 687         foreach my $i ( @$filtered ) {
 688                 my $item = $data->{items}->[$i];
 689                 if ( ! exists $item->{$name} ) {
 690                         $facet->{ _missing }++;
 691                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 692                         $facet->{$_}++ foreach @{ $item->{$name} };
 693                 } else {
 694                         $facet->{ $item->{$name} }++;
 695                 }
 696         }
 697
 698 #       warn "# facet $name ",dump $facet;
 699
 700         my $checked;
 701         my @facet_names =
 702                   $all                      ? keys %$facet
 703                 : defined $filters->{$name} ? @{ $filters->{$name} }
 704                 : keys %$facet;
 705
 706         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 707
 708         my $numeric = $self->_is_numeric($name);
 709
 710         my $sort = $self->param('sort');
 711         # sort numeric facets with more than 5 values ascending
 712         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 713
 714         @facet_names = sort {
 715                 my $result;
 716                 if ( $sort eq 'a' ) {
 717                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 718                 } elsif ( $sort eq 'd' ) {
 719                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 720                 } elsif ( $sort eq 'c' ) {
 721                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 722                 } else {
 723                         warn "unknown sort: $sort";
 724                         $result = $a cmp $b;
 725                 }
 726                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 727                 $result;
 728         } @facet_names;
 729
 730         $self->render( name => $name, facet => $facet, checked => $checked,
 731                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 732         );
 733 }
 734
 735 sub edit {
 736         my $self = shift;
 737         my $new_content = $self->param('new_content');
 738         $new_content  ||= $self->param('content'); # backward compatibility with old actions
 739
 740         my $i = $self->param('_row_id');
 741         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
 742         my $path = $self->param('path') || die "no path";
 743         my $name = $self->param('name') || die "no name";
 744         my $status = 200; # 200 = OK, 201 = Created
 745
 746         my $data = $self->_loaded('data');
 747
 748         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
 749                 $new_content =~ s/^\s+//s;
 750                 $new_content =~ s/\s+$//s;
 751                 my $v;
 752                 if ( $new_content =~ /\xB6/ ) { # para
 753                         $v = [ split(/\s*\xB6\s*/, $new_content) ];
 754                 } else {
 755                         $v = [ $new_content ];
 756                 }
 757
 758                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
 759                 my $new = dump $v;
 760                 if ( $old ne $new
 761                         && ! ( $old eq 'undef' && length($new_content) == 0 ) # new value empty, previous undef
 762                 ) {
 763                         my $change = {
 764                                 path => $path,
 765                                 column => $name,
 766                                 pos => $i,
 767                                 old => $loaded->{$path}->{data}->{items}->[$i]->{$name},
 768                                 new => $v,
 769                                 time => $self->param('time') || time(),
 770                                 user => $self->param('user') || $ENV{'LOGNAME'},
 771                                 unique => {
 772                                         map { $_ => $loaded->{$path}->{data}->{items}->[$i]->{$_}->[0] }
 773                                         grep { defined $loaded->{$path}->{stats}->{$_}->{unique} }
 774                                         keys %{ $loaded->{$path}->{stats} }
 775                                 },
 776                         };
 777                         my $change_path = $self->_permanent_path( 'changes' );
 778                         mkdir $change_path unless -d $change_path;
 779                         $change_path .= '/' . $change->{time};
 780                         store $change, $change_path;
 781                         utime $change->{time}, $change->{time}, $change_path;
 782                         warn "# $change_path ", dump($change);
 783
 784                         warn "# change $path $i $old -> $new\n";
 785                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
 786
 787                         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
 788                             delete $loaded->{$path}->{sorted}->{$name};
 789                                 warn "# invalidate $path sorted $name\n";
 790                         }
 791
 792                         foreach ( grep { m/$name/ } keys %{ $loaded->{$path}->{filtered} } ) {
 793                             delete $loaded->{$path}->{filtered}->{$_};
 794                                 warn "# invalidate $path filtered $_\n";
 795                         }
 796
 797                         $status = 201; # created
 798                         # modified = 2 -- force rebuild of stats
 799                         $loaded->{$path}->{modified}  = 2;
 800                         $self->session( 'modified' => 2 );
 801
 802                         $new_content = join("\xB6",@$v);
 803
 804                 } else {
 805                         warn "# unchanged $path $i $old\n";
 806                         $status = 304;
 807                 }
 808         } else {
 809                 $new_content = "$path $i $name doesn't exist\n";
 810                 $status = 404;
 811         }
 812
 813         warn "# edit $status ", dump $new_content;
 814
 815         $self->render(
 816                 status => $status,
 817                 new_content => scalar $new_content,
 818         );
 819 }
 820
 821
 822 sub save {
 823         my $self = shift;
 824         my $path = $self->_param_or_session('path');
 825         my $dump_path = $self->_save( $path );
 826         $loaded->{$path}->{modified} = 0;
 827         $self->session( 'modified' => 0 );
 828
 829         $self->redirect_to( '/data/items' );
 830 }
 831
 832 sub export {
 833         my $self = shift;
 834         $self->render( export => [
 835                 map { s{^.+/public/export/}{}; $_ }
 836                 glob( $self->_export_path . '*' )
 837         ] );
 838 }
 839
 840 sub __loaded_paths {
 841         return
 842                 grep { defined $loaded->{$_}->{data} }
 843                 keys %$loaded;
 844 }
 845
 846 1;