lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12
  13 sub index {
  14         my $self = shift;
  15
  16         my $path = $self->app->home->rel_dir('data');
  17         die "no data dir $path" unless -d $path;
  18
  19         opendir(my $dir, $path) || die $!;
  20         my @files =
  21                 grep { -f "$path/$_" && $_ =~ m/\.js(on)?$/ }
  22                 readdir $dir;
  23         close($dir);
  24
  25         $self->render( files => [ @files ] );
  26 }
  27
  28 our $data;
  29 our $stats;
  30
  31 sub load {
  32         my $self = shift;
  33
  34         my $path = $self->app->home->rel_file( 'data/' . $self->param('path') );
  35         die "$path $!" unless -r $path;
  36
  37         $self->session('path' => $self->param('path'));
  38
  39         # we could use Mojo::JSON here, but it's too slow
  40 #       $data = from_json read_file $path;
  41         $data = read_file $path;
  42         Encode::_utf8_on($data);
  43         warn "# json snippet: ", substr($data,0,200);
  44         $data = from_json $data;
  45
  46         $stats = {};
  47
  48         foreach my $e ( @{ $data->{items} } ) {
  49                 foreach my $n ( keys %$e ) {
  50                         $stats->{$n}->{count}++;
  51                         $stats->{$n}->{number}++
  52                                 if $e->{$n} =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  53                         $stats->{$n}->{array} += $#{ $e->{$n} } + 1
  54                                 if ref $e->{$n} eq 'ARRAY';
  55                 }
  56         }
  57
  58         foreach my $n ( keys %$stats ) {
  59                 next unless defined $stats->{$n}->{array};
  60                 delete $stats->{$n}->{array}
  61                         if $stats->{$n}->{array} == $stats->{$n}->{count};
  62         }
  63
  64         warn dump($stats);
  65
  66         $self->redirect_to( '/data/columns' );
  67 }
  68
  69
  70 sub columns {
  71     my $self = shift;
  72
  73     $self->render(
  74                 message => 'Select columns to display',
  75                 stats => $stats,
  76                 checked => $self->_checked( $self->_perm_array('columns') ),
  77         );
  78 }
  79
  80 sub _perm_array {
  81     my ($self,$name) = @_;
  82
  83         my @array = $self->param($name);
  84
  85         if ( @array ) {
  86                 $self->session($name => [ @array ]);
  87         } elsif ( my $session = $self->session($name) ) {
  88                 if ( ref $session eq 'ARRAY' ) {
  89                         @array = @$session;
  90                 } else {
  91                         die "$name not array ",dump($session);
  92                 }
  93         }
  94         warn "# $name ",dump @array;
  95         return @array;
  96 }
  97
  98 sub _perm_scalar {
  99     my ($self,$name,$default) = @_;
 100
 101         my $scalar = $self->param($name);
 102
 103         if ( defined $scalar ) {
 104                 $self->session($name => $scalar);
 105         } else {
 106                 $scalar = $self->session($name);
 107         }
 108
 109         if ( ! defined $scalar ) {
 110                 $scalar = $default;
 111                 die "no default for $name" unless defined $scalar;
 112                 $self->session($name => $scalar);
 113         }
 114
 115         warn "# $name ",dump $scalar;
 116         return $scalar;
 117 }
 118
 119 sub filter {
 120         my $self = shift;
 121
 122         my $name = $self->param('filter_name') || die "name?";
 123         my @vals = $self->param('filter_vals');
 124
 125         warn "# filter $name vals ",dump(@vals);
 126
 127
 128         my $filters = $self->session('filters');
 129         $filters->{$name} = [ @vals ];
 130         $self->session( 'filters' => $filters );
 131
 132         warn "# filters ",dump($self->session('filters'));
 133
 134         $self->redirect_to('/data/table');
 135 }
 136
 137 sub table {
 138     my $self = shift;
 139
 140         $self->redirect_to('/data/index') unless $data->{items};
 141
 142         my @columns = $self->_perm_array('columns');
 143         my $order   = $self->_perm_scalar('order', $columns[0]);
 144         my $offset  = $self->_perm_scalar('offset', 0);
 145         my $limit   = $self->_perm_scalar('limit', 20);
 146
 147         my @sorted = sort {
 148                 $a->{$order} cmp $b->{$order}
 149         } @{ $data->{items} };
 150
 151         @sorted = splice @sorted, $offset, $limit;
 152
 153 #       warn "# sorted ", dump @sorted;
 154
 155         warn "$order $offset $limit";
 156
 157         $self->render(
 158                 order => $order,
 159                 offset => $offset,
 160                 limit => $limit,
 161                 sorted => [ @sorted ],
 162                 columns => [ @columns ],
 163                 rows => $#{ $data->{items} } + 1,
 164         );
 165
 166 }
 167
 168
 169 sub facet {
 170         my $self = shift;
 171
 172         my $facet;
 173         my $name = $self->param('name') || die "no name";
 174
 175         foreach my $i ( @{ $data->{items} } ) {
 176                 next unless exists $i->{$name};
 177                 if ( ref $i->{$name} eq 'ARRAY' ) {
 178                         $facet->{$_}++ foreach @{ $i->{$name} };
 179                 } else {
 180                         $facet->{ $i->{$name} }++;
 181                 }
 182         }
 183
 184 #       warn "# facet $name ",dump $facet;
 185
 186         my $checked;
 187         if ( my $f = $self->session('filters') ) {
 188                 if ( defined $f->{$name} ) {
 189                         $checked = $self->_checked( @{ $f->{$name} } );
 190                 }
 191         }
 192
 193         $self->render( name => $name, facet => $facet, checked => $checked );
 194 }
 195
 196 sub _checked {
 197         my $self = shift;
 198         my $checked;
 199         $checked->{$_}++ foreach @_;
 200         warn "# _checked ",dump($checked);
 201         return $checked;
 202 }
 203
 204 1;