opac/opac-sendbasket.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Doxulting 2004
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw(encode);
  24 use Carp;
  25 use Digest::MD5 qw(md5_base64);
  26 use Mail::Sendmail;
  27 use MIME::QuotedPrint;
  28 use MIME::Base64;
  29
  30 use C4::Biblio;
  31 use C4::Items;
  32 use C4::Auth;
  33 use C4::Output;
  34 use C4::Members;
  35 use C4::Templates ();
  36 use Koha::Email;
  37 use Koha::Token;
  38
  39 my $query = new CGI;
  40
  41 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  42     {
  43         template_name   => "opac-sendbasketform.tt",
  44         query           => $query,
  45         type            => "opac",
  46         authnotrequired => 0,
  47     }
  48 );
  49
  50 my $bib_list     = $query->param('bib_list') || '';
  51 my $email_add    = $query->param('email_add');
  52
  53 my $dbh          = C4::Context->dbh;
  54
  55 my $csrf_err;
  56 if ( $email_add ) {
  57     $csrf_err = 1 unless Koha::Token->new->check_csrf({
  58         id     => C4::Context->userenv->{id},
  59         secret => md5_base64( C4::Context->config('pass') ),
  60         token  => scalar $query->param('csrf_token'),
  61     });
  62 }
  63
  64 if( $csrf_err ) {
  65     $template->param( csrf_error => 1, email_add => 1 );
  66     output_html_with_http_headers $query, $cookie, $template->output;
  67 } elsif ( $email_add ) {
  68     my $email = Koha::Email->new();
  69     my $user = GetMember(borrowernumber => $borrowernumber);
  70     my $user_email = GetFirstValidEmailAddress($borrowernumber)
  71     || C4::Context->preference('KohaAdminEmailAddress');
  72
  73     my $email_replyto = "$user->{firstname} $user->{surname} <$user_email>";
  74     my $comment    = $query->param('comment');
  75
  76    # if you want to use the KohaAdmin address as from, that is the default no need to set it
  77     my %mail = $email->create_message_headers({
  78         to => $email_add,
  79         replyto => $email_replyto,
  80     });
  81     $mail{'X-Abuse-Report'} = C4::Context->preference('KohaAdminEmailAddress');
  82
  83     # Since we are already logged in, no need to check credentials again
  84     # when loading a second template.
  85     my $template2 = C4::Templates::gettemplate(
  86         'opac-sendbasket.tt', 'opac', $query,
  87     );
  88
  89     my @bibs = split( /\//, $bib_list );
  90     my @results;
  91     my $iso2709;
  92     my $marcflavour = C4::Context->preference('marcflavour');
  93     foreach my $biblionumber (@bibs) {
  94         $template2->param( biblionumber => $biblionumber );
  95
  96         my $dat              = GetBiblioData($biblionumber);
  97         next unless $dat;
  98         my $record           = GetMarcBiblio($biblionumber, 1);
  99         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
 100         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
 101
 102         my @items = GetItemsInfo( $biblionumber );
 103
 104         my $hasauthors = 0;
 105         if($dat->{'author'} || @$marcauthorsarray) {
 106           $hasauthors = 1;
 107         }
 108
 109
 110         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
 111         $dat->{MARCAUTHORS}    = $marcauthorsarray;
 112         $dat->{HASAUTHORS}     = $hasauthors;
 113         $dat->{'biblionumber'} = $biblionumber;
 114         $dat->{ITEM_RESULTS}   = \@items;
 115
 116         $iso2709 .= $record->as_usmarc();
 117
 118         push( @results, $dat );
 119     }
 120
 121     my $resultsarray = \@results;
 122
 123     $template2->param(
 124         BIBLIO_RESULTS => $resultsarray,
 125         comment        => $comment,
 126         firstname      => $user->{firstname},
 127         surname        => $user->{surname},
 128     );
 129
 130     # Getting template result
 131     my $template_res = $template2->output();
 132     my $body;
 133
 134     # Analysing information and getting mail properties
 135
 136     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 137         $mail{subject} = $1;
 138         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 139         $mail{subject} = Encode::encode("UTF-8", $mail{subject});
 140     }
 141     else { $mail{'subject'} = "no subject"; }
 142
 143     my $email_header = "";
 144     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 145         $email_header = $1;
 146         $email_header =~ s|\n?(.*)\n?|$1|;
 147         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 148     }
 149
 150     my $email_file = "basket.txt";
 151     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 152         $email_file = $1;
 153         $email_file =~ s|\n?(.*)\n?|$1|;
 154     }
 155
 156     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 157         $body = $1;
 158         $body =~ s|\n?(.*)\n?|$1|;
 159         $body = encode_qp(Encode::encode("UTF-8", $body));
 160     }
 161
 162     $mail{body} = $body;
 163
 164     my $boundary = "====" . time() . "====";
 165
 166     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 167     my $isofile = encode_base64(encode("UTF-8", $iso2709));
 168     $boundary = '--' . $boundary;
 169     $mail{body} = <<END_OF_BODY;
 170 $boundary
 171 MIME-Version: 1.0
 172 Content-Type: text/plain; charset="UTF-8"
 173 Content-Transfer-Encoding: quoted-printable
 174
 175 $email_header
 176 $body
 177 $boundary
 178 Content-Type: application/octet-stream; name="basket.iso2709"
 179 Content-Transfer-Encoding: base64
 180 Content-Disposition: attachment; filename="basket.iso2709"
 181
 182 $isofile
 183 $boundary--
 184 END_OF_BODY
 185
 186     # Sending mail (if not empty basket)
 187     if ( defined($iso2709) && sendmail %mail ) {
 188     # do something if it works....
 189         $template->param( SENT      => "1" );
 190     }
 191     else {
 192         # do something if it doesnt work....
 193     carp "Error sending mail: empty basket" if !defined($iso2709);
 194         carp "Error sending mail: $Mail::Sendmail::error" if $Mail::Sendmail::error;
 195         $template->param( error => 1 );
 196     }
 197     $template->param( email_add => $email_add );
 198     output_html_with_http_headers $query, $cookie, $template->output;
 199 }
 200 else {
 201     $template->param(
 202         bib_list       => $bib_list,
 203         url            => "/cgi-bin/koha/opac-sendbasket.pl",
 204         suggestion     => C4::Context->preference("suggestion"),
 205         virtualshelves => C4::Context->preference("virtualshelves"),
 206         csrf_token     => Koha::Token->new->generate_csrf(
 207             {   id     => C4::Context->userenv->{id},
 208                 secret => md5_base64( C4::Context->config('pass') ),
 209             }
 210         ),
 211     );
 212     output_html_with_http_headers $query, $cookie, $template->output;
 213 }