scripts/mqr-irc-client.pl

   1 #!/usr/bin/env perl
   2 # This is a simple script that connects stdin/stdout with a client
   3 # connection to an irc server. the command line arguments are:
   4 #
   5 # $ ./debug_console <nick> <server> <port>
   6 #
   7 use common::sense;
   8 use IO::Handle;
   9 use AnyEvent;
  10 use AnyEvent::IRC::Client;
  11 use AnyEvent::IRC::Util qw/mk_msg parse_irc_msg encode_ctcp/;
  12 use Data::Dumper;
  13
  14 my ($nick, $server, $port) = @ARGV;
  15
  16 $nick ||= 'mqr-irc';
  17 $server ||= 'irc.freenode.net';
  18 $port ||= 6667;
  19
  20 my $c = AnyEvent->condvar;
  21 my $stdout = AnyEvent::Handle->new (fh => \*STDOUT);
  22 my $con = new AnyEvent::IRC::Client;
  23
  24 $con->reg_cb (
  25    connect => sub {
  26       my ($con, $err) = @_;
  27
  28       if (defined $err) {
  29          warn "Couldn't connect: $err\n";
  30          $c->broadcast;
  31       } else {
  32          $stdout->push_write ("Connected!\n");
  33       }
  34
  35       $con->register ($nick, $nick, $nick);
  36    },
  37    debug_recv => sub {
  38       my ($con, $msg) = @_;
  39       $stdout->push_write (
  40          "< "
  41          . mk_msg ($msg->{prefix}, $msg->{command}, @{$msg->{params}})
  42          . "\n"
  43       );
  44    },
  45    debug_send => sub {
  46       my ($con, @msg) = @_;
  47       $stdout->push_write (
  48          "> " . mk_msg (undef, @msg) . "\n"
  49       );
  50    },
  51    registered => sub {
  52       my ($con) = @_;
  53
  54       my $stdin;
  55       $stdin = AnyEvent::Handle->new (
  56          fh => \*STDIN,
  57          on_eof => sub {
  58             warn "EOF on STDIN, disconnecting...\n";
  59             $con->disconnect ("Console EOF");
  60          },
  61          on_error => sub {
  62             warn "Error on STDIN: $!\n";
  63          },
  64          on_read => sub {
  65             $stdin->push_read (line => sub {
  66                my ($stdin, $line) = @_;
  67
  68                if ($line =~ /^!/) {
  69                   my $r = eval $line;
  70                   if ($@) {
  71                      warn "eval error: $@\n";
  72                   } else {
  73                      $Data::Dumper::Terse = 1;
  74                      $stdout->push_write ("result: " . Data::Dumper::Dumper ($r));
  75                   }
  76                } else {
  77                   my $msg = parse_irc_msg ($line);
  78                   $con->send_msg ($msg->{command}, @{$msg->{params}});
  79                }
  80             });
  81          }
  82       );
  83    },
  84    disconnect => sub {
  85       warn "disconnect: $_[1]!\n";
  86       $c->broadcast
  87    },
  88 );
  89
  90 $con->ctcp_auto_reply ('VERSION', ['VERSION', 'DebugConsole:0.1:Perl']);
  91
  92 $con->connect ($server, $port || 6667);
  93
  94 $c->wait;