git.rot13.org Git - webpac2/blob - run.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4
   5 use Cwd qw/abs_path/;
   6 use File::Temp qw/tempdir/;
   7 use lib './lib';
   8
   9 use WebPAC::Common 0.02;
  10 use WebPAC::Parser 0.08;
  11 use WebPAC::Input 0.16;
  12 use WebPAC::Store 0.14;
  13 use WebPAC::Normalize 0.22;
  14 use WebPAC::Output::TT;
  15 use WebPAC::Validate 0.11;
  16 use WebPAC::Output::MARC;
  17 use WebPAC::Config;
  18 use Getopt::Long;
  19 use File::Path;
  20 use Time::HiRes qw/time/;
  21 use File::Slurp;
  22 use Data::Dump qw/dump/;
  23 use Storable qw/dclone/;
  24 use Pod::Usage qw/pod2usage/;
  25
  26 use Proc::Queue size => 1;
  27 use POSIX ":sys_wait_h"; # imports WNOHANG
  28
  29 =head1 NAME
  30
  31 run.pl - start WebPAC indexing
  32
  33 B<this command will probably go away. Don't get used to it!>
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item --offset 42
  40
  41 start loading (all) databases at offset 42
  42
  43 =item --limit 100
  44
  45 limit loading to 100 records
  46
  47 =item --clean
  48
  49 remove database and Hyper Estraier index before indexing
  50
  51 =item --only=database_name/input_filter
  52
  53 reindex just single database (legacy name is --one)
  54
  55 C</input_filter> is optional part which can be C<name>
  56 or C<type> from input
  57
  58 =item --config conf/config.yml
  59
  60 path to YAML configuration file
  61
  62 =item --stats
  63
  64 disable indexing, modify_* in configuration and dump statistics about field
  65 and subfield usage for each input
  66
  67 =item --validate path/to/validation_file
  68
  69 turn on extra validation of imput records, see L<WebPAC::Validation>
  70
  71 You can use special variables C<$database> and $C<$input> in this parametar
  72 like C<--validate 'conf/validate/$database-$input'> to construct filename
  73
  74 =item --validate-delimiters path/to/validate_delimiters_file
  75
  76 this option is used with C<--validate> to turn on extra validation of
  77 delimiters. If file is non existant, it will be created on first run.
  78
  79 =item --marc-generate
  80
  81 Generate MARC file. This will automatically be on if file contains C<marc*> directives.
  82 You can use this option as C<--no-marc-generate> to disable MARC generation.
  83
  84 =item --marc-lint
  85
  86 By default turned on if normalisation file has C<marc*> directives. You can disable lint
  87 messages with C<--no-marc-lint>.
  88
  89 =item --marc-dump
  90
  91 Force dump or input and marc record for debugging.
  92
  93 =item --parallel 4
  94
  95 Run databases in parallel (aproximatly same as number of processors in
  96 machine if you want to use full load)
  97
  98 =item --only-links
  99
 100 Create just links
 101
 102 =item --merge
 103
 104 Create merged index of databases which have links
 105
 106 =back
 107
 108 =cut
 109
 110 my $offset;
 111 my $limit;
 112
 113 my $clean = 0;
 114 my $config_path;
 115 my $debug = 0;
 116 my $only_filter;
 117 my $stats = 0;
 118 my $validate_path;
 119 my $validate_delimiters_path;
 120 my $marc_generate = 1;
 121 my $marc_lint = 1;
 122 my $marc_dump = 0;
 123 my $parallel = 0;
 124 my $only_links = 0;
 125 my $merge = 0;
 126 my $help;
 127
 128 my $log = _new WebPAC::Common()->_get_logger();
 129
 130 GetOptions(
 131         "limit=i" => \$limit,
 132         "offset=i" => \$offset,
 133         "clean" => \$clean,
 134         "one=s" => \$only_filter,
 135         "only=s" => \$only_filter,
 136         "config" => \$config_path,
 137         "debug+" => \$debug,
 138         "stats" => \$stats,
 139         "validate=s" => \$validate_path,
 140         "validate-delimiters=s" => \$validate_delimiters_path,
 141         "marc-generate!" => \$marc_generate,
 142         "marc-lint!" => \$marc_lint,
 143         "marc-dump!" => \$marc_dump,
 144         "parallel=i" => \$parallel,
 145         "only-links!" => \$only_links,
 146         "merge" => \$merge,
 147         "help" => \$help,
 148 );
 149
 150 $marc_generate = 0 if ( $validate_delimiters_path );
 151
 152 pod2usage(-verbose => 2) if ($help);
 153
 154 my $config = new WebPAC::Config( path => $config_path );
 155
 156 #print "config = ",dump($config) if ($debug);
 157
 158 die "no databases in config file!\n" unless ($config->databases);
 159
 160 $log->info( "-" x 79 );
 161
 162 my $log_file = 'log';
 163
 164 if (-e $log_file ) {    # && -s $log_file > 5 * 1024 * 1024) {
 165         $log->info("moved old log with ", -s $log_file, " bytes to '${log_file}.old'");
 166         rename $log_file, "${log_file}.old" || $log->logwarn("can't rename $log_file to ${log_file}.old: $!");
 167 }
 168
 169 my $estcmd_fh;
 170 my $estcmd_path = './estcmd-merge.sh';
 171 if ($merge) {
 172         open($estcmd_fh, '>', $estcmd_path) || $log->logdie("can't open $estcmd_path: $!");
 173         print $estcmd_fh 'cd /data/estraier/_node/ || exit 1',$/;
 174         print $estcmd_fh 'sudo /etc/init.d/hyperestraier stop',$/;
 175         $log->info("created merge batch file $estcmd_path");
 176 }
 177
 178 my $validate;
 179 $validate = new WebPAC::Validate(
 180         delimiters => $config->webpac('delimiters'),
 181 ) if ($validate_path || $validate_delimiters_path);
 182
 183 my $use_indexer = $config->use_indexer;
 184 $stats ||= $validate;
 185 if ($stats) {
 186         $log->debug("disabled indexing for stats collection");
 187         $use_indexer = undef;
 188 } elsif ( $use_indexer ) {
 189         $log->info("using $use_indexer indexing engine...");
 190 }
 191
 192 # parse normalize files and create source files for lookup and normalization
 193
 194 my $parser = new WebPAC::Parser( config => $config );
 195
 196 my $total_rows = 0;
 197 my $start_t = time();
 198
 199 my @links;
 200
 201 if ($parallel) {
 202         $log->info("Using $parallel processes for speedup");
 203         Proc::Queue::size($parallel);
 204 }
 205
 206 sub create_ds_config {
 207         my ($db_config, $database, $input, $mfn) = @_;
 208         my $c = dclone( $db_config );
 209         $c->{_} = $database || $log->logconfess("need database");
 210         $c->{_mfn} = $mfn || $log->logconfess("need mfn");
 211         $c->{input} = $input || $log->logconfess("need input");
 212         return $c;
 213 }
 214
 215 foreach my $database ( sort keys %{ $config->databases } ) {
 216         my $db_config = $config->databases->{$database};
 217
 218         my ($only_database,$only_input) = split(m#/#, $only_filter) if ($only_filter);
 219         next if ($only_database && $database !~ m/$only_database/i);
 220
 221         if ($parallel) {
 222                 my $f=fork;
 223                 if(defined ($f) and $f==0) {
 224                         $log->info("Created processes $$ for speedup");
 225                 } else {
 226                         next;
 227                 }
 228         }
 229
 230         my $indexer;
 231         if ($use_indexer && $parser->have_rules( 'search', $database )) {
 232
 233                 my $cfg_name = $use_indexer;
 234                 $cfg_name =~ s/\-.*$//;
 235
 236                 my $indexer_config = $config->get( $cfg_name ) || $log->logdie("can't find '$cfg_name' part in confguration");
 237                 $indexer_config->{database} = $database;
 238                 $indexer_config->{clean} = $clean;
 239                 $indexer_config->{label} = $db_config->{name};
 240
 241                 # force clean if database has links
 242                 $indexer_config->{clean} = 1 if ($db_config->{links});
 243
 244                 if ($use_indexer eq 'hyperestraier') {
 245
 246                         # open Hyper Estraier database
 247                         require WebPAC::Output::Estraier;
 248                         $indexer = new WebPAC::Output::Estraier( %{ $indexer_config } );
 249
 250                 } elsif ($use_indexer eq 'hyperestraier-native') {
 251
 252                         # open Hyper Estraier database
 253                         require WebPAC::Output::EstraierNative;
 254                         $indexer = new WebPAC::Output::EstraierNative( %{ $indexer_config } );
 255
 256                 } elsif ($use_indexer eq 'kinosearch') {
 257
 258                         # open KinoSearch
 259                         require WebPAC::Output::KinoSearch;
 260                         $indexer_config->{clean} = 1 unless (-e $indexer_config->{index_path});
 261                         $indexer = new WebPAC::Output::KinoSearch( %{ $indexer_config } );
 262
 263                 } else {
 264                         $log->logdie("unknown use_indexer: $use_indexer");
 265                 }
 266
 267                 $log->logdie("can't continue without valid indexer") unless ($indexer);
 268         }
 269
 270
 271         #
 272         # store Hyper Estraier links to other databases
 273         #
 274         if (ref($db_config->{links}) eq 'ARRAY' && $use_indexer) {
 275                 foreach my $link (@{ $db_config->{links} }) {
 276                         if ($use_indexer eq 'hyperestraier') {
 277                                 if ($merge) {
 278                                         print $estcmd_fh 'sudo -u www-data estcmd merge ' . $database . ' ' . $link->{to},$/;
 279                                 } else {
 280                                         $log->info("saving link $database -> $link->{to} [$link->{credit}]");
 281                                         push @links, sub {
 282                                                 $log->info("adding link $database -> $link->{to} [$link->{credit}]");
 283                                                 $indexer->add_link(
 284                                                         from => $database,
 285                                                         to => $link->{to},
 286                                                         credit => $link->{credit},
 287                                                 );
 288                                         };
 289                                 }
 290                         } else {
 291                                 $log->warn("NOT IMPLEMENTED WITH $use_indexer: adding link $database -> $link->{to} [$link->{credit}]");
 292                         }
 293                 }
 294         }
 295         next if ($only_links);
 296
 297
 298         #
 299         # now WebPAC::Store
 300         #
 301         my $abs_path = abs_path($0);
 302         $abs_path =~ s#/[^/]*$#/#;
 303
 304         my $db_path = $config->webpac('db_path');
 305
 306         if ($clean) {
 307                 $log->info("creating new database '$database' in $db_path");
 308                 rmtree( $db_path ) || $log->warn("can't remove $db_path: $!");
 309         } else {
 310                 $log->info("working on database '$database' in $db_path");
 311         }
 312
 313         my $store = new WebPAC::Store(
 314                 path => $db_path,
 315                 debug => $debug,
 316         );
 317
 318
 319         #
 320         # now, iterate through input formats
 321         #
 322
 323         my @inputs;
 324         if (ref($db_config->{input}) eq 'ARRAY') {
 325                 @inputs = @{ $db_config->{input} };
 326         } elsif ($db_config->{input}) {
 327                 push @inputs, $db_config->{input};
 328         } else {
 329                 $log->info("database $database doesn't have inputs defined");
 330         }
 331
 332         foreach my $input (@inputs) {
 333
 334                 my $input_name = $input->{name} || $log->logdie("input without a name isn't valid: ",dump($input));
 335
 336                 next if ($only_input && ($input_name !~ m#$only_input#i && $input->{type} !~ m#$only_input#i));
 337
 338                 my $type = lc($input->{type});
 339
 340                 die "I know only how to handle input types ", join(",", $config->webpac('inputs') ), " not '$type'!\n" unless (grep(/$type/, $config->webpac('inputs')));
 341
 342                 my $input_module = $config->webpac('inputs')->{$type};
 343
 344                 my @lookups = $parser->have_lookup_create($database, $input);
 345
 346                 $log->info("working on input '$input_name' in $input->{path} [type: $input->{type}] using $input_module",
 347                         @lookups ? " creating lookups: ".join(", ", @lookups) : ""
 348                 );
 349
 350                 if ($stats) {
 351                         # disable modification of records if --stats is in use
 352                         delete($input->{modify_records});
 353                         delete($input->{modify_file});
 354                 }
 355
 356                 my $input_db = new WebPAC::Input(
 357                         module => $input_module,
 358                         encoding => $config->webpac('webpac_encoding'),
 359                         limit => $limit || $input->{limit},
 360                         offset => $offset,
 361                         recode => $input->{recode},
 362                         stats => $stats,
 363                         modify_records => $input->{modify_records},
 364                         modify_file => $input->{modify_file},
 365                 );
 366                 $log->logdie("can't create input using $input_module") unless ($input);
 367
 368                 if (defined( $input->{lookup} )) {
 369                         $log->warn("$database/$input_name has depriciated lookup definition, removing it...");
 370                         delete( $input->{lookup} );
 371                 }
 372
 373                 my $lookup_coderef;
 374
 375                 if (@lookups) {
 376
 377                         my $rules = $parser->lookup_create_rules($database, $input) || $log->logdie("no rules found for $database/$input");
 378
 379                         $lookup_coderef = sub {
 380                                 my $rec = shift || die "need rec!";
 381                                 my $mfn = $rec->{'000'}->[0] || die "need mfn in 000";
 382
 383                                 WebPAC::Normalize::data_structure(
 384                                         row => $rec,
 385                                         rules => $rules,
 386                                         config => create_ds_config( $db_config, $database, $input, $mfn ),
 387                                 );
 388
 389                                 #warn "current lookup: ", dump(WebPAC::Normalize::_get_lookup());
 390                         };
 391
 392                         WebPAC::Normalize::_set_lookup( undef );
 393
 394                         $log->debug("created lookup_coderef using:\n$rules");
 395
 396                 };
 397
 398                 my $lookup_jar;
 399
 400                 my $maxmfn = $input_db->open(
 401                         path => $input->{path},
 402                         code_page => $input->{encoding},        # database encoding
 403                         lookup_coderef => $lookup_coderef,
 404                         lookup => $lookup_jar,
 405                         %{ $input },
 406                         load_row => sub {
 407                                 my $a = shift;
 408                                 return $store->load_row(
 409                                         database => $database,
 410                                         input => $input_name,
 411                                         id => $a->{id},
 412                                 );
 413                         },
 414                         save_row => sub {
 415                                 my $a = shift;
 416                                 return $store->save_row(
 417                                         database => $database,
 418                                         input => $input_name,
 419                                         id => $a->{id},
 420                                         row => $a->{row},
 421                                 );
 422                         },
 423
 424                 );
 425
 426                 my $lookup_data = WebPAC::Normalize::_get_lookup();
 427
 428                 if (defined( $lookup_data->{$database}->{$input_name} )) {
 429                         $log->debug("created following lookups: ", sub { dump( $lookup_data ) } );
 430
 431                         foreach my $key (keys %{ $lookup_data->{$database}->{$input_name} }) {
 432                                 $store->save_lookup(
 433                                         database => $database,
 434                                         input => $input_name,
 435                                         key => $key,
 436                                         data => $lookup_data->{$database}->{$input_name}->{$key},
 437                                 );
 438                         }
 439                 }
 440
 441                 my $report_fh;
 442                 if ($stats || $validate) {
 443                         my $path = "out/report/${database}-${input_name}.txt";
 444                         open($report_fh, '>', $path) || $log->logdie("can't open $path: $!");
 445
 446                         print $report_fh "Report for database '$database' input '$input_name' records ",
 447                                 $offset || 1, "-", $limit || $input->{limit} || $maxmfn, "\n\n";
 448                         $log->info("Generating report file $path");
 449
 450                         if ( $validate ) {
 451                                 $validate->read_validate_file( $validate->fill_in( $validate_path, database => $database, input => $input_name ) ) if ( $validate_path );
 452                                 $validate->read_validate_delimiters_file( $validate->fill_in( $validate_delimiters_path, database => $database, input => $input_name ) ) if ( $validate_delimiters_path );
 453                         }
 454                 }
 455
 456                 my $marc;
 457                 if ($marc_generate && $parser->have_rules( 'marc', $database, $input_name )) {
 458                         $marc = new WebPAC::Output::MARC(
 459                                 path => "out/marc/${database}-${input_name}.marc",
 460                                 lint => $marc_lint,
 461                                 dump => $marc_dump,
 462                         );
 463                 }
 464
 465                 my $rules = $parser->normalize_rules($database,$input_name) || $log->logdie("no normalize rules found for $database/$input_name");
 466                 $log->debug("parsed normalize rules:\n$rules");
 467
 468                 # reset position in database
 469                 $input_db->seek(1);
 470
 471                 # generate name of config key for indexer (strip everything after -)
 472                 my $indexer_config = $use_indexer;
 473                 $indexer_config =~ s/^(\w+)-?.*$/$1/g if ($indexer_config);
 474
 475                 my $lookup_hash;
 476                 my $depends = $parser->depends($database,$input_name);
 477
 478                 if ($depends) {
 479                         $log->debug("$database/$input_name depends on: ", dump($depends)) if ($depends);
 480                         $log->logdie("parser->depends didn't return HASH") unless (ref($depends) eq 'HASH');
 481
 482                         foreach my $db (keys %$depends) {
 483                                 foreach my $i (keys %{$depends->{$db}}) {
 484                                         foreach my $k (keys %{$depends->{$db}->{$i}}) {
 485                                                 my $t = time();
 486                                                 $log->debug("loading lookup $db/$i");
 487                                                 $lookup_hash->{$db}->{$i}->{$k} = $store->load_lookup(
 488                                                         database => $db,
 489                                                         input => $i,
 490                                                         key => $k,
 491                                                 );
 492                                                 $log->debug(sprintf("lookup $db/$i took %.2fs", time() - $t));
 493                                         }
 494                                 }
 495                         }
 496
 497                         $log->debug("lookup_hash = ", sub { dump( $lookup_hash ) });
 498                 }
 499
 500
 501                 foreach my $pos ( 0 ... $input_db->size ) {
 502
 503                         my $row = $input_db->fetch || next;
 504
 505                         $total_rows++;
 506
 507                         my $mfn = $row->{'000'}->[0];
 508
 509                         if (! $mfn || $mfn !~ m#^\d+$#) {
 510                                 $log->warn("record $pos doesn't have valid MFN but '$mfn', using $pos");
 511                                 $mfn = $pos;
 512                                 push @{ $row->{'000'} }, $pos;
 513                         }
 514
 515
 516                         if ($validate) {
 517                                 if ( my $errors = $validate->validate_rec( $row, $input_db->dump_ascii ) ) {
 518                                         $log->error( "MFN $mfn validation error:\n",
 519                                                 $validate->report_error( $errors )
 520                                         );
 521                                 }
 522                                 next;   # validation doesn't create any output
 523                         }
 524
 525                         my $ds = WebPAC::Normalize::data_structure(
 526                                 row => $row,
 527                                 rules => $rules,
 528                                 lookup => $lookup_hash,
 529                                 config => create_ds_config( $db_config, $database, $input, $mfn ),
 530                                 marc_encoding => 'utf-8',
 531                                 load_row_coderef => sub {
 532                                         my ($database,$input,$mfn) = @_;
 533                                         return $store->load_row(
 534                                                 database => $database,
 535                                                 input => $input,
 536                                                 id => $mfn,
 537                                         );
 538                                 },
 539                         );
 540
 541                         $log->debug("ds = ", sub { dump($ds) }) if ($ds);
 542
 543                         $store->save_ds(
 544                                 database => $database,
 545                                 input => $input_name,
 546                                 id => $mfn,
 547                                 ds => $ds,
 548                         ) if ($ds && !$stats);
 549
 550                         $indexer->add(
 551                                 id => "${input_name}/${mfn}",
 552                                 ds => $ds,
 553                                 type => $config->get($indexer_config)->{type},
 554                         ) if ($indexer && $ds);
 555
 556                         if ($marc) {
 557                                 my $i = 0;
 558
 559                                 while (my $fields = WebPAC::Normalize::_get_marc_fields( fetch_next => 1 ) ) {
 560                                         $marc->add(
 561                                                 id => $mfn . ( $i ? "/$i" : '' ),
 562                                                 fields => $fields,
 563                                                 leader => WebPAC::Normalize::_get_marc_leader(),
 564                                                 row => $row,
 565                                         );
 566                                         $i++;
 567                                 }
 568
 569                                 $log->info("Created $i instances of MFN $mfn\n") if ($i > 1);
 570                         }
 571                 }
 572
 573                 if ($validate) {
 574                         my $errors = $validate->report;
 575                         if ($errors) {
 576                                 $log->info("validation errors:\n$errors\n" );
 577                                 print $report_fh "$errors\n" if ($report_fh);
 578                         }
 579
 580                         print $report_fh "\nAll possible subfields/delimiter templates:\n", $validate->delimiters_templates( report => 1, current_input => 1 ), "\n\n";
 581
 582                         # must be last thing that touches $validate for this input
 583                         $validate->reset;
 584                 }
 585
 586                 if ($stats) {
 587                         my $s = $input_db->stats;
 588                         $log->info("statistics of fields usage:\n$s");
 589                         print $report_fh "Statistics of fields usage:\n$s" if ($report_fh);
 590                 }
 591
 592                 # close MARC file
 593                 $marc->finish if ($marc);
 594
 595                 # close report
 596                 close($report_fh) if ($report_fh);
 597         }
 598
 599         eval { $indexer->finish } if ($indexer && $indexer->can('finish'));
 600
 601         my $dt = time() - $start_t;
 602         $log->info("$total_rows records ", $indexer ? "indexed " : "",
 603                 sprintf("in %.2f sec [%.2f rec/sec]",
 604                         $dt, ($total_rows / $dt)
 605                 )
 606         );
 607
 608
 609         # end forked process
 610         if ($parallel) {
 611                 $log->info("parallel process $$ finished");
 612                 exit(0);
 613         }
 614
 615 }
 616
 617 if ($parallel) {
 618         # wait all children to finish
 619         sleep(1) while wait != -1;
 620         $log->info("all parallel processes finished");
 621 }
 622
 623 # save new delimiters if needed
 624 $validate->save_delimiters_templates if ( $validate_delimiters_path );
 625
 626 #
 627 # handle links or merge after indexing
 628 #
 629
 630 if ($merge) {
 631         print $estcmd_fh 'sudo /etc/init.d/hyperestraier start',$/;
 632         close($estcmd_fh);
 633         chmod 0700, $estcmd_path || $log->warn("can't chmod 0700 $estcmd_path: $!");
 634         system $estcmd_path;
 635 } else {
 636         foreach my $link (@links) {
 637                 $log->logdie("coderef in link ", Dumper($link), " is ", ref($link), " and not CODE") unless (ref($link) eq 'CODE');
 638                 $link->();
 639         }
 640 }