git.rot13.org Git - webpac2/blob - lib/WebPAC/Common.pm

   1 package WebPAC::Common;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Log::Log4perl qw/get_logger :levels/;
   7 use Time::HiRes qw/time/;
   8 use Data::Dump qw/dump/;
   9 use File::Spec;
  10
  11 use base qw/Class::Accessor/;
  12 __PACKAGE__->mk_accessors( qw/log_debug no_log debug/ );
  13
  14 =head1 NAME
  15
  16 WebPAC::Common - internal methods called from other WebPAC modules
  17
  18 =head1 VERSION
  19
  20 Version 0.05
  21
  22 =cut
  23
  24 our $VERSION = '0.05';
  25
  26 =head1 SYNOPSYS
  27
  28 This module defines common functions, and is used as base for other, more
  29 specific modules.
  30
  31 my $o = WebPAC::Common->new({
  32         log_debug => 1,
  33         no_log => 1,
  34         debug => 1,
  35 });
  36
  37 Options:
  38
  39 =over 20
  40
  41 =item log_debug
  42
  43 Generate additional debugging log on C<STDERR>
  44
  45 =item no_log
  46
  47 Disable all logging (useful for tests)
  48
  49 =item debug
  50
  51 Use debugging logger which dumps output only yo C<STDERR>
  52
  53 =back
  54
  55
  56 =head1 FUNCTIONS
  57
  58 =head2 progress_bar
  59
  60 Draw progress bar on STDERR.
  61
  62  $webpac->progress_bar($current, $max);
  63
  64 =cut
  65
  66 sub progress_bar {
  67         my $self = shift;
  68
  69         my ($curr,$max) = @_;
  70
  71         my $log = $self->_get_logger();
  72
  73         $self->{last_pcnt_t} ||= time();
  74
  75         $log->logconfess("no current value!") if (! $curr);
  76         $log->logconfess("no maximum value!") if (! $max);
  77
  78         if ($curr > $max) {
  79                 $max = $curr;
  80                 $log->debug("overflow to $curr");
  81         }
  82
  83         $self->{'last_pcnt'} ||= 1;
  84         $self->{'start_t'} ||= time();
  85
  86         my $p = int($curr * 100 / $max) || 1;
  87
  88         # reset on re-run
  89         if ($p < $self->{'last_pcnt'}) {
  90                 $self->{'last_pcnt'} = $p;
  91                 $self->{'start_t'} = time();
  92         }
  93
  94         my $t = time();
  95
  96         if ($p != $self->{'last_pcnt'} || ( $t - $self->{last_pcnt_t} ) > 2 ) {
  97
  98                 my $rate = ($curr / ($t - $self->{'start_t'} || 1));
  99                 my $eta = ($max-$curr) / ($rate || 1);
 100                 printf STDERR ("%5d [%-38s] %-5d %0.1f/s %s\r",$curr,"=" x ($p/3)."$p%>", $max, $rate, $self->fmt_time($eta));
 101                 $self->{'last_pcnt'} = $p;
 102                 $self->{'last_curr'} = $curr;
 103                 $self->{last_pcnt_t} = $t;
 104         }
 105         print STDERR "\n" if ($p == 100);
 106 }
 107
 108 =head2 fmt_time
 109
 110 Format time (in seconds) for display.
 111
 112  print $webpac->fmt_time(time());
 113
 114 This method is called by L<progress_bar> to display remaining time.
 115
 116 =cut
 117
 118 sub fmt_time {
 119         my $self = shift;
 120
 121         my $t = shift || 0;
 122         my $out = "";
 123
 124         my ($ss,$mm,$hh) = gmtime($t);
 125         $out .= "${hh}h" if ($hh);
 126         $out .= sprintf("%02d:%02d", $mm,$ss);
 127         $out .= "  " if ($hh == 0);
 128         return $out;
 129 }
 130
 131 =head2 fill_in
 132
 133 Fill in variable names by values
 134
 135   print $webpac->fill_in( 'foo = $foo bar = $bar',
 136         foo => 42, bar => 11,
 137   );
 138
 139 =cut
 140
 141 sub fill_in {
 142         my $self = shift;
 143
 144         my $format = shift || die "no format?";
 145         my $d = {@_};
 146
 147         foreach my $n ( keys %$d ) {
 148                 $format =~ s/\$\Q$n\E/$d->{$n}/gs;
 149         }
 150
 151         die "unknown variables in '$format' input data = ", dump( $d ) if ( $format =~ m/\$\w+/ );
 152
 153         return $format;
 154 }
 155
 156 #
 157 #
 158 #
 159
 160 =head2 var_path
 161
 162   my $path = $self->var_path('data_dir', 'data_file', ... );
 163
 164 =cut
 165
 166 sub var_path {
 167         my $self = shift;
 168
 169         return File::Spec->catfile('var', @_);
 170 }
 171
 172
 173 =head1 INTERNAL METHODS
 174
 175 Here is a quick list of internal methods, mostly useful to turn debugging
 176 on them (see L<LOGGING> below for explanation).
 177
 178 =cut
 179
 180 =head2 _eval
 181
 182 Internal function to eval code without C<strict 'subs'>.
 183
 184 =cut
 185
 186 sub _eval {
 187         my $self = shift;
 188
 189         my $code = shift || return;
 190
 191         my $log = $self->_get_logger();
 192
 193         no strict 'subs';
 194         my $ret = eval $code;
 195         if ($@) {
 196                 $log->error("problem with eval code [$code]: $@");
 197         }
 198
 199         $log->debug("eval: ",$code," [",$ret,"]");
 200
 201         return $ret || undef;
 202 }
 203
 204 =head2 _init_logger
 205
 206 This function will init C<Log::Log4perl> using provided configuration file.
 207
 208   $webpac->_init_logger('/path/to/log.conf');
 209
 210 If no path to configuration file is given, dummy empty configuration
 211 will be created. If any mode which inherits from this one is called
 212 with C<debug> flag, it will turn logging to debug level.
 213
 214 This function will also read C<log_conf> value from current object and try
 215 to read that as configuration file if it exists, if it doesn't it will
 216 fallback to default C<conf/log.conf>.
 217
 218 You can disable all logging by adding C<no_log> to constructor of WebPAC
 219 object. Object in C<Test::Exception> class will disable logging
 220 automatically.
 221
 222 =cut
 223
 224 sub _init_logger {
 225         my $self = shift;
 226         my $file = shift;
 227         $file ||= $self->{'log_conf'};
 228         $file = 'conf/log.conf';
 229         my $name = (caller(2))[3] || caller;
 230
 231         my $conf = q( );
 232         if ($self->no_log) {
 233                 warn "# $name disabled logging\n" if $self->log_debug;
 234         } elsif ($self->debug) {
 235                 $conf = << '_log4perl_';
 236
 237 log4perl.rootLogger=INFO, SCREEN
 238
 239 log4perl.logger.WebPAC.=DEBUG
 240
 241 log4perl.appender.SCREEN=Log::Log4perl::Appender::Screen
 242 log4perl.appender.SCREEN.layout=PatternLayout
 243 log4perl.appender.SCREEN.layout.ConversionPattern=%d %p> %F{1}:%L %M - %m%n
 244
 245 _log4perl_
 246                 warn "# $name is using debug logger\n" if $self->log_debug;
 247         } elsif ($name =~ m/Test::Exception/o) {
 248                 warn "# disabled logging for Text::Exception\n" if $self->log_debug;
 249         } elsif (-e $file) {
 250                 warn "# $name is using $file logger\n" if $self->log_debug;
 251                 Log::Log4perl->init($file);
 252                 return 1;
 253         } else {
 254                 warn "# $name is using null logger\n" if $self->log_debug;
 255         }
 256         Log::Log4perl->init( \$conf );
 257
 258         return 1;
 259 }
 260
 261
 262 =head2 _get_logger
 263
 264 Get C<Log::Log4perl> object with a twist: domains are defined for each
 265 method
 266
 267  my $log = $webpac->_get_logger();
 268
 269 =cut
 270
 271 my $_logger_seen;
 272
 273 sub _get_logger {
 274         my $self = shift;
 275
 276         my $name = (caller(1))[3] || caller;
 277
 278         # make name full
 279         my $f = '';
 280         if ( $self->log_debug ) {
 281                 foreach ( 0 .. 5 ) {
 282                         my $s = (caller($_))[3];
 283                         $f .= "#### $_ >> $s\n" if ($s);
 284                 }
 285         }
 286
 287         $self->{'_logger_'} ||= $self->_init_logger;
 288
 289         my $log = get_logger( $name );
 290         warn "# get_logger( $name ) level ", $log->level, "\n$f" if ($self->log_debug && !defined($_logger_seen->{$name}));
 291         $_logger_seen->{$name}++;
 292         return $log;
 293 }
 294
 295
 296 =head2 _log
 297
 298 Quick cludge to make logging object available to scripts which
 299 use webpac line this:
 300
 301   my $log = _new WebPAC::Common()->_get_logger();
 302
 303 =cut
 304
 305 sub _new {
 306         my $class = shift;
 307         my $self = {@_};
 308         bless($self, $class);
 309
 310         $self ? return $self : return undef;
 311 }
 312
 313 =head1 LOGGING
 314
 315 Logging in WebPAC is performed by L<Log::Log4perl> with config file
 316 C<log.conf>.
 317
 318 Methods defined above have different levels of logging, so
 319 it's descriptions will be useful to turn (mostry B<debug> logging) on
 320 or off to see why WabPAC isn't perforing as you expect it (it might even
 321 be a bug!).
 322
 323 B<This is different from normal Log4perl behaviour>. To repeat, you can
 324 also use method names, and not only classes (which are just few)
 325 to filter logging.
 326
 327 =cut
 328
 329 1;