git.rot13.org Git - webpac2/blob - run.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4
   5 use Cwd qw/abs_path/;
   6 use File::Temp qw/tempdir/;
   7 use lib './lib';
   8
   9 use WebPAC::Common 0.02;
  10 use WebPAC::Lookup 0.03;
  11 use WebPAC::Input 0.11;
  12 use WebPAC::Store 0.03;
  13 use WebPAC::Normalize 0.11;
  14 use WebPAC::Output::TT;
  15 use WebPAC::Validate;
  16 use WebPAC::Output::MARC;
  17 use YAML qw/LoadFile/;
  18 use Getopt::Long;
  19 use File::Path;
  20 use Time::HiRes qw/time/;
  21 use File::Slurp;
  22 use Data::Dump qw/dump/;
  23 use Storable qw/dclone/;
  24
  25 use Proc::Queue size => 1;
  26 use POSIX ":sys_wait_h"; # imports WNOHANG
  27
  28 =head1 NAME
  29
  30 run.pl - start WebPAC indexing
  31
  32 B<this command will probably go away. Don't get used to it!>
  33
  34 Options:
  35
  36 =over 4
  37
  38 =item --offset 42
  39
  40 start loading (all) databases at offset 42
  41
  42 =item --limit 100
  43
  44 limit loading to 100 records
  45
  46 =item --clean
  47
  48 remove database and Hyper Estraier index before indexing
  49
  50 =item --only=database_name/input_filter
  51
  52 reindex just single database (legacy name is --one)
  53
  54 C</input_filter> is optional part which can be C<name>
  55 or C<type> from input
  56
  57 =item --config conf/config.yml
  58
  59 path to YAML configuration file
  60
  61 =item --stats
  62
  63 disable indexing and dump statistics about field and subfield
  64 usage for each input
  65
  66 =item --validate path/to/validation_file
  67
  68 turn on extra validation of imput records, see L<WebPAC::Validation>
  69
  70 =item --marc-normalize conf/normalize/mapping.pl
  71
  72 This option specifies normalisation file for MARC creation
  73
  74 =item --marc-output out/marc/test.marc
  75
  76 Optional path to output file
  77
  78 =item --marc-lint
  79
  80 By default turned on if C<--marc-normalize> is used. You can disable lint
  81 messages with C<--no-marc-lint>.
  82
  83 =item --marc-dump
  84
  85 Force dump or input and marc record for debugging.
  86
  87 =item --parallel 4
  88
  89 Run databases in parallel (aproximatly same as number of processors in
  90 machine if you want to use full load)
  91
  92 =item --only-links
  93
  94 Create just links
  95
  96 =item --merge
  97
  98 Create merged index of databases which have links
  99
 100 =back
 101
 102 =cut
 103
 104 my $offset;
 105 my $limit;
 106
 107 my $clean = 0;
 108 my $config = 'conf/config.yml';
 109 my $debug = 0;
 110 my $only_filter;
 111 my $stats = 0;
 112 my $validate_path;
 113 my ($marc_normalize, $marc_output);
 114 my $marc_lint = 1;
 115 my $marc_dump = 0;
 116 my $parallel = 0;
 117 my $only_links = 0;
 118 my $merge = 0;
 119
 120 my $log = _new WebPAC::Common()->_get_logger();
 121
 122 my $hostname = `hostname`;
 123 chomp($hostname);
 124 $hostname =~ s/\..+$//;
 125 if (-e "conf/$hostname.yml") {
 126         $config = "conf/$hostname.yml";
 127         $log->info("using host configuration file: $config");
 128 }
 129
 130 GetOptions(
 131         "limit=i" => \$limit,
 132         "offset=i" => \$offset,
 133         "clean" => \$clean,
 134         "one=s" => \$only_filter,
 135         "only=s" => \$only_filter,
 136         "config" => \$config,
 137         "debug+" => \$debug,
 138         "stats" => \$stats,
 139         "validate=s" => \$validate_path,
 140         "marc-normalize=s" => \$marc_normalize,
 141         "marc-output=s" => \$marc_output,
 142         "marc-lint!" => \$marc_lint,
 143         "marc-dump!" => \$marc_dump,
 144         "parallel=i" => \$parallel,
 145         "only-links!" => \$only_links,
 146         "merge" => \$merge,
 147 );
 148
 149 $config = LoadFile($config);
 150
 151 #print "config = ",dump($config) if ($debug);
 152
 153 die "no databases in config file!\n" unless ($config->{databases});
 154
 155 $log->info( "-" x 79 );
 156
 157
 158 my $estcmd_fh;
 159 my $estcmd_path = './estcmd-merge.sh';
 160 if ($merge) {
 161         open($estcmd_fh, '>', $estcmd_path) || $log->logdie("can't open $estcmd_path: $!");
 162         print $estcmd_fh 'cd /data/estraier/_node/ || exit 1',$/;
 163         print $estcmd_fh 'sudo /etc/init.d/hyperestraier stop',$/;
 164         $log->info("created merge batch file $estcmd_path");
 165 }
 166
 167
 168 my $validate;
 169 $validate = new WebPAC::Validate(
 170         path => $validate_path,
 171 ) if ($validate_path);
 172
 173
 174 my $use_indexer = $config->{use_indexer} || 'hyperestraier';
 175 if ($stats) {
 176         $log->debug("option --stats disables update of indexing engine...");
 177         $use_indexer = undef;
 178 } else {
 179         $log->info("using $use_indexer indexing engine...");
 180 }
 181
 182 # disable indexing when creating marc
 183 $use_indexer = undef if ($marc_normalize);
 184
 185 my $total_rows = 0;
 186 my $start_t = time();
 187
 188 my @links;
 189
 190 if ($parallel) {
 191         $log->info("Using $parallel processes for speedup");
 192         Proc::Queue::size($parallel);
 193 }
 194
 195 while (my ($database, $db_config) = each %{ $config->{databases} }) {
 196
 197         my ($only_database,$only_input) = split(m#/#, $only_filter) if ($only_filter);
 198         next if ($only_database && $database !~ m/$only_database/i);
 199
 200         if ($parallel) {
 201                 my $f=fork;
 202                 if(defined ($f) and $f==0) {
 203                         $log->info("Created processes $$ for speedup");
 204                 } else {
 205                         next;
 206                 }
 207         }
 208
 209         my $indexer;
 210         if ($use_indexer) {
 211
 212                 my $cfg_name = $use_indexer;
 213                 $cfg_name =~ s/\-.*$//;
 214
 215                 my $indexer_config = $config->{$cfg_name} || $log->logdie("can't find '$cfg_name' part in confguration");
 216                 $indexer_config->{database} = $database;
 217                 $indexer_config->{clean} = $clean;
 218                 $indexer_config->{label} = $db_config->{name};
 219
 220                 # force clean if database has links
 221                 $indexer_config->{clean} = 1 if ($db_config->{links});
 222
 223                 if ($use_indexer eq 'hyperestraier') {
 224
 225                         # open Hyper Estraier database
 226                         use WebPAC::Output::Estraier '0.10';
 227                         $indexer = new WebPAC::Output::Estraier( %{ $indexer_config } );
 228
 229                 } elsif ($use_indexer eq 'hyperestraier-native') {
 230
 231                         # open Hyper Estraier database
 232                         use WebPAC::Output::EstraierNative;
 233                         $indexer = new WebPAC::Output::EstraierNative( %{ $indexer_config } );
 234
 235                         $use_indexer = 'hyperestraier';
 236
 237                 } elsif ($use_indexer eq 'kinosearch') {
 238
 239                         # open KinoSearch
 240                         use WebPAC::Output::KinoSearch;
 241                         $indexer_config->{clean} = 1 unless (-e $indexer_config->{index_path});
 242                         $indexer = new WebPAC::Output::KinoSearch( %{ $indexer_config } );
 243
 244                 } else {
 245                         $log->logdie("unknown use_indexer: $use_indexer");
 246                 }
 247
 248                 $log->logide("can't continue without valid indexer") unless ($indexer);
 249         }
 250
 251
 252         #
 253         # store Hyper Estraier links to other databases
 254         #
 255         if (ref($db_config->{links}) eq 'ARRAY' && $use_indexer) {
 256                 foreach my $link (@{ $db_config->{links} }) {
 257                         if ($use_indexer eq 'hyperestraier') {
 258                                 if ($merge) {
 259                                         print $estcmd_fh 'sudo -u www-data estcmd merge ' . $database . ' ' . $link->{to},$/;
 260                                 } else {
 261                                         $log->info("saving link $database -> $link->{to} [$link->{credit}]");
 262                                         push @links, sub {
 263                                                 $log->info("adding link $database -> $link->{to} [$link->{credit}]");
 264                                                 $indexer->add_link(
 265                                                         from => $database,
 266                                                         to => $link->{to},
 267                                                         credit => $link->{credit},
 268                                                 );
 269                                         };
 270                                 }
 271                         } else {
 272                                 $log->warn("NOT IMPLEMENTED WITH $use_indexer: adding link $database -> $link->{to} [$link->{credit}]");
 273                         }
 274                 }
 275         }
 276         next if ($only_links);
 277
 278
 279         #
 280         # now WebPAC::Store
 281         #
 282         my $abs_path = abs_path($0);
 283         $abs_path =~ s#/[^/]*$#/#;
 284
 285         my $db_path = $config->{webpac}->{db_path} . '/' . $database;
 286
 287         if ($clean) {
 288                 $log->info("creating new database '$database' in $db_path");
 289                 rmtree( $db_path ) || $log->warn("can't remove $db_path: $!");
 290         } else {
 291                 $log->info("working on database '$database' in $db_path");
 292         }
 293
 294         my $db = new WebPAC::Store(
 295                 path => $db_path,
 296                 database => $database,
 297                 debug => $debug,
 298         );
 299
 300
 301         #
 302         # now, iterate through input formats
 303         #
 304
 305         my @inputs;
 306         if (ref($db_config->{input}) eq 'ARRAY') {
 307                 @inputs = @{ $db_config->{input} };
 308         } elsif ($db_config->{input}) {
 309                 push @inputs, $db_config->{input};
 310         } else {
 311                 $log->info("database $database doesn't have inputs defined");
 312         }
 313
 314         my @supported_inputs = keys %{ $config->{webpac}->{inputs} };
 315
 316         foreach my $input (@inputs) {
 317
 318                 next if ($only_input && ($input->{name} !~ m#$only_input#i && $input->{type} !~ m#$only_input#i));
 319
 320                 my $type = lc($input->{type});
 321
 322                 die "I know only how to handle input types ", join(",", @supported_inputs), " not '$type'!\n" unless (grep(/$type/, @supported_inputs));
 323
 324                 my $lookup;
 325                 if ($input->{lookup}) {
 326                         $lookup = new WebPAC::Lookup(
 327                                 lookup_file => $input->{lookup},
 328                         );
 329                         delete( $input->{lookup} );
 330                 }
 331
 332                 my $input_module = $config->{webpac}->{inputs}->{$type};
 333
 334                 $log->info("working on input '$input->{name}' in $input->{path} [type: $input->{type}] using $input_module",
 335                         $input->{lookup} ? "lookup '$input->{lookup}'" : ""
 336                 );
 337
 338                 my $input_db = new WebPAC::Input(
 339                         module => $input_module,
 340                         encoding => $config->{webpac}->{webpac_encoding},
 341                         limit => $limit || $input->{limit},
 342                         offset => $offset,
 343                         lookup_coderef => sub {
 344                                 my $rec = shift || return;
 345                                 $lookup->add( $rec );
 346                         },
 347                         recode => $input->{recode},
 348                         stats => $stats,
 349                         modify_records => $input->{modify_records},
 350                         modify_file => $input->{modify_file},
 351                 );
 352                 $log->logdie("can't create input using $input_module") unless ($input);
 353
 354                 my $maxmfn = $input_db->open(
 355                         path => $input->{path},
 356                         code_page => $input->{encoding},        # database encoding
 357                         %{ $input },
 358                 );
 359
 360                 my @norm_array = ref($input->{normalize}) eq 'ARRAY' ?
 361                         @{ $input->{normalize} } : ( $input->{normalize} );
 362
 363                 if ($marc_normalize) {
 364                         @norm_array = ( {
 365                                 path => $marc_normalize,
 366                                 output => $marc_output || 'out/marc/' . $database . '-' . $input->{name} . '.marc',
 367                         } );
 368                 }
 369
 370                 foreach my $normalize (@norm_array) {
 371
 372                         my $normalize_path = $normalize->{path} || $log->logdie("can't find normalize path in config");
 373
 374                         $log->logdie("Found '$normalize_path' as normalization file which isn't supported any more!") unless ( $normalize_path =~ m!\.pl$!i );
 375
 376                         my $rules = read_file( $normalize_path ) or die "can't open $normalize_path: $!";
 377
 378                         $log->info("Using $normalize_path for normalization...");
 379
 380                         my $marc = new WebPAC::Output::MARC(
 381                                 path => $normalize->{output},
 382                                 lint => $marc_lint,
 383                                 dump => $marc_dump,
 384                         ) if ($normalize->{output});
 385
 386                         # reset position in database
 387                         $input_db->seek(1);
 388
 389                         foreach my $pos ( 0 ... $input_db->size ) {
 390
 391                                 my $row = $input_db->fetch || next;
 392
 393                                 my $mfn = $row->{'000'}->[0];
 394
 395                                 if (! $mfn || $mfn !~ m#^\d+$#) {
 396                                         $log->warn("record $pos doesn't have valid MFN but '$mfn', using $pos");
 397                                         $mfn = $pos;
 398                                         push @{ $row->{'000'} }, $pos;
 399                                 }
 400
 401
 402                                 if ($validate) {
 403                                         my @errors = $validate->validate_errors( $row );
 404                                         $log->error( "MFN $mfn validation errors:\n", join("\n", @errors) ) if (@errors);
 405                                 }
 406
 407                                 my $ds_config = dclone($db_config);
 408
 409                                 # default values -> database key
 410                                 $ds_config->{_} = $database;
 411
 412                                 # current mfn
 413                                 $ds_config->{_mfn} = $mfn;
 414
 415                                 # attach current input
 416                                 $ds_config->{input} = $input;
 417
 418                                 my $ds = WebPAC::Normalize::data_structure(
 419                                         row => $row,
 420                                         rules => $rules,
 421                                         lookup => $lookup ? $lookup->lookup_hash : undef,
 422                                         config => $ds_config,
 423                                         marc_encoding => 'utf-8',
 424                                 );
 425
 426                                 $db->save_ds(
 427                                         id => $mfn,
 428                                         ds => $ds,
 429                                         prefix => $input->{name},
 430                                 ) if ($ds && !$stats);
 431
 432                                 $indexer->add(
 433                                         id => $input->{name} . "/" . $mfn,
 434                                         ds => $ds,
 435                                         type => $config->{$use_indexer}->{type},
 436                                 ) if ($indexer && $ds);
 437
 438                                 if ($marc) {
 439                                         my $i = 0;
 440
 441                                         while (my $fields = WebPAC::Normalize::_get_marc_fields( fetch_next => 1 ) ) {
 442                                                 $marc->add(
 443                                                         id => $mfn . ( $i ? "/$i" : '' ),
 444                                                         fields => $fields,
 445                                                         leader => WebPAC::Normalize::marc_leader(),
 446                                                         row => $row,
 447                                                 );
 448                                                 $i++;
 449                                         }
 450
 451                                         $log->info("Created $i instances of MFN $mfn\n") if ($i > 1);
 452                                 }
 453
 454                                 $total_rows++;
 455                         }
 456
 457                         $log->info("statistics of fields usage:\n", $input_db->stats) if ($stats);
 458
 459                         # close MARC file
 460                         $marc->finish if ($marc);
 461
 462                 }
 463
 464         }
 465
 466         eval { $indexer->finish } if ($indexer && $indexer->can('finish'));
 467
 468         my $dt = time() - $start_t;
 469         $log->info("$total_rows records ", $indexer ? "indexed " : "",
 470                 sprintf("in %.2f sec [%.2f rec/sec]",
 471                         $dt, ($total_rows / $dt)
 472                 )
 473         );
 474
 475
 476         # end forked process
 477         if ($parallel) {
 478                 $log->info("parallel process $$ finished");
 479                 exit(0);
 480         }
 481
 482 }
 483
 484 if ($parallel) {
 485         # wait all children to finish
 486         sleep(1) while wait != -1;
 487         $log->info("all parallel processes finished");
 488 }
 489
 490 #
 491 # handle links or merge after indexing
 492 #
 493
 494 if ($merge) {
 495         print $estcmd_fh 'sudo /etc/init.d/hyperestraier start',$/;
 496         close($estcmd_fh);
 497         chmod 0700, $estcmd_path || $log->warn("can't chmod 0700 $estcmd_path: $!");
 498         system $estcmd_path;
 499 } else {
 500         foreach my $link (@links) {
 501                 $log->logdie("coderef in link ", Dumper($link), " is ", ref($link), " and not CODE") unless (ref($link) eq 'CODE');
 502                 $link->();
 503         }
 504 }