opac/opac-sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 SARL Biblibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw( encode );
  25 use Carp;
  26
  27 use Mail::Sendmail;
  28 use MIME::QuotedPrint;
  29 use MIME::Base64;
  30 use C4::Auth;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Output;
  34 use C4::Members;
  35 use Koha::Email;
  36 use Koha::Virtualshelves;
  37
  38 my $query = new CGI;
  39
  40 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  41     {
  42         template_name   => "opac-sendshelfform.tt",
  43         query           => $query,
  44         type            => "opac",
  45         authnotrequired => 0,
  46     }
  47 );
  48
  49 my $shelfid = $query->param('shelfid');
  50 my $email   = $query->param('email');
  51
  52 my $dbh          = C4::Context->dbh;
  53
  54 my $shelf = Koha::Virtualshelves->find( $shelfid );
  55 if ( $shelf and $shelf->can_be_viewed( $borrowernumber ) ) {
  56
  57 if ( $email ) {
  58     my $message = Koha::Email->new();
  59     my $comment    = $query->param('comment');
  60
  61     my %mail = $message->create_message_headers(
  62         {
  63             to => $email,
  64         }
  65     );
  66
  67     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  68         {
  69             template_name   => "opac-sendshelf.tt",
  70             query           => $query,
  71             type            => "opac",
  72             authnotrequired => 1,
  73         }
  74     );
  75
  76     my $shelf = Koha::Virtualshelves->find( $shelfid );
  77     my $contents = $shelf->get_contents;
  78     my $marcflavour         = C4::Context->preference('marcflavour');
  79     my $iso2709;
  80     my @results;
  81
  82     while ( my $content = $contents->next ) {
  83         my $biblionumber = $content->biblionumber->biblionumber;
  84         my $fw               = GetFrameworkCode($biblionumber);
  85         my $dat              = GetBiblioData($biblionumber);
  86         my $record           = GetMarcBiblio($biblionumber, 1);
  87         my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
  88         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  89         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  90         my $subtitle         = GetRecordValue('subtitle', $record, $fw);
  91
  92         my @items = GetItemsInfo( $biblionumber );
  93
  94         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
  95         $dat->{MARCNOTES}      = $marcnotesarray;
  96         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  97         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  98         $dat->{'biblionumber'} = $biblionumber;
  99         $dat->{ITEM_RESULTS}   = \@items;
 100         $dat->{subtitle}       = $subtitle;
 101         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
 102
 103         $iso2709 .= $record->as_usmarc();
 104
 105         push( @results, $dat );
 106     }
 107
 108     my $user = GetMember(borrowernumber => $borrowernumber);
 109
 110     $template2->param(
 111         BIBLIO_RESULTS => \@results,
 112         comment        => $comment,
 113         shelfname      => $shelf->shelfname,
 114         firstname      => $user->{firstname},
 115         surname        => $user->{surname},
 116     );
 117
 118     # Getting template result
 119     my $template_res = $template2->output();
 120     my $body;
 121
 122     # Analysing information and getting mail properties
 123     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 124         $mail{subject} = $1;
 125         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 126     }
 127     else { $mail{'subject'} = "no subject"; }
 128     $mail{subject} = Encode::encode("UTF-8", $mail{subject});
 129
 130     my $email_header = "";
 131     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 132         $email_header = $1;
 133         $email_header =~ s|\n?(.*)\n?|$1|;
 134         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 135     }
 136
 137     my $email_file = "list.txt";
 138     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 139         $email_file = $1;
 140         $email_file =~ s|\n?(.*)\n?|$1|;
 141     }
 142
 143     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 144         $body = $1;
 145         $body =~ s|\n?(.*)\n?|$1|;
 146         $body = encode_qp(Encode::encode("UTF-8", $body));
 147     }
 148
 149     my $boundary = "====" . time() . "====";
 150
 151     # We set and put the multipart content
 152     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 153
 154     my $isofile = encode_base64(encode("UTF-8", $iso2709));
 155     $boundary = '--' . $boundary;
 156
 157     $mail{body} = <<END_OF_BODY;
 158 $boundary
 159 MIME-Version: 1.0
 160 Content-Type: text/plain; charset="utf-8"
 161 Content-Transfer-Encoding: quoted-printable
 162
 163 $email_header
 164 $body
 165 $boundary
 166 Content-Type: application/octet-stream; name="list.iso2709"
 167 Content-Transfer-Encoding: base64
 168 Content-Disposition: attachment; filename="list.iso2709"
 169
 170 $isofile
 171 $boundary--
 172 END_OF_BODY
 173
 174     # Sending mail
 175     if ( sendmail %mail ) {
 176         # do something if it works....
 177         $template->param( SENT      => "1" );
 178     }
 179     else {
 180         # do something if it doesnt work....
 181         carp "Error sending mail: $Mail::Sendmail::error \n";
 182         $template->param( error => 1 );
 183     }
 184
 185     $template->param(
 186         shelfid => $shelfid,
 187         email => $email,
 188     );
 189     output_html_with_http_headers $query, $cookie, $template->output;
 190
 191
 192 }else{
 193     $template->param( shelfid => $shelfid,
 194                       url     => "/cgi-bin/koha/opac-sendshelf.pl",
 195                     );
 196     output_html_with_http_headers $query, $cookie, $template->output;
 197 }
 198
 199 } else {
 200     $template->param( invalidlist => 1,
 201                       url     => "/cgi-bin/koha/opac-sendshelf.pl",
 202     );
 203     output_html_with_http_headers $query, $cookie, $template->output;
 204 }