lib/BackupPC/Xfer/Rsync.pm

   1 #============================================================= -*-perl-*-
   2 #
   3 # BackupPC::Xfer::Rsync package
   4 #
   5 # DESCRIPTION
   6 #
   7 #   This library defines a BackupPC::Xfer::Rsync class for managing
   8 #   the rsync-based transport of backup data from the client.
   9 #
  10 # AUTHOR
  11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
  12 #
  13 # COPYRIGHT
  14 #   Copyright (C) 2002-2003  Craig Barratt
  15 #
  16 #   This program is free software; you can redistribute it and/or modify
  17 #   it under the terms of the GNU General Public License as published by
  18 #   the Free Software Foundation; either version 2 of the License, or
  19 #   (at your option) any later version.
  20 #
  21 #   This program is distributed in the hope that it will be useful,
  22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 #   GNU General Public License for more details.
  25 #
  26 #   You should have received a copy of the GNU General Public License
  27 #   along with this program; if not, write to the Free Software
  28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  29 #
  30 #========================================================================
  31 #
  32 # Version 2.1.0, released 20 Jun 2004.
  33 #
  34 # See http://backuppc.sourceforge.net.
  35 #
  36 #========================================================================
  37
  38 package BackupPC::Xfer::Rsync;
  39
  40 use strict;
  41 use BackupPC::View;
  42 use BackupPC::Xfer::RsyncFileIO;
  43
  44 use vars qw( $RsyncLibOK $RsyncLibErr );
  45
  46 BEGIN {
  47     eval "use File::RsyncP;";
  48     if ( $@ ) {
  49         #
  50         # Rsync module doesn't exist.
  51         #
  52         $RsyncLibOK = 0;
  53         $RsyncLibErr = "File::RsyncP module doesn't exist";
  54     } else {
  55         #
  56         # Note: also update configure.pl when this version number is changed!
  57         #
  58         if ( $File::RsyncP::VERSION < 0.52 ) {
  59             $RsyncLibOK = 0;
  60             $RsyncLibErr = "File::RsyncP module version"
  61                          . " ($File::RsyncP::VERSION) too old: need 0.52";
  62         } else {
  63             $RsyncLibOK = 1;
  64         }
  65     }
  66 };
  67
  68 sub new
  69 {
  70     my($class, $bpc, $args) = @_;
  71
  72     return if ( !$RsyncLibOK );
  73     $args ||= {};
  74     my $t = bless {
  75         bpc       => $bpc,
  76         conf      => { $bpc->Conf },
  77         host      => "",
  78         hostIP    => "",
  79         shareName => "",
  80         badFiles  => [],
  81
  82         #
  83         # Various stats
  84         #
  85         byteCnt         => 0,
  86         fileCnt         => 0,
  87         xferErrCnt      => 0,
  88         xferBadShareCnt => 0,
  89         xferBadFileCnt  => 0,
  90         xferOK          => 0,
  91
  92         #
  93         # User's args
  94         #
  95         %$args,
  96     }, $class;
  97
  98     return $t;
  99 }
 100
 101 sub args
 102 {
 103     my($t, $args) = @_;
 104
 105     foreach my $arg ( keys(%$args) ) {
 106         $t->{$arg} = $args->{$arg};
 107     }
 108 }
 109
 110 sub useTar
 111 {
 112     return 0;
 113 }
 114
 115 sub start
 116 {
 117     my($t) = @_;
 118     my $bpc = $t->{bpc};
 119     my $conf = $t->{conf};
 120     my(@fileList, $rsyncClientCmd, $rsyncArgs, $logMsg,
 121        $incrDate, $argList, $fioArgs);
 122
 123     #
 124     # We add a slash to the share name we pass to rsync
 125     #
 126     ($t->{shareNameSlash} = "$t->{shareName}/") =~ s{//+$}{/};
 127
 128     if ( $t->{type} eq "restore" ) {
 129         $rsyncClientCmd = $conf->{RsyncClientRestoreCmd};
 130         $rsyncArgs = $conf->{RsyncRestoreArgs};
 131         my $remoteDir = "$t->{shareName}/$t->{pathHdrDest}";
 132         $remoteDir    =~ s{//+}{/}g;
 133         $argList = ['--server', @$rsyncArgs, '.', $remoteDir];
 134         $fioArgs = {
 135             client   => $t->{bkupSrcHost},
 136             share    => $t->{bkupSrcShare},
 137             viewNum  => $t->{bkupSrcNum},
 138             fileList => $t->{fileList},
 139         };
 140         $logMsg = "restore started below directory $t->{shareName}"
 141                 . " to host $t->{host}";
 142     } else {
 143         #
 144         # Turn $conf->{BackupFilesOnly} and $conf->{BackupFilesExclude}
 145         # into a hash of arrays of files, and $conf->{RsyncShareName}
 146         # to an array
 147         #
 148         $bpc->backupFileConfFix($conf, "RsyncShareName");
 149
 150         if ( defined($conf->{BackupFilesOnly}{$t->{shareName}}) ) {
 151             my(@inc, @exc, %incDone, %excDone);
 152             foreach my $file ( @{$conf->{BackupFilesOnly}{$t->{shareName}}} ) {
 153                 #
 154                 # If the user wants to just include /home/craig, then
 155                 # we need to do create include/exclude pairs at
 156                 # each level:
 157                 #     --include /home --exclude /*
 158                 #     --include /home/craig --exclude /home/*
 159                 #
 160                 # It's more complex if the user wants to include multiple
 161                 # deep paths.  For example, if they want /home/craig and
 162                 # /var/log, then we need this mouthfull:
 163                 #     --include /home --include /var --exclude /*
 164                 #     --include /home/craig --exclude /home/*
 165                 #     --include /var/log --exclude /var/*
 166                 #
 167                 # To make this easier we do all the includes first and all
 168                 # of the excludes at the end (hopefully they commute).
 169                 #
 170                 $file =~ s{/$}{};
 171                 $file = "/$file";
 172                 $file =~ s{//+}{/}g;
 173                 if ( $file eq "/" ) {
 174                     #
 175                     # This is a special case: if the user specifies
 176                     # "/" then just include it and don't exclude "/*".
 177                     #
 178                     push(@inc, $file) if ( !$incDone{$file} );
 179                     next;
 180                 }
 181                 my $f = "";
 182                 while ( $file =~ m{^/([^/]*)(.*)} ) {
 183                     my $elt = $1;
 184                     $file = $2;
 185                     if ( $file eq "/" ) {
 186                         #
 187                         # preserve a tailing slash
 188                         #
 189                         $file = "";
 190                         $elt = "$elt/";
 191                     }
 192                     push(@exc, "$f/*") if ( !$excDone{"$f/*"} );
 193                     $excDone{"$f/*"} = 1;
 194                     $f = "$f/$elt";
 195                     push(@inc, $f) if ( !$incDone{$f} );
 196                     $incDone{$f} = 1;
 197                 }
 198             }
 199             foreach my $file ( @inc ) {
 200                 push(@fileList, "--include=$file");
 201             }
 202             foreach my $file ( @exc ) {
 203                 push(@fileList, "--exclude=$file");
 204             }
 205         }
 206         if ( defined($conf->{BackupFilesExclude}{$t->{shareName}}) ) {
 207             foreach my $file ( @{$conf->{BackupFilesExclude}{$t->{shareName}}} )
 208             {
 209                 #
 210                 # just append additional exclude lists onto the end
 211                 #
 212                 push(@fileList, "--exclude=$file");
 213             }
 214         }
 215         if ( $t->{type} eq "full" ) {
 216             if ( $t->{partialNum} ) {
 217                 $logMsg = "full backup started for directory $t->{shareName};"
 218                         . " updating partial $t->{partialNum}";
 219             } else {
 220                 $logMsg = "full backup started for directory $t->{shareName}";
 221             }
 222         } else {
 223             $incrDate = $bpc->timeStamp($t->{lastFull} - 3600, 1);
 224             $logMsg = "incr backup started back to $incrDate for directory"
 225                     . " $t->{shareName}";
 226         }
 227
 228         #
 229         # A full dump is implemented with --ignore-times: this causes all
 230         # files to be checksummed, even if the attributes are the same.
 231         # That way all the file contents are checked, but you get all
 232         # the efficiencies of rsync: only files deltas need to be
 233         # transferred, even though it is a full dump.
 234         #
 235         $rsyncArgs = $conf->{RsyncArgs};
 236         $rsyncArgs = [@$rsyncArgs, @fileList] if ( @fileList );
 237         $rsyncArgs = [@$rsyncArgs, "--ignore-times"]
 238                                     if ( $t->{type} eq "full" );
 239         $rsyncClientCmd = $conf->{RsyncClientCmd};
 240         $argList = ['--server', '--sender', @$rsyncArgs,
 241                               '.', $t->{shareNameSlash}];
 242         $argList = File::RsyncP->excludeStrip($argList);
 243         $fioArgs = {
 244             client     => $t->{client},
 245             share      => $t->{shareName},
 246             viewNum    => $t->{lastFullBkupNum},
 247             partialNum => $t->{partialNum},
 248         };
 249     }
 250
 251     #
 252     # Merge variables into $rsyncClientCmd
 253     #
 254     my $args = {
 255         host      => $t->{host},
 256         hostIP    => $t->{hostIP},
 257         client    => $t->{client},
 258         shareName => $t->{shareName},
 259         shareNameSlash => $t->{shareNameSlash},
 260         rsyncPath => $conf->{RsyncClientPath},
 261         sshPath   => $conf->{SshPath},
 262         argList   => $argList,
 263     };
 264     $rsyncClientCmd = $bpc->cmdVarSubstitute($rsyncClientCmd, $args);
 265
 266     #
 267     # Create the Rsync object, and tell it to use our own File::RsyncP::FileIO
 268     # module, which handles all the special BackupPC file storage
 269     # (compression, mangling, hardlinks, special files, attributes etc).
 270     #
 271     $t->{rsyncClientCmd} = $rsyncClientCmd;
 272     $t->{rs} = File::RsyncP->new({
 273         logLevel     => $t->{logLevel} || $conf->{RsyncLogLevel},
 274         rsyncCmd     => sub {
 275                             $bpc->verbose(0);
 276                             $bpc->cmdExecOrEval($rsyncClientCmd, $args);
 277                         },
 278         rsyncCmdType => "full",
 279         rsyncArgs    => $rsyncArgs,
 280         timeout      => $conf->{ClientTimeout},
 281         doPartial    => defined($t->{partialNum}) ? 1 : undef,
 282         logHandler   =>
 283                 sub {
 284                     my($str) = @_;
 285                     $str .= "\n";
 286                     $t->{XferLOG}->write(\$str);
 287                     if ( $str =~ /^Remote\[1\]: read errors mapping "(.*)"/ ) {
 288                         #
 289                         # Files with read errors (eg: region locked files
 290                         # on WinXX) are filled with 0 by rsync.  Remember
 291                         # them and delete them later.
 292                         #
 293                         my $badFile = $1;
 294                         $badFile =~ s/^\/+//;
 295                         push(@{$t->{badFiles}}, {
 296                                 share => $t->{shareName},
 297                                 file  => $badFile
 298                             });
 299                     }
 300                 },
 301         pidHandler   => sub {
 302                             $t->{pidHandler}(@_);
 303                         },
 304         fio          => BackupPC::Xfer::RsyncFileIO->new({
 305                             xfer       => $t,
 306                             bpc        => $t->{bpc},
 307                             conf       => $t->{conf},
 308                             backups    => $t->{backups},
 309                             logLevel   => $t->{logLevel}
 310                                               || $conf->{RsyncLogLevel},
 311                             logHandler => sub {
 312                                               my($str) = @_;
 313                                               $str .= "\n";
 314                                               $t->{XferLOG}->write(\$str);
 315                                           },
 316                             cacheCheckProb => $conf->{RsyncCsumCacheVerifyProb},
 317                             %$fioArgs,
 318                       }),
 319     });
 320
 321     delete($t->{_errStr});
 322
 323     return $logMsg;
 324 }
 325
 326 sub run
 327 {
 328     my($t) = @_;
 329     my $rs = $t->{rs};
 330     my $conf = $t->{conf};
 331     my($remoteSend, $remoteDir, $remoteDirDaemon);
 332
 333     alarm($conf->{ClientTimeout});
 334     if ( $t->{type} eq "restore" ) {
 335         $remoteSend       = 0;
 336         ($remoteDir       = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
 337         ($remoteDirDaemon = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
 338         $remoteDirDaemon  = $t->{shareNameSlash}
 339                                 if ( $t->{pathHdrDest} eq ""
 340                                               || $t->{pathHdrDest} eq "/" );
 341     } else {
 342         $remoteSend      = 1;
 343         $remoteDir       = $t->{shareNameSlash};
 344         $remoteDirDaemon = ".";
 345     }
 346     if ( $t->{XferMethod} eq "rsync" ) {
 347         #
 348         # Run rsync command
 349         #
 350         my $str = "Running: "
 351                 . $t->{bpc}->execCmd2ShellCmd(@{$t->{rsyncClientCmd}})
 352                 . "\n";
 353         $t->{XferLOG}->write(\$str);
 354         $rs->remoteStart($remoteSend, $remoteDir);
 355     } else {
 356         #
 357         # Connect to the rsync server
 358         #
 359         if ( defined(my $err = $rs->serverConnect($t->{hostIP},
 360                                              $conf->{RsyncdClientPort})) ) {
 361             $t->{hostError} = $err;
 362             my $str = "Error connecting to rsync daemon at $t->{hostIP}"
 363                     . ":$conf->{RsyncdClientPort}: $err\n";
 364             $t->{XferLOG}->write(\$str);
 365             return;
 366         }
 367         #
 368         # Pass module name, and follow it with a slash if it already
 369         # contains a slash; otherwise just keep the plain module name.
 370         #
 371         my $module = $t->{shareName};
 372         $module = $t->{shareNameSlash} if ( $module =~ /\// );
 373         if ( defined(my $err = $rs->serverService($module,
 374                                              $conf->{RsyncdUserName},
 375                                              $conf->{RsyncdPasswd},
 376                                              $conf->{RsyncdAuthRequired})) ) {
 377             my $str = "Error connecting to module $module at $t->{hostIP}"
 378                     . ":$conf->{RsyncdClientPort}: $err\n";
 379             $t->{XferLOG}->write(\$str);
 380             $t->{hostError} = $err;
 381             return;
 382         }
 383         $rs->serverStart($remoteSend, $remoteDirDaemon);
 384     }
 385     my $error = $rs->go($t->{shareNameSlash});
 386     $rs->serverClose();
 387
 388     #
 389     # TODO: generate sensible stats
 390     #
 391     # $rs->{stats}{totalWritten}
 392     # $rs->{stats}{totalSize}
 393     #
 394     my $stats = $rs->statsFinal;
 395     if ( !defined($error) && defined($stats) ) {
 396         $t->{xferOK} = 1;
 397     } else {
 398         $t->{xferOK} = 0;
 399     }
 400     $t->{xferErrCnt} = $stats->{remoteErrCnt}
 401                      + $stats->{childStats}{errorCnt}
 402                      + $stats->{parentStats}{errorCnt};
 403     $t->{byteCnt}    = $stats->{childStats}{TotalFileSize}
 404                      + $stats->{parentStats}{TotalFileSize};
 405     $t->{fileCnt}    = $stats->{childStats}{TotalFileCnt}
 406                      + $stats->{parentStats}{TotalFileCnt};
 407     my $str = "Done: $t->{fileCnt} files, $t->{byteCnt} bytes\n";
 408     $t->{XferLOG}->write(\$str);
 409     #
 410     # TODO: get error count, and call fio to get stats...
 411     #
 412     $t->{hostError} = $error if ( defined($error) );
 413
 414     if ( $t->{type} eq "restore" ) {
 415         return (
 416             $t->{fileCnt},
 417             $t->{byteCnt},
 418             0,
 419             0
 420         );
 421     } else {
 422         return (
 423             0,
 424             $stats->{childStats}{ExistFileCnt}
 425                 + $stats->{parentStats}{ExistFileCnt},
 426             $stats->{childStats}{ExistFileSize}
 427                 + $stats->{parentStats}{ExistFileSize},
 428             $stats->{childStats}{ExistFileCompSize}
 429                 + $stats->{parentStats}{ExistFileCompSize},
 430             $stats->{childStats}{TotalFileCnt}
 431                 + $stats->{parentStats}{TotalFileCnt},
 432             $stats->{childStats}{TotalFileSize}
 433                 + $stats->{parentStats}{TotalFileSize},
 434         );
 435     }
 436 }
 437
 438 sub abort
 439 {
 440     my($t, $reason) = @_;
 441     my $rs = $t->{rs};
 442
 443     $rs->abort($reason);
 444     return 1;
 445 }
 446
 447 sub setSelectMask
 448 {
 449     my($t, $FDreadRef) = @_;
 450 }
 451
 452 sub errStr
 453 {
 454     my($t) = @_;
 455
 456     return $RsyncLibErr if ( !defined($t) || ref($t) ne "HASH" );
 457     return $t->{_errStr};
 458 }
 459
 460 sub xferPid
 461 {
 462     my($t) = @_;
 463
 464     return ();
 465 }
 466
 467 sub logMsg
 468 {
 469     my($t, $msg) = @_;
 470
 471     push(@{$t->{_logMsg}}, $msg);
 472 }
 473
 474 sub logMsgGet
 475 {
 476     my($t) = @_;
 477
 478     return shift(@{$t->{_logMsg}});
 479 }
 480
 481 #
 482 # Returns a hash ref giving various status information about
 483 # the transfer.
 484 #
 485 sub getStats
 486 {
 487     my($t) = @_;
 488
 489     return { map { $_ => $t->{$_} }
 490             qw(byteCnt fileCnt xferErrCnt xferBadShareCnt xferBadFileCnt
 491                xferOK hostAbort hostError lastOutputLine)
 492     };
 493 }
 494
 495 sub getBadFiles
 496 {
 497     my($t) = @_;
 498
 499     return @{$t->{badFiles}};
 500 }
 501
 502 1;