lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use Encode;
  11 use locale;
  12 use File::Find;
  13 use Storable;
  14 use Time::HiRes qw(time);
  15 use File::Path qw(mkpath);
  16
  17 use MojoFacets::Import::File;
  18 use MojoFacets::Import::HTMLTable;
  19
  20 our $loaded;
  21 our $filters;
  22
  23 sub index {
  24         my $self = shift;
  25
  26         my $data_dir = $self->app->home->rel_dir('data');
  27         die "no data dir $data_dir" unless -d $data_dir;
  28
  29         my @files;
  30         my $changes;
  31         find( sub {
  32                 my $file = $File::Find::name;
  33                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  34                         $file =~ s/$data_dir\/*//;
  35                         push @files, $file;
  36                 } elsif ( -f $file && $file =~ m/([^\/]+)\.changes\/(\d+\.\d+.+)/ ) {
  37                         push @{ $changes->{$1} }, $2
  38                 } elsif ( -d $file && $file =~ m/\.html$/ ) {
  39                         $file =~ s/$data_dir\/*//;
  40                         push @files, $file;
  41                 } else {
  42                         #warn "IGNORE: $file\n";
  43                 }
  44         }, $data_dir);
  45
  46         @files = sort { $loaded->{$b}->{mtime} <=> $loaded->{$a}->{mtime} || lc $a cmp lc $b } @files,
  47                         grep { defined $loaded->{$_}->{generated} } keys %$loaded;
  48         my $size;
  49         $size->{$_} = -s "$data_dir/$_" foreach @files;
  50
  51         $self->render(
  52                 files => [ @files ],
  53                 size => $size,
  54                 loaded => $loaded,
  55                 filters => $filters,
  56                 dump_path => { map { $_ => $self->_dump_path($_) } @files },
  57                 changes => $changes,
  58         );
  59 }
  60
  61 sub _dump_path {
  62         my ( $self, $name ) = @_;
  63         my $dir = $self->app->home->rel_dir('data');
  64         $name =~ s/^$dir//;
  65         $name =~ s/\/+/_/g;
  66         return '/tmp/mojo_facets.' . $name . '.storable';
  67 }
  68
  69 sub _save {
  70         my ( $self, $path ) = @_;
  71
  72         my $dump_path = $self->_dump_path( $path );
  73         my $first_load = ! -e $dump_path;
  74         warn "save loaded to $dump_path";
  75         my $info = $loaded->{$path};
  76         store $info, $dump_path;
  77
  78         if ( $first_load ) {
  79                 my $mtime = $loaded->{$path}->{mtime};
  80                 utime $mtime, $mtime, $dump_path;
  81                 warn "sync time to $path at $mtime\n";
  82         }
  83
  84         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  85         return $dump_path;
  86 }
  87
  88
  89 sub __stats {
  90
  91         my $stats;
  92
  93         my $nr_items = $#{ $_[0] } + 1;
  94
  95         warn "__stats $nr_items\n";
  96
  97         foreach my $e ( @{ $_[0] } ) {
  98                 foreach my $n ( keys %$e ) {
  99                         $stats->{$n}->{count}++;
 100                         my @v;
 101                         if ( ref $e->{$n} eq 'ARRAY' ) {
 102                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 103                                 @v = @{ $e->{$n} };
 104                         } else {
 105                                 @v = ( $e->{$n} );
 106                         }
 107
 108                         foreach my $x ( @v ) {
 109                                 $stats->{$n}->{numeric}++
 110                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 111                                 $stats->{$n}->{empty}++
 112                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 113                         }
 114
 115                 }
 116         }
 117
 118         foreach my $n ( keys %$stats ) {
 119                 my $s = $stats->{$n};
 120                 next unless defined $s->{array};
 121                 if ( $s->{array} == $s->{count} ) {
 122                         delete $s->{array};
 123                         if ( $s->{count} == $nr_items ) {
 124                                 warn "check $n for uniqeness\n";
 125                                 my $unique;
 126                                 foreach my $e ( @{ $_[0] } ) {
 127                                         if ( ++$unique->{ $e->{$n}->[0] } == 2 ) {
 128                                                 $unique = 0;
 129                                                 last;
 130                                         }
 131                                 }
 132                                 if ( $unique ) {
 133                                         $stats->{$n}->{unique} = 1;
 134                                         #warn "# $n unique ",dump( $unique );
 135                                 }
 136                         }
 137                 }
 138         }
 139
 140         warn "# __stats ",dump($stats);
 141
 142         return $stats;
 143 }
 144
 145 sub _param_or_session {
 146         $_[0]->param( $_[1] ) || $_[0]->session( $_[1] )
 147 }
 148
 149 sub stats {
 150         my $self = shift;
 151         my $path = $self->_param_or_session('path');
 152         warn "stats $path\n";
 153         delete $loaded->{$path}->{stats};
 154         $self->redirect_to( '/data/columns' );
 155 }
 156
 157
 158 sub _load_path {
 159         my ( $self, $path ) = @_;
 160
 161         return if defined $loaded->{$path}->{'generated'};
 162
 163         my $full_path = $self->app->home->rel_file( 'data/' . $path );
 164         die "$full_path $!" unless -r $full_path;
 165
 166         my $dump_path = $self->_dump_path( $path );
 167
 168         if ( defined $loaded->{$path}->{data} ) {
 169                 my $mtime = (stat($full_path))[9];
 170                 return if $loaded->{$path}->{mtime} == $mtime;
 171                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
 172         } elsif ( -e $dump_path ) {
 173                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
 174                 my $info = retrieve $dump_path;
 175                 $loaded->{ $path } = $info;
 176                 return;
 177         }
 178
 179         my $data;
 180         if ( -f $full_path ) {
 181                 $data = MojoFacets::Import::File->new( full_path => $full_path, path => $path )->data;
 182         } elsif ( -d $full_path && $full_path =~ m/.html/ ) {
 183                 $data = MojoFacets::Import::HTMLTable->new( dir => $full_path )->data;
 184         } else {
 185                 die "can't load $full_path";
 186         }
 187
 188         my @header;
 189
 190         if ( defined $data->{header} ) {
 191                 if ( ref $data->{header} eq 'ARRAY' ) {
 192                         @header = @{ $data->{header} };
 193                 } else {
 194                         warn "header not array ", dump( $data->{header} );
 195                 }
 196         }
 197
 198         my $stats = __stats( $data->{items} );
 199
 200         @header =
 201                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 202                 grep { defined $stats->{$_}->{count} } keys %$stats
 203                 unless @header;
 204
 205         my $info = {
 206                 header => [ @header ],
 207                 stats  => $stats,
 208                 full_path => $full_path,
 209                 size => -s $full_path,
 210                 mtime => (stat($full_path))[9],
 211                 data => $data,
 212         };
 213
 214         $loaded->{ $path } = $info;
 215         $self->_save( $path );
 216
 217 }
 218
 219
 220 sub load {
 221         my $self = shift;
 222
 223         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 224
 225         my @paths = $self->param('paths');
 226         warn "# paths ", dump @paths;
 227
 228         foreach my $p ( keys %$loaded ) {
 229                 next if grep { /^\Q$p\E$/ } @paths;
 230                 warn "remove $p from memory\n";
 231                 delete $loaded->{$p};
 232         }
 233
 234         $self->_load_path( $_ ) foreach @paths;
 235
 236         warn "# path $path\n";
 237         $self->_load_path( $path );
 238
 239         $self->session( 'path' => $path );
 240
 241         my $redirect_to = '/data/items';
 242
 243         $self->session( 'header' => $loaded->{$path}->{header} );
 244         if ( ! defined $loaded->{$path}->{columns} ) {
 245                 my $columns_path = $self->_permanent_path( 'columns' );
 246                 if ( -e $columns_path ) {
 247                         my @columns = map { s/[\r\n]+$//; $_ } read_file $columns_path;
 248                         $loaded->{$path}->{columns} = [ @columns ];
 249                         warn "# columns_path $columns_path ",dump(@columns);
 250                 } else {
 251                         $loaded->{$path}->{columns} = $loaded->{$path}->{header}
 252                 }
 253
 254                 $redirect_to = '/data/columns';
 255         }
 256         $self->session( 'columns' => $loaded->{$path}->{columns} );
 257         $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 258         $self->redirect_to( $redirect_to );
 259 }
 260
 261
 262 sub _loaded {
 263         my ( $self, $name ) = @_;
 264         my $path = $self->session('path') || $self->param('path');
 265         $self->redirect_to('/data/index') unless $path;
 266
 267         if ( defined $loaded->{$path}->{modified} && $loaded->{$path}->{modified} > 1 ) {
 268                 my $caller = (caller(1))[3];
 269                 if ( $caller =~ m/::edit/ ) {
 270                         warn "rebuild stats for $path ignored caller $caller\n";
 271                 } else {
 272                         warn "rebuild stats for $path FORCED by modified caller $caller\n";
 273                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 274                         $loaded->{$path}->{modified} = 1;
 275                 }
 276         }
 277
 278         if ( ! defined $loaded->{$path}->{$name} ) {
 279                 warn "$path $name isn't loaded\n";
 280                 $self->_load_path( $path );
 281                 if ( ! defined $loaded->{$path}->{stats} ) {
 282                         warn "rebuild stats for $path\n";
 283                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 284                 }
 285                 if ( ! defined $loaded->{$path}->{$name} ) {
 286                         warn "MISSING $name for $path\n";
 287                         $self->redirect_to('/data/index')
 288                 }
 289         }
 290
 291         $self->session( 'modified' => $loaded->{$path}->{modified} );
 292
 293         return $loaded->{$path}->{$name};
 294 }
 295
 296
 297 sub _checked {
 298         my $self = shift;
 299         my $checked;
 300         $checked->{$_}++ foreach @_;
 301 #       warn "# _checked ",dump($checked);
 302         return $checked;
 303 }
 304
 305 sub _permanent_path {
 306         my $self = shift;
 307         my $path = $self->_param_or_session('path');
 308         $self->app->home->rel_dir('data') . '/' . join('.', $path, @_);
 309 }
 310
 311 sub _export_path {
 312         my $self = shift;
 313         my $path = $self->_param_or_session('path');
 314         if ( ! $path ) {
 315                 warn "no path in param or session";
 316                 return;
 317         }
 318         my $dir = $self->app->home->rel_dir('public') . "/export/$path";
 319         mkpath $dir unless -e $dir;
 320         $dir . '/' . join('.', @_);
 321 }
 322
 323 sub columns {
 324     my $self = shift;
 325
 326         if ( $self->param('columns') ) {
 327                 my @columns = $self->_param_array('columns');
 328                 write_file( $self->_permanent_path( 'columns' ), map { "$_\n" } @columns );
 329                 $self->redirect_to('/data/items');
 330         }
 331
 332         my $stats = $self->_loaded( 'stats' );
 333
 334         my @columns;
 335         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 336
 337         foreach my $c ( @{ $self->session( 'header' ) } ) {
 338                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 339         }
 340
 341     $self->render(
 342                 message => 'Select columns to display',
 343                 stats => $stats,
 344                 columns => \@columns,
 345                 checked => $self->_checked( $self->_param_array('columns') ),
 346         );
 347 }
 348
 349 sub _param_array {
 350     my ($self,$name) = @_;
 351
 352         my @array = $self->param($name);
 353         my $path  = $self->session('path');
 354
 355         if ( @array ) {
 356                 $self->session($name => [ @array ]);
 357                 $loaded->{$path}->{$name} = [ @array ];
 358         } elsif ( my $session = $self->session($name) ) {
 359                 if ( ref $session eq 'ARRAY' ) {
 360                         @array = @$session;
 361                 } else {
 362                         die "$name not array ",dump($session);
 363                 }
 364         }
 365         #warn "# $name ",dump @array;
 366         return @array;
 367 }
 368
 369 sub _param_scalar {
 370     my ($self,$name,$default) = @_;
 371
 372         my $scalar = $self->param($name);
 373
 374         if ( defined $scalar ) {
 375                 $self->session($name => $scalar);
 376         } else {
 377                 $scalar = $self->session($name);
 378         }
 379
 380         if ( ! defined $scalar ) {
 381                 $scalar = $default;
 382                 die "no default for $name" unless defined $scalar;
 383                 $self->session($name => $scalar);
 384         }
 385
 386         warn "# _param_scalar $name ",dump $scalar;
 387         return $scalar;
 388 }
 389
 390 sub filter {
 391         my $self = shift;
 392
 393         my $name = $self->param('filter_name') || die "name?";
 394         my @vals = $self->param('filter_vals');
 395
 396         $self->_remove_filter( $name );
 397         if ( @vals ) {
 398                 $self->_filter_on_data( $name, @vals );
 399                 if ( my $permanent = $self->param('_permanent') ) {
 400                         my $permanent_path = $self->_export_path( 'filter', $name, $permanent );
 401                         write_file $permanent_path, map { "$_\n" } @vals;
 402                         warn "permanent filter $permanent_path ", -s $permanent_path;
 403                 }
 404         }
 405
 406         $self->session( 'offset' => 0 );
 407
 408         $self->redirect_to('/data/items');
 409 }
 410
 411 sub _filter_on_data {
 412         my ( $self, $name, @vals ) = @_;
 413
 414         my $path = $self->session('path');
 415
 416         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 417                 warn "filter $name not found in data set";
 418                 return;
 419         }
 420
 421         $filters->{$name} = [ @vals ];
 422         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 423
 424         my $filter_hash;
 425         $filter_hash->{$_}++ foreach @vals;
 426
 427         #warn "# filter_hash ",dump( $filter_hash );
 428
 429         my $items = $self->_loaded('data')->{items};
 430
 431         my $include_missing = defined $filter_hash->{_missing};
 432         my $filtered_items;
 433
 434         foreach my $i ( 0 .. $#$items ) {
 435
 436                 if ( defined $items->[$i]->{$name} ) {
 437                         my $row = $items->[$i]->{$name};
 438                         $row = [ $row ] unless ref $row eq 'ARRAY'; # FIXME probably wrong place
 439                         foreach my $v ( @$row ) {
 440                                 if ( defined $filter_hash->{ $v } ) {
 441                                         $filtered_items->{$i}++;
 442                                 }
 443                         }
 444                 } elsif ( $include_missing ) {
 445                         $filtered_items->{$i}++;
 446                 }
 447         }
 448
 449         #warn "# filter $name ",dump($filtered_items);
 450
 451         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 452         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 453 }
 454
 455
 456 sub _current_filters {
 457         my $self = shift;
 458         my $current_filters;
 459         my $columns = $self->_loaded('header');
 460         if ( my $sc = $self->session('columns') ) {
 461                 $columns = $sc;
 462         }
 463
 464         $current_filters->{ $_ } = $filters->{ $_ }
 465                 foreach ( grep { defined $filters->{ $_ } } @$columns )
 466         ;
 467         warn "# _current_filters ",dump($columns);
 468         return $current_filters;
 469 }
 470
 471 sub _data_sorted_by {
 472         my ( $self, $order ) = @_;
 473
 474         my $path = $self->session('path');
 475
 476         warn "_data_sorted_by $order from $path";
 477
 478         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 479                 return $loaded->{$path}->{sorted}->{$order};
 480         }
 481
 482         my $data = $self->_loaded( 'data' );
 483         my $numeric = $self->_is_numeric($order);
 484         my $missing = $numeric ? 0 : '';
 485         no warnings qw(numeric);
 486         my $nr = 0;
 487         my @sorted = map {
 488                 $_->[0]
 489         } sort {
 490                 if ( $numeric ) {
 491                         $a->[1] <=> $b->[1]
 492                 } else {
 493                         $a->[1] cmp $b->[1]
 494                 }
 495         } map {
 496                 my $v;
 497                 if ( ! exists $_->{$order} ) {
 498                         $v = $missing;
 499                 } elsif ( ref $_->{$order} eq 'ARRAY' ) {
 500                         $v = join('', @{$_->{$order}});
 501                 } else {
 502                         $v = $_->{$order};
 503                 }
 504                 [ $nr++, $v ]
 505         } @{ $data->{items} }
 506         ;
 507
 508         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 509         #warn "# sorted ",dump( @sorted );
 510
 511         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 512 }
 513
 514
 515 sub __all_filters {
 516         my $order = pop @_;
 517         join(',', sort(@_), 'order', $order);
 518 }
 519
 520 sub items {
 521         my $self = shift;
 522
 523         if ( my $show = $self->param('id') ) {
 524                 $self->param('show', $show);
 525                 warn "show $show\n";
 526         }
 527
 528         my $path = $self->session('path');
 529
 530         my @columns = $self->_param_array('columns');
 531         $self->redirect_to('/data/columns') unless @columns;
 532         my $order   = $self->_param_scalar('order', $columns[0]);
 533         my $sort    = $self->_param_scalar('sort', 'a');
 534         my $offset  = $self->_param_scalar('offset', 0);
 535         my $limit   = $self->_param_scalar('limit', 20);
 536         $self->_param_scalar('show', 'table');
 537
 538         # fix offset when changing limit
 539         $offset = int( $offset / $limit ) * $limit;
 540
 541         if ( ! grep { /^\Q$order\E$/ } @columns ) {
 542                 $order = $columns[0];
 543                 $self->session( order => $order );
 544         }
 545         my $sorted = $self->_data_sorted_by( $order );
 546
 547         my @filter_names;
 548         if ( $filters ) {
 549                 foreach my $name ( keys %$filters ) {
 550                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 551                                 warn "skip filter $name not found in $path\n";
 552                                 next;
 553                         }
 554                         push @filter_names, $name;
 555                 }
 556                 warn "filter_names ",dump( @filter_names );
 557                 foreach my $name ( @filter_names ) {
 558                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 559                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 560                 }
 561         }
 562
 563         my $all_filters = __all_filters( @filter_names,$order );
 564
 565 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 566
 567         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 568
 569                 my $path_filters = $loaded->{$path}->{filters};
 570
 571                 warn "create combined filter for $all_filters from ", $#$sorted + 1, " items\n";
 572
 573                 my @filtered;
 574                 foreach my $i ( 0 .. $#$sorted ) {
 575                         my $pos = $sorted->[$i];
 576
 577                         if ( $#filter_names == -1 ) {
 578                                 push @filtered, $pos;
 579                                 next;
 580                         }
 581
 582                         my $skip = 0;
 583                         foreach ( @filter_names ) {
 584                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 585                         }
 586                         next if $skip;
 587
 588                         push @filtered, $pos;
 589                 }
 590
 591                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 592         }
 593
 594         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 595                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 596
 597         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 598
 599         my $data = $self->_loaded('data');
 600
 601         my $code = $self->_param_scalar('code','');
 602         $code =~ s{[\r\n]+$}{}s;
 603
 604         my $commit = $self->param('commit');
 605         my $test = $self->param('test');
 606
 607         my $cols_changed;
 608         my $cols_order;
 609
 610         if ( $code && ( $test || $commit ) ) {
 611                 # XXX find columns used in code snippet and show them to user
 612                 my $order = 0;
 613                 foreach my $column ( $code =~ m/\$row->{(.+?)}/g ) {
 614                         if ( $column =~ s/^(['"])// ) {
 615                                 $column =~ s/$1$//;
 616                         }
 617                         $cols_changed->{$column}++;
 618                         $cols_order->{$column} = $order++;
 619                         next if grep { /$column/ } @columns;
 620                         $cols_changed->{$column}++;
 621                         unshift @columns, $column;
 622                         if ( $commit ) {
 623                                 $self->session('columns', [ @columns ]);
 624                                 $loaded->{$path}->{columns} = [ @columns ];
 625                                 __path_modified( $path, 2 );
 626                         }
 627                 }
 628         }
 629
 630         my $code_path = $self->app->home->rel_dir('public') . "/code";
 631         if ( $commit ) {
 632                 warn "# commit on ", $#$filtered + 1, " items:\n$code\n";
 633                 my $out;
 634                 foreach ( 0 .. $#$filtered ) {
 635                         my $i = $filtered->[$_];
 636                         my $row = $data->{items}->[$i];
 637                         eval $code;
 638                 }
 639                 if ( my $description = $self->param('code_description') ) {
 640                         my $depends = $self->param('code_depends') || die "no code_depends?";
 641                         my $path = "$code_path/$depends.$description.pl";
 642                         if ( -e $path && ! $self->param('overwrite') ) {
 643                                 warn "# code $path not saved\n";
 644                         } else {
 645                                 write_file(  $path, { binmode => ':utf8' }, $code );
 646                                 warn "code $path ", -s $path, " bytes saved\n";
 647                         }
 648                 }
 649                 $code = '';
 650                 if ( $out ) {
 651                         my $commit_dataset = join('.'
 652                                 , $self->param('code_depends')
 653                                 , $self->param('code_description')
 654                         );
 655                         my $key = $self->param('code_depends');
 656                         $key =~ s/,.+$//;
 657                         $key ||= 'key';
 658                         my $items;
 659                         foreach my $n ( keys %$out ) {
 660                                 my $i = { $key => [ $n ] };
 661                                 $i->{$_} = [ $out->{$n}->{$_} ] foreach keys %{ $out->{$n} };
 662                                 push @$items, $i;
 663                         };
 664                         undef $out;
 665                         my $stats = __stats( $items );
 666                         my @columns = grep { ! m/^\Q$key\E$/ } sort keys %$stats;
 667                         unshift @columns, $key;
 668
 669                         $loaded->{$commit_dataset} = {
 670                                 header => [ @columns ],
 671                                 columns => [ @columns ],
 672                                 mtime => time(),
 673                                 data => { items => $items },
 674                                 stats => $stats,
 675                                 generated => 1,
 676                         };
 677                         warn "# loaded out ", dump( $loaded->{$commit_dataset} );
 678                         $self->session('path', $commit_dataset);
 679                         $self->session('columns', [ @columns ]);
 680                         $self->session('order', $key);
 681                         $self->redirect_to('/data/items');
 682                 }
 683         }
 684
 685         my $sorted_items;
 686         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 687         my $out;
 688         foreach ( 0 .. $limit ) {
 689                 my $i = $_ + $offset;
 690                 last unless defined $filtered->[$i];
 691                 $i = $from_end - $i if $from_end;
 692                 my $id = $filtered->[$i];
 693                 my $row = $data->{items}->[ $id ];
 694                 if ( $code && $test ) {
 695                         $row = Storable::dclone $row;
 696                         eval $code;
 697                         if ( $@ ) {
 698                                 warn "ERROR evaling\n$code\n$@";
 699                                 $self->stash('eval_error', $@) if $@;
 700                         } else {
 701                                 warn "EVAL ",dump($row);
 702                         }
 703                 }
 704                 $row->{_row_id} ||= $id;
 705                 push @$sorted_items, $row;
 706         }
 707
 708         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 709
 710 warn "XXX cols_order ",dump( $cols_order );
 711
 712         my $code_depends = $self->param('code_depends')||
 713         join(',', sort { $cols_order->{$a} <=> $cols_order->{$b} } grep { defined $cols_changed->{$_} && $cols_changed->{$_} == 1 } @columns );
 714         my $code_description = $self->param('code_description') ||
 715         join(',', sort { $cols_order->{$a} <=> $cols_order->{$b} } grep { defined $cols_changed->{$_} && $cols_changed->{$_} == 2 } @columns );
 716
 717         $code_depends ||= $code_description; # self-modifing
 718
 719         warn "# cols_changed ",dump( $cols_changed, $code_depends, $code_description );
 720
 721         $self->render(
 722                 order => $order,
 723                 offset => $offset,
 724                 limit => $limit,
 725                 sorted => $sorted_items,
 726                 columns => [ @columns ],
 727                 rows => $#$filtered + 1,
 728                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 729                 unique  => { map { $_, $self->_is_unique( $_) } @columns },
 730                 filters => $self->_current_filters,
 731                 code => $code,
 732                 cols_changed => $cols_changed,
 733                 code_depends => $code_depends,
 734                 code_description => $code_description,
 735                 code_path => $code_path,
 736                 out => $out,
 737         );
 738
 739 }
 740
 741
 742 sub order {
 743         my $self = shift;
 744         $self->session('order', $self->param('order'));
 745         $self->session('sort', $self->param('sort'));
 746         $self->redirect_to('/data/items');
 747 }
 748
 749 sub _is_numeric {
 750         my ( $self, $name ) = @_;
 751
 752         my $stats = $self->_loaded( 'stats' );
 753
 754         # sort facet numerically if more >50% elements are numeric
 755         my $count = $stats->{$name}->{count};
 756         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 757         defined $stats->{$name}->{numeric} &&
 758                 $stats->{$name}->{numeric} > $count / 2;
 759 }
 760
 761 sub _is_unique {
 762         my ( $self, $name ) = @_;
 763         my $stats = $self->_loaded( 'stats' );
 764         defined $stats->{$name}->{unique};
 765 }
 766
 767 sub _remove_filter {
 768         my ($self,$name) = @_;
 769         warn "_remove_filter $name\n";
 770
 771         my $path = $self->session('path');
 772
 773         delete $filters->{$name};
 774         delete $loaded->{$path}->{filters}->{$name};
 775         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 776
 777         foreach (
 778                         grep { /\Q$name\E/ }
 779                         keys %{ $loaded->{$path}->{filtered} }
 780         ) {
 781                 delete $loaded->{$path}->{filtered}->{$_};
 782                 warn "remove filtered cache $_";
 783         }
 784 }
 785
 786 sub facet {
 787         my $self = shift;
 788
 789         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 790
 791         if ( my $name = $self->param('remove') ) {
 792                 $self->_remove_filter( $name );
 793                 $self->redirect_to( '/data/items' );
 794         }
 795
 796         my $facet;
 797         my $name = $self->param('name') || die "no name";
 798
 799         my $all = $self->_param_scalar('all', 1);
 800         my $data = $self->_loaded('data');
 801
 802         my $filters = $self->_current_filters;
 803         my $all_filters = __all_filters( keys %$filters,$self->session('order') );
 804         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 805                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 806
 807         if ( ! $filtered || $all ) {
 808                 $filtered = [ 0 .. $#{ $data->{items} } ];
 809                 warn "filter all values\n";
 810         } else {
 811                 warn "filter using $all_filters\n";
 812         }
 813
 814         foreach my $i ( @$filtered ) {
 815                 my $item = $data->{items}->[$i];
 816                 if ( ! exists $item->{$name} ) {
 817                         $facet->{ _missing }++;
 818                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 819                         $facet->{$_}++ foreach @{ $item->{$name} };
 820                 } else {
 821                         $facet->{ $item->{$name} }++;
 822                 }
 823         }
 824
 825 #       warn "# facet $name ",dump $facet;
 826
 827         my $checked;
 828         my @facet_names =
 829                   $all                      ? keys %$facet
 830                 : defined $filters->{$name} ? @{ $filters->{$name} }
 831                 : keys %$facet;
 832
 833         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 834
 835         my $numeric = $self->_is_numeric($name);
 836
 837         my $sort = $self->param('sort');
 838         # sort numeric facets with more than 5 values ascending
 839         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 840
 841         @facet_names = sort {
 842                 my $result;
 843                 if ( $sort eq 'a' ) {
 844                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 845                 } elsif ( $sort eq 'd' ) {
 846                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 847                 } elsif ( $sort eq 'c' ) {
 848                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 849                 } else {
 850                         warn "unknown sort: $sort";
 851                         $result = $a cmp $b;
 852                 }
 853                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 854                 $result;
 855         } @facet_names;
 856
 857         $self->render( name => $name, facet => $facet, checked => $checked,
 858                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 859         );
 860 }
 861
 862
 863 sub __invalidate_path_column {
 864         my ( $path, $name ) = @_;
 865
 866         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
 867                 delete $loaded->{$path}->{sorted}->{$name};
 868                 warn "# invalidate $path sorted $name\n";
 869         }
 870
 871         foreach ( grep { m/\Q$name\E/ } keys %{ $loaded->{$path}->{filtered} } ) {
 872                 delete $loaded->{$path}->{filtered}->{$_};
 873                 warn "# invalidate $path filtered $_\n";
 874         }
 875 }
 876
 877 sub __path_modified {
 878         my ( $path, $value ) = @_;
 879         $value = 1 unless defined $value;
 880
 881         $loaded->{$path}->{modified}  = $value;
 882
 883         warn "# __path_modified $path $value\n";
 884 }
 885
 886 sub edit {
 887         my $self = shift;
 888         my $new_content = $self->param('new_content');
 889         $new_content  ||= $self->param('content'); # backward compatibility with old actions
 890
 891         my $i = $self->param('_row_id');
 892         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
 893         my $path = $self->param('path') || die "no path";
 894         my $name = $self->param('name') || die "no name";
 895         my $status = 200; # 200 = OK, 201 = Created
 896
 897         my $data = $self->_loaded('data');
 898
 899         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
 900                 $new_content =~ s/^\s+//s;
 901                 $new_content =~ s/\s+$//s;
 902                 my $v;
 903                 if ( $new_content =~ /\xB6/ ) { # para
 904                         $v = [ split(/\s*\xB6\s*/, $new_content) ];
 905                 } else {
 906                         $v = [ $new_content ];
 907                 }
 908
 909                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
 910                 my $new = dump $v;
 911                 if ( $old ne $new
 912                         && ! ( $old eq 'undef' && length($new_content) == 0 ) # new value empty, previous undef
 913                 ) {
 914                         my $change = {
 915                                 path => $path,
 916                                 column => $name,
 917                                 pos => $i,
 918                                 old => $loaded->{$path}->{data}->{items}->[$i]->{$name},
 919                                 new => $v,
 920                                 time => $self->param('time') || time(),
 921                                 user => $self->param('user') || $ENV{'LOGNAME'},
 922                                 unique => {
 923                                         map { $_ => $loaded->{$path}->{data}->{items}->[$i]->{$_}->[0] }
 924                                         grep { defined $loaded->{$path}->{stats}->{$_}->{unique} }
 925                                         keys %{ $loaded->{$path}->{stats} }
 926                                 },
 927                         };
 928                         my $change_path = $self->_permanent_path( 'changes' );
 929                         mkdir $change_path unless -d $change_path;
 930                         $change_path .= '/' . $change->{time};
 931                         store $change, $change_path;
 932                         utime $change->{time}, $change->{time}, $change_path;
 933                         warn "# $change_path ", dump($change);
 934
 935                         warn "# change $path $i $old -> $new\n";
 936                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
 937
 938                         __invalidate_path_column( $path, $name );
 939
 940                         $status = 201; # created
 941                         # modified = 2 -- force rebuild of stats
 942                         __path_modified( $path, 2 );
 943
 944                         $new_content = join("\xB6",@$v);
 945
 946                 } else {
 947                         warn "# unchanged $path $i $old\n";
 948                         $status = 304;
 949                 }
 950         } else {
 951                 $new_content = "$path $i $name doesn't exist\n";
 952                 $status = 404;
 953         }
 954
 955         warn "# edit $status ", dump $new_content;
 956
 957         $self->render(
 958                 status => $status,
 959                 new_content => scalar $new_content,
 960         );
 961 }
 962
 963
 964 sub save {
 965         my $self = shift;
 966         my $path = $self->_param_or_session('path');
 967         my $dump_path = $self->_save( $path );
 968         __path_modified( $path, 0 );
 969
 970         $self->redirect_to( '/data/items' );
 971 }
 972
 973 sub export {
 974         my $self = shift;
 975
 976         if ( my $import = $self->param('import') ) {
 977
 978                 if ( $import =~ m{/filter\.(.+?)\..+} ) {
 979                         my $name = $1;
 980                         my @vals = map { chomp; $_ }
 981                                 read_file $self->app->home->rel_dir('public') . "/export/$import";
 982                         $self->_remove_filter( $name );
 983                         $self->_filter_on_data( $name, @vals );
 984                         $self->session( 'offset' => 0 );
 985                         $self->redirect_to('/data/items');
 986                 } else {
 987                         warn "UNKNOWN IMPORT $import";
 988                 }
 989         }
 990
 991         $self->render( export => [
 992                 glob( $self->_export_path . '*' )
 993         ] );
 994 }
 995
 996 sub __loaded_paths {
 997         return
 998                 grep { defined $loaded->{$_}->{data} }
 999                 keys %$loaded;
1000 }
1001
1002 1;