lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12
  13 sub index {
  14         my $self = shift;
  15
  16         my $path = $self->app->home->rel_dir('data');
  17         die "no data dir $path" unless -d $path;
  18
  19         opendir(my $dir, $path) || die $!;
  20         my @files =
  21                 grep { -f "$path/$_" && $_ =~ m/\.js(on)?$/ }
  22                 readdir $dir;
  23         close($dir);
  24
  25         $self->render( files => [ @files ] );
  26 }
  27
  28 our $data;
  29 our $stats;
  30
  31 sub load {
  32         my $self = shift;
  33
  34         my $path = $self->app->home->rel_file( 'data/' . $self->param('path') );
  35         die "$path $!" unless -r $path;
  36
  37         $self->session('path' => $self->param('path'));
  38
  39         # we could use Mojo::JSON here, but it's too slow
  40 #       $data = from_json read_file $path;
  41         $data = read_file $path;
  42         Encode::_utf8_on($data);
  43         warn "# json snippet: ", substr($data,0,200);
  44         $data = from_json $data;
  45
  46         $stats = {};
  47
  48         foreach my $e ( @{ $data->{items} } ) {
  49                 foreach my $n ( keys %$e ) {
  50                         $stats->{$n}->{count}++;
  51                         if ( ref $e->{$n} eq 'ARRAY' ) {
  52
  53                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
  54
  55                                 foreach my $x ( @{$e->{$n}} ) {
  56                                         $stats->{$n}->{numeric}++
  57                                                 if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  58                                 }
  59
  60                         } else {
  61                                 $stats->{$n}->{numeric}++
  62                                         if $e->{$n} =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  63                         }
  64                 }
  65         }
  66
  67         foreach my $n ( keys %$stats ) {
  68                 next unless defined $stats->{$n}->{array};
  69                 delete $stats->{$n}->{array}
  70                         if $stats->{$n}->{array} == $stats->{$n}->{count};
  71         }
  72
  73         warn dump($stats);
  74
  75         $self->redirect_to( '/data/columns' );
  76 }
  77
  78
  79 sub columns {
  80     my $self = shift;
  81
  82     $self->render(
  83                 message => 'Select columns to display',
  84                 stats => $stats,
  85                 checked => $self->_checked( $self->_perm_array('columns') ),
  86         );
  87 }
  88
  89 sub _perm_array {
  90     my ($self,$name) = @_;
  91
  92         my @array = $self->param($name);
  93
  94         if ( @array ) {
  95                 $self->session($name => [ @array ]);
  96         } elsif ( my $session = $self->session($name) ) {
  97                 if ( ref $session eq 'ARRAY' ) {
  98                         @array = @$session;
  99                 } else {
 100                         die "$name not array ",dump($session);
 101                 }
 102         }
 103         warn "# $name ",dump @array;
 104         return @array;
 105 }
 106
 107 sub _perm_scalar {
 108     my ($self,$name,$default) = @_;
 109
 110         my $scalar = $self->param($name);
 111
 112         if ( defined $scalar ) {
 113                 $self->session($name => $scalar);
 114         } else {
 115                 $scalar = $self->session($name);
 116         }
 117
 118         if ( ! defined $scalar ) {
 119                 $scalar = $default;
 120                 die "no default for $name" unless defined $scalar;
 121                 $self->session($name => $scalar);
 122         }
 123
 124         warn "# $name ",dump $scalar;
 125         return $scalar;
 126 }
 127
 128 sub filter {
 129         my $self = shift;
 130
 131         my $name = $self->param('filter_name') || die "name?";
 132         my @vals = $self->param('filter_vals');
 133
 134         warn "# filter $name vals ",dump(@vals);
 135
 136         my $filters = $self->session('filters');
 137         if ( @vals ) {
 138                 $filters->{$name} = [ @vals ];
 139         } else {
 140                 delete $filters->{$name};
 141         }
 142         $self->session( 'filters' => $filters );
 143
 144         warn "# filters ",dump($self->session('filters'));
 145
 146         $self->session( 'offset' => 0 );
 147
 148         $self->redirect_to('/data/table');
 149 }
 150
 151 sub _filter_item {
 152         my ( $self, $filters, $i ) = @_;
 153         my $pass = 1;
 154         foreach my $n ( keys %$filters ) {
 155                 if ( ! defined $i->{$n} ) {
 156                         $pass = 0;
 157                         last;
 158                 }
 159                 foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 160                         $pass = 0 unless grep { m/^\Q$v\E$/ } @{ $filters->{$n} };
 161                 }
 162         }
 163         return $pass;
 164 }
 165
 166 sub _data_items {
 167         my $self = shift;
 168         my $filters = $self->session('filters');
 169         grep {
 170                 $filters ? $self->_filter_item( $filters, $_ ) : 1;
 171         } @{ $data->{items} };
 172 }
 173
 174 sub table {
 175     my $self = shift;
 176
 177         $self->redirect_to('/data/index') unless $data->{items};
 178
 179         my @columns = $self->_perm_array('columns');
 180         my $order   = $self->_perm_scalar('order', $columns[0]);
 181         my $offset  = $self->_perm_scalar('offset', 0);
 182         my $limit   = $self->_perm_scalar('limit', 20);
 183
 184         my @sorted = sort {
 185                 ( $a->{$order} || '' ) cmp ( $b->{$order} || '' ) # FIXME - multi-level sort
 186         } $self->_data_items;
 187
 188 #       warn "# sorted ", dump @sorted;
 189
 190         my $rows = $#sorted + 1;
 191
 192         warn "$rows $offset $limit";
 193
 194         $self->render(
 195                 order => $order,
 196                 offset => $offset,
 197                 limit => $limit,
 198                 sorted => [ splice @sorted, $offset, $limit ],
 199                 columns => [ @columns ],
 200                 rows => $rows,
 201         );
 202
 203 }
 204
 205
 206 sub facet {
 207         my $self = shift;
 208
 209         my $facet;
 210         my $name = $self->param('name') || die "no name";
 211
 212         foreach my $i ( $self->_data_items ) {
 213                 next unless exists $i->{$name};
 214                 if ( ref $i->{$name} eq 'ARRAY' ) {
 215                         $facet->{$_}++ foreach @{ $i->{$name} };
 216                 } else {
 217                         $facet->{ $i->{$name} }++;
 218                 }
 219         }
 220
 221 #       warn "# facet $name ",dump $facet;
 222
 223         my $checked;
 224         if ( my $f = $self->session('filters') ) {
 225                 if ( defined $f->{$name} ) {
 226                         $checked = $self->_checked( @{ $f->{$name} } );
 227                 }
 228         }
 229
 230         my $sort = $self->param('sort') || 'c';
 231
 232         my @facet_names = sort {
 233                 $sort =~ m/a/i ? lc $a cmp lc $b :
 234                 $sort =~ m/d/i ? lc $b cmp lc $a :
 235                         $facet->{$b} <=> $facet->{$a}
 236                 ;
 237         } keys %$facet;
 238
 239         $self->render( name => $name, facet => $facet, checked => $checked,
 240                 facet_names => \@facet_names, sort => $sort,
 241         );
 242 }
 243
 244 sub _checked {
 245         my $self = shift;
 246         my $checked;
 247         $checked->{$_}++ foreach @_;
 248         warn "# _checked ",dump($checked);
 249         return $checked;
 250 }
 251
 252 1;