git.rot13.org Git - webpac2/blob - lib/WebPAC/Output/TT.pm

   1 package WebPAC::Output::TT;
   2
   3 use warnings;
   4 use strict;
   5
   6 use base qw/WebPAC::Common/;
   7
   8 use Template;
   9 use List::Util qw/first/;
  10 use Data::Dumper;
  11 use URI::Escape qw/uri_escape_utf8/;
  12
  13 =head1 NAME
  14
  15 WebPAC::Output::TT - use Template Toolkit to produce output
  16
  17 =head1 VERSION
  18
  19 Version 0.03
  20
  21 =cut
  22
  23 our $VERSION = '0.03';
  24
  25 =head1 SYNOPSIS
  26
  27 Produce output using Template Toolkit.
  28
  29 =head1 FUNCTIONS
  30
  31 =head2 new
  32
  33 Create new instance.
  34
  35  my $tt = new WebPAC::Output::TT(
  36         include_path => '/path/to/conf/output/tt',
  37         filters => {
  38                 filter_1 => sub { uc(shift) },
  39         },
  40  );
  41
  42 By default, Template Toolkit will C<EVAL_PERL> if included in templates.
  43
  44 =cut
  45
  46 sub new {
  47         my $class = shift;
  48         my $self = {@_};
  49         bless($self, $class);
  50
  51         my $log = $self->_get_logger;
  52
  53         # create Template toolkit instance
  54         $self->{'tt'} = Template->new(
  55                 INCLUDE_PATH => $self->{'include_path'},
  56                 FILTERS => $self->{'filter'},
  57                 EVAL_PERL => 1,
  58         );
  59
  60         $log->logdie("can't create TT object: $Template::ERROR") unless ($self->{'tt'});
  61
  62         $log->debug("filters defined: ",Dumper($self->{'filter'}));
  63
  64         $self ? return $self : return undef;
  65 }
  66
  67
  68 =head2 apply
  69
  70 Create output from in-memory data structure using Template Toolkit template.
  71
  72  my $text = $tt->apply(
  73         template => 'text.tt',
  74         data => $ds,
  75         record_uri => 'database/prefix/mfn',
  76  );
  77
  78 It also has follwing template toolikit filter routies defined:
  79
  80 =cut
  81
  82 sub apply {
  83         my $self = shift;
  84
  85         my $args = {@_};
  86
  87         my $log = $self->_get_logger();
  88
  89         foreach my $a (qw/template data/) {
  90                 $log->logconfess("need $a") unless ($args->{$a});
  91         }
  92
  93 =head3 tt_filter_type
  94
  95 filter to return values of specified from $ds, usage from TT template is in form
  96 C<d('FieldName','delimiter')>, where C<delimiter> is optional, like this:
  97
  98   [% d('Title') %]
  99   [% d('Author',', ' %]
 100
 101 =cut
 102
 103         sub tt_filter_type {
 104                 my ($data,$type) = @_;
 105
 106                 die "no data?" unless ($data);
 107                 $type ||= 'display';
 108
 109                 my $default_delimiter = {
 110                         'display' => '&#182;<br/>',
 111                         'index' => '\n',
 112                 };
 113
 114                 return sub {
 115
 116                         my ($name,$join) = @_;
 117
 118                         die "no data hash" unless ($data->{'data'} && ref($data->{'data'}) eq 'HASH');
 119                         # Hm? Should we die here?
 120                         return unless ($name);
 121
 122                         my $item = $data->{'data'}->{$name} || return;
 123
 124                         my $v = $item->{$type} || return;
 125
 126                         if (ref($v) eq 'ARRAY') {
 127                                 if ($#{$v} == 0) {
 128                                         $v = $v->[0];
 129                                 } else {
 130                                         $join = $default_delimiter->{$type} unless defined($join);
 131                                         $v = join($join, @{$v});
 132                                 }
 133                         } else {
 134                                 warn("TT filter $type(): field $name values aren't ARRAY, ignoring");
 135                         }
 136
 137                         return $v;
 138                 }
 139         }
 140
 141         $args->{'d'} = tt_filter_type($args, 'display');
 142         $args->{'display'} = tt_filter_type($args, 'display');
 143
 144 =head3 tt_filter_search
 145
 146 filter to return links to search, usage in TT:
 147
 148   [% search('FieldToDisplay','FieldToSearch','optional delimiter') %]
 149
 150 =cut
 151
 152         sub tt_filter_search {
 153
 154                 my ($data) = @_;
 155
 156                 die "no data?" unless ($data);
 157
 158                 return sub {
 159
 160                         my ($display,$search,$delimiter) = @_;
 161
 162                         # default delimiter
 163                         $delimiter ||= '&#182;<br/>',
 164
 165                         die "no data hash" unless ($data->{'data'} && ref($data->{'data'}) eq 'HASH');
 166                         # Hm? Should we die here?
 167                         return unless ($display);
 168
 169                         my $item = $data->{'data'}->{$display} || return;
 170
 171                         return unless($item->{'display'});
 172                         die "error in TT template: field $display didn't insert anything into search, use d('$display') and not search('$display'...)" unless($item->{'search'});
 173
 174                         my @warn;
 175                         foreach my $type (qw/display search/) {
 176                                 push @warn, "field $display type $type values aren't ARRAY" unless (ref($item->{$type}) eq 'ARRAY');
 177                         }
 178
 179                         if (@warn) {
 180                                 warn("TT filter search(): " . join(",", @warn) . ", skipping");
 181                                 return;
 182                         }
 183                         my @html;
 184
 185                         my $d_el = $#{ $item->{'display'} };
 186                         my $s_el = $#{ $item->{'search'} };
 187
 188                         # easy, both fields have same number of elements or there is just
 189                         # one search and multiple display
 190                         if ( $d_el == $s_el || $s_el == 0 ) {
 191
 192                                 foreach my $i ( 0 .. $d_el ) {
 193
 194                                         my $s;
 195                                         if ($s_el > 0) {
 196                                                 $s = $item->{'search'}->[$i] || die "can't find value $i for type search in field $search";
 197                                         } else {
 198                                                 $s = $item->{'search'}->[0];
 199                                         }
 200                                         #$s =~ s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
 201                                         $s = uri_escape_utf8( $s );
 202
 203                                         my $d = $item->{'display'}->[$i] || die "can't find value $i for type display in field $display";
 204
 205                                         push @html, <<__JS_LINK_SEARCH__
 206 <a href="#" onclick="new Ajax.Updater( 'results',  '/search/results?$search=$s', { asynchronous: 1,onLoading: function(request){show_searching();},onLoaded: function(request){hide_searching();} } ) ; return false">$d</a>
 207 __JS_LINK_SEARCH__
 208                                 }
 209
 210                                 return join($delimiter, @html);
 211                         } else {
 212                                 my $html = qq{<div class="notice">WARNING: we should really support if there is $d_el display elements and $s_el search elements, but currently there is no nice way to do so, so we will just display values</div>};
 213                                 my $v = $item->{'display'};
 214
 215                                 if ($#{$v} == 0) {
 216                                         $html .= $v->[0];
 217                                 } else {
 218                                         $html .= join($delimiter, @{$v});
 219                                 }
 220                                 return $html;
 221                         }
 222                 }
 223         }
 224
 225         $args->{'search'} = tt_filter_search($args);
 226
 227 =head3 load_rec
 228
 229 Used mostly for onClick events like this:
 230
 231   <a href="#" onClick="[% load_rec( record_uri, 'template_name.tt') %]>foo</a>
 232
 233 It will automatically do sanity checking and create correct JavaScript code.
 234
 235 =cut
 236
 237         $args->{'load_rec'} = sub {
 238                 my @errors;
 239
 240                 my $record_uri = shift or push @errors, "record_uri missing";
 241                 my $template = shift or push @errors, "template missing";
 242
 243                 if ($record_uri !~ m#^[^/]+/[^/]+/[^/]+$#) {
 244                         push @errors, "invalid format of record_uri: $record_uri";
 245                 }
 246
 247                 if (@errors) {
 248                         return "Logger.error('errors in load_rec: " . join(", ", @errors) . "'); return false;";
 249                 } else {
 250                         return "load_rec('$record_uri','$template'); return false;";
 251                 }
 252         };
 253
 254 =head3 load_template
 255
 256 Used to re-submit search request and load results in different template
 257
 258   <a href="#" onClick="[% load_template( 'template_name.tt' ) %]">bar</a>
 259
 260 =cut
 261
 262         $args->{'load_template'} = sub {
 263                 my $template = shift or return "Logger.error('load_template missing template name!'); return false;";
 264                 return "load_template($template); return false;";
 265         }
 266
 267         my $out;
 268
 269         $self->{'tt'}->process(
 270                 $args->{'template'},
 271                 $args,
 272                 \$out
 273         ) || $log->logconfess( "apply can't process template: ", $self->{'tt'}->error() );
 274
 275         return $out;
 276 }
 277
 278 =head2 to_file
 279
 280 Create output from in-memory data structure using Template Toolkit template
 281 to a file.
 282
 283  $tt->to_file(
 284         file => 'out.txt',
 285         template => 'text.tt',
 286         data => $ds
 287  );
 288
 289 =cut
 290
 291 sub to_file {
 292         my $self = shift;
 293
 294         my $args = {@_};
 295
 296         my $log = $self->_get_logger();
 297
 298         my $file = $args->{'file'} || $log->logconfess("need file name");
 299
 300         $log->debug("creating file ",$file);
 301
 302         open(my $fh, ">", $file) || $log->logdie("can't open output file '$file': $!");
 303         print $fh $self->output(
 304                 template => $args->{'template'},
 305                 data => $args->{'data'},
 306         ) || $log->logdie("print: $!");
 307         close($fh) || $log->logdie("close: $!");
 308
 309         return 1;
 310 }
 311
 312
 313 =head1 AUTHOR
 314
 315 Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>
 316
 317 =head1 COPYRIGHT & LICENSE
 318
 319 Copyright 2005 Dobrica Pavlinusic, All Rights Reserved.
 320
 321 This program is free software; you can redistribute it and/or modify it
 322 under the same terms as Perl itself.
 323
 324 =cut
 325
 326 1; # End of WebPAC::Output::TT