git.rot13.org Git - webpac2/blob - run.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4
   5 use Cwd qw/abs_path/;
   6 use File::Temp qw/tempdir/;
   7 use Data::Dumper;
   8 use lib './lib';
   9
  10 use WebPAC::Common 0.02;
  11 use WebPAC::Lookup;
  12 use WebPAC::Input 0.03;
  13 use WebPAC::Store 0.03;
  14 use WebPAC::Normalize;
  15 use WebPAC::Output::TT;
  16 use WebPAC::Validate;
  17 use YAML qw/LoadFile/;
  18 use Getopt::Long;
  19 use File::Path;
  20 use Time::HiRes qw/time/;
  21 use File::Slurp;
  22 use MARC::Record 2.0;   # need 2.0 for utf-8 encoding see marcpm.sf.net
  23
  24 =head1 NAME
  25
  26 run.pl - start WebPAC indexing
  27
  28 B<this command will probably go away. Don't get used to it!>
  29
  30 Options:
  31
  32 =over 4
  33
  34 =item --offset 42
  35
  36 start loading (all) databases at offset 42
  37
  38 =item --limit 100
  39
  40 limit loading to 100 records
  41
  42 =item --clean
  43
  44 remove database and Hyper Estraier index before indexing
  45
  46 =item --only=database_name/input_filter
  47
  48 reindex just single database (legacy name is --one)
  49
  50 C</input_filter> is optional part which can be C<name>
  51 or C<type> from input
  52
  53 =item --config conf/config.yml
  54
  55 path to YAML configuration file
  56
  57 =item --stats
  58
  59 disable indexing and dump statistics about field and subfield
  60 usage for each input
  61
  62 =item --validate path/to/validation_file
  63
  64 turn on extra validation of imput records, see L<WebPAC::Validation>
  65
  66 =back
  67
  68 =cut
  69
  70 my $offset;
  71 my $limit;
  72
  73 my $clean = 0;
  74 my $config = 'conf/config.yml';
  75 my $debug = 0;
  76 my $only_filter;
  77 my $stats = 0;
  78 my $validate_path;
  79
  80 GetOptions(
  81         "limit=i" => \$limit,
  82         "offset=i" => \$offset,
  83         "clean" => \$clean,
  84         "one=s" => \$only_filter,
  85         "only=s" => \$only_filter,
  86         "config" => \$config,
  87         "debug" => \$debug,
  88         "stats" => \$stats,
  89         "validate=s" => \$validate_path,
  90 );
  91
  92 $config = LoadFile($config);
  93
  94 print "config = ",Dumper($config) if ($debug);
  95
  96 die "no databases in config file!\n" unless ($config->{databases});
  97
  98 my $log = _new WebPAC::Common()->_get_logger();
  99 $log->info( "-" x 79 );
 100
 101 my $validate;
 102 $validate = new WebPAC::Validate(
 103         path => $validate_path,
 104 ) if ($validate_path);
 105
 106 my $use_indexer = $config->{use_indexer} || 'hyperestraier';
 107 if ($stats) {
 108         $log->debug("option --stats disables update of indexing engine...");
 109         $use_indexer = undef;
 110 } else {
 111         $log->info("using $use_indexer indexing engine...");
 112 }
 113
 114 my $total_rows = 0;
 115 my $start_t = time();
 116
 117 my @links;
 118 my $indexer;
 119
 120 while (my ($database, $db_config) = each %{ $config->{databases} }) {
 121
 122         my ($only_database,$only_input) = split(m#/#, $only_filter) if ($only_filter);
 123         next if ($only_database && $database !~ m/$only_database/i);
 124
 125         if ($use_indexer) {
 126                 my $indexer_config = $config->{$use_indexer} || $log->logdie("can't find '$use_indexer' part in confguration");
 127                 $indexer_config->{database} = $database;
 128                 $indexer_config->{clean} = $clean;
 129                 $indexer_config->{label} = $db_config->{name};
 130
 131                 if ($use_indexer eq 'hyperestraier') {
 132
 133                         # open Hyper Estraier database
 134                         use WebPAC::Output::Estraier '0.10';
 135                         $indexer = new WebPAC::Output::Estraier( %{ $indexer_config } );
 136
 137                 } elsif ($use_indexer eq 'kinosearch') {
 138
 139                         # open KinoSearch
 140                         use WebPAC::Output::KinoSearch;
 141                         $indexer_config->{clean} = 1 unless (-e $indexer_config->{index_path});
 142                         $indexer = new WebPAC::Output::KinoSearch( %{ $indexer_config } );
 143
 144                 } else {
 145                         $log->logdie("unknown use_indexer: $use_indexer");
 146                 }
 147
 148                 $log->logide("can't continue without valid indexer") unless ($indexer);
 149         }
 150
 151
 152         #
 153         # now WebPAC::Store
 154         #
 155         my $abs_path = abs_path($0);
 156         $abs_path =~ s#/[^/]*$#/#;
 157
 158         my $db_path = $config->{webpac}->{db_path} . '/' . $database;
 159
 160         if ($clean) {
 161                 $log->info("creating new database '$database' in $db_path");
 162                 rmtree( $db_path ) || $log->warn("can't remove $db_path: $!");
 163         } else {
 164                 $log->info("working on database '$database' in $db_path");
 165         }
 166
 167         my $db = new WebPAC::Store(
 168                 path => $db_path,
 169                 database => $database,
 170                 debug => $debug,
 171         );
 172
 173
 174         #
 175         # now, iterate through input formats
 176         #
 177
 178         my @inputs;
 179         if (ref($db_config->{input}) eq 'ARRAY') {
 180                 @inputs = @{ $db_config->{input} };
 181         } elsif ($db_config->{input}) {
 182                 push @inputs, $db_config->{input};
 183         } else {
 184                 $log->info("database $database doesn't have inputs defined");
 185         }
 186
 187         my @supported_inputs = keys %{ $config->{webpac}->{inputs} };
 188
 189         foreach my $input (@inputs) {
 190
 191                 next if ($only_input && ($input->{name} !~ m#$only_input#i && $input->{type} !~ m#$only_input#i));
 192
 193                 my $type = lc($input->{type});
 194
 195                 die "I know only how to handle input types ", join(",", @supported_inputs), " not '$type'!\n" unless (grep(/$type/, @supported_inputs));
 196
 197                 my $lookup = new WebPAC::Lookup(
 198                         lookup_file => $input->{lookup},
 199                 ) if ($input->{lookup});
 200
 201                 my $input_module = $config->{webpac}->{inputs}->{$type};
 202
 203                 $log->info("working on input '$input->{name}' in $input->{path} [type: $input->{type}] using $input_module",
 204                         $input->{lookup} ? "lookup '$input->{lookup}'" : ""
 205                 );
 206
 207                 my $input_db = new WebPAC::Input(
 208                         module => $input_module,
 209                         code_page => $config->{webpac}->{webpac_encoding},
 210                         limit => $limit || $input->{limit},
 211                         offset => $offset,
 212                         lookup => $lookup,
 213                         recode => $input->{recode},
 214                         stats => $stats,
 215                 );
 216                 $log->logdie("can't create input using $input_module") unless ($input);
 217
 218                 my $maxmfn = $input_db->open(
 219                         path => $input->{path},
 220                         code_page => $input->{encoding},        # database encoding
 221                         %{ $input },
 222                 );
 223
 224                 my @norm_array = ref($input->{normalize}) eq 'ARRAY' ?
 225                         @{ $input->{normalize} } : ( $input->{normalize} );
 226
 227                 foreach my $normalize (@norm_array) {
 228
 229                         my $normalize_path = $normalize->{path} || $log->logdie("can't find normalize path in config");
 230
 231                         $log->logdie("Found '$normalize_path' as normalization file which isn't supported any more!") unless ( $normalize_path =~ m!\.pl$!i );
 232
 233                         my $rules = read_file( $normalize_path ) or die "can't open $normalize_path: $!";
 234
 235                         $log->info("Using $normalize_path for normalization...");
 236
 237                         my $marc_fh;
 238                         if (my $path = $normalize->{marc21}) {
 239                                 open($marc_fh, '>', $path) ||
 240                                         $log->logdie("can't open MARC output $path: $!");
 241
 242                                 $log->info("Creating MARC export file $path\n");
 243                         }
 244
 245                         # reset position in database
 246                         $input_db->seek(1);
 247
 248                         foreach my $pos ( 0 ... $input_db->size ) {
 249
 250                                 my $row = $input_db->fetch || next;
 251
 252                                 my $mfn = $row->{'000'}->[0];
 253
 254                                 if (! $mfn || $mfn !~ m#^\d+$#) {
 255                                         $log->warn("record $pos doesn't have valid MFN but '$mfn', using $pos");
 256                                         $mfn = $pos;
 257                                         push @{ $row->{'000'} }, $pos;
 258                                 }
 259
 260
 261                                 if ($validate) {
 262                                         my @errors = $validate->validate_errors( $row );
 263                                         $log->error( "MFN $mfn validation errors:\n", join("\n", @errors) ) if (@errors);
 264                                 }
 265
 266
 267                                 my $ds = WebPAC::Normalize::data_structure(
 268                                         row => $row,
 269                                         rules => $rules,
 270                                         lookup => $lookup ? $lookup->lookup_hash : undef,
 271                                         marc_encoding => 'utf-8',
 272                                 );
 273
 274                                 $db->save_ds(
 275                                         id => $mfn,
 276                                         ds => $ds,
 277                                         prefix => $input->{name},
 278                                 ) if ($ds && !$stats);
 279
 280                                 $indexer->add(
 281                                         id => $input->{name} . "/" . $mfn,
 282                                         ds => $ds,
 283                                         type => $config->{$use_indexer}->{type},
 284                                 ) if ($indexer && $ds);
 285
 286                                 if ($marc_fh) {
 287                                         my $marc = new MARC::Record;
 288                                         $marc->encoding( 'utf-8' );
 289                                         $marc->add_fields( WebPAC::Normalize::_get_marc21_fields() );
 290                                         print $marc_fh $marc->as_usmarc;
 291                                 }
 292
 293                                 $total_rows++;
 294                         }
 295
 296                         $log->info("statistics of fields usage:\n", $input_db->stats) if ($stats);
 297
 298                         # close MARC file
 299                         close($marc_fh) if ($marc_fh);
 300
 301                 }
 302
 303         }
 304
 305         eval { $indexer->finish } if ($indexer && $indexer->can('finish'));
 306
 307         my $dt = time() - $start_t;
 308         $log->info("$total_rows records ", $indexer ? "indexed " : "",
 309                 sprintf("in %.2f sec [%.2f rec/sec]",
 310                         $dt, ($total_rows / $dt)
 311                 )
 312         );
 313
 314         #
 315         # add Hyper Estraier links to other databases
 316         #
 317         if (ref($db_config->{links}) eq 'ARRAY') {
 318                 foreach my $link (@{ $db_config->{links} }) {
 319                         if ($use_indexer eq 'hyperestraier') {
 320                                 $log->info("saving link $database -> $link->{to} [$link->{credit}]");
 321                                 push @links, {
 322                                         from => $database,
 323                                         to => $link->{to},
 324                                         credit => $link->{credit},
 325                                 };
 326                         } else {
 327                                 $log->warn("NOT IMPLEMENTED WITH $use_indexer: adding link $database -> $link->{to} [$link->{credit}]");
 328                         }
 329                 }
 330         }
 331
 332 }
 333
 334 foreach my $link (@links) {
 335         $log->info("adding link $link->{from} -> $link->{to} [$link->{credit}]");
 336         $indexer->add_link( %{ $link } );
 337 }