virtualshelves/addbybiblionumber.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2016 Koha Development Team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 =head1 NAME
  23
  24 addbybiblionumber.pl
  25
  26 =head1 DESCRIPTION
  27
  28     This script allow to add a virtual in a virtual shelf from a biblionumber.
  29
  30 =head1 CGI PARAMETERS
  31
  32 =over 4
  33
  34 =item biblionumber
  35
  36     The biblionumber
  37
  38 =item shelfnumber
  39
  40     the shelfnumber where to add the virtual.
  41
  42 =item newvirtualshelf
  43
  44     if this parameter exists, then it must be equals to the name of the shelf
  45     to add.
  46
  47 =item category
  48
  49     if this script has to add a shelf, it add one with this category.
  50
  51 =item newshelf
  52
  53     if this parameter exists, then we create a new shelf
  54
  55 =back
  56
  57 =cut
  58
  59 use Modern::Perl;
  60
  61 use CGI qw ( -utf8 );
  62 use C4::Biblio;
  63 use C4::Output;
  64 use C4::Auth;
  65
  66 use Koha::Virtualshelves;
  67
  68 my $query           = new CGI;
  69 my $shelfnumber     = $query->param('shelfnumber');
  70 my $newvirtualshelf = $query->param('newvirtualshelf');
  71 my $newshelf        = $query->param('newshelf');
  72 my $category        = $query->param('category');
  73 my $sortfield       = $query->param('sortfield');
  74 my $confirmed       = $query->param('confirmed') || 0;
  75 my ( $errcode, $authorized ) = ( 0, 1 );
  76 my @biblionumbers = $query->multi_param('biblionumber');
  77
  78 if ( @biblionumbers == 0 && $query->param('biblionumbers') ) {
  79     my $str = $query->param('biblionumbers');
  80     @biblionumbers = split '/', $str;
  81 } elsif ( @biblionumbers == 1 && $biblionumbers[0] =~ /\// ) {
  82     @biblionumbers = split '/', $biblionumbers[0];
  83 }
  84
  85 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  86     {   template_name   => "virtualshelves/addbybiblionumber.tt",
  87         query           => $query,
  88         type            => "intranet",
  89         authnotrequired => 0,
  90         flagsrequired   => { catalogue => 1 },
  91     }
  92 );
  93
  94 if ($newvirtualshelf) {
  95     my $shelf = eval {
  96         Koha::Virtualshelf->new(
  97             {
  98                 shelfname => $newvirtualshelf,
  99                 category  => $category,
 100                 sortfield => $sortfield,
 101                 owner     => $loggedinuser,
 102             }
 103         )->store;
 104     };
 105     if ( $@ or not $shelf ) {
 106         $errcode    = 1;
 107         $authorized = 0;
 108     } else {
 109
 110         for my $biblionumber (@biblionumbers) {
 111             $shelf->add_biblio( $biblionumber, $loggedinuser );
 112         }
 113
 114         #Reload the page where you came from
 115         print $query->header;
 116         print "<html><meta http-equiv=\"refresh\" content=\"0\" /><body onload=\"window.opener.location.reload(true);self.close();\"></body></html>";
 117         exit;
 118     }
 119
 120 } elsif ( $shelfnumber && $confirmed ) {
 121     my $shelf = Koha::Virtualshelves->find($shelfnumber);
 122     if ( $shelf->can_biblios_be_added($loggedinuser) ) {
 123         for my $biblionumber (@biblionumbers) {
 124             $shelf->add_biblio( $biblionumber, $loggedinuser );
 125         }
 126
 127         #Close this page and return
 128         print $query->header;
 129         print "<html><meta http-equiv=\"refresh\" content=\"0\" /><body onload=\"self.close();\"></body></html>";
 130         exit;
 131     } else {
 132         $errcode    = 2;    #no perm
 133         $authorized = 0;
 134     }
 135
 136 } elsif ($shelfnumber) {    #still needs confirmation
 137     my $shelf = Koha::Virtualshelves->find($shelfnumber);
 138     if ( $shelf->can_biblios_be_added($loggedinuser) ) {
 139
 140         #confirm adding to specific shelf
 141         $template->param(
 142             singleshelf => 1,
 143             shelfnumber => $shelf->shelfnumber,
 144             shelfname   => $shelf->shelfname,
 145         );
 146     } else {
 147         $authorized = 0;
 148         $errcode    = 2;    #no perm
 149     }
 150
 151 } else {
 152     my $private_shelves = Koha::Virtualshelves->search(
 153         {   category => 1,
 154             owner    => $loggedinuser,
 155             allow_change_from_owner => 1,
 156         },
 157         { order_by => 'shelfname' }
 158     );
 159     my $shelves_shared_with_me = Koha::Virtualshelves->search(
 160         {   category                            => 1,
 161             'virtualshelfshares.borrowernumber' => $loggedinuser,
 162             allow_change_from_others            => 1,
 163         },
 164         { join => 'virtualshelfshares', }
 165     );
 166     my $public_shelves = Koha::Virtualshelves->search(
 167         {   category => 2,
 168             -or      => [
 169                 -and => {
 170                     allow_change_from_owner => 1,
 171                     owner     => $loggedinuser,
 172                 },
 173                 allow_change_from_others => 1,
 174             ],
 175         },
 176         { order_by => 'shelfname' }
 177     );
 178     $template->param(
 179         private_shelves                => $private_shelves,
 180         private_shelves_shared_with_me => $shelves_shared_with_me,
 181         public_shelves                 => $public_shelves,
 182     );
 183
 184 }
 185
 186 my @biblios;
 187 for my $biblionumber (@biblionumbers) {
 188     my $data = GetBiblioData($biblionumber);
 189     push(
 190         @biblios,
 191         {   biblionumber => $biblionumber,
 192             title        => $data->{'title'},
 193             author       => $data->{'author'},
 194         }
 195     );
 196 }
 197 $template->param(
 198     multiple => ( scalar(@biblios) > 1 ),
 199     total    => scalar @biblios,
 200     biblios  => \@biblios,
 201 );
 202
 203 $template->param(
 204     newshelf => $newshelf || 0,
 205     authorized => $authorized,
 206     errcode    => $errcode,
 207 );
 208 output_html_with_http_headers $query, $cookie, $template->output;