bin/BackupPC_incPartsUpdate

   1 #!/usr/local/bin/perl -w
   2
   3 use strict;
   4 use lib "__INSTALLDIR__/lib";
   5
   6 use DBI;
   7 use BackupPC::Lib;
   8 use BackupPC::View;
   9 use BackupPC::Attrib qw/:all/;
  10 use Data::Dumper;
  11 use Time::HiRes qw/time/;
  12 use POSIX qw/strftime/;
  13 use Cwd qw/abs_path/;
  14 use File::Which;
  15 use Archive::Tar::Streamed;
  16 use Algorithm::Diff;
  17 use Getopt::Std;
  18 use File::Slurp;
  19
  20 my $bpc = BackupPC::Lib->new || die "can't create BackupPC::Lib";
  21 my %Conf = $bpc->Conf();
  22
  23 use BackupPC::SearchLib;
  24 %BackupPC::SearchLib::Conf = %Conf;
  25
  26 my $path = abs_path($0);
  27 $path =~ s#/[^/]+$#/#;
  28 my $tarIncCreate = $path .= 'BackupPC_tarIncCreate';
  29
  30 die "can't find $tarIncCreate: $!\n" unless (-x $tarIncCreate);
  31
  32 my $bin;
  33 foreach my $c (qw/gzip md5sum/) {
  34         $bin->{$c} = which($c) || die "$0 needs $c, install it\n";
  35 }
  36
  37 my %opt;
  38 getopts("cd", \%opt );
  39
  40 my $debug = $opt{d};
  41 my $check = $opt{c} && print STDERR "NOTICE: tar archive check forced\n";
  42
  43 $|=1;
  44
  45 my $start_t = time();
  46
  47 my $t_fmt = '%Y-%m-%d %H:%M:%S';
  48
  49 my $dsn = $Conf{SearchDSN} || die "Need SearchDSN in config.pl\n";
  50 my $user = $Conf{SearchUser} || '';
  51
  52 my $dbh = DBI->connect($dsn, $user, "", { RaiseError => 1, AutoCommit => 0 });
  53
  54 my $tar_dir = $Conf{InstallDir}.'/'.$Conf{GzipTempDir};
  55
  56 die "problem with $tar_dir, check GzipTempDir in configuration\n" unless (-d $tar_dir && -w $tar_dir);
  57
  58 #---- subs ----
  59
  60 sub fmt_time {
  61         my $t = shift || return;
  62         my $out = "";
  63         my ($ss,$mm,$hh) = gmtime($t);
  64         $out .= "${hh}h" if ($hh);
  65         $out .= sprintf("%02d:%02d", $mm,$ss);
  66         return $out;
  67 }
  68
  69 sub curr_time {
  70         return strftime($t_fmt,localtime());
  71 }
  72
  73 my $hsn_cache;
  74
  75 sub get_backup_id($$$) {
  76         my ($host, $share, $num) = @_;
  77
  78         my $key = "$host $share $num";
  79         return $hsn_cache->{$key} if ($hsn_cache->{$key});
  80
  81         my $sth = $dbh->prepare(qq{
  82                 SELECT
  83                         backups.id
  84                 FROM backups
  85                 INNER JOIN shares       ON backups.shareID=shares.ID
  86                 INNER JOIN hosts        ON backups.hostID = hosts.ID
  87                 where hosts.name = ? and shares.name = ? and backups.num = ?
  88         });
  89         $sth->execute($host, $share, $num);
  90         my ($id) = $sth->fetchrow_array;
  91
  92         $hsn_cache->{"$host $share $num"} = $id;
  93
  94         print STDERR "# $host $share $num == $id\n" if ($opt{d});
  95
  96         return $id;
  97 }
  98
  99
 100 sub tar_check($$$$) {
 101         my ($host,$share,$num,$filename) = @_;
 102
 103         my $t = time();
 104         print curr_time, " check $host:$share#$num -> $filename";
 105
 106         sub check_part {
 107                 my ($host, $share, $num, $part_nr, $tar_size, $size, $md5, $items) = @_;
 108                 my $backup_id = get_backup_id($host, $share, $num);
 109                 my $sth_md5 = $dbh->prepare(qq{
 110                         select
 111                                 id, tar_size, size, md5, items
 112                         from backup_parts
 113                         where backup_id = ? and part_nr = ?
 114                 });
 115
 116                 $sth_md5->execute($backup_id, $part_nr);
 117
 118                 if (my $row = $sth_md5->fetchrow_hashref) {
 119                         return if (
 120                                 $row->{tar_size} >= $tar_size &&
 121                                 $row->{size} == $size &&
 122                                 $row->{md5} eq $md5 &&
 123                                 $row->{items} == $items
 124                         );
 125                         print ", deleting invalid backup_parts $row->{id}";
 126                         $dbh->do(qq{ delete from backup_parts where id = $row->{id} });
 127                 }
 128                 print ", inserting new";
 129                 my $sth_insert = $dbh->prepare(qq{
 130                         insert into backup_parts (
 131                                 backup_id,
 132                                 part_nr,
 133                                 tar_size,
 134                                 size,
 135                                 md5,
 136                                 items
 137                         ) values (?,?,?,?,?,?)
 138                 });
 139
 140                 $sth_insert->execute($backup_id, $part_nr, $tar_size, $size, $md5, $items);
 141                 $dbh->commit;
 142         }
 143
 144         my @tar_parts;
 145
 146         if (-d "$tar_dir/$filename") {
 147                 print ", multi-part";
 148                 opendir(my $dir, "$tar_dir/$filename") || die "can't readdir $tar_dir/$filename: $!";
 149                 @tar_parts = map { my $p = $_; $p =~ s#^#${filename}/#; $p } grep { !/^\./ && !/md5/ && -f "$tar_dir/$filename/$_" } readdir($dir);
 150                 closedir($dir);
 151         } else {
 152                 push @tar_parts, "${filename}.tar.gz";
 153         }
 154
 155         print " [parts: ",join(", ", @tar_parts),"]" if ($opt{d});
 156
 157         my $same = 1;
 158         my @tar_files;
 159
 160         my $backup_part;
 161
 162         print " reading" if ($opt{d});
 163
 164         foreach my $tarfilename (@tar_parts) {
 165
 166                 print "\n\t- $tarfilename";
 167
 168                 my $size = (stat( "$tar_dir/$tarfilename" ))[7] || die "can't stat $tar_dir/$tarfilename";
 169
 170                 if ($size > $Conf{MaxArchiveSize}) {
 171                         print STDERR " part bigger than media $size > $Conf{MaxArchiveSize} }}" if ($debug);
 172                         $same = 0;
 173                         last;
 174                 }
 175
 176                 print ", $size bytes";
 177
 178                 my $path = "$tar_dir/$tarfilename";
 179
 180                 open(my $fh, "gzip -cd $tar_dir/$tarfilename |") or die "can't open $tar_dir/$tarfilename: $!";
 181                 binmode($fh);
 182                 my $tar = Archive::Tar::Streamed->new($fh);
 183
 184                 my $tar_size = 0;
 185                 my $items = 0;
 186
 187                 while(my $entry = $tar->next) {
 188                         push @tar_files, $entry->name;
 189                         $items++;
 190                         $tar_size += $entry->size;
 191
 192                         if ($tar_size > $Conf{MaxArchiveFileSize}) {
 193                                 print ", part $tarfilename is too big $tar_size > $Conf{MaxArchiveFileSize}\n";
 194                                 $same = 0;
 195                                 last;
 196                         }
 197
 198                 }
 199
 200                 print ", $items items";
 201
 202                 #
 203                 # check if md5 exists, and if not, create one
 204                 #
 205
 206                 my $md5_path = $path;
 207                 $md5_path =~ s/\.tar\.gz$/.md5/ || die "can't create md5 filename from $md5_path";
 208                 if (! -e $md5_path || -z $md5_path) {
 209                         print ", creating md5";
 210                         system( $bin->{md5sum} . " $path > $md5_path") == 0 or die "can't create md5 $path: $!";
 211                 } else {
 212                         ## FIXME check if existing md5 is valid
 213                 }
 214
 215                 my $md5 = read_file( $md5_path ) || die "can't read md5sum file $md5_path: $!";
 216                 $md5 =~ s#\s.*$##;
 217
 218                 # extract part number from filename
 219                 my $part_nr = 1;
 220                 $part_nr = $1 if ($tarfilename =~ m#/(\d+)\.tar\.gz#);
 221
 222                 #
 223                 # finally, check if backup_parts table in database is valid
 224                 #
 225
 226                 check_part($host, $share, $num, $part_nr, $tar_size, $size, $md5, $items);
 227         }
 228
 229         # short-cut and exit;
 230         return $same unless($same);
 231
 232         @tar_files = sort @tar_files;
 233         print "\n\t",($#tar_files + 1), " tar files";
 234
 235         my $sth = $dbh->prepare(qq{
 236                 SELECT path,type
 237                 FROM files
 238                 JOIN shares on shares.id = shareid
 239                 JOIN hosts on hosts.id = shares.hostid
 240                 WHERE hosts.name = ? and shares.name = ? and backupnum = ?
 241         });
 242         $sth->execute($host, $share, $num);
 243         my @db_files;
 244         while( my $row = $sth->fetchrow_hashref ) {
 245
 246                 my $path = $row->{'path'} || die "no path?";
 247                 $path =~ s#^/#./#;
 248                 $path .= '/' if ($row->{'type'} == BPC_FTYPE_DIR);
 249                 push @db_files, $path;
 250         }
 251
 252         print " ",($#db_files + 1), " database files, diff";
 253
 254         @db_files = sort @db_files;
 255
 256         if ($#tar_files != $#db_files) {
 257                 $same = 0;
 258                 print " NUMBER";
 259         } else {
 260                 my $diff = Algorithm::Diff->new(\@tar_files, \@db_files);
 261                 while ( $diff->Next() ) {
 262                         next if $diff->Same();
 263                         $same = 0;
 264                         print "< $_\n" for $diff->Items(1);
 265                         print "> $_\n" for $diff->Items(2);
 266                 }
 267         }
 268
 269         print " ",($same ? 'ok' : 'DIFFERENT'),
 270                 ", dur: ",fmt_time(time() - $t), "\n";
 271
 272         return $same;
 273 }
 274
 275
 276 #----- main
 277
 278 my $sth = $dbh->prepare( qq{
 279
 280 select
 281         backups.id as backup_id,
 282         hosts.name as host,
 283         shares.name as share,
 284         backups.num as num,
 285         inc_size,
 286         parts
 287 from backups
 288         join shares on backups.hostid = shares.hostid
 289                 and shares.id = backups.shareid
 290         join hosts on shares.hostid = hosts.id
 291 where not inc_deleted
 292 order by backups.date
 293
 294 } );
 295
 296 $sth->execute();
 297 my $num_backups = $sth->rows;
 298 my $curr_backup = 1;
 299
 300 while (my $row = $sth->fetchrow_hashref) {
 301         my $tar_file = BackupPC::SearchLib::getGzipName($row->{'host'}, $row->{'share'}, $row->{'num'});
 302
 303         # this will return -1 if file doesn't exist
 304         my $size = BackupPC::SearchLib::get_tgz_size_by_name($tar_file);
 305
 306         print "# size: $size backup.size: ", $row->{inc_size},"\n" if ($opt{d});
 307
 308         if ( $row->{'inc_size'} != -1 && $size != -1 && $row->{'inc_size'} >= $size) {
 309                 if ($check) {
 310                         tar_check($row->{'host'}, $row->{'share'}, $row->{'num'}, $tar_file) && next;
 311                 } else {
 312                         next;
 313                 }
 314         }
 315
 316         print curr_time, " $curr_backup/$num_backups ", $row->{'host'}, ":", $row->{'share'}, " #", $row->{'num'}, " -> $tar_file";
 317         $curr_backup++;
 318
 319         my $t = time();
 320
 321         # re-create archive?
 322         my $cmd = qq{ $tarIncCreate -h "$row->{'host'}" -s "$row->{'share'}" -n $row->{'num'} -f };
 323         print STDERR "## $cmd\n" if ($debug);
 324
 325         if (system($cmd) != 0) {
 326                 print STDERR " FAILED";
 327         }
 328
 329         print ", dur: ",fmt_time(time() - $t), "\n";
 330
 331         $dbh->commit;
 332
 333 }
 334
 335 undef $sth;
 336 $dbh->disconnect;