opac/opac-reserve.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Katipo Communications 2002
   4 # Copyright Koha Development team 2012
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use CGI qw ( -utf8 );
  24 use C4::Auth;    # checkauth, getborrowernumber.
  25 use C4::Koha;
  26 use C4::Circulation;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Output;
  31 use C4::Context;
  32 use C4::Members;
  33 use C4::Overdues;
  34 use C4::Debug;
  35 use Koha::DateUtils;
  36 use Koha::Libraries;
  37 use Koha::Patrons;
  38 use Date::Calc qw/Today Date_to_Days/;
  39 use List::MoreUtils qw/uniq/;
  40
  41 my $maxreserves = C4::Context->preference("maxreserves");
  42
  43 my $query = new CGI;
  44
  45 # if RequestOnOpac (for placing holds) is disabled, leave immediately
  46 if ( ! C4::Context->preference('RequestOnOpac') ) {
  47     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  48     exit;
  49 }
  50
  51 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  52     {
  53         template_name   => "opac-reserve.tt",
  54         query           => $query,
  55         type            => "opac",
  56         authnotrequired => 0,
  57         debug           => 1,
  58     }
  59 );
  60
  61 my ($show_holds_count, $show_priority);
  62 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  63     m/holds/o and $show_holds_count = 1;
  64     m/priority/ and $show_priority = 1;
  65 }
  66
  67 sub get_out {
  68         output_html_with_http_headers(shift,shift,shift); # $query, $cookie, $template->output;
  69         exit;
  70 }
  71
  72 # get borrower information ....
  73 my ( $borr ) = GetMemberDetails( $borrowernumber );
  74 my $patron = Koha::Patrons->find( $borrowernumber );
  75
  76 # check if this user can place a reserve, -1 means use sys pref, 0 means dont block, 1 means block
  77 if ( $patron->category->effective_BlockExpiredPatronOpacActions ) {
  78
  79     if ( $borr->{'is_expired'} ) {
  80
  81         # cannot reserve, their card has expired and the rules set mean this is not allowed
  82         $template->param( message => 1, expired_patron => 1 );
  83         get_out( $query, $cookie, $template->output );
  84     }
  85 }
  86
  87 # Pass through any reserve charge
  88 if ($borr->{reservefee} > 0){
  89     $template->param( RESERVE_CHARGE => sprintf("%.2f",$borr->{reservefee}));
  90 }
  91
  92 my $itemTypes = GetItemTypes();
  93
  94 # There are two ways of calling this script, with a single biblio num
  95 # or multiple biblio nums.
  96 my $biblionumbers = $query->param('biblionumbers');
  97 my $reserveMode = $query->param('reserve_mode');
  98 if ($reserveMode && ($reserveMode eq 'single')) {
  99     my $bib = $query->param('single_bib');
 100     $biblionumbers = "$bib/";
 101 }
 102 if (! $biblionumbers) {
 103     $biblionumbers = $query->param('biblionumber');
 104 }
 105
 106 if ((! $biblionumbers) && (! $query->param('place_reserve'))) {
 107     $template->param(message=>1, no_biblionumber=>1);
 108     &get_out($query, $cookie, $template->output);
 109 }
 110
 111 # Pass the numbers to the page so they can be fed back
 112 # when the hold is confirmed. TODO: Not necessary?
 113 $template->param( biblionumbers => $biblionumbers );
 114
 115 # Each biblio number is suffixed with '/', e.g. "1/2/3/"
 116 my @biblionumbers = split /\//, $biblionumbers;
 117 if (($#biblionumbers < 0) && (! $query->param('place_reserve'))) {
 118     # TODO: New message?
 119     $template->param(message=>1, no_biblionumber=>1);
 120     &get_out($query, $cookie, $template->output);
 121 }
 122
 123
 124 # pass the pickup branch along....
 125 my $branch = $query->param('branch') || $borr->{'branchcode'} || C4::Context->userenv->{branch} || '' ;
 126 $template->param( branch => $branch );
 127
 128 # Is the person allowed to choose their branch
 129 my $OPACChooseBranch = (C4::Context->preference("OPACAllowUserToChooseBranch")) ? 1 : 0;
 130
 131 $template->param( choose_branch => $OPACChooseBranch);
 132
 133 #
 134 #
 135 # Build hashes of the requested biblio(item)s and items.
 136 #
 137 #
 138
 139 my %biblioDataHash; # Hash of biblionumber to biblio/biblioitems record.
 140 my %itemInfoHash; # Hash of itemnumber to item info.
 141 foreach my $biblioNumber (@biblionumbers) {
 142
 143     my $biblioData = GetBiblioData($biblioNumber);
 144     $biblioDataHash{$biblioNumber} = $biblioData;
 145
 146     my @itemInfos = GetItemsInfo($biblioNumber);
 147
 148     my $marcrecord= GetMarcBiblio($biblioNumber);
 149
 150     # flag indicating existence of at least one item linked via a host record
 151     my $hostitemsflag;
 152     # adding items linked via host biblios
 153     my @hostitemInfos = GetHostItemsInfo($marcrecord);
 154     if (@hostitemInfos){
 155         $hostitemsflag =1;
 156         push (@itemInfos,@hostitemInfos);
 157     }
 158
 159     $biblioData->{itemInfos} = \@itemInfos;
 160     foreach my $itemInfo (@itemInfos) {
 161         $itemInfoHash{$itemInfo->{itemnumber}} = $itemInfo;
 162     }
 163
 164     # Compute the priority rank.
 165     my $reserves = GetReservesFromBiblionumber({ biblionumber => $biblioNumber, all_dates => 1 });
 166     my $rank = scalar( @$reserves );
 167     $biblioData->{reservecount} = 1;    # new reserve
 168     foreach my $res (@{$reserves}) {
 169         my $found = $res->{found};
 170         if ( $found && $found eq 'W' ) {
 171             $rank--;
 172         }
 173         else {
 174             $biblioData->{reservecount}++;
 175         }
 176     }
 177     $biblioData->{rank} = $rank + 1;
 178 }
 179
 180 #
 181 #
 182 # If this is the second time through this script, it
 183 # means we are carrying out the hold request, possibly
 184 # with a specific item for each biblionumber.
 185 #
 186 #
 187 if ( $query->param('place_reserve') ) {
 188     my $reserve_cnt = 0;
 189     if ($maxreserves) {
 190         $reserve_cnt = GetReservesFromBorrowernumber( $borrowernumber );
 191     }
 192
 193     # List is composed of alternating biblio/item/branch
 194     my $selectedItems = $query->param('selecteditems');
 195
 196     if ($query->param('reserve_mode') eq 'single') {
 197         # This indicates non-JavaScript mode, so there was
 198         # only a single biblio number selected.
 199         my $bib = $query->param('single_bib');
 200         my $item = $query->param("checkitem_$bib");
 201         if ($item eq 'any') {
 202             $item = '';
 203         }
 204         my $branch = $query->param('branch');
 205         $selectedItems = "$bib/$item/$branch/";
 206     }
 207
 208     $selectedItems =~ s!/$!!;
 209     my @selectedItems = split /\//, $selectedItems, -1;
 210
 211     # Make sure there is a biblionum/itemnum/branch triplet for each item.
 212     # The itemnum can be 'any', meaning next available.
 213     my $selectionCount = @selectedItems;
 214     if (($selectionCount == 0) || (($selectionCount % 3) != 0)) {
 215         $template->param(message=>1, bad_data=>1);
 216         &get_out($query, $cookie, $template->output);
 217     }
 218
 219     my $failed_holds = 0;
 220     while (@selectedItems) {
 221         my $biblioNum = shift(@selectedItems);
 222         my $itemNum   = shift(@selectedItems);
 223         my $branch    = shift(@selectedItems);    # i.e., branch code, not name
 224
 225         my $canreserve = 0;
 226
 227         my $singleBranchMode = Koha::Libraries->search->count == 1;
 228         if ( $singleBranchMode || !$OPACChooseBranch )
 229         {    # single branch mode or disabled user choosing
 230             $branch = $borr->{'branchcode'};
 231         }
 232
 233 #item may belong to a host biblio, if yes change biblioNum to hosts bilbionumber
 234         if ( $itemNum ne '' ) {
 235             my $hostbiblioNum = GetBiblionumberFromItemnumber($itemNum);
 236             if ( $hostbiblioNum ne $biblioNum ) {
 237                 $biblioNum = $hostbiblioNum;
 238             }
 239         }
 240
 241         my $biblioData = $biblioDataHash{$biblioNum};
 242         my $found;
 243
 244         # Check for user supplied reserve date
 245         my $startdate;
 246         if (   C4::Context->preference('AllowHoldDateInFuture')
 247             && C4::Context->preference('OPACAllowHoldDateInFuture') )
 248         {
 249             $startdate = $query->param("reserve_date_$biblioNum");
 250         }
 251
 252         my $expiration_date = $query->param("expiration_date_$biblioNum");
 253
 254       # If a specific item was selected and the pickup branch is the same as the
 255       # holdingbranch, force the value $rank and $found.
 256         my $rank = $biblioData->{rank};
 257         if ( $itemNum ne '' ) {
 258             $canreserve = 1 if CanItemBeReserved( $borrowernumber, $itemNum ) eq 'OK';
 259             $rank = '0' unless C4::Context->preference('ReservesNeedReturns');
 260             my $item = GetItem($itemNum);
 261             if ( $item->{'holdingbranch'} eq $branch ) {
 262                 $found = 'W'
 263                   unless C4::Context->preference('ReservesNeedReturns');
 264             }
 265         }
 266         else {
 267             $canreserve = 1 if CanBookBeReserved( $borrowernumber, $biblioNum ) eq 'OK';
 268
 269             # Inserts a null into the 'itemnumber' field of 'reserves' table.
 270             $itemNum = undef;
 271         }
 272         my $notes = $query->param('notes_'.$biblioNum)||'';
 273
 274         if (   $maxreserves
 275             && $reserve_cnt >= $maxreserves )
 276         {
 277             $canreserve = 0;
 278         }
 279
 280         my $itemtype = $query->param('itemtype') || undef;
 281         $itemtype = undef if $itemNum;
 282
 283         # Here we actually do the reserveration. Stage 3.
 284         if ($canreserve) {
 285             my $reserve_id = AddReserve(
 286                 $branch,          $borrowernumber, $biblioNum,
 287                 [$biblioNum],     $rank,           $startdate,
 288                 $expiration_date, $notes,          $biblioData->{title},
 289                 $itemNum,         $found,          $itemtype,
 290             );
 291             $failed_holds++ unless $reserve_id;
 292             ++$reserve_cnt;
 293         }
 294     }
 295
 296     print $query->redirect("/cgi-bin/koha/opac-user.pl?" . ( $failed_holds ? "failed_holds=$failed_holds" : q|| ) . "#opac-user-holds");
 297     exit;
 298 }
 299
 300 #
 301 #
 302 # Here we check that the borrower can actually make reserves Stage 1.
 303 #
 304 #
 305 my $noreserves     = 0;
 306 my $maxoutstanding = C4::Context->preference("maxoutstanding");
 307 $template->param( noreserve => 1 ) unless $maxoutstanding;
 308 my $amountoutstanding = GetMemberAccountRecords($borrowernumber);
 309 if ( $amountoutstanding && ($amountoutstanding > $maxoutstanding) ) {
 310     my $amount = sprintf "%.02f", $amountoutstanding;
 311     $template->param( message => 1 );
 312     $noreserves = 1;
 313     $template->param( too_much_oweing => $amount );
 314 }
 315
 316 if ( $borr->{gonenoaddress} && ($borr->{gonenoaddress} == 1) ) {
 317     $noreserves = 1;
 318     $template->param(
 319         message => 1,
 320         GNA     => 1
 321     );
 322 }
 323
 324 if ( $borr->{lost} && ($borr->{lost} == 1) ) {
 325     $noreserves = 1;
 326     $template->param(
 327         message => 1,
 328         lost    => 1
 329     );
 330 }
 331
 332 if ( Koha::Patrons->find( $borrowernumber )->is_debarred ) {
 333     $noreserves = 1;
 334     $template->param(
 335         message          => 1,
 336         debarred         => 1,
 337         debarred_comment => $borr->{debarredcomment},
 338         debarred_date    => $borr->{debarred},
 339     );
 340 }
 341
 342 my @reserves = GetReservesFromBorrowernumber( $borrowernumber );
 343 my $reserves_count = scalar(@reserves);
 344 $template->param( RESERVES => \@reserves );
 345 if ( $maxreserves && ( $reserves_count >= $maxreserves ) ) {
 346     $template->param( message => 1 );
 347     $noreserves = 1;
 348     $template->param( too_many_reserves => scalar(@reserves));
 349 }
 350
 351 unless ( $noreserves ) {
 352     my $requested_reserves_count = scalar( @biblionumbers );
 353     if ( $maxreserves && ( $reserves_count + $requested_reserves_count > $maxreserves ) ) {
 354         $template->param( new_reserves_allowed => $maxreserves - $reserves_count );
 355     }
 356 }
 357
 358 unless ($noreserves) {
 359     $template->param( select_item_types => 1 );
 360 }
 361
 362
 363 #
 364 #
 365 # Build the template parameters that will show the info
 366 # and items for each biblionumber.
 367 #
 368 #
 369 my $notforloan_label_of = get_notforloan_label_of();
 370
 371 my $biblioLoop = [];
 372 my $numBibsAvailable = 0;
 373 my $itemdata_enumchron = 0;
 374 my $anyholdable = 0;
 375 my $itemLevelTypes = C4::Context->preference('item-level_itypes');
 376 $template->param('item_level_itypes' => $itemLevelTypes);
 377
 378 foreach my $biblioNum (@biblionumbers) {
 379
 380     my $record = GetMarcBiblio($biblioNum);
 381     # Init the bib item with the choices for branch pickup
 382     my %biblioLoopIter;
 383
 384     # Get relevant biblio data.
 385     my $biblioData = $biblioDataHash{$biblioNum};
 386     if (! $biblioData) {
 387         $template->param(message=>1, bad_biblionumber=>$biblioNum);
 388         &get_out($query, $cookie, $template->output);
 389     }
 390
 391     $biblioLoopIter{biblionumber} = $biblioData->{biblionumber};
 392     $biblioLoopIter{title} = $biblioData->{title};
 393     $biblioLoopIter{subtitle} = GetRecordValue('subtitle', $record, GetFrameworkCode($biblioData->{biblionumber}));
 394     $biblioLoopIter{author} = $biblioData->{author};
 395     $biblioLoopIter{rank} = $biblioData->{rank};
 396     $biblioLoopIter{reservecount} = $biblioData->{reservecount};
 397     $biblioLoopIter{already_reserved} = $biblioData->{already_reserved};
 398     $biblioLoopIter{mandatorynotes}=0; #FIXME: For future use
 399
 400     if (!$itemLevelTypes && $biblioData->{itemtype}) {
 401         $biblioLoopIter{translated_description} = $itemTypes->{$biblioData->{itemtype}}{translated_description};
 402         $biblioLoopIter{imageurl} = getitemtypeimagesrc() . "/". $itemTypes->{$biblioData->{itemtype}}{imageurl};
 403     }
 404
 405     foreach my $itemInfo (@{$biblioData->{itemInfos}}) {
 406         if ($itemLevelTypes && $itemInfo->{itype}) {
 407             $itemInfo->{translated_description} = $itemTypes->{$itemInfo->{itype}}{translated_description};
 408             $itemInfo->{imageurl} = getitemtypeimagesrc() . "/". $itemTypes->{$itemInfo->{itype}}{imageurl};
 409         }
 410
 411         if (!$itemInfo->{'notforloan'} && !($itemInfo->{'itemnotforloan'} > 0)) {
 412             $biblioLoopIter{forloan} = 1;
 413         }
 414     }
 415
 416     $biblioLoopIter{itemLoop} = [];
 417     my $numCopiesAvailable = 0;
 418     my $numCopiesOPACAvailable = 0;
 419     foreach my $itemInfo (@{$biblioData->{itemInfos}}) {
 420         my $itemNum = $itemInfo->{itemnumber};
 421         my $itemLoopIter = {};
 422
 423         $itemLoopIter->{itemnumber} = $itemNum;
 424         $itemLoopIter->{barcode} = $itemInfo->{barcode};
 425         $itemLoopIter->{homeBranchName} = $itemInfo->{homebranch};
 426         $itemLoopIter->{callNumber} = $itemInfo->{itemcallnumber};
 427         $itemLoopIter->{enumchron} = $itemInfo->{enumchron};
 428         $itemLoopIter->{copynumber} = $itemInfo->{copynumber};
 429         if ($itemLevelTypes) {
 430             $itemLoopIter->{translated_description} = $itemInfo->{translated_description};
 431             $itemLoopIter->{itype} = $itemInfo->{itype};
 432             $itemLoopIter->{imageurl} = $itemInfo->{imageurl};
 433         }
 434
 435         # If the holdingbranch is different than the homebranch, we show the
 436         # holdingbranch of the document too.
 437         if ( $itemInfo->{homebranch} ne $itemInfo->{holdingbranch} ) {
 438             $itemLoopIter->{holdingBranchName} = $itemInfo->{holdingbranch};
 439         }
 440
 441         # If the item is currently on loan, we display its return date and
 442         # change the background color.
 443         my $issues= GetItemIssue($itemNum);
 444         if ( $issues->{'date_due'} ) {
 445             $itemLoopIter->{dateDue} = output_pref({ dt => dt_from_string($issues->{date_due}, 'sql'), as_due_date => 1 });
 446             $itemLoopIter->{backgroundcolor} = 'onloan';
 447         }
 448
 449         # checking reserve
 450         my ($reservedate,$reservedfor,$expectedAt,undef,$wait) = GetReservesFromItemnumber($itemNum);
 451         my $ItemBorrowerReserveInfo = GetMemberDetails( $reservedfor, 0);
 452
 453         # the item could be reserved for this borrower vi a host record, flag this
 454         $reservedfor //= '';
 455
 456         if ( defined $reservedate ) {
 457             $itemLoopIter->{backgroundcolor} = 'reserved';
 458             $itemLoopIter->{reservedate}     = output_pref({ dt => dt_from_string($reservedate), dateonly => 1 });
 459             $itemLoopIter->{ReservedForBorrowernumber} = $reservedfor;
 460             $itemLoopIter->{ReservedForSurname}        = $ItemBorrowerReserveInfo->{'surname'};
 461             $itemLoopIter->{ReservedForFirstname}      = $ItemBorrowerReserveInfo->{'firstname'};
 462             $itemLoopIter->{ExpectedAtLibrary}         = $expectedAt;
 463             #waiting status
 464             $itemLoopIter->{waitingdate} = $wait;
 465         }
 466
 467         $itemLoopIter->{notforloan} = $itemInfo->{notforloan};
 468         $itemLoopIter->{itemnotforloan} = $itemInfo->{itemnotforloan};
 469
 470         # Management of the notforloan document
 471         if ( $itemLoopIter->{notforloan} || $itemLoopIter->{itemnotforloan}) {
 472             $itemLoopIter->{backgroundcolor} = 'other';
 473             $itemLoopIter->{notforloanvalue} =
 474               $notforloan_label_of->{ $itemLoopIter->{notforloan} };
 475         }
 476
 477         # Management of lost or long overdue items
 478         if ( $itemInfo->{itemlost} ) {
 479
 480             # FIXME localized strings should never be in Perl code
 481             $itemLoopIter->{message} =
 482                 $itemInfo->{itemlost} == 1 ? "(lost)"
 483               : $itemInfo->{itemlost} == 2 ? "(long overdue)"
 484               : "";
 485             $itemInfo->{backgroundcolor} = 'other';
 486         }
 487
 488         # Check of the transfered documents
 489         my ( $transfertwhen, $transfertfrom, $transfertto ) =
 490           GetTransfers($itemNum);
 491         if ( $transfertwhen && ($transfertwhen ne '') ) {
 492             $itemLoopIter->{transfertwhen} = output_pref({ dt => dt_from_string($transfertwhen), dateonly => 1 });
 493             $itemLoopIter->{transfertfrom} = $transfertfrom;
 494             $itemLoopIter->{transfertto} = $transfertto;
 495             $itemLoopIter->{nocancel} = 1;
 496         }
 497
 498         # if the items belongs to a host record, show link to host record
 499         if ( $itemInfo->{biblionumber} ne $biblioNum ) {
 500             $biblioLoopIter{hostitemsflag}    = 1;
 501             $itemLoopIter->{hostbiblionumber} = $itemInfo->{biblionumber};
 502             $itemLoopIter->{hosttitle}        = GetBiblioData( $itemInfo->{biblionumber} )->{title};
 503         }
 504
 505         # If there is no loan, return and transfer, we show a checkbox.
 506         $itemLoopIter->{notforloan} = $itemLoopIter->{notforloan} || 0;
 507
 508         my $branch = GetReservesControlBranch( $itemInfo, $borr );
 509
 510         my $policy_holdallowed = !$itemLoopIter->{already_reserved};
 511         $policy_holdallowed &&=
 512             IsAvailableForItemLevelRequest($itemInfo,$borr) &&
 513             CanItemBeReserved($borrowernumber,$itemNum) eq 'OK';
 514
 515         if ($policy_holdallowed) {
 516             if ( my $hold_allowed = OPACItemHoldsAllowed( $itemInfo, $borr ) ) {
 517                 $itemLoopIter->{available} = 1;
 518                 $numCopiesOPACAvailable++;
 519                 $biblioLoopIter{force_hold} = 1 if $hold_allowed eq 'F';
 520             }
 521             $numCopiesAvailable++;
 522         }
 523
 524         $itemLoopIter->{imageurl} = getitemtypeimagelocation( 'opac', $itemTypes->{ $itemInfo->{itype} }{imageurl} );
 525
 526     # Show serial enumeration when needed
 527         if ($itemLoopIter->{enumchron}) {
 528             $itemdata_enumchron = 1;
 529         }
 530
 531         push @{$biblioLoopIter{itemLoop}}, $itemLoopIter;
 532     }
 533     $template->param( itemdata_enumchron => $itemdata_enumchron );
 534
 535     if ($numCopiesAvailable > 0) {
 536         $numBibsAvailable++;
 537         $biblioLoopIter{bib_available} = 1;
 538         $biblioLoopIter{holdable} = 1;
 539         $biblioLoopIter{itemholdable} = 1 if $numCopiesOPACAvailable;
 540     }
 541     if ($biblioLoopIter{already_reserved}) {
 542         $biblioLoopIter{holdable} = undef;
 543         $biblioLoopIter{itemholdable} = undef;
 544     }
 545     if(not C4::Context->preference('AllowHoldsOnPatronsPossessions') and CheckIfIssuedToPatron($borrowernumber,$biblioNum)) {
 546         $biblioLoopIter{holdable} = undef;
 547         $biblioLoopIter{already_patron_possession} = 1;
 548     }
 549
 550     $biblioLoopIter{holdable} &&= CanBookBeReserved($borrowernumber,$biblioNum) eq 'OK';
 551
 552     # For multiple holds per record, if a patron has previously placed a hold,
 553     # the patron can only place more holds of the same type. That is, if the
 554     # patron placed a record level hold, all the holds the patron places must
 555     # be record level. If the patron placed an item level hold, all holds
 556     # the patron places must be item level
 557     my $forced_hold_level = Koha::Holds->search(
 558         {
 559             borrowernumber => $borrowernumber,
 560             biblionumber   => $biblioNum,
 561             found          => undef,
 562         }
 563     )->forced_hold_level();
 564     if ($forced_hold_level) {
 565         $biblioLoopIter{force_hold}   = 1 if $forced_hold_level eq 'item';
 566         $biblioLoopIter{itemholdable} = 0 if $forced_hold_level eq 'record';
 567     }
 568
 569
 570     push @$biblioLoop, \%biblioLoopIter;
 571
 572     $anyholdable = 1 if $biblioLoopIter{holdable};
 573 }
 574
 575
 576 if ( $numBibsAvailable == 0 || $anyholdable == 0) {
 577     $template->param( none_available => 1 );
 578 }
 579
 580 my $show_notes=C4::Context->preference('OpacHoldNotes');
 581 $template->param(OpacHoldNotes=>$show_notes);
 582
 583 # display infos
 584 $template->param(bibitemloop => $biblioLoop);
 585 # can set reserve date in future
 586 if (
 587     C4::Context->preference( 'AllowHoldDateInFuture' ) &&
 588     C4::Context->preference( 'OPACAllowHoldDateInFuture' )
 589     ) {
 590     $template->param(
 591             reserve_in_future         => 1,
 592     );
 593 }
 594
 595 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };