makeDist

   1 #!/bin/perl
   2 #
   3 # makeDist: Build a BackupPC distribution
   4 #
   5 # DESCRIPTION
   6 #
   7 #   This script should be run with no arguments to build a
   8 #   distribution.  The $Version and $ReleaseDate should be
   9 #   edited below to specify the version name and the release
  10 #   date.  The distribution is createede in the sub-directory
  11 #   dist.  The dsitribution is in the file name:
  12 #
  13 #           dist/BackupPC-$Version.tar.gz.
  14 #
  15 #   Often the language files are not up to date, and makeDist
  16 #   exits after complaining about the lang files being inconsistent.
  17 #   Use the -l option to turn off that behavior.
  18 #
  19 # AUTHOR
  20 #   Craig Barratt <cbarratt@users.sourceforge.net>
  21 #
  22 # COPYRIGHT
  23 #   Copyright (C) 2001-2007  Craig Barratt
  24 #
  25 #   This program is free software; you can redistribute it and/or modify
  26 #   it under the terms of the GNU General Public License as published by
  27 #   the Free Software Foundation; either version 2 of the License, or
  28 #   (at your option) any later version.
  29 #
  30 #   This program is distributed in the hope that it will be useful,
  31 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  32 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  33 #   GNU General Public License for more details.
  34 #
  35 #   You should have received a copy of the GNU General Public License
  36 #   along with this program; if not, write to the Free Software
  37 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  38 #
  39 #========================================================================
  40 #
  41
  42 use strict;
  43 use File::Path;
  44 use File::Copy;
  45 use Getopt::Std;
  46 use lib "./lib";
  47 use BackupPC::Lib;
  48 use BackupPC::Config::Meta qw(:all);
  49
  50 my $bpc;
  51 die("BackupPC::Lib->new failed\n")
  52         if ( !($bpc = BackupPC::Lib->new(".", ".", "./conf", 1)) );
  53
  54 umask(0022);
  55
  56 my $Version     = "3.1.0beta0";
  57 my $ReleaseDate = "3 Sep 2007";
  58 my $DistDir     = "dist/BackupPC-$Version";
  59
  60 my @PerlSrc = qw(
  61     bin/BackupPC
  62     bin/BackupPC_archive
  63     bin/BackupPC_archiveHost
  64     bin/BackupPC_archiveStart
  65     bin/BackupPC_attribPrint
  66     bin/BackupPC_dump
  67     bin/BackupPC_fixupBackupSummary
  68     bin/BackupPC_link
  69     bin/BackupPC_nightly
  70     bin/BackupPC_restore
  71     bin/BackupPC_sendEmail
  72     bin/BackupPC_serverMesg
  73     bin/BackupPC_trashClean
  74     bin/BackupPC_tarExtract
  75     bin/BackupPC_tarCreate
  76     bin/BackupPC_tarPCCopy
  77     bin/BackupPC_compressPool
  78     bin/BackupPC_zipCreate
  79     bin/BackupPC_zcat
  80     lib/BackupPC/Attrib.pm
  81     lib/BackupPC/Config.pm
  82     lib/BackupPC/FileZIO.pm
  83     lib/BackupPC/Lib.pm
  84     lib/BackupPC/PoolWrite.pm
  85     lib/BackupPC/Storage.pm
  86     lib/BackupPC/View.pm
  87     lib/BackupPC/CGI/AdminOptions.pm
  88     lib/BackupPC/CGI/Archive.pm
  89     lib/BackupPC/CGI/ArchiveInfo.pm
  90     lib/BackupPC/CGI/Browse.pm
  91     lib/BackupPC/CGI/DirHistory.pm
  92     lib/BackupPC/CGI/EditConfig.pm
  93     lib/BackupPC/CGI/EmailSummary.pm
  94     lib/BackupPC/CGI/GeneralInfo.pm
  95     lib/BackupPC/CGI/HostInfo.pm
  96     lib/BackupPC/CGI/Lib.pm
  97     lib/BackupPC/CGI/LOGlist.pm
  98     lib/BackupPC/CGI/Queue.pm
  99     lib/BackupPC/CGI/ReloadServer.pm
 100     lib/BackupPC/CGI/RestoreFile.pm
 101     lib/BackupPC/CGI/RestoreInfo.pm
 102     lib/BackupPC/CGI/Restore.pm
 103     lib/BackupPC/CGI/RSS.pm
 104     lib/BackupPC/CGI/StartServer.pm
 105     lib/BackupPC/CGI/StartStopBackup.pm
 106     lib/BackupPC/CGI/StopServer.pm
 107     lib/BackupPC/CGI/Summary.pm
 108     lib/BackupPC/CGI/View.pm
 109     lib/BackupPC/Config/Meta.pm
 110     lib/BackupPC/Lang/de.pm
 111     lib/BackupPC/Lang/en.pm
 112     lib/BackupPC/Lang/es.pm
 113     lib/BackupPC/Lang/fr.pm
 114     lib/BackupPC/Lang/it.pm
 115     lib/BackupPC/Lang/nl.pm
 116     lib/BackupPC/Lang/pl.pm
 117     lib/BackupPC/Lang/pt_br.pm
 118     lib/BackupPC/Lang/zh_CN.pm
 119     lib/BackupPC/Storage/Text.pm
 120     lib/BackupPC/Xfer/Archive.pm
 121     lib/BackupPC/Xfer/BackupPCd.pm
 122     lib/BackupPC/Xfer/Smb.pm
 123     lib/BackupPC/Xfer/Tar.pm
 124     lib/BackupPC/Xfer/Rsync.pm
 125     lib/BackupPC/Xfer/RsyncDigest.pm
 126     lib/BackupPC/Xfer/RsyncFileIO.pm
 127     lib/BackupPC/Zip/FileMember.pm
 128     cgi-bin/BackupPC_Admin
 129 );
 130
 131 my %opts;
 132 if ( !getopts("l", \%opts) || @ARGV != 0 ) {
 133     print("usage: $0 [-l]\n");
 134     exit(1);
 135 }
 136
 137 #
 138 # Check config parameters
 139 #
 140 my $ConfVars = {};
 141 my $errCnt;
 142
 143 $errCnt += CheckConfigParams("conf/config.pl", $ConfVars, 0);
 144
 145 $errCnt += CheckConfigParams("doc-src/BackupPC.pod", $ConfVars, 1);
 146
 147 $errCnt += CheckMetaDataVsConfig($ConfVars, "lib/BackupPC/Config/Meta.pm");
 148
 149 $errCnt += CheckEditorVsConfig($ConfVars, "lib/BackupPC/CGI/EditConfig.pm");
 150
 151 #
 152 # These config parameters are not used in the code, so ignore them.
 153 #
 154 $ConfVars->{BackupPCUser} = 2;
 155 $ConfVars->{CgiDir}       = 2;
 156 $ConfVars->{TopDir}       = 2;
 157 $ConfVars->{LogDir}       = 2;
 158 $ConfVars->{ConfDir}      = 2;
 159 $ConfVars->{InstallDir}   = 2;
 160 $ConfVars->{CgiImageDir}  = 2;
 161 $ConfVars->{ClientCharsetLegacy}  = 2;      # actually used
 162
 163 #
 164 # These config parameters are used in the code to be backward compatible,
 165 # but are not present in the current config file, so ignore them.
 166 #
 167 $ConfVars->{BlackoutHourBegin} = 2;
 168 $ConfVars->{BlackoutHourEnd}   = 2;
 169 $ConfVars->{BlackoutWeekDays}  = 2;
 170 $ConfVars->{RsyncLogLevel}     = 2;
 171
 172 foreach my $file ( @PerlSrc ) {
 173     $errCnt += CheckConfigParams($file, $ConfVars, 1);
 174 }
 175 if ( !$opts{l} ) {
 176     $errCnt += CheckLangUsage();
 177     $errCnt += CheckLangTags();
 178 }
 179 if ( $errCnt ) {
 180     print("Exiting because of errors\n");
 181     exit(1)
 182 }
 183
 184 $errCnt = 0;
 185 foreach my $var ( sort(keys(%$ConfVars) ) ) {
 186     next if ( $ConfVars->{$var} >= 2 || $var =~ /^\$/ );
 187     printf("Unused config parameter $var\n");
 188     $errCnt++;
 189 }
 190 if ( $errCnt ) {
 191     print("Exiting because of errors\n");
 192     exit(1)
 193 }
 194
 195 rmtree($DistDir, 0, 0);
 196 mkpath($DistDir, 0, 0777);
 197
 198 foreach my $dir ( qw(bin doc conf images init.d/src cgi-bin
 199                      lib/BackupPC/CGI
 200                      lib/BackupPC/Config
 201                      lib/BackupPC/Lang
 202                      lib/BackupPC/Storage
 203                      lib/BackupPC/Xfer
 204                      lib/BackupPC/Zip
 205                 ) ) {
 206     mkpath("$DistDir/$dir", 0, 0777);
 207 }
 208
 209 my %ConfName;
 210 my $ConfPod = config2pod();
 211 rmtree("doc", 0, 0);
 212 mkpath("doc", 0, 0777);
 213 InstallFile("doc-src/BackupPC.pod", "doc/BackupPC.pod");
 214
 215 use Pod::Html;
 216 pod2html("doc/BackupPC.pod",
 217         "--backlink=Back to Top",
 218         "--header",
 219         "--title=BackupPC",
 220         "--outfile=doc/BackupPC.html");
 221
 222 foreach my $file ( (@PerlSrc,
 223             <images/*.gif>,
 224             <images/*.png>,
 225             qw(
 226                 conf/config.pl
 227                 conf/hosts
 228                 conf/BackupPC_stnd.css
 229                 conf/BackupPC_stnd_orig.css
 230                 conf/sorttable.js
 231                 init.d/README
 232                 init.d/src/debian-backuppc
 233                 init.d/src/freebsd-backuppc
 234                 init.d/src/gentoo-backuppc
 235                 init.d/src/gentoo-backuppc.conf
 236                 init.d/src/linux-backuppc
 237                 init.d/src/slackware-backuppc
 238                 init.d/src/solaris-backuppc
 239                 init.d/src/suse-backuppc
 240                 doc/BackupPC.pod
 241                 doc/BackupPC.html
 242                 README
 243                 LICENSE
 244                 ChangeLog
 245                 configure.pl
 246         )) ) {
 247     InstallFile("$file", "$DistDir/$file");
 248 }
 249 rmtree("doc", 0, 0);
 250 system("cd dist ; tar zcf BackupPC-$Version.tar.gz BackupPC-$Version");
 251 print("Distribution written to dist/BackupPC-$Version.tar.gz\n");
 252 unlink("pod2htmd.x~~");
 253 unlink("pod2htmi.x~~");
 254 unlink("pod2htmd.tmp");
 255 unlink("pod2htmi.tmp");
 256
 257 ###########################################################################
 258 # Subroutines
 259 ###########################################################################
 260
 261 sub InstallFile
 262 {
 263     my($file, $dest) = @_;
 264
 265     unlink($dest) if ( -d $dest );
 266     if ( $file =~ /\.gif/ || $file =~ /\.png/ ) {
 267         die("can't copy($file, $dest)\n") unless copy($file, $dest);
 268     } else {
 269         open(FILE, $file)   || die("can't open $file for reading\n");
 270         open(OUT, ">$dest") || die("can't open $dest for writing\n");
 271         binmode(FILE);
 272         binmode(OUT);
 273         while ( <FILE> ) {
 274             s/^([#*\s]+)Version \d+\.\d+[\.\w]*, released \d+ \w+ \d{4}\.?/$1Version __VERSION__, released __RELEASEDATE__./;
 275             s/__VERSION__/$Version/g;
 276             s/__RELEASEDATE__/$ReleaseDate/g;
 277             if ( $file =~ /BackupPC\.html$/ ) {
 278                 #
 279                 # fixup for conf links
 280                 #
 281                 if ( !/A NAME="item_(%|_)conf/i ) {
 282                     s/\$Conf{([^}]*)}/
 283                         defined($ConfName{$1})
 284                             ? "\L<a href=\"#$ConfName{$1}\">\E\$Conf{$1}<\/A>"
 285                             : "\$Conf{$1}"/eg;
 286                 }
 287                 s/^<DD>/<DD><P>/;
 288                 s/^<li><\/li>/<li>/;
 289             }
 290             if ( /__CONFIGPOD__/ ) {
 291                 print OUT $ConfPod;
 292             } elsif ( /^use lib ".*BackupPC\/lib";/
 293                     || /^use lib "\/home\/pcbackup\/install\/lib";/ ) {
 294                 print OUT "use lib \"__INSTALLDIR__/lib\";\n";
 295             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$topDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
 296                 print OUT "$1'__TOPDIR__'$2\n";
 297             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$installDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
 298                 print OUT "$1'__INSTALLDIR__'$2\n";
 299             } elsif ( $file =~ /Lib.pm/ && /^(\s*ConfDir\s*=\>\s*\$confDir eq.*)'.*'(.*)/ ) {
 300                 print OUT "$1'__CONFDIR__'$2\n";
 301             } elsif ( $file =~ /Lib.pm/ && /^(\s*my \$useFHS\s*=\s*)\d;/ ) {
 302                 print OUT "${1}0;\n";
 303             } elsif ( $file =~ /Lib.pm/ && /(.*Version *=> .*)'[\w\d\.]+',/ ) {
 304                 print OUT "$1'$Version',\n";
 305             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_BIN_LIST__/ ) {
 306                 print OUT "        ", join("\n        ", grep(/^bin\//, @PerlSrc)), "\n";
 307             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_LIB_LIST__/ ) {
 308                 print OUT "        ", join("\n        ", grep(/^lib\//, @PerlSrc)), "\n";
 309             } elsif ( $file =~ /BackupPC_Admin/ && /(my *\$installDir *= *)'.*'/ ) {
 310                 print OUT "$1'__INSTALLDIR__/lib';\n";
 311             } else {
 312                 print OUT;
 313             }
 314         }
 315         close(FILE);
 316         close(OUT);
 317     }
 318     if ( -x $file ) {
 319         chmod(0555, $dest);
 320     } else {
 321         chmod(0444, $dest);
 322     }
 323 }
 324
 325 sub config2pod
 326 {
 327     open(C, "conf/config.pl") || die("can't open conf/config.pl");
 328     binmode(C);
 329     my($str, $out, $getHdr, @conf);
 330     my $first = 1;
 331     while ( <C> ) {
 332         chomp;
 333         s/ +$//;
 334         if ( /^#########################/ ) {
 335             if ( $getHdr ) {
 336                 $str =~ s/\n.*//sg;
 337                 $out .= "=back\n\n" if ( !$first );
 338                 $out .= "=head2 $str\n\n=over 4\n\n";
 339                 $str = "";
 340                 $first = 0;
 341             }
 342             $getHdr = !$getHdr;
 343             next;
 344         }
 345         if ( /^#/ ) {
 346             s/# ?//;
 347             next if ( $str eq "" && /^$/ );
 348             $str .= $_ . "\n";
 349             $str .= "\n" if ( $str =~ /examples?:\n$/i );
 350         } elsif ( /^\$Conf{([^}]*)/ ) {
 351             my $var = $1;
 352             s/  +/ /g;
 353             s/;\s*#.*/;/;
 354             if ( !s/\[$/[ ... ];/ && !s/<<'EOF'/.../ ) {
 355                 s/([^;])\s*$/$1 .../;
 356             }
 357             push(@conf, $_);
 358             my $text = "_conf_${var}_";
 359             $text =~ s{[\W\s]}{_}g;
 360             $ConfName{$var} = "item_$text";
 361         } elsif ( /^$/ ) {
 362             if ( $str ne "" && @conf ) {
 363                 $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
 364                 $out .= $str;
 365                 $out .= "\n" if ( $str !~ /\n$/ );
 366             }
 367             $str = "";
 368             @conf = ();
 369         }
 370     }
 371     if ( $str ne "" && @conf ) {
 372         $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
 373         $out .= $str;
 374         $out .= "\n" if ( $str !~ /\n$/ );
 375     }
 376     $out .= "=back\n\n" if ( !$first );
 377     return $out;
 378 }
 379
 380 sub CheckConfigParams
 381 {
 382     my($file, $vars, $check) = @_;
 383     my $errors;
 384
 385     open(F, $file) || die("can't open $file\n");
 386     binmode(F);
 387     if ( $check ) {
 388         while ( <F> ) {
 389             s/\$(self|bpc)->{Conf}{([^}\$]+)}/if ( !defined($vars->{$2}) ) {
 390                     print("Unexpected Conf var $2 in $file\n");
 391                     $errors++;
 392                 } else {
 393                     $vars->{$2}++;
 394                 }/eg;
 395             s/\$[Cc]onf(?:->)?{([^}\$]+)}/if ( !defined($vars->{$1}) ) {
 396                     print("Unexpected Conf var $1 in $file\n");
 397                     $errors++;
 398                 } else {
 399                     $vars->{$1}++;
 400                 }/eg;
 401             s/UserCommandRun\("([^"]*)"/if ( !defined($vars->{$1}) ) {
 402                     print("Unexpected Conf var $1 in $file\n");
 403                     $errors++;
 404                 } else {
 405                     $vars->{$1}++;
 406                 }/eg;
 407         }
 408     } else {
 409         while ( <F> ) {
 410             s/^[^#]*\$self->{Conf}{([^}]*)/$vars->{$1} = 1;/eg;
 411             s/^[^#]*\$Conf{([^}]*)/$vars->{$1} = 1;/eg;
 412         }
 413     }
 414     close(F);
 415     return $errors;
 416 }
 417
 418 sub CheckMetaDataVsConfig
 419 {
 420     my($confVars, $file) = @_;
 421     my $done = {};
 422     my $errors;
 423
 424     #
 425     # Check that the meta file mentions all the config
 426     # parameters
 427     #
 428     open(F, $file) || die("can't open $file");
 429
 430     while ( <F> ) {
 431         next if ( !/^\s{4}(\w+)\s+=>/ );
 432         if ( $confVars->{$1} ) {
 433             $done->{$1} = 1;
 434             next;
 435         }
 436         next if ( $1 eq "Hosts" );
 437         print("$file has $1 but missing from conf/config.pl\n");
 438         $errors++;
 439     }
 440     close(F);
 441     foreach my $v ( keys(%$confVars) ) {
 442         next if ( $done->{$v} );
 443         print("$file missing $v from conf/config.pl\n");
 444         $errors++;
 445     }
 446
 447     #
 448     # Do extra checks that the CgiUserConfigEdit hash in the Meta
 449     # file matches the config file
 450     #
 451     foreach my $p ( keys(%{$ConfigMeta{CgiUserConfigEdit}{child}}) ) {
 452         if ( !defined($bpc->{Conf}{CgiUserConfigEdit}{$p}) ) {
 453             print("lib/BackupPC/Config/Meta.pm has $p in CgiUserConfigEdit,"
 454                 . " but conf/config.pl CgiUserConfigEdit does not\n");
 455             $errors++;
 456         }
 457     }
 458     foreach my $p ( keys(%{$bpc->{Conf}{CgiUserConfigEdit}}) ) {
 459         if ( !defined($ConfigMeta{CgiUserConfigEdit}{child}{$p}) ) {
 460             print("conf/config.pl CgiUserConfigEdit has $p, but"
 461                 . " lib/BackupPC/Config/Meta.pm does not\n");
 462             $errors++;
 463         }
 464     }
 465     return $errors;
 466 }
 467
 468 sub CheckEditorVsConfig
 469 {
 470     my($confVars, $file) = @_;
 471     my $done = {};
 472     my $errors;
 473
 474     #
 475     # Check that the config editor file mentions all the config
 476     # parameters
 477     #
 478     open(F, $file) || die("can't open $file");
 479
 480     while ( <F> ) {
 481         next if ( !/name\s*=>\s*"(\w+)"/ );
 482         if ( $confVars->{$1} ) {
 483             $done->{$1} = 1;
 484             next;
 485         }
 486         next if ( $1 eq "Hosts" );
 487         print("$file has $1 but missing from conf/config.pl\n");
 488         $errors++;
 489     }
 490     close(F);
 491     foreach my $v ( keys(%$confVars) ) {
 492         next if ( $done->{$v} );
 493         print("$file missing $v from conf/config.pl\n");
 494         $errors++;
 495     }
 496     return $errors;
 497 }
 498
 499 #
 500 # Make sure that every lang variable in cgi-bin/BackupPC_Admin matches
 501 # the strings in each lib/BackupPC/Lang/*.pm file.  This makes sure
 502 # we didn't miss any translations in any of the languages.
 503 #
 504 sub CheckLangUsage
 505 {
 506     my $errors;
 507     my $vars = {};
 508
 509     foreach my $file ( (
 510                 qw(cgi-bin/BackupPC_Admin bin/BackupPC_sendEmail),
 511                 <lib/BackupPC/CGI/*pm>,
 512                 <lib/BackupPC/Lang/en.pm>,
 513             ) ) {
 514         open(F, $file) || die("can't open $file");
 515         binmode(F);
 516         while ( <F> ) {
 517             next if ( /^\s*#/ );
 518             s/\$Lang->{([^}]*)}/$vars->{$1} = 1;/eg;
 519             s/(text|comment)\s*=>\s*"(CfgEdit_.*)"/$vars->{$2} = 1;/eg;
 520         }
 521         close(F);
 522     }
 523
 524     foreach my $f ( <lib/BackupPC/Lang/*.pm> ) {
 525         my $done = {};
 526         open(F, $f) || die("can't open $f\n");
 527         binmode(F);
 528         while ( <F> ) {
 529             s/#.*//g;
 530             s/\$Lang{([^}]*)}/
 531                     my $var = $1;
 532                     next if ( $var =~ m{^(Reason_|Status_|backupType_|Disabled_)} );
 533                     next if ( $var eq "Documentation" );
 534                     if ( !defined($vars->{$var}) ) {
 535                         print("Unexpected Lang var $var in $f\n");
 536                         $errors++;
 537                     } else {
 538                         $done->{$var} = 1;
 539                     }/eg;
 540         }
 541         close(F);
 542         foreach my $v ( keys(%$vars) ) {
 543             #
 544             # skip "variables" with "$", since they are like expressions
 545             #
 546             next if ( $v =~ /\$/ );
 547             if ( !defined($done->{$v}) ) {
 548                 print("Lang var $v missing from $f\n");
 549                 $errors++;
 550             }
 551         }
 552     }
 553     return $errors;
 554 }
 555
 556 #
 557 # Pedantically check that all the html tags in each language file
 558 # match.
 559 #
 560 sub CheckLangTags
 561 {
 562     my($en, $enVars) = LangParse("lib/BackupPC/Lang/en.pm");
 563     my($errors);
 564
 565     foreach my $lang ( qw(fr.pm de.pm es.pm it.pm nl.pm pl.pm pt_br.pm zh_CN.pm) ) {
 566         my($d, $dVars) = LangParse("lib/BackupPC/Lang/$lang");
 567         foreach my $v1 ( @$en ) {
 568             my $v2 = shift(@$d);
 569             if ( $v1->{var} ne $v2->{var} ) {
 570                 print("Botch: got $lang var $v2->{var} vs en.pm $v1->{var}\n");
 571                 exit;
 572             }
 573             my $t1 = LangTextStrip($v1->{val});
 574             my $t2 = LangTextStrip($v2->{val});
 575             if ( $t1 ne $t2 ) {
 576                 my $i;
 577                 for ( $i = 0 ; $i < length($t1) ; $i++ ) {
 578                     last if ( substr($t1, 0, $i) ne substr($t2, 0, $i) );
 579                 }
 580                 print("$v1->{var}: ($i) got en.pm $t1\nvs $lang $t2\n\n");
 581                 $errors++;
 582             }
 583         }
 584     }
 585     return $errors;
 586 }
 587
 588 sub LangTextStrip
 589 {
 590     my($t) = @_;
 591
 592     $t = "" if ( $t !~ /<.*>/ );
 593     $t =~ s/^[^<]*</</s;
 594     $t =~ s/([}>])[^<]*</$1</g;
 595     $t =~ s/>[^<]*$/>/;
 596     $t =~ s/(value=)"[^"]*"/$1""/sg;
 597     $t =~ s/({h[12]\()"[^"]*"/$1""/g;
 598     $t =~ s/ENG[\s\n]*//sg;
 599     $t =~ s/^(<<EOF;\n)[^<]*/$1/g;
 600     return $t;
 601 }
 602
 603 sub LangParse
 604 {
 605     my($file) = @_;
 606     open(C, $file) || die("can't open $file");
 607     binmode(C);
 608     my($out, @lang, $var);
 609     my $comment = 1;
 610     my $allVars = {};
 611     my $endLine = undef;
 612     while ( <C> ) {
 613         if ( /^#/ && !defined($endLine) ) {
 614             if ( $comment ) {
 615                 $out .= $_;
 616             } else {
 617                 if ( $out ne "" ) {
 618                     $allVars->{$var} = @lang if ( defined($var) );
 619                     push(@lang, {
 620                         text => $out,
 621                         var => $var,
 622                     });
 623                 }
 624                 $var = undef;
 625                 $comment = 1;
 626                 $out = $_;
 627             }
 628         } elsif ( /^\s*\$Lang\{([^}]*)/ ) {
 629             $comment = 0;
 630             if ( defined($var) ) {
 631                 $allVars->{$var} = @lang if ( defined($var) );
 632                 push(@lang, {
 633                     text => $out,
 634                     var => $var,
 635                 });
 636                 $out = $_;
 637             } else {
 638                 $out .= $_;
 639             }
 640             $var = $1;
 641             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<(.*);/ );
 642             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<'(.*)';/ );
 643         } else {
 644             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
 645             $out .= $_;
 646         }
 647     }
 648     if ( $out ne "" ) {
 649         $allVars->{$var} = @lang if ( defined($var) );
 650         push(@lang, {
 651             text => $out,
 652             var  => $var,
 653         });
 654     }
 655     close(C);
 656     foreach my $v ( @lang ) {
 657         if ( $v->{text} =~ /\$Lang{$v->{var}}\s*=\s*(.*)/s ) {
 658             $v->{val} = $1;
 659         }
 660     }
 661     return (\@lang, $allVars);
 662 }