lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use Encode;
  11 use locale;
  12 use File::Find;
  13 use Storable;
  14 use Time::HiRes qw(time);
  15 use File::Path qw(mkpath);
  16 use Text::Unaccent::PurePerl;
  17
  18 use MojoFacets::Import::File;
  19 use MojoFacets::Import::HTMLTable;
  20 use MojoFacets::Import::CSV;
  21
  22 our $loaded;
  23 our $filters;
  24
  25 sub index {
  26         my $self = shift;
  27
  28         my $data_dir = $self->app->home->rel_dir('data');
  29         die "no data dir $data_dir" unless -d $data_dir;
  30
  31         my @files;
  32         my $changes;
  33         find( sub {
  34                 my $file = $File::Find::name;
  35                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  36                         $file =~ s/$data_dir\/*//;
  37                         push @files, $file;
  38                 } elsif ( -f $file && $file =~ m/([^\/]+)\.changes\/(\d+\.\d+.+)/ ) {
  39                         push @{ $changes->{$1} }, $2
  40                 } elsif ( -d $file && $file =~ m/\.html$/ ) {
  41                         $file =~ s/$data_dir\/*//;
  42                         push @files, $file;
  43                 } elsif ( -f $file && $file =~ m/\.csv$/i ) {
  44                         $file =~ s/$data_dir\/*//;
  45                         push @files, $file;
  46                 } else {
  47                         #warn "IGNORE: $file\n";
  48                 }
  49         }, $data_dir);
  50
  51         @files = sort { $loaded->{$b}->{mtime} <=> $loaded->{$a}->{mtime} || lc $a cmp lc $b } @files,
  52                         grep { defined $loaded->{$_}->{generated} } keys %$loaded;
  53         my $size;
  54         $size->{$_} = -s "$data_dir/$_" foreach @files;
  55
  56         $self->render(
  57                 files => [ @files ],
  58                 size => $size,
  59                 loaded => $loaded,
  60                 filters => $filters,
  61                 dump_path => { map { $_ => $self->_dump_path($_) } @files },
  62                 changes => $changes,
  63         );
  64 }
  65
  66 sub _dump_path {
  67         my ( $self, $name ) = @_;
  68         my $dir = $self->app->home->rel_dir('data');
  69         $name =~ s/^$dir//;
  70         $name =~ s/\/+/_/g;
  71         return '/tmp/mojo_facets.' . $name . '.storable';
  72 }
  73
  74 sub _save {
  75         my ( $self, $path ) = @_;
  76
  77         my $dump_path = $self->_dump_path( $path );
  78         my $first_load = ! -e $dump_path;
  79         warn "save loaded to $dump_path";
  80         my $info = $loaded->{$path};
  81         store $info, $dump_path;
  82
  83         if ( $first_load ) {
  84                 my $mtime = $loaded->{$path}->{mtime};
  85                 utime $mtime, $mtime, $dump_path;
  86                 warn "sync time to $path at $mtime\n";
  87         }
  88
  89         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  90         return $dump_path;
  91 }
  92
  93
  94 sub __stats {
  95
  96         my $stats;
  97
  98         my $nr_items = $#{ $_[0] } + 1;
  99
 100         warn "__stats $nr_items\n";
 101
 102         foreach my $e ( @{ $_[0] } ) {
 103                 foreach my $n ( keys %$e ) {
 104                         $stats->{$n}->{count}++;
 105                         my @v;
 106                         if ( ref $e->{$n} eq 'ARRAY' ) {
 107                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 108                                 @v = @{ $e->{$n} };
 109                         } else {
 110                                 @v = ( $e->{$n} );
 111                         }
 112
 113                         foreach my $x ( @v ) {
 114                                 $stats->{$n}->{numeric}++
 115                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 116                                 $stats->{$n}->{empty}++
 117                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 118                         }
 119
 120                 }
 121         }
 122
 123         foreach my $n ( keys %$stats ) {
 124                 my $s = $stats->{$n};
 125                 next unless defined $s->{array};
 126                 if ( $s->{array} == $s->{count} ) {
 127                         delete $s->{array};
 128                         if ( $s->{count} == $nr_items ) {
 129                                 warn "check $n for uniqeness\n";
 130                                 my $unique;
 131                                 foreach my $e ( @{ $_[0] } ) {
 132                                         if ( ++$unique->{ $e->{$n}->[0] } == 2 ) {
 133                                                 $unique = 0;
 134                                                 last;
 135                                         }
 136                                 }
 137                                 if ( $unique ) {
 138                                         $stats->{$n}->{unique} = 1;
 139                                         #warn "# $n unique ",dump( $unique );
 140                                 }
 141                         }
 142                 }
 143         }
 144
 145         warn "# __stats ",dump($stats);
 146
 147         return $stats;
 148 }
 149
 150 sub _param_or_session {
 151         $_[0]->param( $_[1] ) || $_[0]->session( $_[1] )
 152 }
 153
 154 sub stats {
 155         my $self = shift;
 156         my $path = $self->_param_or_session('path');
 157         warn "stats $path\n";
 158         delete $loaded->{$path}->{stats};
 159         $self->redirect_to( '/data/columns' );
 160 }
 161
 162
 163 sub _load_path {
 164         my ( $self, $path ) = @_;
 165
 166         return if defined $loaded->{$path}->{'generated'};
 167
 168         my $full_path = $self->app->home->rel_file( 'data/' . $path );
 169         $self->redirect_to('/data/index') unless -r $full_path;
 170
 171         my $dump_path = $self->_dump_path( $path );
 172
 173         if ( defined $loaded->{$path}->{data} ) {
 174                 my $mtime = (stat($full_path))[9];
 175                 return if $loaded->{$path}->{mtime} == $mtime;
 176                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
 177         } elsif ( -e $dump_path ) {
 178                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
 179                 my $info = retrieve $dump_path;
 180                 $loaded->{ $path } = $info;
 181                 return;
 182         }
 183
 184         my $data;
 185         if ( -f $full_path ) {
 186                 if ( $full_path =~ m/.csv/i ) {
 187                         $data = MojoFacets::Import::CSV->new( full_path => $full_path )->data;
 188                 } else {
 189                         $data = MojoFacets::Import::File->new( full_path => $full_path, path => $path )->data;
 190                 }
 191         } elsif ( -d $full_path && $full_path =~ m/.html/ ) {
 192                 $data = MojoFacets::Import::HTMLTable->new( dir => $full_path )->data;
 193         } else {
 194                 die "can't load $full_path";
 195         }
 196
 197         my @header;
 198
 199         if ( defined $data->{header} ) {
 200                 if ( ref $data->{header} eq 'ARRAY' ) {
 201                         @header = @{ $data->{header} };
 202                 } else {
 203                         warn "header not array ", dump( $data->{header} );
 204                 }
 205         }
 206
 207         my $stats = __stats( $data->{items} );
 208
 209         @header =
 210                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 211                 grep { defined $stats->{$_}->{count} } keys %$stats
 212                 unless @header;
 213
 214         my $info = {
 215                 header => [ @header ],
 216                 stats  => $stats,
 217                 full_path => $full_path,
 218                 size => -s $full_path,
 219                 mtime => (stat($full_path))[9],
 220                 data => $data,
 221         };
 222
 223         $loaded->{ $path } = $info;
 224         $self->_save( $path );
 225
 226 }
 227
 228
 229 sub load {
 230         my $self = shift;
 231
 232         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 233
 234         my @paths = $self->param('paths');
 235         warn "# paths ", dump @paths;
 236
 237         foreach my $p ( keys %$loaded ) {
 238                 next if grep { /^\Q$p\E$/ } @paths;
 239                 warn "remove $p from memory\n";
 240                 delete $loaded->{$p};
 241         }
 242
 243         $self->_load_path( $_ ) foreach @paths;
 244
 245         warn "# path $path\n";
 246         $self->_load_path( $path );
 247
 248         $self->session( 'path' => $path );
 249
 250         my $redirect_to = '/data/items';
 251
 252         $self->session( 'header' => $loaded->{$path}->{header} );
 253         if ( ! defined $loaded->{$path}->{columns} ) {
 254                 my $columns_path = $self->_permanent_path( 'columns' );
 255                 if ( -e $columns_path ) {
 256                         my @columns = map { s/[\r\n]+$//; $_ } read_file $columns_path, binmode => ':utf8';
 257                         $loaded->{$path}->{columns} = [ @columns ];
 258                         warn "# columns_path $columns_path ",dump(@columns);
 259                 } else {
 260                         $loaded->{$path}->{columns} = $loaded->{$path}->{header}
 261                 }
 262
 263                 $redirect_to = '/data/columns';
 264         }
 265         $self->session( 'columns' => $loaded->{$path}->{columns} );
 266         $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 267         $self->redirect_to( $redirect_to );
 268 }
 269
 270
 271 sub _loaded {
 272         my ( $self, $name ) = @_;
 273         my $path = $self->session('path') || $self->param('path');
 274         $self->redirect_to('/data/index') unless $path;
 275
 276         if ( defined $loaded->{$path}->{modified} && $loaded->{$path}->{modified} > 1 ) {
 277                 my $caller = (caller(1))[3];
 278                 if ( $caller =~ m/::edit/ ) {
 279                         warn "rebuild stats for $path ignored caller $caller\n";
 280                 } else {
 281                         warn "rebuild stats for $path FORCED by modified caller $caller\n";
 282                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 283                         $loaded->{$path}->{modified} = 1;
 284                 }
 285         }
 286
 287         if ( ! defined $loaded->{$path}->{$name} ) {
 288                 warn "$path $name isn't loaded\n";
 289                 $self->_load_path( $path );
 290                 if ( ! defined $loaded->{$path}->{stats} ) {
 291                         warn "rebuild stats for $path\n";
 292                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 293                 }
 294                 if ( ! defined $loaded->{$path}->{$name} ) {
 295                         warn "MISSING $name for $path\n";
 296                         $self->redirect_to('/data/index')
 297                 }
 298         }
 299
 300         $self->session( 'modified' => $loaded->{$path}->{modified} );
 301
 302         return $loaded->{$path}->{$name};
 303 }
 304
 305
 306 sub _checked {
 307         my $self = shift;
 308         my $checked;
 309         $checked->{$_}++ foreach @_;
 310 #       warn "# _checked ",dump($checked);
 311         return $checked;
 312 }
 313
 314 sub _permanent_path {
 315         my $self = shift;
 316         my $path = $self->_param_or_session('path');
 317         $self->app->home->rel_dir('data') . '/' . join('.', $path, @_);
 318 }
 319
 320 sub __unac {
 321         my $n = shift;
 322         $n = unac_string($n);
 323         $n =~ s/\W+/_/g;
 324         return $n;
 325 }
 326
 327 sub _column_from_unac {
 328         my ($self,$name) = @_;
 329
 330         my $stats = $self->_loaded('stats');
 331         my $cols_norm = { map { __unac( $_ ) => $_ } keys %$stats };
 332
 333         $cols_norm->{$name} || die "can't find column $name in ", dump($cols_norm);
 334 }
 335
 336 sub _export_path {
 337         my $self = shift;
 338         my $path = $self->_param_or_session('path');
 339         if ( ! $path ) {
 340                 warn "no path in param or session";
 341                 return;
 342         }
 343         my $dir = $self->app->home->rel_dir('public') . "/export/$path";
 344         mkpath $dir unless -e $dir;
 345         my $name = join('.', map { __unac($_) } @_ );
 346         $dir . '/' . $name;
 347 }
 348
 349 sub columns {
 350     my $self = shift;
 351
 352         if ( $self->param('columns') ) {
 353                 my @columns = $self->_param_array('columns');
 354                 write_file( $self->_permanent_path( 'columns' ), { binmode => ':utf8' }, map { "$_\n" } @columns );
 355                 $self->redirect_to('/data/items');
 356         }
 357
 358         my $stats = $self->_loaded( 'stats' );
 359
 360         my @columns;
 361         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 362
 363         foreach my $c ( @{ $self->session( 'header' ) } ) {
 364                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 365         }
 366
 367     $self->render(
 368                 message => 'Select columns to display',
 369                 stats => $stats,
 370                 columns => \@columns,
 371                 checked => $self->_checked( $self->_param_array('columns') ),
 372         );
 373 }
 374
 375 sub _param_array {
 376     my ($self,$name) = @_;
 377
 378         my @array = $self->param($name);
 379         my $path  = $self->session('path');
 380
 381         if ( @array ) {
 382                 $self->session($name => [ @array ]);
 383                 $loaded->{$path}->{$name} = [ @array ];
 384         } elsif ( my $session = $self->session($name) ) {
 385                 if ( ref $session eq 'ARRAY' ) {
 386                         @array = @$session;
 387                 } else {
 388                         die "$name not array ",dump($session);
 389                 }
 390         }
 391         #warn "# $name ",dump @array;
 392         return @array;
 393 }
 394
 395 sub _param_scalar {
 396     my ($self,$name,$default) = @_;
 397
 398         my $scalar = $self->param($name);
 399
 400         if ( defined $scalar ) {
 401                 $self->session($name => $scalar);
 402         } else {
 403                 $scalar = $self->session($name);
 404         }
 405
 406         if ( ! defined $scalar ) {
 407                 $scalar = $default;
 408                 die "no default for $name" unless defined $scalar;
 409                 $self->session($name => $scalar);
 410         }
 411
 412         warn "# _param_scalar $name ",dump $scalar;
 413         return $scalar;
 414 }
 415
 416 sub filter {
 417         my $self = shift;
 418
 419         my $name = $self->param('filter_name') || die "name?";
 420         my @vals = $self->param('filter_vals');
 421
 422         $self->_remove_filter( $name );
 423         if ( @vals ) {
 424                 $self->_filter_on_data( $name, @vals );
 425                 if ( my $permanent = $self->param('_permanent') ) {
 426                         my $permanent_path = $self->_export_path( 'filter', $name, $permanent );
 427                         write_file $permanent_path, { binmode => ':utf8' }, map { "$_\n" } @vals;
 428                         warn "permanent filter $permanent_path ", -s $permanent_path;
 429                 }
 430         }
 431
 432         $self->session( 'offset' => 0 );
 433
 434         $self->redirect_to('/data/items');
 435 }
 436
 437 sub _filter_on_data {
 438         my ( $self, $name, @vals ) = @_;
 439
 440         my $path = $self->session('path');
 441
 442         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 443                 warn "filter $name not found in data set";
 444                 return;
 445         }
 446
 447         $filters->{$name} = [ @vals ];
 448         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 449
 450         my $filter_hash;
 451         $filter_hash->{$_}++ foreach @vals;
 452
 453         #warn "# filter_hash ",dump( $filter_hash );
 454
 455         my $items = $self->_loaded('data')->{items};
 456
 457         my $include_missing = defined $filter_hash->{_missing};
 458         my $filtered_items;
 459
 460         foreach my $i ( 0 .. $#$items ) {
 461
 462                 if ( defined $items->[$i]->{$name} ) {
 463                         my $row = $items->[$i]->{$name};
 464                         $row = [ $row ] unless ref $row eq 'ARRAY'; # FIXME probably wrong place
 465                         foreach my $v ( @$row ) {
 466                                 if ( defined $filter_hash->{ $v } ) {
 467                                         $filtered_items->{$i}++;
 468                                 }
 469                         }
 470                 } elsif ( $include_missing ) {
 471                         $filtered_items->{$i}++;
 472                 }
 473         }
 474
 475         #warn "# filter $name ",dump($filtered_items);
 476
 477         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 478         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 479 }
 480
 481
 482 sub _current_filters {
 483         my $self = shift;
 484         my $current_filters;
 485         my $stats = $self->_loaded('stats');
 486
 487         $current_filters->{ $_ } = $filters->{ $_ }
 488                 foreach ( grep { defined $filters->{ $_ } } keys %$stats )
 489         ;
 490         warn "# _current_filters ",dump( keys %$current_filters );
 491         return $current_filters;
 492 }
 493
 494 sub _data_sorted_by {
 495         my ( $self, $order ) = @_;
 496
 497         my $path = $self->session('path');
 498
 499         warn "_data_sorted_by $order from $path";
 500
 501         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 502                 return $loaded->{$path}->{sorted}->{$order};
 503         }
 504
 505         my $data = $self->_loaded( 'data' );
 506         my $numeric = $self->_is_numeric($order);
 507         my $missing = $numeric ? 0 : '';
 508         no warnings qw(numeric);
 509         my $nr = 0;
 510         my @sorted = map {
 511                 $_->[0]
 512         } sort {
 513                 if ( $numeric ) {
 514                         $a->[1] <=> $b->[1]
 515                 } else {
 516                         $a->[1] cmp $b->[1]
 517                 }
 518         } map {
 519                 my $v;
 520                 if ( ! exists $_->{$order} ) {
 521                         $v = $missing;
 522                 } elsif ( ref $_->{$order} eq 'ARRAY' ) {
 523                         $v = join('', @{$_->{$order}});
 524                 } else {
 525                         $v = $_->{$order};
 526                 }
 527                 [ $nr++, $v ]
 528         } @{ $data->{items} }
 529         ;
 530
 531         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 532         #warn "# sorted ",dump( @sorted );
 533
 534         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 535 }
 536
 537
 538 sub __all_filters {
 539         my $order = pop @_;
 540         join(',', sort(@_), 'order', $order);
 541 }
 542
 543 sub items {
 544         my $self = shift;
 545
 546         if ( my $show = $self->param('id') ) {
 547                 $self->param('show', $show);
 548                 warn "show $show\n";
 549         }
 550
 551         my $path = $self->session('path');
 552
 553         my @columns = $self->_param_array('columns');
 554         $self->redirect_to('/data/columns') unless @columns;
 555         my $order   = $self->_param_scalar('order', $columns[0]);
 556         my $sort    = $self->_param_scalar('sort', 'a');
 557         my $offset  = $self->_param_scalar('offset', 0);
 558         my $limit   = $self->_param_scalar('limit', 20);
 559         $self->_param_scalar('show', 'table');
 560
 561         # fix offset when changing limit
 562         $offset = int( $offset / $limit ) * $limit;
 563
 564         if ( ! grep { /^\Q$order\E$/ } @columns ) {
 565                 $order = $columns[0];
 566                 $self->session( order => $order );
 567         }
 568         my $sorted = $self->_data_sorted_by( $order );
 569
 570         my @filter_names;
 571         if ( $filters ) {
 572                 foreach my $name ( keys %$filters ) {
 573                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 574                                 warn "skip filter $name not found in $path\n";
 575                                 next;
 576                         }
 577                         push @filter_names, $name;
 578                 }
 579                 warn "filter_names ",dump( @filter_names );
 580                 foreach my $name ( @filter_names ) {
 581                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 582                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 583                 }
 584         }
 585
 586         my $all_filters = __all_filters( @filter_names,$order );
 587
 588 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 589
 590         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 591
 592                 my $path_filters = $loaded->{$path}->{filters};
 593
 594                 warn "create combined filter for $all_filters from ", $#$sorted + 1, " items\n";
 595
 596                 my @filtered;
 597                 foreach my $i ( 0 .. $#$sorted ) {
 598                         my $pos = $sorted->[$i];
 599
 600                         if ( $#filter_names == -1 ) {
 601                                 push @filtered, $pos;
 602                                 next;
 603                         }
 604
 605                         my $skip = 0;
 606                         foreach ( @filter_names ) {
 607                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 608                         }
 609                         next if $skip;
 610
 611                         push @filtered, $pos;
 612                 }
 613
 614                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 615         }
 616
 617         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 618                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 619
 620         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 621
 622         my $data = $self->_loaded('data');
 623
 624         my $code = $self->_param_scalar('code','');
 625         $code =~ s{[\r\n]+$}{}s;
 626
 627         my $commit = $self->param('commit');
 628         my $test = $self->param('test');
 629
 630         my $commit_changed;
 631
 632         if ( $code && ( $test || $commit ) ) {
 633                 # XXX find columns used in code snippet and show them to user
 634                 my $order = 0;
 635                 foreach my $column ( $code =~ m/\$row->{([^}]+)}/g ) {
 636                         if ( $column =~ s/^(['"])// ) {
 637                                 $column =~ s/$1$//;
 638                         }
 639                         next if $column =~ m/\$/; # hide columns with vars in them
 640                         $commit_changed->{$column} = 0;
 641                 }
 642         }
 643
 644         my $code_path = $self->app->home->rel_dir('public') . "/code";
 645         if ( $commit ) {
 646
 647                 warn "# commit on ", $#$filtered + 1, " items:\n$code\n";
 648                 my $out;
 649                 foreach ( 0 .. $#$filtered ) {
 650                         my $i = $filtered->[$_];
 651                         my $row = $data->{items}->[$i];
 652                         my $update;
 653                         eval $code;
 654                         foreach ( keys %$update ) {
 655                                 $commit_changed->{$_}++;
 656                                 $row->{$_} = $update->{$_};
 657                         }
 658                 }
 659                 if ( my $description = $self->param('code_description') ) {
 660                         my $depends = $self->param('code_depends') || die "no code_depends?";
 661                         my $path = "$code_path/$depends.$description.pl";
 662                         if ( -e $path && ! $self->param('overwrite') ) {
 663                                 warn "# code $path not saved\n";
 664                         } else {
 665                                 write_file(  $path, { binmode => ':utf8' }, $code );
 666                                 warn "code $path ", -s $path, " bytes saved\n";
 667                         }
 668                 }
 669                 $code = '';
 670                 if ( $out ) {
 671                         my $commit_dataset = join('.'
 672                                 , $self->param('code_depends')
 673                                 , $self->param('code_description')
 674                                 , time()
 675                         );
 676                         my $key = $self->param('code_depends');
 677                         $key =~ s/,.+$//;
 678                         $key ||= 'key';
 679                         my $items;
 680                         foreach my $n ( keys %$out ) {
 681                                 my $i = { $key => [ $n ] };
 682                                 my $ref = ref $out->{$n};
 683                                 if ( $ref eq 'HASH' ) {
 684                                         $i->{$_} = [ $out->{$n}->{$_} ] foreach keys %{ $out->{$n} };
 685                                 } elsif ( $ref eq 'ARRAY' ) {
 686                                         $i->{$_} = $out->{$n};
 687                                 } elsif ( ! $ref ) {
 688                                         $i->{value} = [ $out->{$n} ];
 689                                 } else {
 690                                         $i->{_error} = [ dump($out->{$n}) ];
 691                                 }
 692                                 push @$items, $i;
 693                         };
 694                         undef $out;
 695                         my $stats = __stats( $items );
 696                         my @columns = grep { ! m/^\Q$key\E$/ } sort keys %$stats;
 697                         unshift @columns, $key;
 698
 699                         $loaded->{$commit_dataset} = {
 700                                 header => [ @columns ],
 701                                 columns => [ @columns ],
 702                                 mtime => time(),
 703                                 data => { items => $items },
 704                                 stats => $stats,
 705                                 generated => 1,
 706                         };
 707                         warn "# loaded out ", dump( $loaded->{$commit_dataset} );
 708                         $self->session('path', $commit_dataset);
 709                         $self->session('columns', [ @columns ]);
 710                         $self->session('order', $key);
 711                         $self->redirect_to('/data/items');
 712                         return; # FIXME needed to correctly show columns
 713                 }
 714
 715                 # this might move before $out to recalculate stats on source dataset?
 716                 __path_modified( $path, 2 );
 717                 my $c = { map { $_ => 1 } @columns };
 718                 my @added_columns = sort grep { ! $c->{$_} } keys %$commit_changed;
 719                 warn "# added_columns ",dump( @added_columns );
 720                 unshift @columns, @added_columns;
 721
 722                 $self->session('columns', [ @columns ]);
 723                 $loaded->{$path}->{columns} = [ @columns ];
 724                 warn "# new columns ",dump( @columns );
 725
 726                 __invalidate_path_column( $path, $_ ) foreach keys %$commit_changed;
 727         }
 728
 729         my $sorted_items;
 730         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 731         my $test_changed;
 732         my $out;
 733         foreach ( 0 .. $limit ) {
 734                 my $i = $_ + $offset;
 735                 last unless defined $filtered->[$i];
 736                 $i = $from_end - $i if $from_end;
 737                 my $id = $filtered->[$i];
 738                 my $row = Storable::dclone $data->{items}->[ $id ];
 739                 if ( $code && $test ) {
 740                         my $update;
 741                         eval $code;
 742                         if ( $@ ) {
 743                                 warn "ERROR evaling\n$code\n$@";
 744                                 $self->stash('eval_error', $@) if $@;
 745                         } else {
 746                                 warn "EVAL ",dump($update);
 747                                 foreach ( keys %$update ) {
 748                                         $test_changed->{$_}++;
 749                                         $row->{$_} = $update->{$_};
 750                                 }
 751                         }
 752                 }
 753                 $row->{_row_id} ||= $id;
 754                 push @$sorted_items, $row;
 755         }
 756
 757         if ( $self->param('export') ) {
 758                 my $export_path = $self->_export_path( 'items', @columns);
 759                 open(my $fh, '>', $export_path) || warn "ERROR: can't open $export_path: $!";
 760                 foreach my $f ( 0 .. $#$filtered ) {
 761                         print $fh join("\t", map {
 762                                 my $i = $data->{items}->[ $filtered->[$f] ];
 763                                 my $v = '\N';
 764                                 if ( ! defined $i->{$_} ) {
 765                                         # nop
 766                                 } elsif ( ref $i->{$_} eq 'ARRAY' ) {
 767                                         $v =join(',', @{ $i->{$_} });
 768                                         $v = '\N' if length($v) == 0;
 769                                 } else {
 770                                         $v = dump $i->{$_};
 771                                 }
 772                                 $v;
 773                         } @columns),"\n";
 774                 }
 775                 close($fh);
 776                 warn "export $export_path ", -s $export_path, " bytes\n";
 777         }
 778
 779         warn "# test_changed ",dump( $test_changed );
 780         my $c = { map { $_ => 1 } @columns };
 781         my @added_columns = sort grep { ! $c->{$_} } keys %$test_changed;
 782         unshift @columns, @added_columns;
 783
 784         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 785
 786         my $code_depends = $self->param('code_depends')||
 787         join(',', sort grep { $test_changed->{$_} == 0 } keys %$test_changed );
 788         my $code_description = $self->param('code_description') ||
 789         join(',', @added_columns);
 790
 791         $code_depends ||= $code_description; # self-modifing
 792
 793         warn "# test_changed ",dump( $test_changed, $code_depends, $code_description );
 794
 795         $self->render(
 796                 order => $order,
 797                 offset => $offset,
 798                 limit => $limit,
 799                 sorted => $sorted_items,
 800                 columns => [ @columns ],
 801                 rows => $#$filtered + 1,
 802                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 803                 unique  => { map { $_, $self->_is_unique( $_) } @columns },
 804                 filters => $self->_current_filters,
 805                 code => $code,
 806                 cols_changed => $commit ? $commit_changed : $test_changed,
 807                 code_depends => $code_depends,
 808                 code_description => $code_description,
 809                 code_path => $code_path,
 810                 out => $out,
 811         );
 812
 813 }
 814
 815
 816 sub order {
 817         my $self = shift;
 818         $self->session('order', $self->param('order'));
 819         $self->session('sort', $self->param('sort'));
 820         $self->redirect_to('/data/items');
 821 }
 822
 823 sub _is_numeric {
 824         my ( $self, $name ) = @_;
 825
 826         my $stats = $self->_loaded( 'stats' );
 827
 828         # sort facet numerically if more >50% elements are numeric
 829         my $count = $stats->{$name}->{count};
 830         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 831         defined $stats->{$name}->{numeric} &&
 832                 $stats->{$name}->{numeric} > $count / 2;
 833 }
 834
 835 sub _is_unique {
 836         my ( $self, $name ) = @_;
 837         my $stats = $self->_loaded( 'stats' );
 838         defined $stats->{$name}->{unique};
 839 }
 840
 841 sub _remove_filter {
 842         my ($self,$name) = @_;
 843         warn "_remove_filter $name\n";
 844
 845         my $path = $self->session('path');
 846
 847         delete $filters->{$name};
 848         delete $loaded->{$path}->{filters}->{$name};
 849         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 850
 851         foreach (
 852                         grep { /\Q$name\E/ }
 853                         keys %{ $loaded->{$path}->{filtered} }
 854         ) {
 855                 delete $loaded->{$path}->{filtered}->{$_};
 856                 warn "remove filtered cache $_";
 857         }
 858 }
 859
 860 sub facet {
 861         my $self = shift;
 862
 863         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 864
 865         if ( my $name = $self->param('remove') ) {
 866                 $self->_remove_filter( $name );
 867                 $self->redirect_to( '/data/items' );
 868         }
 869
 870         my $facet;
 871         my $name = $self->param('name') || die "no name";
 872
 873         my $all = $self->_param_scalar('all', 1);
 874         my $data = $self->_loaded('data');
 875
 876         my $filters = $self->_current_filters;
 877         my $all_filters = __all_filters( keys %$filters,$self->session('order') );
 878         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 879                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 880
 881         if ( ! $filtered || $all ) {
 882                 $filtered = [ 0 .. $#{ $data->{items} } ];
 883                 warn "filter all values\n";
 884         } else {
 885                 warn "filter using $all_filters\n";
 886         }
 887
 888         foreach my $i ( @$filtered ) {
 889                 my $item = $data->{items}->[$i];
 890                 if ( ! exists $item->{$name} ) {
 891                         $facet->{ _missing }++;
 892                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 893                         $facet->{$_}++ foreach @{ $item->{$name} };
 894                 } else {
 895                         $facet->{ $item->{$name} }++;
 896                 }
 897         }
 898
 899 #       warn "# facet $name ",dump $facet;
 900
 901         my $checked;
 902         my @facet_names =
 903                   $all                      ? keys %$facet
 904                 : defined $filters->{$name} ? @{ $filters->{$name} }
 905                 : keys %$facet;
 906
 907         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 908
 909         my $numeric = $self->_is_numeric($name);
 910
 911         my $sort = $self->param('sort');
 912         # sort numeric facets with more than 5 values ascending
 913         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 914
 915         @facet_names = sort {
 916                 my $result;
 917                 if ( $sort eq 'a' ) {
 918                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 919                 } elsif ( $sort eq 'd' ) {
 920                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 921                 } elsif ( $sort eq 'c' ) {
 922                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 923                 } else {
 924                         warn "unknown sort: $sort";
 925                         $result = $a cmp $b;
 926                 }
 927                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 928                 $result;
 929         } @facet_names;
 930
 931         $self->render( name => $name, facet => $facet, checked => $checked,
 932                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 933         );
 934 }
 935
 936
 937 sub __invalidate_path_column {
 938         my ( $path, $name ) = @_;
 939
 940         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
 941                 delete $loaded->{$path}->{sorted}->{$name};
 942                 warn "# invalidate $path sorted $name\n";
 943         }
 944
 945         foreach ( grep { m/\Q$name\E/ } keys %{ $loaded->{$path}->{filtered} } ) {
 946                 delete $loaded->{$path}->{filtered}->{$_};
 947                 warn "# invalidate $path filtered $_\n";
 948         }
 949 }
 950
 951 sub __path_modified {
 952         my ( $path, $value ) = @_;
 953         $value = 1 unless defined $value;
 954
 955         $loaded->{$path}->{modified}  = $value;
 956
 957         warn "# __path_modified $path $value\n";
 958 }
 959
 960 sub edit {
 961         my $self = shift;
 962         my $new_content = $self->param('new_content');
 963         $new_content  ||= $self->param('content'); # backward compatibility with old actions
 964
 965         my $i = $self->param('_row_id');
 966         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
 967         my $path = $self->param('path') || die "no path";
 968         my $name = $self->param('name') || die "no name";
 969         my $status = 200; # 200 = OK, 201 = Created
 970
 971         my $data = $self->_loaded('data');
 972
 973         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
 974                 $new_content =~ s/^\s+//s;
 975                 $new_content =~ s/\s+$//s;
 976                 my $v;
 977                 if ( $new_content =~ /\xB6/ ) { # para
 978                         $v = [ split(/\s*\xB6\s*/, $new_content) ];
 979                 } else {
 980                         $v = [ $new_content ];
 981                 }
 982
 983                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
 984                 my $new = dump $v;
 985                 if ( $old ne $new
 986                         && ! ( $old eq 'undef' && length($new_content) == 0 ) # new value empty, previous undef
 987                 ) {
 988                         my $change = {
 989                                 path => $path,
 990                                 column => $name,
 991                                 pos => $i,
 992                                 old => $loaded->{$path}->{data}->{items}->[$i]->{$name},
 993                                 new => $v,
 994                                 time => $self->param('time') || time(),
 995                                 user => $self->param('user') || $ENV{'LOGNAME'},
 996                                 unique => {
 997                                         map { $_ => $loaded->{$path}->{data}->{items}->[$i]->{$_}->[0] }
 998                                         grep { defined $loaded->{$path}->{stats}->{$_}->{unique} }
 999                                         keys %{ $loaded->{$path}->{stats} }
1000                                 },
1001                         };
1002                         my $change_path = $self->_permanent_path( 'changes' );
1003                         mkdir $change_path unless -d $change_path;
1004                         $change_path .= '/' . $change->{time};
1005                         store $change, $change_path;
1006                         utime $change->{time}, $change->{time}, $change_path;
1007                         warn "# $change_path ", dump($change);
1008
1009                         warn "# change $path $i $old -> $new\n";
1010                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
1011
1012                         __invalidate_path_column( $path, $name );
1013
1014                         $status = 201; # created
1015                         # modified = 2 -- force rebuild of stats
1016                         __path_modified( $path, 2 );
1017
1018                         $new_content = join("\xB6",@$v);
1019
1020                 } else {
1021                         warn "# unchanged $path $i $old\n";
1022                         $status = 304;
1023                 }
1024         } else {
1025                 $new_content = "$path $i $name doesn't exist\n";
1026                 $status = 404;
1027         }
1028
1029         warn "# edit $status ", dump $new_content;
1030
1031         $self->render(
1032                 status => $status,
1033                 new_content => scalar $new_content,
1034         );
1035 }
1036
1037
1038 sub save {
1039         my $self = shift;
1040         my $path = $self->_param_or_session('path');
1041         my $dump_path = $self->_save( $path );
1042         __path_modified( $path, 0 );
1043
1044         $self->redirect_to( '/data/items' );
1045 }
1046
1047 sub export {
1048         my $self = shift;
1049
1050         my $dir = $self->app->home->rel_dir('public');
1051
1052         if ( my $import = $self->param('import') ) {
1053
1054                 if ( $import =~ m{/filter\.(.+?)\..+} ) {
1055                         my $name = $self->_column_from_unac( $1 );
1056
1057                         my @vals = map { chomp; $_ }
1058                                 read_file "$dir/export/$import", binmode => ':utf8';
1059
1060                         $self->_remove_filter( $name );
1061                         $self->_filter_on_data( $name, @vals );
1062                         $self->session( 'offset' => 0 );
1063                         $self->redirect_to('/data/items');
1064                 } else {
1065                         warn "UNKNOWN IMPORT $import";
1066                 }
1067         }
1068
1069         if ( my $remove = $self->param('remove') ) {
1070                 my $path = "$dir/export/$remove";
1071                 unlink $path if -e $path;
1072                 $path .= '.png';
1073                 unlink $path if -e $path;
1074         }
1075
1076         my $path = $self->_export_path || $self->redirect_to('/data/index');
1077
1078         my @files = grep { ! /\.png$/ } glob "$path/*";
1079         my $mtime = { map { $_ => (stat($_))[9] } @files };
1080         @files = sort { $mtime->{$b} <=> $mtime->{$a} } @files;
1081         $self->render( export => [ @files ] );
1082 }
1083
1084 sub __loaded_paths {
1085         return
1086                 grep { defined $loaded->{$_}->{data} }
1087                 keys %$loaded;
1088 }
1089
1090 1;