+use C4::Branch;
+require C4::Reserves;
+use C4::Charset;
+
+use vars qw($VERSION @ISA @EXPORT);
+
+BEGIN {
+ $VERSION = 3.01;
+
+ require Exporter;
+ @ISA = qw( Exporter );
+
+ # function exports
+ @EXPORT = qw(
+ GetItem
+ AddItemFromMarc
+ AddItem
+ AddItemBatchFromMarc
+ ModItemFromMarc
+ ModItem
+ ModDateLastSeen
+ ModItemTransfer
+ DelItem
+ DelItemCheck
+
+ CheckItemPreSave
+
+ GetItemStatus
+ GetItemLocation
+ GetLostItems
+ GetItemsForInventory
+ GetItemsCount
+ GetItemInfosOf
+ GetItemsByBiblioitemnumber
+ GetItemsInfo
+ get_itemnumbers_of
+ GetItemnumberFromBarcode
+ );
+}
+
+=head1 NAME
+
+C4::Items - item management functions
+
+=head1 DESCRIPTION
+
+This module contains an API for manipulating item
+records in Koha, and is used by cataloguing, circulation,
+acquisitions, and serials management.
+
+A Koha item record is stored in two places: the
+items table and embedded in a MARC tag in the XML
+version of the associated bib record in C<biblioitems.marcxml>.
+This is done to allow the item information to be readily
+indexed (e.g., by Zebra), but means that each item
+modification transaction must keep the items table
+and the MARC XML in sync at all times.
+
+Consequently, all code that creates, modifies, or deletes
+item records B<must> use an appropriate function from
+C<C4::Items>. If no existing function is suitable, it is
+better to add one to C<C4::Items> than to use add
+one-off SQL statements to add or modify items.
+
+The items table will be considered authoritative. In other
+words, if there is ever a discrepancy between the items
+table and the MARC XML, the items table should be considered
+accurate.
+
+=head1 HISTORICAL NOTE
+
+Most of the functions in C<C4::Items> were originally in
+the C<C4::Biblio> module.
+
+=head1 CORE EXPORTED FUNCTIONS
+
+The following functions are meant for use by users
+of C<C4::Items>
+
+=cut
+
+=head2 GetItem
+
+=over 4
+
+$item = GetItem($itemnumber,$barcode,$serial);
+
+=back
+
+Return item information, for a given itemnumber or barcode.
+The return value is a hashref mapping item column
+names to values. If C<$serial> is true, include serial publication data.
+
+=cut
+
+sub GetItem {
+ my ($itemnumber,$barcode, $serial) = @_;
+ my $dbh = C4::Context->dbh;
+ my $data;
+ if ($itemnumber) {
+ my $sth = $dbh->prepare("
+ SELECT * FROM items
+ WHERE itemnumber = ?");
+ $sth->execute($itemnumber);
+ $data = $sth->fetchrow_hashref;
+ } else {
+ my $sth = $dbh->prepare("
+ SELECT * FROM items
+ WHERE barcode = ?"
+ );
+ $sth->execute($barcode);
+ $data = $sth->fetchrow_hashref;
+ }
+ if ( $serial) {
+ my $ssth = $dbh->prepare("SELECT serialseq,publisheddate from serialitems left join serial on serialitems.serialid=serial.serialid where serialitems.itemnumber=?");
+ $ssth->execute($data->{'itemnumber'}) ;
+ ($data->{'serialseq'} , $data->{'publisheddate'}) = $ssth->fetchrow_array();
+ warn $data->{'serialseq'} , $data->{'publisheddate'};
+ }
+ #if we don't have an items.itype, use biblioitems.itemtype.
+ if( ! $data->{'itype'} ) {
+ my $sth = $dbh->prepare("SELECT itemtype FROM biblioitems WHERE biblionumber = ?");
+ $sth->execute($data->{'biblionumber'});
+ ($data->{'itype'}) = $sth->fetchrow_array;
+ }
+ return $data;
+} # sub GetItem
+
+=head2 AddItemFromMarc
+
+=over 4
+
+my ($biblionumber, $biblioitemnumber, $itemnumber)
+ = AddItemFromMarc($source_item_marc, $biblionumber);
+
+=back
+
+Given a MARC::Record object containing an embedded item
+record and a biblionumber, create a new item record.
+
+=cut
+
+sub AddItemFromMarc {
+ my ( $source_item_marc, $biblionumber ) = @_;
+ my $dbh = C4::Context->dbh;
+
+ # parse item hash from MARC
+ my $frameworkcode = GetFrameworkCode( $biblionumber );
+ my $item = &TransformMarcToKoha( $dbh, $source_item_marc, $frameworkcode );
+ my $unlinked_item_subfields = _get_unlinked_item_subfields($source_item_marc, $frameworkcode);
+ return AddItem($item, $biblionumber, $dbh, $frameworkcode, $unlinked_item_subfields);
+}
+
+=head2 AddItem
+
+=over 4
+
+my ($biblionumber, $biblioitemnumber, $itemnumber)
+ = AddItem($item, $biblionumber[, $dbh, $frameworkcode, $unlinked_item_subfields]);
+
+=back
+
+Given a hash containing item column names as keys,
+create a new Koha item record.
+
+The first two optional parameters (C<$dbh> and C<$frameworkcode>)
+do not need to be supplied for general use; they exist
+simply to allow them to be picked up from AddItemFromMarc.
+
+The final optional parameter, C<$unlinked_item_subfields>, contains
+an arrayref containing subfields present in the original MARC
+representation of the item (e.g., from the item editor) that are
+not mapped to C<items> columns directly but should instead
+be stored in C<items.more_subfields_xml> and included in
+the biblio items tag for display and indexing.
+
+=cut
+
+sub AddItem {
+ my $item = shift;
+ my $biblionumber = shift;
+
+ my $dbh = @_ ? shift : C4::Context->dbh;
+ my $frameworkcode = @_ ? shift : GetFrameworkCode( $biblionumber );
+ my $unlinked_item_subfields;
+ if (@_) {
+ $unlinked_item_subfields = shift
+ };
+
+ # needs old biblionumber and biblioitemnumber
+ $item->{'biblionumber'} = $biblionumber;
+ my $sth = $dbh->prepare("SELECT biblioitemnumber FROM biblioitems WHERE biblionumber=?");
+ $sth->execute( $item->{'biblionumber'} );
+ ($item->{'biblioitemnumber'}) = $sth->fetchrow;
+
+ _set_defaults_for_add($item);
+ _set_derived_columns_for_add($item);
+ $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
+ # FIXME - checks here
+ unless ( $item->{itype} ) { # default to biblioitem.itemtype if no itype
+ my $itype_sth = $dbh->prepare("SELECT itemtype FROM biblioitems WHERE biblionumber = ?");
+ $itype_sth->execute( $item->{'biblionumber'} );
+ ( $item->{'itype'} ) = $itype_sth->fetchrow_array;
+ }
+
+ my ( $itemnumber, $error ) = _koha_new_item( $item, $item->{barcode} );
+ $item->{'itemnumber'} = $itemnumber;
+
+ # create MARC tag representing item and add to bib
+ my $new_item_marc = _marc_from_item_hash($item, $frameworkcode, $unlinked_item_subfields);
+ _add_item_field_to_biblio($new_item_marc, $item->{'biblionumber'}, $frameworkcode );
+
+ logaction("CATALOGUING", "ADD", $itemnumber, "item") if C4::Context->preference("CataloguingLog");
+
+ return ($item->{biblionumber}, $item->{biblioitemnumber}, $itemnumber);
+}
+
+=head2 AddItemBatchFromMarc
+
+=over 4
+
+($itemnumber_ref, $error_ref) = AddItemBatchFromMarc($record, $biblionumber, $biblioitemnumber, $frameworkcode);
+
+=back
+
+Efficiently create item records from a MARC biblio record with
+embedded item fields. This routine is suitable for batch jobs.
+
+This API assumes that the bib record has already been
+saved to the C<biblio> and C<biblioitems> tables. It does
+not expect that C<biblioitems.marc> and C<biblioitems.marcxml>
+are populated, but it will do so via a call to ModBibiloMarc.
+
+The goal of this API is to have a similar effect to using AddBiblio
+and AddItems in succession, but without inefficient repeated
+parsing of the MARC XML bib record.
+
+This function returns an arrayref of new itemsnumbers and an arrayref of item
+errors encountered during the processing. Each entry in the errors
+list is a hashref containing the following keys:
+
+=over 2
+
+=item item_sequence
+
+Sequence number of original item tag in the MARC record.
+
+=item item_barcode
+
+Item barcode, provide to assist in the construction of
+useful error messages.
+
+=item error_condition
+
+Code representing the error condition. Can be 'duplicate_barcode',
+'invalid_homebranch', or 'invalid_holdingbranch'.
+
+=item error_information
+
+Additional information appropriate to the error condition.
+
+=back
+
+=cut
+
+sub AddItemBatchFromMarc {
+ my ($record, $biblionumber, $biblioitemnumber, $frameworkcode) = @_;
+ my $error;
+ my @itemnumbers = ();
+ my @errors = ();
+ my $dbh = C4::Context->dbh;
+
+ # loop through the item tags and start creating items
+ my @bad_item_fields = ();
+ my ($itemtag, $itemsubfield) = &GetMarcFromKohaField("items.itemnumber",'');
+ my $item_sequence_num = 0;
+ ITEMFIELD: foreach my $item_field ($record->field($itemtag)) {
+ $item_sequence_num++;
+ # we take the item field and stick it into a new
+ # MARC record -- this is required so far because (FIXME)
+ # TransformMarcToKoha requires a MARC::Record, not a MARC::Field
+ # and there is no TransformMarcFieldToKoha
+ my $temp_item_marc = MARC::Record->new();
+ $temp_item_marc->append_fields($item_field);
+
+ # add biblionumber and biblioitemnumber
+ my $item = TransformMarcToKoha( $dbh, $temp_item_marc, $frameworkcode, 'items' );
+ my $unlinked_item_subfields = _get_unlinked_item_subfields($temp_item_marc, $frameworkcode);
+ $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
+ $item->{'biblionumber'} = $biblionumber;
+ $item->{'biblioitemnumber'} = $biblioitemnumber;
+
+ # check for duplicate barcode
+ my %item_errors = CheckItemPreSave($item);
+ if (%item_errors) {
+ push @errors, _repack_item_errors($item_sequence_num, $item, \%item_errors);
+ push @bad_item_fields, $item_field;
+ next ITEMFIELD;
+ }
+
+ _set_defaults_for_add($item);
+ _set_derived_columns_for_add($item);
+ my ( $itemnumber, $error ) = _koha_new_item( $item, $item->{barcode} );
+ warn $error if $error;
+ push @itemnumbers, $itemnumber; # FIXME not checking error
+ $item->{'itemnumber'} = $itemnumber;
+
+ logaction("CATALOGUING", "ADD", $itemnumber, "item") if C4::Context->preference("CataloguingLog");
+
+ my $new_item_marc = _marc_from_item_hash($item, $frameworkcode, $unlinked_item_subfields);
+ $item_field->replace_with($new_item_marc->field($itemtag));
+ }
+
+ # remove any MARC item fields for rejected items
+ foreach my $item_field (@bad_item_fields) {
+ $record->delete_field($item_field);
+ }
+
+ # update the MARC biblio
+ $biblionumber = ModBiblioMarc( $record, $biblionumber, $frameworkcode );
+
+ return (\@itemnumbers, \@errors);
+}
+
+=head2 ModItemFromMarc
+
+=over 4
+
+ModItemFromMarc($item_marc, $biblionumber, $itemnumber);
+
+=back
+
+This function updates an item record based on a supplied
+C<MARC::Record> object containing an embedded item field.
+This API is meant for the use of C<additem.pl>; for
+other purposes, C<ModItem> should be used.
+
+This function uses the hash %default_values_for_mod_from_marc,
+which contains default values for item fields to
+apply when modifying an item. This is needed beccause
+if an item field's value is cleared, TransformMarcToKoha
+does not include the column in the
+hash that's passed to ModItem, which without
+use of this hash makes it impossible to clear
+an item field's value. See bug 2466.
+
+Note that only columns that can be directly
+changed from the cataloging and serials
+item editors are included in this hash.
+
+=cut
+
+my %default_values_for_mod_from_marc = (
+ barcode => undef,
+ booksellerid => undef,
+ ccode => undef,
+ 'items.cn_source' => undef,
+ copynumber => undef,
+ damaged => 0,
+ dateaccessioned => undef,
+ enumchron => undef,
+ holdingbranch => undef,
+ homebranch => undef,
+ itemcallnumber => undef,
+ itemlost => 0,
+ itemnotes => undef,
+ itype => undef,
+ location => undef,
+ materials => undef,
+ notforloan => 0,
+ paidfor => undef,
+ price => undef,
+ replacementprice => undef,
+ replacementpricedate => undef,
+ restricted => undef,
+ stack => undef,
+ uri => undef,
+ wthdrawn => 0,
+);
+
+sub ModItemFromMarc {
+ my $item_marc = shift;
+ my $biblionumber = shift;
+ my $itemnumber = shift;
+
+ my $dbh = C4::Context->dbh;
+ my $frameworkcode = GetFrameworkCode( $biblionumber );
+ my $item = &TransformMarcToKoha( $dbh, $item_marc, $frameworkcode );
+ foreach my $item_field (keys %default_values_for_mod_from_marc) {
+ $item->{$item_field} = $default_values_for_mod_from_marc{$item_field} unless exists $item->{$item_field};
+ }
+ my $unlinked_item_subfields = _get_unlinked_item_subfields($item_marc, $frameworkcode);
+
+ return ModItem($item, $biblionumber, $itemnumber, $dbh, $frameworkcode, $unlinked_item_subfields);
+}
+
+=head2 ModItem
+
+=over 4
+
+ModItem({ column => $newvalue }, $biblionumber, $itemnumber[, $original_item_marc]);
+
+=back
+
+Change one or more columns in an item record and update
+the MARC representation of the item.
+
+The first argument is a hashref mapping from item column
+names to the new values. The second and third arguments
+are the biblionumber and itemnumber, respectively.
+
+The fourth, optional parameter, C<$unlinked_item_subfields>, contains
+an arrayref containing subfields present in the original MARC
+representation of the item (e.g., from the item editor) that are
+not mapped to C<items> columns directly but should instead
+be stored in C<items.more_subfields_xml> and included in
+the biblio items tag for display and indexing.
+
+If one of the changed columns is used to calculate
+the derived value of a column such as C<items.cn_sort>,
+this routine will perform the necessary calculation
+and set the value.
+
+=cut
+
+sub ModItem {
+ my $item = shift;
+ my $biblionumber = shift;
+ my $itemnumber = shift;
+
+ # if $biblionumber is undefined, get it from the current item
+ unless (defined $biblionumber) {
+ $biblionumber = _get_single_item_column('biblionumber', $itemnumber);
+ }
+
+ my $dbh = @_ ? shift : C4::Context->dbh;
+ my $frameworkcode = @_ ? shift : GetFrameworkCode( $biblionumber );
+
+ my $unlinked_item_subfields;
+ if (@_) {
+ $unlinked_item_subfields = shift;
+ $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
+ };
+
+ $item->{'itemnumber'} = $itemnumber or return undef;
+ _set_derived_columns_for_mod($item);
+ _do_column_fixes_for_mod($item);
+ # FIXME add checks
+ # duplicate barcode
+ # attempt to change itemnumber
+ # attempt to change biblionumber (if we want
+ # an API to relink an item to a different bib,
+ # it should be a separate function)
+
+ # update items table
+ _koha_modify_item($item);
+
+ # update biblio MARC XML
+ my $whole_item = GetItem($itemnumber) or die "FAILED GetItem($itemnumber)";
+
+ unless (defined $unlinked_item_subfields) {
+ $unlinked_item_subfields = _parse_unlinked_item_subfields_from_xml($whole_item->{'more_subfields_xml'});
+ }
+ my $new_item_marc = _marc_from_item_hash($whole_item, $frameworkcode, $unlinked_item_subfields)
+ or die "FAILED _marc_from_item_hash($whole_item, $frameworkcode)";
+
+ _replace_item_field_in_biblio($new_item_marc, $biblionumber, $itemnumber, $frameworkcode);
+ ($new_item_marc eq '0') and die "$new_item_marc is '0', not hashref"; # logaction line would crash anyway
+ logaction("CATALOGUING", "MODIFY", $itemnumber, $new_item_marc->as_formatted) if C4::Context->preference("CataloguingLog");
+}
+
+=head2 ModItemTransfer
+
+=over 4
+
+ModItemTransfer($itenumber, $frombranch, $tobranch);
+
+=back
+
+Marks an item as being transferred from one branch
+to another.
+
+=cut
+
+sub ModItemTransfer {
+ my ( $itemnumber, $frombranch, $tobranch ) = @_;
+
+ my $dbh = C4::Context->dbh;
+
+ #new entry in branchtransfers....
+ my $sth = $dbh->prepare(
+ "INSERT INTO branchtransfers (itemnumber, frombranch, datesent, tobranch)
+ VALUES (?, ?, NOW(), ?)");
+ $sth->execute($itemnumber, $frombranch, $tobranch);
+
+ ModItem({ holdingbranch => $tobranch }, undef, $itemnumber);
+ ModDateLastSeen($itemnumber);
+ return;
+}
+
+=head2 ModDateLastSeen
+
+=over 4
+
+ModDateLastSeen($itemnum);
+
+=back
+
+Mark item as seen. Is called when an item is issued, returned or manually marked during inventory/stocktaking.
+C<$itemnum> is the item number
+
+=cut
+
+sub ModDateLastSeen {
+ my ($itemnumber) = @_;
+
+ my $today = C4::Dates->new();
+ ModItem({ itemlost => 0, datelastseen => $today->output("iso") }, undef, $itemnumber);
+}
+
+=head2 DelItem
+
+=over 4
+
+DelItem($biblionumber, $itemnumber);
+
+=back
+
+Exported function (core API) for deleting an item record in Koha.
+
+=cut
+
+sub DelItem {
+ my ( $dbh, $biblionumber, $itemnumber ) = @_;
+
+ # FIXME check the item has no current issues
+
+ _koha_delete_item( $dbh, $itemnumber );
+
+ # get the MARC record
+ my $record = GetMarcBiblio($biblionumber);
+ my $frameworkcode = GetFrameworkCode($biblionumber);
+
+ # backup the record
+ my $copy2deleted = $dbh->prepare("UPDATE deleteditems SET marc=? WHERE itemnumber=?");
+ $copy2deleted->execute( $record->as_usmarc(), $itemnumber );
+
+ #search item field code
+ my ( $itemtag, $itemsubfield ) = GetMarcFromKohaField("items.itemnumber",$frameworkcode);
+ my @fields = $record->field($itemtag);
+
+ # delete the item specified
+ foreach my $field (@fields) {
+ if ( $field->subfield($itemsubfield) eq $itemnumber ) {
+ $record->delete_field($field);
+ }
+ }
+ &ModBiblioMarc( $record, $biblionumber, $frameworkcode );
+ logaction("CATALOGUING", "DELETE", $itemnumber, "item") if C4::Context->preference("CataloguingLog");
+}
+
+=head2 DelItemCheck
+
+=over 4
+
+DelItemCheck($dbh, $biblionumber, $itemnumber);
+
+=back
+
+Exported function (core API) for deleting an item record in Koha if there no current issue.
+
+=cut
+
+sub DelItemCheck {
+ my ( $dbh, $biblionumber, $itemnumber ) = @_;
+ my $error;
+
+ # check that there is no issue on this item before deletion.
+ my $sth=$dbh->prepare("select * from issues i where i.itemnumber=?");
+ $sth->execute($itemnumber);
+
+ my $onloan=$sth->fetchrow;
+
+ $sth->finish();
+ if ($onloan){
+ $error = "book_on_loan"
+ }else{
+ # check it doesnt have a waiting reserve
+ $sth=$dbh->prepare("SELECT * FROM reserves WHERE found = 'W' AND itemnumber = ?");
+ $sth->execute($itemnumber);
+ my $reserve=$sth->fetchrow;
+ $sth->finish();
+ if ($reserve){
+ $error = "book_reserved";
+ }else{
+ DelItem($dbh, $biblionumber, $itemnumber);
+ return 1;
+ }
+ }
+ return $error;
+}
+
+=head2 CheckItemPreSave
+
+=over 4
+
+ my $item_ref = TransformMarcToKoha($marc, 'items');
+ # do stuff
+ my %errors = CheckItemPreSave($item_ref);
+ if (exists $errors{'duplicate_barcode'}) {
+ print "item has duplicate barcode: ", $errors{'duplicate_barcode'}, "\n";
+ } elsif (exists $errors{'invalid_homebranch'}) {
+ print "item has invalid home branch: ", $errors{'invalid_homebranch'}, "\n";
+ } elsif (exists $errors{'invalid_holdingbranch'}) {
+ print "item has invalid holding branch: ", $errors{'invalid_holdingbranch'}, "\n";
+ } else {
+ print "item is OK";
+ }
+
+=back
+
+Given a hashref containing item fields, determine if it can be
+inserted or updated in the database. Specifically, checks for
+database integrity issues, and returns a hash containing any
+of the following keys, if applicable.
+
+=over 2
+
+=item duplicate_barcode
+
+Barcode, if it duplicates one already found in the database.
+
+=item invalid_homebranch
+
+Home branch, if not defined in branches table.
+
+=item invalid_holdingbranch
+
+Holding branch, if not defined in branches table.
+
+=back
+
+This function does NOT implement any policy-related checks,
+e.g., whether current operator is allowed to save an
+item that has a given branch code.
+
+=cut
+
+sub CheckItemPreSave {
+ my $item_ref = shift;
+
+ my %errors = ();
+
+ # check for duplicate barcode
+ if (exists $item_ref->{'barcode'} and defined $item_ref->{'barcode'}) {
+ my $existing_itemnumber = GetItemnumberFromBarcode($item_ref->{'barcode'});
+ if ($existing_itemnumber) {
+ if (!exists $item_ref->{'itemnumber'} # new item
+ or $item_ref->{'itemnumber'} != $existing_itemnumber) { # existing item
+ $errors{'duplicate_barcode'} = $item_ref->{'barcode'};
+ }
+ }
+ }
+
+ # check for valid home branch
+ if (exists $item_ref->{'homebranch'} and defined $item_ref->{'homebranch'}) {
+ my $branch_name = GetBranchName($item_ref->{'homebranch'});
+ unless (defined $branch_name) {
+ # relies on fact that branches.branchname is a non-NULL column,
+ # so GetBranchName returns undef only if branch does not exist
+ $errors{'invalid_homebranch'} = $item_ref->{'homebranch'};
+ }
+ }
+
+ # check for valid holding branch
+ if (exists $item_ref->{'holdingbranch'} and defined $item_ref->{'holdingbranch'}) {
+ my $branch_name = GetBranchName($item_ref->{'holdingbranch'});
+ unless (defined $branch_name) {
+ # relies on fact that branches.branchname is a non-NULL column,
+ # so GetBranchName returns undef only if branch does not exist
+ $errors{'invalid_holdingbranch'} = $item_ref->{'holdingbranch'};
+ }
+ }
+
+ return %errors;
+
+}
+
+=head1 EXPORTED SPECIAL ACCESSOR FUNCTIONS
+
+The following functions provide various ways of
+getting an item record, a set of item records, or
+lists of authorized values for certain item fields.
+
+Some of the functions in this group are candidates
+for refactoring -- for example, some of the code
+in C<GetItemsByBiblioitemnumber> and C<GetItemsInfo>
+has copy-and-paste work.
+
+=cut
+
+=head2 GetItemStatus
+
+=over 4
+
+$itemstatushash = GetItemStatus($fwkcode);
+
+=back
+
+Returns a list of valid values for the
+C<items.notforloan> field.
+
+NOTE: does B<not> return an individual item's
+status.
+
+Can be MARC dependant.
+fwkcode is optional.
+But basically could be can be loan or not
+Create a status selector with the following code
+
+=head3 in PERL SCRIPT
+
+=over 4
+
+my $itemstatushash = getitemstatus;
+my @itemstatusloop;
+foreach my $thisstatus (keys %$itemstatushash) {
+ my %row =(value => $thisstatus,
+ statusname => $itemstatushash->{$thisstatus}->{'statusname'},
+ );
+ push @itemstatusloop, \%row;
+}
+$template->param(statusloop=>\@itemstatusloop);
+
+=back
+
+=head3 in TEMPLATE
+
+=over 4
+
+<select name="statusloop">
+ <option value="">Default</option>
+<!-- TMPL_LOOP name="statusloop" -->
+ <option value="<!-- TMPL_VAR name="value" -->" <!-- TMPL_IF name="selected" -->selected<!-- /TMPL_IF -->><!-- TMPL_VAR name="statusname" --></option>
+<!-- /TMPL_LOOP -->
+</select>
+
+=back
+
+=cut
+
+sub GetItemStatus {
+
+ # returns a reference to a hash of references to status...
+ my ($fwk) = @_;
+ my %itemstatus;
+ my $dbh = C4::Context->dbh;
+ my $sth;
+ $fwk = '' unless ($fwk);
+ my ( $tag, $subfield ) =
+ GetMarcFromKohaField( "items.notforloan", $fwk );
+ if ( $tag and $subfield ) {
+ my $sth =
+ $dbh->prepare(
+ "SELECT authorised_value
+ FROM marc_subfield_structure
+ WHERE tagfield=?
+ AND tagsubfield=?
+ AND frameworkcode=?
+ "
+ );
+ $sth->execute( $tag, $subfield, $fwk );
+ if ( my ($authorisedvaluecat) = $sth->fetchrow ) {
+ my $authvalsth =
+ $dbh->prepare(
+ "SELECT authorised_value,lib
+ FROM authorised_values
+ WHERE category=?
+ ORDER BY lib
+ "
+ );
+ $authvalsth->execute($authorisedvaluecat);
+ while ( my ( $authorisedvalue, $lib ) = $authvalsth->fetchrow ) {
+ $itemstatus{$authorisedvalue} = $lib;
+ }
+ $authvalsth->finish;
+ return \%itemstatus;
+ exit 1;
+ }
+ else {
+
+ #No authvalue list
+ # build default
+ }
+ $sth->finish;
+ }
+
+ #No authvalue list
+ #build default
+ $itemstatus{"1"} = "Not For Loan";
+ return \%itemstatus;
+}
+
+=head2 GetItemLocation
+
+=over 4
+
+$itemlochash = GetItemLocation($fwk);
+
+=back
+
+Returns a list of valid values for the
+C<items.location> field.
+
+NOTE: does B<not> return an individual item's
+location.
+
+where fwk stands for an optional framework code.
+Create a location selector with the following code
+
+=head3 in PERL SCRIPT
+
+=over 4
+
+my $itemlochash = getitemlocation;
+my @itemlocloop;
+foreach my $thisloc (keys %$itemlochash) {
+ my $selected = 1 if $thisbranch eq $branch;
+ my %row =(locval => $thisloc,
+ selected => $selected,
+ locname => $itemlochash->{$thisloc},
+ );
+ push @itemlocloop, \%row;
+}
+$template->param(itemlocationloop => \@itemlocloop);
+
+=back
+
+=head3 in TEMPLATE
+
+=over 4
+
+<select name="location">
+ <option value="">Default</option>
+<!-- TMPL_LOOP name="itemlocationloop" -->
+ <option value="<!-- TMPL_VAR name="locval" -->" <!-- TMPL_IF name="selected" -->selected<!-- /TMPL_IF -->><!-- TMPL_VAR name="locname" --></option>
+<!-- /TMPL_LOOP -->
+</select>
+
+=back
+
+=cut
+
+sub GetItemLocation {
+
+ # returns a reference to a hash of references to location...
+ my ($fwk) = @_;
+ my %itemlocation;
+ my $dbh = C4::Context->dbh;
+ my $sth;
+ $fwk = '' unless ($fwk);
+ my ( $tag, $subfield ) =
+ GetMarcFromKohaField( "items.location", $fwk );
+ if ( $tag and $subfield ) {
+ my $sth =
+ $dbh->prepare(
+ "SELECT authorised_value
+ FROM marc_subfield_structure
+ WHERE tagfield=?
+ AND tagsubfield=?
+ AND frameworkcode=?"
+ );
+ $sth->execute( $tag, $subfield, $fwk );
+ if ( my ($authorisedvaluecat) = $sth->fetchrow ) {
+ my $authvalsth =
+ $dbh->prepare(
+ "SELECT authorised_value,lib
+ FROM authorised_values
+ WHERE category=?
+ ORDER BY lib"
+ );
+ $authvalsth->execute($authorisedvaluecat);
+ while ( my ( $authorisedvalue, $lib ) = $authvalsth->fetchrow ) {
+ $itemlocation{$authorisedvalue} = $lib;
+ }
+ $authvalsth->finish;
+ return \%itemlocation;
+ exit 1;
+ }
+ else {
+
+ #No authvalue list
+ # build default
+ }
+ $sth->finish;
+ }
+
+ #No authvalue list
+ #build default
+ $itemlocation{"1"} = "Not For Loan";
+ return \%itemlocation;
+}
+
+=head2 GetLostItems
+
+=over 4
+
+$items = GetLostItems( $where, $orderby );
+
+=back
+
+This function gets a list of lost items.
+
+=over 2
+
+=item input:
+
+C<$where> is a hashref. it containts a field of the items table as key
+and the value to match as value. For example:
+
+{ barcode => 'abc123',
+ homebranch => 'CPL', }
+
+C<$orderby> is a field of the items table by which the resultset
+should be orderd.
+
+=item return:
+
+C<$items> is a reference to an array full of hashrefs with columns
+from the "items" table as keys.
+
+=item usage in the perl script:
+
+my $where = { barcode => '0001548' };
+my $items = GetLostItems( $where, "homebranch" );
+$template->param( itemsloop => $items );
+
+=back
+
+=cut
+
+sub GetLostItems {
+ # Getting input args.
+ my $where = shift;
+ my $orderby = shift;
+ my $dbh = C4::Context->dbh;
+
+ my $query = "
+ SELECT *
+ FROM items
+ LEFT JOIN biblio ON (items.biblionumber = biblio.biblionumber)
+ LEFT JOIN biblioitems ON (items.biblionumber = biblioitems.biblionumber)
+ LEFT JOIN authorised_values ON (items.itemlost = authorised_values.authorised_value)
+ WHERE
+ authorised_values.category = 'LOST'
+ AND itemlost IS NOT NULL
+ AND itemlost <> 0
+ ";
+ my @query_parameters;
+ foreach my $key (keys %$where) {
+ $query .= " AND $key LIKE ?";
+ push @query_parameters, "%$where->{$key}%";
+ }
+ my @ordervalues = qw/title author homebranch itype barcode price replacementprice lib datelastseen location/;
+
+ if ( defined $orderby && grep($orderby, @ordervalues)) {
+ $query .= ' ORDER BY '.$orderby;
+ }
+
+ my $sth = $dbh->prepare($query);
+ $sth->execute( @query_parameters );
+ my $items = [];
+ while ( my $row = $sth->fetchrow_hashref ){
+ push @$items, $row;
+ }
+ return $items;
+}
+
+=head2 GetItemsForInventory
+
+=over 4
+
+$itemlist = GetItemsForInventory($minlocation, $maxlocation, $location, $itemtype $datelastseen, $branch, $offset, $size);
+
+=back
+
+Retrieve a list of title/authors/barcode/callnumber, for biblio inventory.
+
+The sub returns a reference to a list of hashes, each containing
+itemnumber, author, title, barcode, item callnumber, and date last
+seen. It is ordered by callnumber then title.
+
+The required minlocation & maxlocation parameters are used to specify a range of item callnumbers
+the datelastseen can be used to specify that you want to see items not seen since a past date only.
+offset & size can be used to retrieve only a part of the whole listing (defaut behaviour)
+
+=cut
+
+sub GetItemsForInventory {
+ my ( $minlocation, $maxlocation,$location, $itemtype, $ignoreissued, $datelastseen, $branch, $offset, $size ) = @_;
+ my $dbh = C4::Context->dbh;
+ my ( @bind_params, @where_strings );
+
+ my $query = <<'END_SQL';
+SELECT items.itemnumber, barcode, itemcallnumber, title, author, biblio.biblionumber, datelastseen
+FROM items
+ LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
+ LEFT JOIN biblioitems on items.biblionumber = biblioitems.biblionumber
+END_SQL
+
+ if ($minlocation) {
+ push @where_strings, 'itemcallnumber >= ?';
+ push @bind_params, $minlocation;
+ }
+
+ if ($maxlocation) {
+ push @where_strings, 'itemcallnumber <= ?';
+ push @bind_params, $maxlocation;
+ }
+
+ if ($datelastseen) {
+ $datelastseen = format_date_in_iso($datelastseen);
+ push @where_strings, '(datelastseen < ? OR datelastseen IS NULL)';
+ push @bind_params, $datelastseen;
+ }
+
+ if ( $location ) {
+ push @where_strings, 'items.location = ?';
+ push @bind_params, $location;
+ }
+
+ if ( $branch ) {
+ push @where_strings, 'items.homebranch = ?';
+ push @bind_params, $branch;
+ }
+
+ if ( $itemtype ) {
+ push @where_strings, 'biblioitems.itemtype = ?';
+ push @bind_params, $itemtype;
+ }
+ if ( $ignoreissued) {
+ $query .= "LEFT JOIN issues ON items.itemnumber = issues.itemnumber ";
+ push @where_strings, 'issues.date_due IS NULL';
+ }
+
+ if ( @where_strings ) {
+ $query .= 'WHERE ';
+ $query .= join ' AND ', @where_strings;
+ }
+ $query .= ' ORDER BY itemcallnumber, title';
+ my $sth = $dbh->prepare($query);
+ $sth->execute( @bind_params );
+
+ my @results;
+ $size--;
+ while ( my $row = $sth->fetchrow_hashref ) {
+ $offset-- if ($offset);
+ $row->{datelastseen}=format_date($row->{datelastseen});
+ if ( ( !$offset ) && $size ) {
+ push @results, $row;
+ $size--;
+ }
+ }
+ return \@results;
+}
+
+=head2 GetItemsCount
+
+=over 4
+$count = &GetItemsCount( $biblionumber);
+
+=back
+
+This function return count of item with $biblionumber
+
+=cut
+
+sub GetItemsCount {
+ my ( $biblionumber ) = @_;
+ my $dbh = C4::Context->dbh;
+ my $query = "SELECT count(*)
+ FROM items
+ WHERE biblionumber=?";
+ my $sth = $dbh->prepare($query);
+ $sth->execute($biblionumber);
+ my $count = $sth->fetchrow;
+ $sth->finish;
+ return ($count);
+}
+
+=head2 GetItemInfosOf
+
+=over 4
+
+GetItemInfosOf(@itemnumbers);
+
+=back
+
+=cut
+
+sub GetItemInfosOf {
+ my @itemnumbers = @_;
+
+ my $query = '
+ SELECT *
+ FROM items
+ WHERE itemnumber IN (' . join( ',', @itemnumbers ) . ')
+ ';
+ return get_infos_of( $query, 'itemnumber' );
+}
+
+=head2 GetItemsByBiblioitemnumber
+
+=over 4
+
+GetItemsByBiblioitemnumber($biblioitemnumber);
+
+=back
+
+Returns an arrayref of hashrefs suitable for use in a TMPL_LOOP
+Called by C<C4::XISBN>
+
+=cut