tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use Modern::Perl;
  44 use CGI qw ( -utf8 );
  45 use C4::Auth;
  46 use C4::Context;
  47 use C4::Output;
  48 use C4::Letters;
  49 use C4::Members::Attributes;
  50
  51 # $protected_letters = protected_letters()
  52 # - return a hashref of letter_codes representing letters that should never be deleted
  53 sub protected_letters {
  54     my $dbh = C4::Context->dbh;
  55     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  56     return { map { $_->[0] => 1 } @{$codes} };
  57 }
  58
  59 our $input       = new CGI;
  60 my $searchfield = $input->param('searchfield');
  61 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  62 our $branchcode  = $input->param('branchcode');
  63 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  64 my $code        = $input->param('code');
  65 my $module      = $input->param('module') || '';
  66 my $content     = $input->param('content');
  67 my $op          = $input->param('op') || '';
  68 my $redirect      = $input->param('redirect');
  69 my $dbh = C4::Context->dbh;
  70
  71 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  72     {
  73         template_name   => 'tools/letter.tt',
  74         query           => $input,
  75         type            => 'intranet',
  76         authnotrequired => 0,
  77         flagsrequired   => { tools => 'edit_notices' },
  78         debug           => 1,
  79     }
  80 );
  81
  82 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  83   ?  C4::Context->userenv()->{'branch'}
  84   : undef;
  85 # we show only the TMPL_VAR names $op
  86
  87 $template->param(
  88     independant_branch => $my_branch,
  89         script_name => $script_name,
  90   searchfield => $searchfield,
  91     branchcode => $branchcode,
  92         action => $script_name
  93 );
  94
  95 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  96     add_validate();
  97     if( $redirect eq "just_save" ){
  98         print $input->redirect("/cgi-bin/koha/tools/letter.pl?op=add_form&branchcode=$branchcode&module=$module&code=$code&redirect=done");
  99         exit;
 100     } else {
 101         $op = q{}; # we return to the default screen for the next operation
 102     }
 103 }
 104 if ($op eq 'copy_form') {
 105     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 106     my $branchcode = $input->param('branchcode');
 107     add_form($oldbranchcode, $module, $code);
 108     $template->param(
 109         oldbranchcode => $oldbranchcode,
 110         branchcode => $branchcode,
 111         copying => 1,
 112         modify => 0,
 113     );
 114 }
 115 elsif ( $op eq 'add_form' ) {
 116     add_form($branchcode, $module, $code);
 117 }
 118 elsif ( $op eq 'delete_confirm' ) {
 119     delete_confirm($branchcode, $module, $code);
 120 }
 121 elsif ( $op eq 'delete_confirmed' ) {
 122     delete_confirmed($branchcode, $module, $code);
 123     $op = q{}; # next operation is to return to default screen
 124 }
 125 else {
 126     default_display($branchcode,$searchfield);
 127 }
 128
 129 # Do this last as delete_confirmed resets
 130 if ($op) {
 131     $template->param($op  => 1);
 132 } else {
 133     $template->param(no_op_set => 1);
 134 }
 135
 136 output_html_with_http_headers $input, $cookie, $template->output;
 137
 138 sub add_form {
 139     my ( $branchcode,$module, $code ) = @_;
 140
 141     my $letters;
 142     # if code has been passed we can identify letter and its an update action
 143     if ($code) {
 144         $letters = C4::Letters::GetLetterTemplates(
 145             {
 146                 branchcode => $branchcode,
 147                 module     => $module,
 148                 code       => $code,
 149             }
 150         );
 151     }
 152
 153     my $message_transport_types = GetMessageTransportTypes();
 154     my $templates = { map { $_ => { message_transport_type => $_ } } sort @$message_transport_types };
 155     my %letters = ( default => { templates => $templates } );
 156
 157     if ( C4::Context->preference('TranslateNotices') ) {
 158         my $translated_languages =
 159           C4::Languages::getTranslatedLanguages( 'opac',
 160             C4::Context->preference('template') );
 161         for my $language (@$translated_languages) {
 162             for my $sublanguage( @{ $language->{sublanguages_loop} } ) {
 163                 if ( $language->{plural} ) {
 164                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 165                         description => $sublanguage->{native_description}
 166                           . ' '
 167                           . $sublanguage->{region_description} . ' ('
 168                           . $sublanguage->{rfc4646_subtag} . ')',
 169                         templates => { %$templates },
 170                     };
 171                 }
 172                 else {
 173                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 174                         description => $sublanguage->{native_description}
 175                           . ' ('
 176                           . $sublanguage->{rfc4646_subtag} . ')',
 177                         templates => { %$templates },
 178                     };
 179                 }
 180             }
 181         }
 182         $template->param( languages => $translated_languages );
 183     }
 184     if ($letters) {
 185         $template->param(
 186             modify     => 1,
 187             code       => $code,
 188         );
 189         my $first_flag_name = 1;
 190         my ( $lang, @templates );
 191         # The letter name is contained into each mtt row.
 192         # So we can only sent the first one to the template.
 193         for my $letter ( @$letters ) {
 194             # The letter_name
 195             if ( $first_flag_name and $letter->{name} ) {
 196                 $template->param(
 197                     letter_name=> $letter->{name},
 198                 );
 199                 $first_flag_name = 0;
 200             }
 201
 202             my $lang = $letter->{lang};
 203             my $mtt = $letter->{message_transport_type};
 204             $letters{ $lang }{templates}{$mtt} = {
 205                 message_transport_type => $letter->{message_transport_type},
 206                 is_html    => $letter->{is_html},
 207                 title      => $letter->{title},
 208                 content    => $letter->{content} // '',
 209             };
 210         }
 211     }
 212     else {
 213         $template->param( adding => 1 );
 214     }
 215
 216     $template->param(
 217         letters => \%letters,
 218     );
 219
 220     my $field_selection;
 221     push @{$field_selection}, add_fields('branches');
 222     if ($module eq 'reserves') {
 223         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 224     }
 225     elsif ( $module eq 'acquisition' ) {
 226         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 227     }
 228     elsif ($module eq 'claimacquisition' || $module eq 'orderacquisition') {
 229         push @{$field_selection}, add_fields('aqbooksellers', 'aqbasket', 'aqorders', 'biblio', 'biblioitems');
 230     }
 231     elsif ($module eq 'claimissues') {
 232         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription');
 233         push @{$field_selection},
 234         {
 235             value => q{},
 236             text => '---BIBLIO---'
 237         };
 238         foreach(qw(title author serial)) {
 239             push @{$field_selection}, {value => "biblio.$_", text => ucfirst $_ };
 240         }
 241     }
 242     elsif ($module eq 'serial') {
 243         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 244     }
 245     elsif ($module eq 'suggestions') {
 246         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 247     }
 248     else {
 249         push @{$field_selection}, add_fields('biblio','biblioitems'),
 250             add_fields('items'),
 251             {value => 'items.content', text => 'items.content'},
 252             {value => 'items.fine',    text => 'items.fine'},
 253             add_fields('borrowers');
 254         if ($module eq 'circulation') {
 255             push @{$field_selection}, add_fields('opac_news');
 256
 257         }
 258
 259         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 260             push @{$field_selection}, add_fields('old_issues');
 261         } else {
 262             push @{$field_selection}, add_fields('issues');
 263         }
 264
 265         if ( $module eq 'circulation' and $code =~ /^AR_/  ) {
 266             push @{$field_selection}, add_fields('article_requests');
 267         }
 268     }
 269
 270     $template->param(
 271         module     => $module,
 272         SQLfieldnames => $field_selection,
 273         branchcode => $branchcode,
 274     );
 275     return;
 276 }
 277
 278 sub add_validate {
 279     my $dbh        = C4::Context->dbh;
 280     my $branchcode    = $input->param('branchcode');
 281     my $module        = $input->param('module');
 282     my $oldmodule     = $input->param('oldmodule');
 283     my $code          = $input->param('code');
 284     my $name          = $input->param('name');
 285     my @mtt           = $input->multi_param('message_transport_type');
 286     my @title         = $input->multi_param('title');
 287     my @content       = $input->multi_param('content');
 288     my @lang          = $input->multi_param('lang');
 289     for my $mtt ( @mtt ) {
 290         my $is_html = $input->param("is_html_$mtt");
 291         my $title   = shift @title;
 292         my $content = shift @content;
 293         my $lang = shift @lang;
 294         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt, $lang );
 295
 296         # getletter can return the default letter even if we pass a branchcode
 297         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 298         if ( $letter and $branchcode and $branchcode ne $letter->{branchcode} ) {
 299             $letter = undef;
 300         }
 301         unless ( $title and $content ) {
 302             # Delete this mtt if no title or content given
 303             delete_confirmed( $branchcode, $oldmodule, $code, $mtt, $lang );
 304             next;
 305         }
 306         elsif ( $letter and $letter->{message_transport_type} eq $mtt and $letter->{lang} eq $lang ) {
 307             $dbh->do(
 308                 q{
 309                     UPDATE letter
 310                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?, lang = ?
 311                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ? AND lang = ?
 312                 },
 313                 undef,
 314                 $branchcode || '', $module, $name, $is_html || 0, $title, $content, $lang,
 315                 $branchcode, $oldmodule, $code, $mtt, $lang
 316             );
 317         } else {
 318             $dbh->do(
 319                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type, lang) VALUES (?,?,?,?,?,?,?,?,?)},
 320                 undef,
 321                 $branchcode || '', $module, $code, $name, $is_html || 0, $title, $content, $mtt, $lang
 322             );
 323         }
 324     }
 325     # set up default display
 326     default_display($branchcode);
 327     return 1;
 328 }
 329
 330 sub delete_confirm {
 331     my ($branchcode, $module, $code) = @_;
 332     my $dbh = C4::Context->dbh;
 333     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 334     my @values = values %$letter;
 335     $template->param(
 336         letter => $letter,
 337     );
 338     return;
 339 }
 340
 341 sub delete_confirmed {
 342     my ($branchcode, $module, $code, $mtt, $lang) = @_;
 343     C4::Letters::DelLetter(
 344         {
 345             branchcode => $branchcode || '',
 346             module     => $module,
 347             code       => $code,
 348             mtt        => $mtt,
 349             lang       => $lang,
 350         }
 351     );
 352     # setup default display for screen
 353     default_display($branchcode);
 354     return;
 355 }
 356
 357 sub retrieve_letters {
 358     my ($branchcode, $searchstring) = @_;
 359
 360     $branchcode = $my_branch if $branchcode && $my_branch;
 361
 362     my $dbh = C4::Context->dbh;
 363     my ($sql, @where, @args);
 364     $sql = "SELECT branchcode, module, code, name, branchname
 365             FROM letter
 366             LEFT OUTER JOIN branches USING (branchcode)
 367     ";
 368     if ($searchstring && $searchstring=~m/(\S+)/) {
 369         $searchstring = $1 . q{%};
 370         push @where, 'code LIKE ?';
 371         push @args, $searchstring;
 372     }
 373     elsif ($branchcode) {
 374         push @where, 'branchcode = ?';
 375         push @args, $branchcode || '';
 376     }
 377     elsif ($my_branch) {
 378         push @where, "(branchcode = ? OR branchcode = '')";
 379         push @args, $my_branch;
 380     }
 381
 382     $sql .= " WHERE ".join(" AND ", @where) if @where;
 383     $sql .= " GROUP BY branchcode,module,code";
 384     $sql .= " ORDER BY module, code, branchcode";
 385
 386     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 387 }
 388
 389 sub default_display {
 390     my ($branchcode, $searchfield) = @_;
 391
 392     unless ( defined $branchcode ) {
 393         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 394             $branchcode = C4::Context::mybranch();
 395         }
 396     }
 397
 398     if ( $searchfield  ) {
 399         $template->param( search      => 1 );
 400     }
 401     my $results = retrieve_letters($branchcode,$searchfield);
 402
 403     my $loop_data = [];
 404     my $protected_letters = protected_letters();
 405     foreach my $row (@{$results}) {
 406         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 407         push @{$loop_data}, $row;
 408
 409     }
 410
 411     $template->param(
 412         letter => $loop_data,
 413         branchcode => $branchcode,
 414     );
 415 }
 416
 417 sub add_fields {
 418     my @tables = @_;
 419     my @fields = ();
 420
 421     for my $table (@tables) {
 422         push @fields, get_columns_for($table);
 423
 424     }
 425     return @fields;
 426 }
 427
 428 sub get_columns_for {
 429     my $table = shift;
 430 # FIXME untranslatable
 431     my %column_map = (
 432         aqbooksellers => '---BOOKSELLERS---',
 433         aqorders      => '---ORDERS---',
 434         serial        => '---SERIALS---',
 435         reserves      => '---HOLDS---',
 436         suggestions   => '---SUGGESTIONS---',
 437     );
 438     my @fields = ();
 439     if (exists $column_map{$table} ) {
 440         push @fields, {
 441             value => q{},
 442             text  => $column_map{$table} ,
 443         };
 444     }
 445     else {
 446         my $tlabel = '---' . uc $table;
 447         $tlabel.= '---';
 448         push @fields, {
 449             value => q{},
 450             text  => $tlabel,
 451         };
 452     }
 453
 454     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 455     my $table_prefix = $table . q|.|;
 456     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 457     for my $row (@{$rows}) {
 458         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 459         push @fields, {
 460             value => $table_prefix . $row->{Field},
 461             text  => $table_prefix . $row->{Field},
 462         }
 463     }
 464     if ($table eq 'borrowers') {
 465         if ( my $attributes = C4::Members::Attributes::GetAttributes() ) {
 466             foreach (@$attributes) {
 467                 push @fields, {
 468                     value => "borrower-attribute:$_",
 469                     text  => "attribute:$_",
 470                 }
 471             }
 472         }
 473     }
 474     return @fields;
 475 }