lib/Biblio/RFID/Reader.pm

   1 package Biblio::RFID::Reader;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Data::Dump qw(dump);
   7 use Time::HiRes;
   8 use lib 'lib';
   9 use Biblio::RFID;
  10 use Carp qw(confess);
  11
  12 =head1 NAME
  13
  14 Biblio::RFID::Reader - simple way to write RFID applications in perl
  15
  16 =head1 DESCRIPTION
  17
  18 This module will probe all available readers and use calls from
  19 L<Biblio::RFID::Reader::API> to invoke correct reader.
  20
  21 =head1 FUNCTIONS
  22
  23 =head2 new
  24
  25   my $rfid = Biblio::RFID::Reader->new( 'optional reader filter' );
  26
  27 =cut
  28
  29 sub new {
  30         my ( $class, $filter ) = @_;
  31         my $self = {};
  32         bless $self, $class;
  33         $self->{_readers} = [ $self->_available( $filter ) ];
  34         return $self;
  35 }
  36
  37 =head2 tags
  38
  39   my @visible = $rfid->tags(
  40                 enter => sub { my $tag = shift; },
  41                 leave => sub { my $tag = shift; },
  42                 reader => sub { my $reader = shift; ref($reader) =~ m/something/ },
  43   );
  44
  45 =cut
  46
  47 sub tags {
  48         my $self = shift;
  49         my $triggers = {@_};
  50
  51         $self->{_tags} ||= {};
  52         $self->{_tags}->{$_}->{time} = 0 foreach keys %{$self->{_tags}};
  53         my $t = time;
  54
  55         foreach my $rfid ( @{ $self->{_readers} } ) {
  56
  57                 if ( exists $triggers->{reader} ) {
  58                         next unless $triggers->{reader}->($rfid);
  59                 }
  60
  61                 warn "# inventory on $rfid";
  62                 my @tags = $rfid->inventory;
  63
  64                 foreach my $tag ( @tags ) {
  65
  66                         if ( ! exists $self->{_tags}->{$tag} ) {
  67                                 eval {
  68                                         my $blocks = $rfid->read_blocks($tag);
  69                                         $self->{_tags}->{$tag}->{blocks} = $blocks->{$tag} || die "no $tag in ",dump($blocks);
  70                                         my $afi = $rfid->read_afi($tag);
  71                                         $self->{_tags}->{$tag}->{afi} = $afi;
  72                                         $self->{_tags}->{$tag}->{type} = $rfid->tag_type( $tag );
  73                                         $self->{_tags}->{$tag}->{reader} = ref $rfid; # save reader info
  74
  75                                 };
  76                                 if ( $@ ) {
  77                                         warn "ERROR reading $tag: $@\n";
  78                                         $self->_invalidate_tag( $tag );
  79                                         next;
  80                                 }
  81
  82                                 $triggers->{enter}->( $tag ) if $triggers->{enter};
  83                         }
  84
  85                         $self->{_tags}->{$tag}->{time} = $t;
  86
  87                 }
  88
  89         }
  90
  91         foreach my $tag ( grep { $self->{_tags}->{$_}->{time} == 0 } keys %{ $self->{_tags} } ) {
  92                 $triggers->{leave}->( $tag ) if $triggers->{leave};
  93                 $self->_invalidate_tag( $tag );
  94         }
  95
  96         warn "## _tags ",dump( $self->{_tags} );
  97
  98         return grep { $self->{_tags}->{$_}->{time} } keys %{ $self->{_tags} };
  99 }
 100
 101 =head2 blocks
 102
 103   my $blocks_arrayref = $rfid->blocks( $tag );
 104
 105 =head2 afi
 106
 107   my $afi = $rfid->afi( $tag );
 108
 109 =cut
 110
 111 sub blocks { $_[0]->{_tags}->{$_[1]}->{ 'blocks' } || confess "no blocks for $_[1]"; };
 112 sub afi    { $_[0]->{_tags}->{$_[1]}->{ 'afi'    } || confess "no afi for $_[1]"; };
 113
 114 =head2 to_hash
 115
 116   $self->to_hash( $tag );
 117
 118 =cut
 119
 120 sub to_hash {
 121         my ( $self, $tag ) = @_;
 122         return unless exists $self->{_tags}->{$tag};
 123         my $type = $self->{_tags}->{$tag}->{type} || confess "can't find type for tag $tag ",dump( $self->{_tags} );
 124         my $decode = 'Biblio::RFID::' . $type;
 125         my $hash = $decode->to_hash( $self->blocks( $tag ) );
 126         $hash->{tag_type} = $type;
 127         return $hash;
 128 }
 129
 130 =head2 debug
 131
 132   $self->debug(1); # or more
 133
 134 =cut
 135
 136 sub debug {
 137         my ( $self, $level ) = @_;
 138         $debug = $level if $level > $debug;
 139         warn "debug level $level\n" if $level;
 140 }
 141
 142 =head2 from_reader
 143
 144   my $reader = $self->from_reader( $tag );
 145
 146 =cut
 147
 148 sub from_reader {
 149         my ( $self, $tag ) = @_;
 150         return unless exists $self->{_tags}->{$tag};
 151         my $reader = $self->{_tags}->{$tag}->{reader};
 152         $reader =~ s/^.*:://; # strip module prefix
 153         return $reader;
 154 }
 155
 156 =head1 PRIVATE
 157
 158 =head2 _invalidate_tag
 159
 160   $rfid->_invalidate_tag( $tag );
 161
 162 =cut
 163
 164 sub _invalidate_tag {
 165         my ( $self, $tag ) = @_;
 166         my @caller = caller(0);
 167         warn "## _invalidate_tag caller $caller[0] $caller[1] +$caller[2]\n";
 168         my $old = delete $self->{_tags}->{$tag};
 169         warn "# _invalidate_tag $tag ", dump($old);
 170 }
 171
 172 =head2 _available
 173
 174 Probe each RFID reader supported and returns succefull ones
 175
 176   my $rfid_readers = Biblio::RFID::Reader->_available( $regex_filter );
 177
 178 =cut
 179
 180 #my @readers = ( '3M810', 'CPRM02', 'librfid' );
 181 my @readers = ( '3M810', 'librfid' );
 182
 183 sub _available {
 184         my ( $self, $filter ) = @_;
 185
 186         $filter = '' unless defined $filter;
 187
 188         warn "# filter: $filter";
 189
 190         my @rfid;
 191
 192         foreach my $reader ( @readers ) {
 193                 next if $filter && $reader !~ /$filter/i;
 194                 my $module = "Biblio::RFID::Reader::$reader";
 195                 eval "use $module";
 196                 die $@ if $@;
 197                 if ( my $rfid = $module->new ) {
 198                         push @rfid, $rfid;
 199                         warn "# added $module\n";
 200                 } else {
 201                         warn "# ignored $module\n";
 202                 }
 203         }
 204
 205         die "no readers found" unless @rfid;
 206
 207         return @rfid;
 208 }
 209
 210 =head1 AUTOLOAD
 211
 212 On any other function calls, we just marshall to all readers
 213
 214 =cut
 215
 216 # we don't want DESTROY to fallback into AUTOLOAD
 217 sub DESTROY {}
 218
 219 our $AUTOLOAD;
 220 sub AUTOLOAD {
 221         my $self = shift;
 222         my $command = $AUTOLOAD;
 223         $command =~ s/.*://;
 224
 225         my @out;
 226
 227         foreach my $r ( @{ $self->{_readers} } ) {
 228                 push @out, $r->$command(@_);
 229         }
 230
 231         $self->_invalidate_tag( $_[0] ) if $command =~ m/write/;
 232
 233         return @out;
 234 }
 235
 236 1
 237 __END__
 238
 239 =head1 SEE ALSO
 240
 241 =head2 RFID reader implementations
 242
 243 L<Biblio::RFID::Reader::3M810>
 244
 245 L<Biblio::RFID::Reader::CPRM02>
 246
 247 L<Biblio::RFID::Reader::librfid>
 248