git.rot13.org Git - webpac2/blob - run.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4
   5 use Cwd qw/abs_path/;
   6 use File::Temp qw/tempdir/;
   7 use lib './lib';
   8
   9 use WebPAC::Common 0.02;
  10 use WebPAC::Parser 0.08;
  11 use WebPAC::Input 0.16;
  12 use WebPAC::Store 0.14;
  13 use WebPAC::Normalize 0.22;
  14 use WebPAC::Output::TT;
  15 use WebPAC::Validate 0.11;
  16 use WebPAC::Output::MARC;
  17 use WebPAC::Config;
  18 use Getopt::Long;
  19 use File::Path;
  20 use Time::HiRes qw/time/;
  21 use File::Slurp;
  22 use Data::Dump qw/dump/;
  23 use Storable qw/dclone/;
  24 use Pod::Usage qw/pod2usage/;
  25
  26 use Proc::Queue size => 1;
  27 use POSIX ":sys_wait_h"; # imports WNOHANG
  28
  29 =head1 NAME
  30
  31 run.pl - start WebPAC indexing
  32
  33 B<this command will probably go away. Don't get used to it!>
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item --offset 42
  40
  41 start loading (all) databases at offset 42
  42
  43 =item --limit 100
  44
  45 limit loading to 100 records
  46
  47 =item --clean
  48
  49 remove database and Hyper Estraier index before indexing
  50
  51 =item --only=database_name/input_filter
  52
  53 reindex just single database (legacy name is --one)
  54
  55 C</input_filter> is optional part which can be C<name>
  56 or C<type> from input
  57
  58 =item --config conf/config.yml
  59
  60 path to YAML configuration file
  61
  62 =item --stats
  63
  64 disable indexing, modify_* in configuration and dump statistics about field
  65 and subfield usage for each input
  66
  67 =item --validate path/to/validation_file
  68
  69 turn on extra validation of imput records, see L<WebPAC::Validation>
  70
  71 =item --validate-delimiters path/to/validate_delimiters_file
  72
  73 this option is used with C<--validate> to turn on extra validation of
  74 delimiters. If file is non existant, it will be created on first run.
  75
  76 =item --marc-generate
  77
  78 Generate MARC file. This will automatically be on if file contains C<marc*> directives.
  79 You can use this option as C<--no-marc-generate> to disable MARC generation.
  80
  81 =item --marc-lint
  82
  83 By default turned on if normalisation file has C<marc*> directives. You can disable lint
  84 messages with C<--no-marc-lint>.
  85
  86 =item --marc-dump
  87
  88 Force dump or input and marc record for debugging.
  89
  90 =item --parallel 4
  91
  92 Run databases in parallel (aproximatly same as number of processors in
  93 machine if you want to use full load)
  94
  95 =item --only-links
  96
  97 Create just links
  98
  99 =item --merge
 100
 101 Create merged index of databases which have links
 102
 103 =back
 104
 105 =cut
 106
 107 my $offset;
 108 my $limit;
 109
 110 my $clean = 0;
 111 my $config_path;
 112 my $debug = 0;
 113 my $only_filter;
 114 my $stats = 0;
 115 my $validate_path;
 116 my $validate_delimiters_path;
 117 my $marc_generate = 1;
 118 my $marc_lint = 1;
 119 my $marc_dump = 0;
 120 my $parallel = 0;
 121 my $only_links = 0;
 122 my $merge = 0;
 123 my $help;
 124
 125 my $log = _new WebPAC::Common()->_get_logger();
 126
 127 GetOptions(
 128         "limit=i" => \$limit,
 129         "offset=i" => \$offset,
 130         "clean" => \$clean,
 131         "one=s" => \$only_filter,
 132         "only=s" => \$only_filter,
 133         "config" => \$config_path,
 134         "debug+" => \$debug,
 135         "stats" => \$stats,
 136         "validate=s" => \$validate_path,
 137         "validate-delimiters=s" => \$validate_delimiters_path,
 138         "marc-generate!" => \$marc_generate,
 139         "marc-lint!" => \$marc_lint,
 140         "marc-dump!" => \$marc_dump,
 141         "parallel=i" => \$parallel,
 142         "only-links!" => \$only_links,
 143         "merge" => \$merge,
 144         "help" => \$help,
 145 );
 146
 147 pod2usage(-verbose => 2) if ($help);
 148
 149 my $config = new WebPAC::Config( path => $config_path );
 150
 151 #print "config = ",dump($config) if ($debug);
 152
 153 die "no databases in config file!\n" unless ($config->databases);
 154
 155 $log->info( "-" x 79 );
 156
 157 my $log_file = 'log';
 158
 159 if (-e $log_file ) {    # && -s $log_file > 5 * 1024 * 1024) {
 160         $log->info("moved old log with ", -s $log_file, " bytes to '${log_file}.old'");
 161         rename $log_file, "${log_file}.old" || $log->logwarn("can't rename $log_file to ${log_file}.old: $!");
 162 }
 163
 164 my $estcmd_fh;
 165 my $estcmd_path = './estcmd-merge.sh';
 166 if ($merge) {
 167         open($estcmd_fh, '>', $estcmd_path) || $log->logdie("can't open $estcmd_path: $!");
 168         print $estcmd_fh 'cd /data/estraier/_node/ || exit 1',$/;
 169         print $estcmd_fh 'sudo /etc/init.d/hyperestraier stop',$/;
 170         $log->info("created merge batch file $estcmd_path");
 171 }
 172
 173 my $validate;
 174 $validate = new WebPAC::Validate(
 175         path => $validate_path,
 176         delimiters => $config->webpac('delimiters'),
 177         delimiters_path => $validate_delimiters_path,
 178 ) if ($validate_path || $validate_delimiters_path);
 179
 180 my $use_indexer = $config->use_indexer;
 181 $stats ||= $validate;
 182 if ($stats) {
 183         $log->debug("disabled indexing for stats collection");
 184         $use_indexer = undef;
 185 } else {
 186         $log->info("using $use_indexer indexing engine...");
 187 }
 188
 189 # parse normalize files and create source files for lookup and normalization
 190
 191 my $parser = new WebPAC::Parser( config => $config );
 192
 193 my $total_rows = 0;
 194 my $start_t = time();
 195
 196 my @links;
 197
 198 if ($parallel) {
 199         $log->info("Using $parallel processes for speedup");
 200         Proc::Queue::size($parallel);
 201 }
 202
 203 sub create_ds_config {
 204         my ($db_config, $database, $input, $mfn) = @_;
 205         my $c = dclone( $db_config );
 206         $c->{_} = $database || $log->logconfess("need database");
 207         $c->{_mfn} = $mfn || $log->logconfess("need mfn");
 208         $c->{input} = $input || $log->logconfess("need input");
 209         return $c;
 210 }
 211
 212 while (my ($database, $db_config) = each %{ $config->databases }) {
 213
 214         my ($only_database,$only_input) = split(m#/#, $only_filter) if ($only_filter);
 215         next if ($only_database && $database !~ m/$only_database/i);
 216
 217         if ($parallel) {
 218                 my $f=fork;
 219                 if(defined ($f) and $f==0) {
 220                         $log->info("Created processes $$ for speedup");
 221                 } else {
 222                         next;
 223                 }
 224         }
 225
 226         my $indexer;
 227         if ($use_indexer && $parser->have_rules( 'search', $database )) {
 228
 229                 my $cfg_name = $use_indexer;
 230                 $cfg_name =~ s/\-.*$//;
 231
 232                 my $indexer_config = $config->get( $cfg_name ) || $log->logdie("can't find '$cfg_name' part in confguration");
 233                 $indexer_config->{database} = $database;
 234                 $indexer_config->{clean} = $clean;
 235                 $indexer_config->{label} = $db_config->{name};
 236
 237                 # force clean if database has links
 238                 $indexer_config->{clean} = 1 if ($db_config->{links});
 239
 240                 if ($use_indexer eq 'hyperestraier') {
 241
 242                         # open Hyper Estraier database
 243                         use WebPAC::Output::Estraier '0.10';
 244                         $indexer = new WebPAC::Output::Estraier( %{ $indexer_config } );
 245
 246                 } elsif ($use_indexer eq 'hyperestraier-native') {
 247
 248                         # open Hyper Estraier database
 249                         use WebPAC::Output::EstraierNative;
 250                         $indexer = new WebPAC::Output::EstraierNative( %{ $indexer_config } );
 251
 252                 } elsif ($use_indexer eq 'kinosearch') {
 253
 254                         # open KinoSearch
 255                         use WebPAC::Output::KinoSearch;
 256                         $indexer_config->{clean} = 1 unless (-e $indexer_config->{index_path});
 257                         $indexer = new WebPAC::Output::KinoSearch( %{ $indexer_config } );
 258
 259                 } else {
 260                         $log->logdie("unknown use_indexer: $use_indexer");
 261                 }
 262
 263                 $log->logide("can't continue without valid indexer") unless ($indexer);
 264         }
 265
 266
 267         #
 268         # store Hyper Estraier links to other databases
 269         #
 270         if (ref($db_config->{links}) eq 'ARRAY' && $use_indexer) {
 271                 foreach my $link (@{ $db_config->{links} }) {
 272                         if ($use_indexer eq 'hyperestraier') {
 273                                 if ($merge) {
 274                                         print $estcmd_fh 'sudo -u www-data estcmd merge ' . $database . ' ' . $link->{to},$/;
 275                                 } else {
 276                                         $log->info("saving link $database -> $link->{to} [$link->{credit}]");
 277                                         push @links, sub {
 278                                                 $log->info("adding link $database -> $link->{to} [$link->{credit}]");
 279                                                 $indexer->add_link(
 280                                                         from => $database,
 281                                                         to => $link->{to},
 282                                                         credit => $link->{credit},
 283                                                 );
 284                                         };
 285                                 }
 286                         } else {
 287                                 $log->warn("NOT IMPLEMENTED WITH $use_indexer: adding link $database -> $link->{to} [$link->{credit}]");
 288                         }
 289                 }
 290         }
 291         next if ($only_links);
 292
 293
 294         #
 295         # now WebPAC::Store
 296         #
 297         my $abs_path = abs_path($0);
 298         $abs_path =~ s#/[^/]*$#/#;
 299
 300         my $db_path = $config->webpac('db_path');
 301
 302         if ($clean) {
 303                 $log->info("creating new database '$database' in $db_path");
 304                 rmtree( $db_path ) || $log->warn("can't remove $db_path: $!");
 305         } else {
 306                 $log->info("working on database '$database' in $db_path");
 307         }
 308
 309         my $store = new WebPAC::Store(
 310                 path => $db_path,
 311                 debug => $debug,
 312         );
 313
 314
 315         #
 316         # now, iterate through input formats
 317         #
 318
 319         my @inputs;
 320         if (ref($db_config->{input}) eq 'ARRAY') {
 321                 @inputs = @{ $db_config->{input} };
 322         } elsif ($db_config->{input}) {
 323                 push @inputs, $db_config->{input};
 324         } else {
 325                 $log->info("database $database doesn't have inputs defined");
 326         }
 327
 328         foreach my $input (@inputs) {
 329
 330                 my $input_name = $input->{name} || $log->logdie("input without a name isn't valid: ",dump($input));
 331
 332                 next if ($only_input && ($input_name !~ m#$only_input#i && $input->{type} !~ m#$only_input#i));
 333
 334                 my $type = lc($input->{type});
 335
 336                 die "I know only how to handle input types ", join(",", $config->webpac('inputs') ), " not '$type'!\n" unless (grep(/$type/, $config->webpac('inputs')));
 337
 338                 my $input_module = $config->webpac('inputs')->{$type};
 339
 340                 my @lookups = $parser->have_lookup_create($database, $input);
 341
 342                 $log->info("working on input '$input_name' in $input->{path} [type: $input->{type}] using $input_module",
 343                         @lookups ? " creating lookups: ".join(", ", @lookups) : ""
 344                 );
 345
 346                 if ($stats) {
 347                         # disable modification of records if --stats is in use
 348                         delete($input->{modify_records});
 349                         delete($input->{modify_file});
 350                 }
 351
 352                 my $input_db = new WebPAC::Input(
 353                         module => $input_module,
 354                         encoding => $config->webpac('webpac_encoding'),
 355                         limit => $limit || $input->{limit},
 356                         offset => $offset,
 357                         recode => $input->{recode},
 358                         stats => $stats,
 359                         modify_records => $input->{modify_records},
 360                         modify_file => $input->{modify_file},
 361                 );
 362                 $log->logdie("can't create input using $input_module") unless ($input);
 363
 364                 if (defined( $input->{lookup} )) {
 365                         $log->warn("$database/$input_name has depriciated lookup definition, removing it...");
 366                         delete( $input->{lookup} );
 367                 }
 368
 369                 my $lookup_coderef;
 370
 371                 if (@lookups) {
 372
 373                         my $rules = $parser->lookup_create_rules($database, $input) || $log->logdie("no rules found for $database/$input");
 374
 375                         $lookup_coderef = sub {
 376                                 my $rec = shift || die "need rec!";
 377                                 my $mfn = $rec->{'000'}->[0] || die "need mfn in 000";
 378
 379                                 WebPAC::Normalize::data_structure(
 380                                         row => $rec,
 381                                         rules => $rules,
 382                                         config => create_ds_config( $db_config, $database, $input, $mfn ),
 383                                 );
 384
 385                                 #warn "current lookup: ", dump(WebPAC::Normalize::_get_lookup());
 386                         };
 387
 388                         WebPAC::Normalize::_set_lookup( undef );
 389
 390                         $log->debug("created lookup_coderef using:\n$rules");
 391
 392                 };
 393
 394                 my $lookup_jar;
 395
 396                 my $maxmfn = $input_db->open(
 397                         path => $input->{path},
 398                         code_page => $input->{encoding},        # database encoding
 399                         lookup_coderef => $lookup_coderef,
 400                         lookup => $lookup_jar,
 401                         %{ $input },
 402                         load_row => sub {
 403                                 my $a = shift;
 404                                 return $store->load_row(
 405                                         database => $database,
 406                                         input => $input_name,
 407                                         id => $a->{id},
 408                                 );
 409                         },
 410                         save_row => sub {
 411                                 my $a = shift;
 412                                 return $store->save_row(
 413                                         database => $database,
 414                                         input => $input_name,
 415                                         id => $a->{id},
 416                                         row => $a->{row},
 417                                 );
 418                         },
 419
 420                 );
 421
 422                 my $lookup_data = WebPAC::Normalize::_get_lookup();
 423
 424                 if (defined( $lookup_data->{$database}->{$input_name} )) {
 425                         $log->debug("created following lookups: ", sub { dump( $lookup_data ) } );
 426
 427                         foreach my $key (keys %{ $lookup_data->{$database}->{$input_name} }) {
 428                                 $store->save_lookup(
 429                                         database => $database,
 430                                         input => $input_name,
 431                                         key => $key,
 432                                         data => $lookup_data->{$database}->{$input_name}->{$key},
 433                                 );
 434                         }
 435                 }
 436
 437                 my $report_fh;
 438                 if ($stats || $validate) {
 439                         my $path = "out/report/${database}-${input_name}.txt";
 440                         open($report_fh, '>', $path) || $log->logdie("can't open $path: $!");
 441
 442                         print $report_fh "Report for database '$database' input '$input_name' records ",
 443                                 $offset || 1, "-", $limit || $input->{limit} || $maxmfn, "\n\n";
 444                         $log->info("Generating report file $path");
 445                 }
 446
 447                 my $marc;
 448                 if ($marc_generate && $parser->have_rules( 'marc', $database, $input_name )) {
 449                         $marc = new WebPAC::Output::MARC(
 450                                 path => "out/marc/${database}-${input_name}.marc",
 451                                 lint => $marc_lint,
 452                                 dump => $marc_dump,
 453                         );
 454                 }
 455
 456                 my $rules = $parser->normalize_rules($database,$input_name) || $log->logdie("no normalize rules found for $database/$input_name");
 457                 $log->debug("parsed normalize rules:\n$rules");
 458
 459                 # reset position in database
 460                 $input_db->seek(1);
 461
 462                 # generate name of config key for indexer (strip everything after -)
 463                 my $indexer_config = $use_indexer;
 464                 $indexer_config =~ s/^(\w+)-?.*$/$1/g if ($indexer_config);
 465
 466                 my $lookup_hash;
 467                 my $depends = $parser->depends($database,$input_name);
 468
 469                 if ($depends) {
 470                         $log->debug("$database/$input_name depends on: ", dump($depends)) if ($depends);
 471                         $log->logdie("parser->depends didn't return HASH") unless (ref($depends) eq 'HASH');
 472
 473                         foreach my $db (keys %$depends) {
 474                                 foreach my $i (keys %{$depends->{$db}}) {
 475                                         foreach my $k (keys %{$depends->{$db}->{$i}}) {
 476                                                 my $t = time();
 477                                                 $log->debug("loading lookup $db/$i");
 478                                                 $lookup_hash->{$db}->{$i}->{$k} = $store->load_lookup(
 479                                                         database => $db,
 480                                                         input => $i,
 481                                                         key => $k,
 482                                                 );
 483                                                 $log->debug(sprintf("lookup $db/$i took %.2fs", time() - $t));
 484                                         }
 485                                 }
 486                         }
 487
 488                         $log->debug("lookup_hash = ", sub { dump( $lookup_hash ) });
 489                 }
 490
 491
 492                 foreach my $pos ( 0 ... $input_db->size ) {
 493
 494                         my $row = $input_db->fetch || next;
 495
 496                         $total_rows++;
 497
 498                         my $mfn = $row->{'000'}->[0];
 499
 500                         if (! $mfn || $mfn !~ m#^\d+$#) {
 501                                 $log->warn("record $pos doesn't have valid MFN but '$mfn', using $pos");
 502                                 $mfn = $pos;
 503                                 push @{ $row->{'000'} }, $pos;
 504                         }
 505
 506
 507                         if ($validate) {
 508                                 if ( my $errors = $validate->validate_rec( $row, $input_db->dump_ascii ) ) {
 509                                         $log->error( "MFN $mfn validation error:\n",
 510                                                 $validate->report_error( $errors )
 511                                         );
 512                                 }
 513                                 next;   # validation doesn't create any output
 514                         }
 515
 516                         my $ds = WebPAC::Normalize::data_structure(
 517                                 row => $row,
 518                                 rules => $rules,
 519                                 lookup => $lookup_hash,
 520                                 config => create_ds_config( $db_config, $database, $input, $mfn ),
 521                                 marc_encoding => 'utf-8',
 522                                 load_row_coderef => sub {
 523                                         my ($database,$input,$mfn) = @_;
 524                                         return $store->load_row(
 525                                                 database => $database,
 526                                                 input => $input,
 527                                                 id => $mfn,
 528                                         );
 529                                 },
 530                         );
 531
 532                         $log->debug("ds = ", sub { dump($ds) }) if ($ds);
 533
 534                         $store->save_ds(
 535                                 database => $database,
 536                                 input => $input_name,
 537                                 id => $mfn,
 538                                 ds => $ds,
 539                         ) if ($ds && !$stats);
 540
 541                         $indexer->add(
 542                                 id => "${input_name}/${mfn}",
 543                                 ds => $ds,
 544                                 type => $config->get($indexer_config)->{type},
 545                         ) if ($indexer && $ds);
 546
 547                         if ($marc) {
 548                                 my $i = 0;
 549
 550                                 while (my $fields = WebPAC::Normalize::_get_marc_fields( fetch_next => 1 ) ) {
 551                                         $marc->add(
 552                                                 id => $mfn . ( $i ? "/$i" : '' ),
 553                                                 fields => $fields,
 554                                                 leader => WebPAC::Normalize::_get_marc_leader(),
 555                                                 row => $row,
 556                                         );
 557                                         $i++;
 558                                 }
 559
 560                                 $log->info("Created $i instances of MFN $mfn\n") if ($i > 1);
 561                         }
 562                 }
 563
 564                 if ($validate) {
 565                         my $errors = $validate->report;
 566                         if ($errors) {
 567                                 $log->info("validation errors:\n$errors\n" );
 568                                 print $report_fh "$errors\n" if ($report_fh);
 569                         }
 570
 571                         print $report_fh "\nAll possible subfields/delimiter templates:\n", $validate->delimiters_templates( report => 1 ), "\n\n";
 572                 }
 573
 574                 if ($stats) {
 575                         my $s = $input_db->stats;
 576                         $log->info("statistics of fields usage:\n$s");
 577                         print $report_fh "Statistics of fields usage:\n$s" if ($report_fh);
 578                 }
 579
 580                 # close MARC file
 581                 $marc->finish if ($marc);
 582
 583                 # close report
 584                 close($report_fh) if ($report_fh)
 585
 586         }
 587
 588         eval { $indexer->finish } if ($indexer && $indexer->can('finish'));
 589
 590         my $dt = time() - $start_t;
 591         $log->info("$total_rows records ", $indexer ? "indexed " : "",
 592                 sprintf("in %.2f sec [%.2f rec/sec]",
 593                         $dt, ($total_rows / $dt)
 594                 )
 595         );
 596
 597
 598         # end forked process
 599         if ($parallel) {
 600                 $log->info("parallel process $$ finished");
 601                 exit(0);
 602         }
 603
 604 }
 605
 606 if ($parallel) {
 607         # wait all children to finish
 608         sleep(1) while wait != -1;
 609         $log->info("all parallel processes finished");
 610 }
 611
 612 # save new delimiters if needed
 613 $validate->save_delimiters_templates if ( $validate );
 614
 615 #
 616 # handle links or merge after indexing
 617 #
 618
 619 if ($merge) {
 620         print $estcmd_fh 'sudo /etc/init.d/hyperestraier start',$/;
 621         close($estcmd_fh);
 622         chmod 0700, $estcmd_path || $log->warn("can't chmod 0700 $estcmd_path: $!");
 623         system $estcmd_path;
 624 } else {
 625         foreach my $link (@links) {
 626                 $log->logdie("coderef in link ", Dumper($link), " is ", ref($link), " and not CODE") unless (ref($link) eq 'CODE');
 627                 $link->();
 628         }
 629 }