lib/RFID/Biblio/RFID501.pm

   1 package RFID::Biblio::RFID501;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Data::Dump qw(dump);
   7
   8 =head1 NAME
   9
  10 RFID::Biblio::RFID501 - RFID Standard for Libraries
  11
  12 =head1 DESCRIPTION
  13
  14 This module tries to decode tag format as described in document
  15
  16   RFID 501: RFID Standards for Libraries
  17
  18 L<http://solutions.3m.com/wps/portal/3M/en_US/3MLibrarySystems/Home/Resources/CaseStudiesAndWhitePapers/RFID501/>
  19
  20 Goal is to be compatibile with existing 3M Alphanumeric tag format
  21 which, as far as I know, isn't specificed anywhere. My documentation about
  22 this format is available at
  23
  24 L<http://saturn.ffzg.hr/rot13/index.cgi?hitchhikers_guide_to_rfid>
  25
  26 =head1 Data model
  27
  28 =head2 3M Alphanumeric tag
  29
  30  0   04 is 00 tt   i [4 bit] = number of item in set    [1 .. i .. s]
  31                    s [4 bit] = total items in set
  32                    tt [8 bit] = item type
  33
  34  1   dd dd dd dd   dd [16 bytes] = barcode data
  35  2   dd dd dd dd
  36  3   dd dd dd dd
  37  4   dd dd dd dd
  38
  39  5   bb bl ll ll   b [12 bit] = branch [unsigned]
  40                    l [20 bit] = library [unsigned]
  41
  42  6   cc cc cc cc   c [32 bit] = custom signed integer
  43
  44 =head2 3M Manufacturing Blank
  45
  46  0   55 55 55 55
  47  1   55 55 55 55
  48  2   55 55 55 55
  49  3   55 55 55 55
  50  4   55 55 55 55
  51  5   55 55 55 55
  52  6   00 00 00 00
  53
  54 =head2 Generic blank
  55
  56  0   00 00 00 00
  57  1   00 00 00 00
  58  2   00 00 00 00
  59
  60 =head1 METHODS
  61
  62 =head2 decode_tag
  63
  64   my $hash = RFID::Biblio::Decode::RFID501->to_hash( $bytes );
  65
  66   my $hash = RFID::Biblio::Decode::RFID501->to_hash( [ 'blk1', 'blk2', ... , 'blk7' ] );
  67
  68 =cut
  69
  70 my $item_type = {
  71         1 => 'Book',
  72         6 => 'CD/CD ROM',
  73         2 => 'Magazine',
  74         13 => 'Book with Audio Tape',
  75         9 => 'Book with CD/CD ROM',
  76         0 => 'Other',
  77
  78         5 => 'Video',
  79         4 => 'Audio Tape',
  80         3 => 'Bound Journal',
  81         8 => 'Book with Diskette',
  82         7 => 'Diskette',
  83 };
  84
  85 sub to_hash {
  86         my ( $self, $data ) = @_;
  87
  88         return unless $data;
  89
  90         $data = join('', @$data) if ref $data eq 'ARRAY';
  91
  92         warn "## to_hash ",dump($data);
  93
  94         my ( $u1, $set_item, $u2, $type, $content, $br_lib, $custom, $zero ) = unpack('C4Z16Nl>l',$data);
  95         my $hash = {
  96                 u1 => $u1,      # FIXME 0x04
  97                 set => ( $set_item & 0xf0 ) >> 4,
  98                 total => ( $set_item & 0x0f ),
  99
 100                 u2 => $u2,      # FIXME 0x00
 101
 102                 type => $type,
 103                 type_label => $item_type->{$type},
 104
 105                 content => $content,
 106
 107                 branch => $br_lib >> 20,
 108                 library => $br_lib & 0x000fffff,
 109
 110                 custom => $custom,
 111         };
 112
 113         warn "expected first byte to be 0x04, not $u1\n"   if $u1 != 4;
 114         warn "expected third byte to be 0x00, not $u2\n"   if $u2 != 0;
 115         warn "expected last block to be zero, not $zero\n" if $zero != 0;
 116
 117         return $hash;
 118 }
 119
 120 sub from_hash {
 121         my $self = shift;
 122         my $hash = {@_};
 123
 124         warn "## from_hash ",dump($hash);
 125
 126         return pack('C4Z16Nl>l',
 127                 0x04,
 128                 ( $hash->{set} << 4 ) | ( $hash->{total} & 0x0f ),
 129                 0x00,
 130                 $hash->{type},
 131
 132                 $hash->{content},
 133
 134                 ( $hash->{branch} << 20 ) | ( $hash->{library} & 0x000fffff ),
 135
 136                 $hash->{custom},
 137                 0x00,
 138         );
 139 }
 140
 141 1;