git.rot13.org Git - webpac2/blob - run.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4
   5 use Cwd qw/abs_path/;
   6 use File::Temp qw/tempdir/;
   7 use Data::Dumper;
   8 use lib './lib';
   9
  10 use WebPAC::Common 0.02;
  11 use WebPAC::Lookup;
  12 use WebPAC::Input 0.03;
  13 use WebPAC::Store 0.03;
  14 use WebPAC::Normalize::XML;
  15 use WebPAC::Output::TT;
  16 use WebPAC::Output::Estraier '0.10';
  17 use YAML qw/LoadFile/;
  18 use Getopt::Long;
  19 use File::Path;
  20 use Time::HiRes qw/time/;
  21
  22 =head1 NAME
  23
  24 run.pl - start WebPAC indexing
  25
  26 B<this command will probably go away. Don't get used to it!>
  27
  28 Options:
  29
  30 =over 4
  31
  32 =item --offset 42
  33
  34 start loading (all) databases at offset 42
  35
  36 =item --limit 100
  37
  38 limit loading to 100 records
  39
  40 =item --clean
  41
  42 remove database and Hyper Estraier index before indexing
  43
  44 =item --one=database_name
  45
  46 reindex just single database
  47
  48 =item --config conf/config.yml
  49
  50 path to YAML configuration file
  51
  52 =back
  53
  54 =cut
  55
  56 my $offset;
  57 my $limit;
  58
  59 my $clean = 0;
  60 my $config = 'conf/config.yml';
  61 my $debug = 0;
  62 my $one_db_name;
  63
  64 GetOptions(
  65         "limit=i" => \$limit,
  66         "offset=i" => \$offset,
  67         "clean" => \$clean,
  68         "one=s" => \$one_db_name,
  69         "config" => \$config,
  70         "debug" => \$debug,
  71 );
  72
  73 $config = LoadFile($config);
  74
  75 print "config = ",Dumper($config) if ($debug);
  76
  77 die "no databases in config file!\n" unless ($config->{databases});
  78
  79 my $total_rows = 0;
  80 my $start_t = time();
  81
  82 while (my ($database, $db_config) = each %{ $config->{databases} }) {
  83
  84         next if ($one_db_name && $database !~ m/$one_db_name/i);
  85
  86         my $log = _new WebPAC::Common()->_get_logger();
  87
  88         #
  89         # open Hyper Estraier database
  90         #
  91
  92         my $est_config = $config->{hyperestraier} || $log->logdie("can't find 'hyperestraier' part in confguration");
  93         $est_config->{database} = $database;
  94         $est_config->{clean} = $clean;
  95         $est_config->{label} = $db_config->{name};
  96
  97         my $est = new WebPAC::Output::Estraier( %{ $est_config } );
  98
  99         #
 100         # now WebPAC::Store
 101         #
 102         my $abs_path = abs_path($0);
 103         $abs_path =~ s#/[^/]*$#/#;
 104
 105         my $db_path = $config->{webpac}->{db_path} . '/' . $database;
 106
 107         if ($clean) {
 108                 $log->info("creating new database $database in $db_path");
 109                 rmtree( $db_path ) || $log->warn("can't remove $db_path: $!");
 110         } else {
 111                 $log->debug("working on $database in $db_path");
 112         }
 113
 114         my $db = new WebPAC::Store(
 115                 path => $db_path,
 116                 database => $database,
 117                 debug => $debug,
 118         );
 119
 120
 121         #
 122         # now, iterate through input formats
 123         #
 124
 125         my @inputs;
 126         if (ref($db_config->{input}) eq 'ARRAY') {
 127                 @inputs = @{ $db_config->{input} };
 128         } elsif ($db_config->{input}) {
 129                 push @inputs, $db_config->{input};
 130         } else {
 131                 $log->info("database $database doesn't have inputs defined");
 132         }
 133
 134         my @supported_inputs = keys %{ $config->{webpac}->{inputs} };
 135
 136         foreach my $input (@inputs) {
 137
 138                 my $type = lc($input->{type});
 139
 140                 die "I know only how to handle input types ", join(",", @supported_inputs), " not '$type'!\n" unless (grep(/$type/, @supported_inputs));
 141
 142                 my $lookup = new WebPAC::Lookup(
 143                         lookup_file => $input->{lookup},
 144                 );
 145
 146                 my $input_module = $config->{webpac}->{inputs}->{$type};
 147
 148                 $log->info("working on input '$input->{path}' [$input->{type}] using $input_module lookup '$input->{lookup}'");
 149
 150                 my $input_db = new WebPAC::Input(
 151                         module => $input_module,
 152                         code_page => $config->{webpac}->{webpac_encoding},
 153                         limit => $limit || $input->{limit},
 154                         offset => $offset,
 155                         lookup => $lookup,
 156                         recode => $input->{recode},
 157                 );
 158                 $log->logdie("can't create input using $input_module") unless ($input);
 159
 160                 my $maxmfn = $input_db->open(
 161                         path => $input->{path},
 162                         code_page => $input->{encoding},        # database encoding
 163                 );
 164
 165                 my $n = new WebPAC::Normalize::XML(
 166                 #       filter => { 'foo' => sub { shift } },
 167                         db => $db,
 168                         lookup_regex => $lookup->regex,
 169                         lookup => $lookup,
 170                         prefix => $input->{name},
 171                 );
 172
 173                 my $normalize_path = $input->{normalize}->{path};
 174
 175                 if ($normalize_path =~ m/\.xml$/i) {
 176                         $n->open(
 177                                 tag => $input->{normalize}->{tag},
 178                                 xml_file => $input->{normalize}->{path},
 179                         );
 180                 } elsif ($normalize_path =~ m/\.(?:yml|yaml)$/i) {
 181                         $n->open_yaml(
 182                                 path => $normalize_path,
 183                                 tag => $input->{normalize}->{tag},
 184                         );
 185                 }
 186
 187                 foreach my $pos ( 0 ... $input_db->size ) {
 188
 189                         my $row = $input_db->fetch || next;
 190
 191                         my $mfn = $row->{'000'}->[0];
 192
 193                         if (! $mfn || $mfn !~ m#^\d+$#) {
 194                                 $log->warn("record $pos doesn't have valid MFN but '$mfn', using $pos");
 195                                 $mfn = $pos;
 196                                 push @{ $row->{'000'} }, $pos;
 197                         }
 198
 199                         my $ds = $n->data_structure($row);
 200
 201                         $est->add(
 202                                 id => $input->{name} . "/" . $mfn,
 203                                 ds => $ds,
 204                                 type => $config->{hyperestraier}->{type},
 205                         );
 206
 207                         $total_rows++;
 208                 }
 209
 210         };
 211
 212         my $dt = time() - $start_t;
 213         $log->info("$total_rows records indexed in " .
 214                 sprintf("%.2f sec [%.2f rec/sec]",
 215                         $dt, ($total_rows / $dt)
 216                 )
 217         );
 218
 219         #
 220         # add Hyper Estraier links to other databases
 221         #
 222         if (ref($db_config->{links}) eq 'ARRAY') {
 223                 foreach my $link (@{ $db_config->{links} }) {
 224                         $log->info("adding link $database -> $link->{to} [$link->{credit}]");
 225                         $est->add_link(
 226                                 from => $database,
 227                                 to => $link->{to},
 228                                 credit => $link->{credit},
 229                         );
 230                 }
 231         }
 232
 233 }
 234