git.rot13.org Git - dell-switch/blob - sbw-parse.pl

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4 use autodie;
   5
   6 # ./sw-name-mac.sh
   7
   8 # usage: NAME_MAC=/dev/shm/file-with-name-space-mac sbw-parse.pl [optional-switch-snmpbulkwalk-dump]
   9 #
  10 # cat /dev/shm/neighbors.tab | grep MikroTik | tee /dev/stderr | awk '{ print $7 "_" $8 " " $3 }' > /tmp/name-mac
  11 # NAME_MAC=/tmp/name-mac ./sbw-parse.pl
  12
  13 use Data::Dump qw(dump);
  14
  15 $|=1; # flush stdout
  16
  17 my $debug = $ENV{DEBUG} || 0;
  18
  19 my @cols = qw( ifName ifHighSpeed ifAdminStatus ifOperStatus ifType dot1dStpPortPathCost ifAlias );
  20
  21 my $mac2name;
  22
  23 foreach my $name_mac ( qw( /dev/shm/sw-name-mac /dev/shm/wap-name-mac ), $ENV{NAME_MAC} ) {
  24         next unless -e $name_mac;
  25         open(my $f, '<'. $name_mac);
  26         while(<$f>) {
  27                 chomp;
  28                 #my ( $ip, $name, $mac ) = split(/ /,$_);
  29                 my ( $name, $mac ) = split(/ /,$_);
  30                 $mac = lc($mac);
  31                 $mac2name->{$mac} = $name;
  32         }
  33 }
  34
  35 sub mac2name {
  36         my ( $mac, $name ) = @_;
  37
  38         $mac = lc($mac);
  39
  40         if ( exists $mac2name->{$mac} ) {
  41                 my $mac_name = $mac2name->{$mac};
  42                 warn "ERROR: name different $name != $mac_name" if $name && $name ne $mac_name;
  43                 return ( $mac, $mac_name );
  44         }
  45         return ( $mac, $name );
  46 }
  47
  48 warn "# mac2name = ",dump($mac2name) if $debug;
  49
  50
  51 my $sw;
  52
  53 sub fix_mac {
  54         my $mac = shift;
  55         $mac = lc($mac);
  56         $mac =~ s/^([0-9a-f]):/0$1:/;
  57         while ( $mac =~ s/:([0-9a-f]):/:0$1:/g ) {};
  58         $mac =~ s/:([0-9a-f])$/:0$1/;
  59 #       warn "# $mac\n";
  60         return $mac;
  61 }
  62
  63 sub sw_name_mac_port {
  64         my ( $name, $mac, $port ) = @_;
  65         $mac = fix_mac($mac);
  66         if ( exists $mac2name->{$mac} ) {
  67                 my $sw_name = $mac2name->{$mac};
  68                 $sw->{$name}->{port_for_switch}->{$port}->{ $sw_name }++;
  69                 #print "## $name $port $sw_name\n";
  70         }
  71 }
  72
  73 my $gv; # collect for graphviz
  74
  75 my @files = @ARGV;
  76 @files = glob('snmpbulkwalk/*') unless @files;
  77
  78 foreach my $file ( @files ) {
  79         my ( undef, $name ) = split(/\//, $file);
  80         print "# $name $file\n" if $debug;
  81
  82         if ( -s "/dev/shm/$file" ) {
  83                 if ( -M $file < -M "/dev/shm/$file" ) {
  84                         warn "UPDATE $file\n";
  85                         system "cp -pv /dev/shm/$file $file";
  86                 }
  87                 $file="/dev/shm/$file";
  88         } else {
  89                 warn "WARNING: using old file $file\n";
  90         }
  91
  92         open(my $f, '<', $file);
  93         while(<$f>) {
  94                 chomp;
  95                 if ( m/::(sysName|sysLocation|ipDefaultTTL|dot1dStpPriority|dot1dStpTopChanges|dot1dStpDesignatedRoot|dot1dStpRootCost|dot1dStpRootPort|dot1qNumVlans)\./ ) {
  96                         my ( undef, $v ) = split(/ = \w+: /,$_,2);
  97                         $sw->{$name}->{$1} = $v;
  98                 } elsif ( m/::(ifMtu|ifHighSpeed|ifSpeed)\[(\d\d?)\] = (?:INTEGER|Gauge32): (\d+)/ ) {
  99                         $sw->{$name}->{$1}->[$2] = $3;
 100                         # Dell PowerConnect 5548 doeesn't have ifHighSpeed
 101                         if ( $1 eq 'ifSpeed' && ! exists $sw->{$name}->{'ifHighSpeed'}->[$2] ) {
 102                                 $sw->{$name}->{'ifHighSpeed'}->[$2] = $3 / 1_000_000;
 103                         }
 104                 } elsif ( m/::(ifPhysAddress)\[(\d\d?)\] = STRING: ([0-9a-f:]+)/ ) {
 105                         $sw->{$name}->{$1}->[$2] = fix_mac($3);
 106                 } elsif ( m/::(ifDescr|ifName|ifAlias)\[(\d\d?)\] = STRING: (.+)/ ) {
 107                         $sw->{$name}->{$1}->[$2] = $3;
 108                         if ( $1 eq 'ifName' ) {
 109                                 my ( $if_name, $port ) = ($3,$2);
 110                                 $sw->{$name}->{port_name_to_number}->{$if_name} = $port;
 111                         }
 112                         if ( $1 eq 'ifDescr' ) { # some switches miss ifName
 113                                 my ( $if_name, $port ) = ($3,$2);
 114                                 $if_name =~ s/gigabitethernet/ge/;
 115                                 $if_name =~ s/tengigabitethernet/te/;
 116                                 $sw->{$name}->{'ifName'}->[$port] = $if_name
 117                                         if ( ! exists $sw->{name}->{'ifName'} );
 118                                 $sw->{$name}->{port_name_to_number}->{$if_name} = $port
 119                                         if ( ! exists $sw->{$name}->{port_name_to_number}->{$if_name} );
 120                         }
 121                 } elsif ( m/::(ifAdminStatus|ifOperStatus|ifType|dot3StatsDuplexStatus)\[(\d\d?)\] = INTEGER: (\w+)\(/ ) {
 122                         $sw->{$name}->{$1}->[$2] = $3;
 123                 } elsif ( m/::(dot1dStpPortPathCost)\[(\d\d?)\] = INTEGER: (\d+)/ ) {
 124                         $sw->{$name}->{$1}->[$2] = $3;
 125                 } elsif ( m/::(dot1dTpFdbPort)\[STRING: ([0-9a-f:]+)\] = INTEGER: (\d+)/ ) {
 126                         $sw->{$name}->{$1}->{ fix_mac($2) } = $3;
 127                         sw_name_mac_port( $name, $2, $3 );
 128                 } elsif ( m/::(dot1qTpFdbPort)\[(\d+)\]\[STRING: ([0-9a-f:]+)\] = INTEGER: (\d+)/ ) {
 129                         $sw->{$name}->{$1}->{ fix_mac($3) } = [ $4, $2 ]; # port, vlan
 130                         sw_name_mac_port( $name, $3, $4 );
 131                 }
 132
 133                 # dot1qVlanCurrentEgressPorts
 134                 # dot1qVlanCurrentUntaggedPorts
 135                 # dot1qVlanStaticName
 136                 # dot1qVlanStaticEgressPorts
 137                 # dot1qVlanStaticUntaggedPorts
 138                 # dot1qPvid
 139
 140                 # entPhysicalDescr
 141                 # entPhysicalClass
 142
 143                 #print "## $_<--\n";
 144         }
 145         warn "# sw $name = ",dump($sw->{$name}) if $debug;
 146
 147         foreach my $port ( 1 .. $#{ $sw->{$name}->{ifDescr} } ) {
 148                 print "$name $port";
 149                 foreach my $oid ( @cols ) {
 150                         if ( $oid eq 'ifAlias' ) {
 151                                 if ( defined( $sw->{$name}->{$oid}->[$port] ) ) {
 152                                         print " [",$sw->{$name}->{$oid}->[$port],"]";
 153                                 }
 154                         } elsif ( defined $sw->{$name}->{$oid}->[$port] ) {
 155                                 print " ", $sw->{$name}->{$oid}->[$port];
 156                         } else {
 157                                 print " ?";
 158                                 #warn "MISSING $name $oid $port\n";
 159                         }
 160
 161                 }
 162                 if ( exists( $sw->{$name}->{port_for_switch}->{ $port } ) ) {
 163                         my @visible = sort keys %{ $sw->{$name}->{port_for_switch}->{ $port } };
 164                         print " ",join(',', @visible);
 165
 166                         if ( scalar @visible == 1 ) {
 167                                 $gv->{$name}->{$port}->{ $visible[0] }->{ 'no_port' } = [$port,0]; # no port
 168                         }
 169                 }
 170                 print "\n";
 171         }}
 172
 173 # fix ifPhysAddress
 174
 175 # read neighbour visibility from lldp
 176
 177 sub port2number {
 178         my ($name,$port) = @_;
 179
 180         return $port if $port =~ m/^\d+$/;
 181         $port =~ s{bridge\d*/}{};  # remove mikrotik port prefix
 182         $port =~ s{,bridge\d*$}{}; # remove mikrotik port suffix
 183         $port =~ s{,bonding\d*$}{}; # remove mikrotik port suffix
 184
 185         if ( exists $sw->{$name}->{port_name_to_number}->{$port} ) {
 186                 return $sw->{$name}->{port_name_to_number}->{$port};
 187         }
 188
 189         # gigabitethernet1/0/45 or gi1/0/45
 190         if ( $port =~ m{(.+)1/0/(\d+)$} ) {
 191                 my ($type,$port) = ($1,$2);
 192                 if ( $type =~ m{gi}i ) {
 193                         return $port;
 194                 } elsif ( $type =~ m{te}i ) {
 195                         return $port <= 4 ? $port + 10000 : $port;
 196                 } else {
 197                         die "unknown [$type]";
 198                 }
 199         }
 200
 201         # linux
 202         if ( $port =~ m{eth(\d+)} ) {
 203                 return $1;
 204         }
 205
 206         my @fuzzy = grep { m/^$port/ } keys %{ $sw->{$name}->{port_name_to_number} };
 207         if ( scalar @fuzzy == 1 ) {
 208                 return $sw->{$name}->{port_name_to_number}->{$fuzzy[0]}
 209         }
 210
 211         warn "ERROR [$_] can't find port $port for $name in ",dump( $sw->{$name}->{port_name_to_number} );
 212 }
 213
 214 sub fix_sw_name {
 215         my $name = shift;
 216         if ( $name eq 'rack3-lib' ) {
 217                 $name = 'sw-lib-srv';
 218         }
 219         return $name;
 220 }
 221
 222
 223 open(my $n_fh, '<', '/dev/shm/neighbors.tab');
 224 while(<$n_fh>) {
 225         chomp;
 226         my ( $sw1, $port1, undef, $port2, $sw2, undef ) = split(/\t/, $_, 6 );
 227         next if $port2 =~ m/:/; # skip mac in port number (wap lldp leek)
 228         next unless $sw2 && $port2;
 229         $sw1 = fix_sw_name($sw1);
 230         my $port1_nr = port2number( $sw1, $port1 );
 231         my $port2_nr = port2number( $sw2, $port2 );
 232
 233         if ( $sw->{$sw1}->{ifType}->[$port1_nr] ne 'ethernetCsmacd' ) {
 234                 warn "SKIP $sw1 $port1_nr $sw->{$sw1}->{ifType}->[$port1_nr]\n";
 235                 next;
 236         } elsif ( $port1 =~ m{bridge} ) { # skip mikrotik bridges
 237 #               warn "SKIP $sw1 $port1_nr $port1\n";
 238 #               next;
 239         }
 240
 241         $gv->{$sw1}->{$port1_nr}->{$sw2}->{$port2_nr} = [ $port1, $port2 ];
 242         delete $gv->{$sw1}->{$port1_nr}->{$sw2}->{'no_port'} if exists $gv->{$sw1}->{$port1_nr}->{$sw2}->{'no_port'};
 243 }
 244
 245 # FIXME sw-b101 doesn't have lldp so we insert data here manually from pictures
 246 sub fake_gv {
 247         my ($sw1, $p1, $sw2, $p2) = @_;
 248         $gv->{$sw1}->{$p1}->{$sw2}->{$p2} = [ $p1, $p2 ];
 249         $gv->{$sw2}->{$p2}->{$sw1}->{$p1} = [ $p2, $p1 ];
 250 }
 251 delete $gv->{'sw-b101'};
 252 fake_gv( 'sw-b101' => 3, 'sw-b101' => 4 ); # vlan1-to-vlan2 / vlan2-to-vlan1
 253
 254 fake_gv( 'sw-b101' => 21, 'sw-rack2' => 50 );
 255 fake_gv( 'sw-b101' => 23, 'sw-lib-srv' => 48 );
 256 fake_gv( 'sw-b101' => 24, 'sw-rack1' => 48 );
 257
 258 #delete $gv->{'sw-ganeti'};
 259 # spf-16 -> "sw-rack2"        => { 2 => ["16-sfp-uplink-b101,bridge", "te1/0/2"] },
 260
 261 print "# gv = ",dump( $gv );
 262
 263 open(my $dot_fh, '>', '/tmp/network.dot');
 264 print $dot_fh qq|
 265 digraph topology {
 266 graph [ rankdir = LR ]
 267 node [ shape = record ]
 268 edge [ color = "gray" ]
 269 |;
 270
 271 my @edges;
 272 my $node;
 273
 274 foreach my $sw1 ( sort keys %$gv ) {
 275         foreach my $p1 ( sort { $a <=> $b } keys %{ $gv->{$sw1} } ) {
 276                 foreach my $sw2 ( sort keys %{ $gv->{$sw1}->{$p1} } ) {
 277                         if ( $sw1 eq $sw2 ) {
 278                                 warn "SKIP same switch $sw1 == $sw2\n";
 279                                 next;
 280                         }
 281                         #push @{ $node->{$sw1} }, [ $p1, $sw2 ];
 282                         foreach my $p2 ( keys %{ $gv->{$sw1}->{$p1}->{$sw2} } ) {
 283                                 push @edges, [ $sw1, $sw2, $p1, $p2 ];
 284                                 ##push @{ $node->{$sw2} }, [ $p2, $sw1 ];
 285                                 push @{ $node->{$sw1} }, [ $p1, $sw2, $p2 ];
 286                         }
 287                 }
 288         }
 289 }
 290
 291 foreach my $n ( keys %$node ) {
 292         no warnings;
 293         my @port_sw =
 294                 sort { $a->[0] <=> $b->[0] }
 295                 @{ $node->{$n} };
 296         print $dot_fh qq!"$n" [ label="!.uc($n).'|' . join('|', map {
 297                 sprintf "<%d>%2d %s%s", $_->[0], $_->[0], $_->[1], $_->[2] eq 'no_port' ? '' : ' ' . $_->[2]
 298         } @port_sw ) . qq!" ];\n!;
 299 }
 300
 301 foreach my $e ( @edges ) {
 302         no warnings;
 303         print $dot_fh sprintf qq{ "%s":%d -> "%s":%d\n}, $e->[0], $e->[2], $e->[1], $e->[3];
 304 }
 305
 306 print $dot_fh qq|
 307 }
 308 |;
 309
 310 system "dot -Tsvg /tmp/network.dot > /var/www/network.svg";