r339@llin: dpavlin | 2005-12-31 15:02:38 +0100

[webpac2] / run.pl

#!/usr/bin/perl -w

use strict;

use Cwd qw/abs_path/;
use File::Temp qw/tempdir/;
use Data::Dumper;
use lib './lib';

use WebPAC::Common 0.02;
use WebPAC::Lookup;
use WebPAC::Input 0.03;
use WebPAC::Store 0.03;
use WebPAC::Normalize::XML;
use WebPAC::Output::TT;
use WebPAC::Output::Estraier 0.08;
use YAML qw/LoadFile/;
use Getopt::Long;
use File::Path;

=head1 NAME

run.pl - start WebPAC indexing

B<this command will probably go away. Don't get used to it!>

Options:

=over 4

=item --offset 42

start loading (all) databases at offset 42

=item --limit 100

limit loading to 100 records

=item --clean

remove database and Hyper Estraier index before indexing

=item --one=database_name

reindex just single database

=item --config conf/config.yml

path to YAML configuration file

=back

=cut

my $offset;
my $limit;

my $clean = 0;
my $config = 'conf/config.yml';
my $debug = 0;
my $one_db_name;

GetOptions(
        "limit=i" => \$limit,
        "offset=i" => \$offset,
        "clean" => \$clean,
        "one=s" => \$one_db_name,
        "config" => \$config,
        "debug" => \$debug,
);

$config = LoadFile($config);

print "config = ",Dumper($config) if ($debug);

die "no databases in config file!\n" unless ($config->{databases});

my $total_rows = 0;

while (my ($database, $db_config) = each %{ $config->{databases} }) {

        next if ($one_db_name && $database !~ m/$one_db_name/i);

        my $log = _new WebPAC::Common()->_get_logger();

        #
        # open Hyper Estraier database
        #

        my $est_config = $config->{hyperestraier} || $log->logdie("can't find 'hyperestraier' part in confguration");
        $est_config->{database} = $database;
        $est_config->{clean} = $clean;

        my $est = new WebPAC::Output::Estraier( %{ $est_config } );

        #
        # now WebPAC::Store
        #
        my $abs_path = abs_path($0);
        $abs_path =~ s#/[^/]*$#/#;

        my $db_path = $config->{webpac}->{db_path} . '/' . $database;

        if ($clean) {
                $log->info("creating new database $database in $db_path");
                rmtree( $db_path ) || $log->warn("can't remove $db_path: $!");
        } else {
                $log->info("working on $database in $db_path");
        }

        my $db = new WebPAC::Store(
                path => $db_path,
                database => $database,
                debug => $debug,
        );


        #
        # now, iterate through input formats
        #

        my @inputs;
        if (ref($db_config->{input}) eq 'ARRAY') {
                @inputs = @{ $db_config->{input} };
        } elsif ($db_config->{input}) {
                push @inputs, $db_config->{input};
        } else {
                $log->info("database $database doesn't have inputs defined");
        }

        my @supported_inputs = keys %{ $config->{webpac}->{inputs} };

        foreach my $input (@inputs) {

                my $type = lc($input->{type});

                die "I know only how to handle input types ", join(",", @supported_inputs), " not '$type'!\n" unless (grep(/$type/, @supported_inputs));

                my $lookup = new WebPAC::Lookup(
                        lookup_file => $input->{lookup},
                );

                my $input_module = $config->{webpac}->{inputs}->{$type};

                $log->info("working on input $input->{path} [$input->{type}] using $input_module");

                my $input_db = new WebPAC::Input(
                        module => $input_module,
                        code_page => $config->{webpac}->{webpac_encoding},
                        limit => $limit || $input->{limit},
                        offset => $offset,
                        lookup => $lookup,
                );
                $log->logdie("can't create input using $input_module") unless ($input);

                my $maxmfn = $input_db->open(
                        path => $input->{path},
                        code_page => $input->{encoding},        # database encoding
                );

                my $n = new WebPAC::Normalize::XML(
                #       filter => { 'foo' => sub { shift } },
                        db => $db,
                        lookup_regex => $lookup->regex,
                        lookup => $lookup,
                        prefix => $input->{name},
                );

                my $normalize_path = $input->{normalize}->{path};

                if ($normalize_path =~ m/\.xml$/i) {
                        $n->open(
                                tag => $input->{normalize}->{tag},
                                xml_file => $input->{normalize}->{path},
                        );
                } elsif ($normalize_path =~ m/\.(?:yml|yaml)$/i) {
                        $n->open_yaml(
                                path => $normalize_path,
                                tag => $input->{normalize}->{tag},
                        );
                }

                foreach my $pos ( 0 ... $input_db->size ) {

                        my $row = $input_db->fetch || next;

                        my $mfn = $row->{'000'}->[0];

                        if (! $mfn || $mfn !~ m#^\d+$#) {
                                $log->warn("record $pos doesn't have valid MFN but '$mfn', using $pos");
                                $mfn = $pos;
                                push @{ $row->{'000'} }, $pos;
                        }

                        my $ds = $n->data_structure($row);

                        $est->add(
                                id => $input->{name} . "/" . $mfn,
                                ds => $ds,
                                type => $config->{hyperestraier}->{type},
                        );

                        $total_rows++;
                }

        };

        $log->info("$total_rows records indexed");

        #
        # add Hyper Estraier links to other databases
        #
        if (ref($db_config->{links}) eq 'ARRAY') {
                foreach my $link (@{ $db_config->{links} }) {
                        $log->info("adding link $database -> $link->{to} [$link->{credit}]");
                        $est->add_link(
                                from => $database,
                                to => $link->{to},
                                credit => $link->{credit},
                        );
                }
        }

}