members/statistics.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2012 BibLibre
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 =head1 members/statistics.pl
  20
  21   Generate statistic issues for a member
  22
  23 =cut
  24
  25 use Modern::Perl;
  26
  27 use CGI qw ( -utf8 );
  28 use C4::Auth;
  29 use C4::Context;
  30 use C4::Members;
  31 use C4::Members::Statistics;
  32 use C4::Members::Attributes qw(GetBorrowerAttributes);
  33 use C4::Output;
  34 use Koha::Patrons;
  35 use Koha::Patron::Categories;
  36
  37 my $input = new CGI;
  38
  39 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  40     {   template_name   => "members/statistics.tt",
  41         query           => $input,
  42         type            => "intranet",
  43         authnotrequired => 0,
  44         flagsrequired   => { borrowers => 'edit_borrowers' },
  45         debug           => 1,
  46     }
  47 );
  48
  49 my $borrowernumber = $input->param('borrowernumber');
  50
  51 my $logged_in_user = Koha::Patrons->find( $loggedinuser ) or die "Not logged in";
  52 my $patron         = Koha::Patrons->find( $borrowernumber );
  53 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  54
  55 my $category = $patron->category;
  56
  57 # Construct column names
  58 my $fields = C4::Members::Statistics::get_fields();
  59 our @statistic_column_names = split '\|', $fields;
  60 our @value_column_names = ( 'count_precedent_state', 'count_total_issues_today', 'count_total_issues_returned_today' );
  61 our @column_names = ( @statistic_column_names, @value_column_names );
  62
  63 # Get statistics
  64 my $precedent_state = GetPrecedentStateByBorrower( $borrowernumber );
  65 my $total_issues_today = GetTotalIssuesTodayByBorrower( $borrowernumber );
  66 my $total_issues_returned_today = GetTotalIssuesReturnedTodayByBorrower( $borrowernumber );
  67 my $r = merge (
  68     @$precedent_state, @$total_issues_today, @$total_issues_returned_today
  69 );
  70
  71 add_actual_state( $r );
  72 my ( $total, $datas ) = build_array( $r );
  73
  74 # Gettings sums
  75 my $count_total_precedent_state = $total->{count_precedent_state} || 0;
  76 my $count_total_issues = $total->{count_total_issues_today} || 0;
  77 my $count_total_issues_returned = $total->{count_total_issues_returned_today} || 0;
  78 my $count_total_actual_state = ($count_total_precedent_state - $count_total_issues_returned + $count_total_issues);
  79
  80 if (C4::Context->preference('ExtendedPatronAttributes')) {
  81     my $attributes = GetBorrowerAttributes($borrowernumber);
  82     $template->param(
  83         ExtendedPatronAttributes => 1,
  84         extendedattributes => $attributes
  85     );
  86 }
  87
  88 if ( $patron->is_child ) {
  89     my $patron_categories = Koha::Patron::Categories->search_limited({ category_type => 'A' }, {order_by => ['categorycode']});
  90     $template->param( 'CATCODE_MULTI' => 1) if $patron_categories->count > 1;
  91     $template->param( 'catcode' => $patron_categories->next->categorycode )  if $patron_categories->count == 1;
  92 }
  93
  94 $template->param(
  95     patron             => $patron,
  96     statisticsview     => 1,
  97     datas              => $datas,
  98     column_names       => \@statistic_column_names,
  99     count_total_issues => $count_total_issues,
 100     count_total_issues_returned => $count_total_issues_returned,
 101     count_total_precedent_state => $count_total_precedent_state,
 102     count_total_actual_state => $count_total_actual_state,
 103 );
 104
 105 output_html_with_http_headers $input, $cookie, $template->output;
 106
 107
 108 =head1 FUNCTIONS
 109
 110 =head2 add_actual_state
 111
 112   Add a 'count_actual_state' key in all hashes
 113   count_actual_state = count_precedent_state - count_total_issues_returned_today + count_total_issues_today
 114
 115 =cut
 116
 117 sub add_actual_state {
 118     my ( $array ) = @_;
 119     for my $hash ( @$array ) {
 120         $hash->{count_actual_state} = ( $hash->{count_precedent_state} // 0 ) - ( $hash->{count_total_issues_returned_today} // 0 ) + ( $hash->{count_total_issues_today} // 0 );
 121     }
 122 }
 123
 124 =head2 build_array
 125
 126   Build a new array containing values of hashes.
 127   It used by template whitch display silly values.
 128   ex:
 129     $array = [
 130       {
 131         'count_total_issues_returned_today' => 1,
 132         'ccode' => 'ccode',
 133         'count_actual_state' => 1,
 134         'count_precedent_state' => 1,
 135         'homebranch' => 'homebranch',
 136         'count_total_issues_today' => 1,
 137         'itype' => 'itype'
 138       }
 139     ];
 140   and returns:
 141     [
 142       [
 143         'homebranch',
 144         'itype',
 145         'ccode',
 146         1,
 147         1,
 148         1,
 149         1
 150       ]
 151     ];
 152
 153 =cut
 154
 155 sub build_array {
 156     my ( $array ) = @_;
 157     my ( @r, $total );
 158     for my $hash ( @$array) {
 159         my @line;
 160         for my $cn ( ( @column_names, 'count_actual_state') ) {
 161             if ( grep /$cn/, ( @value_column_names, 'count_actual_state') ) {
 162                 $hash->{$cn} //= 0;
 163                 if ( exists $total->{$cn} ) {
 164                     $total->{$cn} += $hash->{$cn} if $hash->{$cn};
 165                 } else {
 166                     $total->{$cn} = $hash->{$cn};
 167                 }
 168             }
 169             push @line, $hash->{$cn};
 170         }
 171         push @r, \@line;
 172     }
 173     return ( $total, \@r );
 174 }
 175
 176 =head2 merge
 177
 178   Merge hashes with the same statistic column names into one
 179   param: array, a arrayref of arrayrefs
 180   ex:
 181   @array = (
 182      {
 183        'ccode' => 'ccode',
 184        'count_precedent_state' => '1',
 185        'homebranch' => 'homebranch',
 186        'itype' => 'itype'
 187      },
 188      {
 189        'count_total_issues_returned_today' => '1',
 190        'ccode' => 'ccode',
 191        'homebranch' => 'homebranch',
 192        'itype' => 'itype'
 193      }
 194    );
 195    and returns:
 196    [
 197      {
 198        'count_total_issues_returned_today' => '1',
 199        'ccode' => 'ccode',
 200        'count_precedent_state' => '1',
 201        'homebranch' => 'homebranch',
 202        'itype' => 'itype'
 203      }
 204    ];
 205
 206 =cut
 207
 208 sub merge {
 209     my @array = @_;
 210     my @r;
 211     for my $h ( @array ) {
 212         my $exists = 0;
 213         for my $ch ( @r ) {
 214             $exists = 1;
 215             for my $cn ( @statistic_column_names ) {
 216                 if ( $ch->{$cn} and not $ch->{$cn} eq $h->{$cn} ) {
 217                     $exists = 0;
 218                     last;
 219                 }
 220             }
 221             if ($exists){
 222                 for my $cn ( @value_column_names ) {
 223                     next if not exists $h->{$cn};
 224                     $ch->{$cn} = $h->{$cn} ? $h->{$cn} : 0;
 225                 }
 226                 last;
 227             }
 228         }
 229
 230         if ( not $exists ) {push @r, $h;}
 231     }
 232     return \@r;
 233 }