+=head2 GetRSSMessages
+
+ my $message_list = GetRSSMessages( { limit => 10, borrowernumber => '14' } )
+
+returns a listref of all queued RSS messages for a particular person.
+
+=cut
+
+sub GetRSSMessages {
+ my $params = shift;
+
+ return unless $params;
+ return unless ref $params;
+ return unless $params->{'borrowernumber'};
+
+ return _get_unsent_messages( { message_transport_type => 'rss',
+ limit => $params->{'limit'},
+ borrowernumber => $params->{'borrowernumber'}, } );
+}
+
+=head2 GetPrintMessages
+
+ my $message_list = GetPrintMessages( { borrowernumber => $borrowernumber } )
+
+Returns a arrayref of all queued print messages (optionally, for a particular
+person).
+
+=cut
+
+sub GetPrintMessages {
+ my $params = shift || {};
+
+ return _get_unsent_messages( { message_transport_type => 'print',
+ borrowernumber => $params->{'borrowernumber'}, } );
+}
+
+=head2 GetQueuedMessages ([$hashref])
+
+ my $messages = GetQueuedMessage( { borrowernumber => '123', limit => 20 } );
+
+fetches messages out of the message queue.
+
+returns:
+list of hashes, each has represents a message in the message queue.
+
+=cut
+
+sub GetQueuedMessages {
+ my $params = shift;
+
+ my $dbh = C4::Context->dbh();
+ my $statement = << 'ENDSQL';
+SELECT message_id, borrowernumber, subject, content, message_transport_type, status, time_queued
+FROM message_queue
+ENDSQL
+
+ my @query_params;
+ my @whereclauses;
+ if ( exists $params->{'borrowernumber'} ) {
+ push @whereclauses, ' borrowernumber = ? ';
+ push @query_params, $params->{'borrowernumber'};
+ }
+
+ if ( @whereclauses ) {
+ $statement .= ' WHERE ' . join( 'AND', @whereclauses );
+ }
+
+ if ( defined $params->{'limit'} ) {
+ $statement .= ' LIMIT ? ';
+ push @query_params, $params->{'limit'};
+ }
+
+ my $sth = $dbh->prepare( $statement );
+ my $result = $sth->execute( @query_params );
+ return $sth->fetchall_arrayref({});
+}
+
+=head2 _add_attachements
+
+named parameters:
+letter - the standard letter hashref
+attachments - listref of attachments. each attachment is a hashref of:
+ type - the mime type, like 'text/plain'
+ content - the actual attachment
+ filename - the name of the attachment.
+message - a MIME::Lite object to attach these to.
+
+returns your letter object, with the content updated.
+
+=cut
+
+sub _add_attachments {
+ my $params = shift;
+
+ return unless 'HASH' eq ref $params;
+ foreach my $required_parameter (qw( letter attachments message )) {
+ return unless exists $params->{$required_parameter};
+ }
+ return $params->{'letter'} unless @{ $params->{'attachments'} };
+
+ # First, we have to put the body in as the first attachment
+ $params->{'message'}->attach(
+ Type => 'TEXT',
+ Data => $params->{'letter'}->{'content'},
+ );
+
+ foreach my $attachment ( @{ $params->{'attachments'} } ) {
+ $params->{'message'}->attach(
+ Type => $attachment->{'type'},
+ Data => $attachment->{'content'},
+ Filename => $attachment->{'filename'},
+ );
+ }
+ # we're forcing list context here to get the header, not the count back from grep.
+ ( $params->{'letter'}->{'content-type'} ) = grep( /^Content-Type:/, split( /\n/, $params->{'message'}->header_as_string ) );
+ $params->{'letter'}->{'content-type'} =~ s/^Content-Type:\s+//;
+ $params->{'letter'}->{'content'} = $params->{'message'}->body_as_string;
+
+ return $params->{'letter'};
+
+}
+
+sub _get_unsent_messages (;$) {
+ my $params = shift;
+
+ my $dbh = C4::Context->dbh();
+ my $statement = << 'ENDSQL';
+SELECT message_id, borrowernumber, subject, content, message_transport_type, status, time_queued, from_address, to_address, content_type
+ FROM message_queue
+ WHERE status = ?
+ENDSQL
+
+ my @query_params = ('pending');
+ if ( ref $params ) {
+ if ( $params->{'message_transport_type'} ) {
+ $statement .= ' AND message_transport_type = ? ';
+ push @query_params, $params->{'message_transport_type'};
+ }
+ if ( $params->{'borrowernumber'} ) {
+ $statement .= ' AND borrowernumber = ? ';
+ push @query_params, $params->{'borrowernumber'};
+ }
+ if ( $params->{'limit'} ) {
+ $statement .= ' limit ? ';
+ push @query_params, $params->{'limit'};
+ }
+ }
+ $debug and warn "_get_unsent_messages SQL: $statement";
+ $debug and warn "_get_unsent_messages params: " . join(',',@query_params);
+ my $sth = $dbh->prepare( $statement );
+ my $result = $sth->execute( @query_params );
+ return $sth->fetchall_arrayref({});
+}
+
+sub _send_message_by_email ($;$$$) {
+ my $message = shift or return;
+
+ my $to_address = $message->{to_address};
+ unless ($to_address) {
+ my $member = C4::Members::GetMember( 'borrowernumber' => $message->{'borrowernumber'} );
+ unless ($member) {
+ warn "FAIL: No 'to_address' and INVALID borrowernumber ($message->{borrowernumber})";
+ _set_message_status( { message_id => $message->{'message_id'},
+ status => 'failed' } );
+ return;
+ }
+ my $which_address = C4::Context->preference('AutoEmailPrimaryAddress');
+ # If the system preference is set to 'first valid' (value == OFF), look up email address
+ if ($which_address eq 'OFF') {
+ $to_address = GetFirstValidEmailAddress( $message->{'borrowernumber'} );
+ } else {
+ $to_address = $member->{$which_address};
+ }
+ unless ($to_address) {
+ # warn "FAIL: No 'to_address' and no email for " . ($member->{surname} ||'') . ", borrowernumber ($message->{borrowernumber})";
+ # warning too verbose for this more common case?
+ _set_message_status( { message_id => $message->{'message_id'},
+ status => 'failed' } );
+ return;
+ }
+ }
+
+ my $content = encode('utf8', $message->{'content'});
+ my %sendmail_params = (
+ To => $to_address,
+ From => $message->{'from_address'} || C4::Context->preference('KohaAdminEmailAddress'),
+ Subject => encode('utf8', $message->{'subject'}),
+ charset => 'utf8',
+ Message => $content,
+ 'content-type' => $message->{'content_type'} || 'text/plain; charset="UTF-8"',
+ );
+ if ( my $bcc = C4::Context->preference('OverdueNoticeBcc') ) {
+ $sendmail_params{ Bcc } = $bcc;
+ }
+
+
+ if ( sendmail( %sendmail_params ) ) {
+ _set_message_status( { message_id => $message->{'message_id'},
+ status => 'sent' } );
+ return 1;
+ } else {
+ _set_message_status( { message_id => $message->{'message_id'},
+ status => 'failed' } );
+ carp $Mail::Sendmail::error;
+ return;
+ }
+}
+
+sub _send_message_by_sms ($) {
+ my $message = shift or return undef;
+ my $member = C4::Members::GetMember( 'borrowernumber' => $message->{'borrowernumber'} );
+ return unless $member->{'smsalertnumber'};
+
+ my $success = C4::SMS->send_sms( { destination => $member->{'smsalertnumber'},
+ message => $message->{'content'},
+ } );
+ _set_message_status( { message_id => $message->{'message_id'},
+ status => ($success ? 'sent' : 'failed') } );
+ return $success;
+}
+
+sub _set_message_status ($) {
+ my $params = shift or return undef;
+
+ foreach my $required_parameter ( qw( message_id status ) ) {
+ return undef unless exists $params->{ $required_parameter };
+ }
+
+ my $dbh = C4::Context->dbh();
+ my $statement = 'UPDATE message_queue SET status= ? WHERE message_id = ?';
+ my $sth = $dbh->prepare( $statement );
+ my $result = $sth->execute( $params->{'status'},
+ $params->{'message_id'} );
+ return $result;
+}
+
+
+1;
+__END__