lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14
  15 our $loaded;
  16 our $filters;
  17
  18 sub index {
  19         my $self = shift;
  20
  21         my $path = $self->app->home->rel_dir('data');
  22         die "no data dir $path" unless -d $path;
  23
  24         my @files;
  25         find( sub {
  26                 my $file = $File::Find::name;
  27                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  28                         $file =~ s/$path\/*//;
  29                         push @files, $file;
  30                 } else {
  31                         warn "IGNORE: $file\n";
  32                 }
  33         }, $path);
  34
  35         @files = sort { lc $a cmp lc $b } @files;
  36         my $size;
  37         $size->{$_} = -s "$path/$_" foreach @files;
  38
  39         $self->render(
  40                 files => [ @files ],
  41                 size => $size,
  42                 loaded => $loaded,
  43                 filters => $filters,
  44         );
  45 }
  46
  47 sub _load_path {
  48         my ( $self, $path ) = @_;
  49
  50         return if defined $loaded->{$path}->{data};
  51
  52         my $full_path = $self->app->home->rel_file( 'data/' . $path );
  53         die "$full_path $!" unless -r $full_path;
  54
  55         # we could use Mojo::JSON here, but it's too slow
  56 #       $data = from_json read_file $path;
  57         my $data = read_file $full_path;
  58         warn "# data snippet: ", substr($data,0,200);
  59         my @header;
  60         if ( $path =~ m/\.js/ ) {
  61                 Encode::_utf8_on($data);
  62                 $data = from_json $data;
  63         } elsif ( $path =~ m/\.txt/ ) {
  64                 my @lines = split(/\r?\n/, $data);
  65                 $data = { items => [] };
  66
  67                 my $header_line = shift @lines;
  68                 my $multiline = $header_line =~ s/\^//g;
  69                 @header = split(/\|/, $header_line );
  70                 warn "# header ", dump( @header );
  71                 while ( my $line = shift @lines ) {
  72                         $line =~ s/\^//g;
  73                         chomp $line;
  74                         my @v = split(/\|/, $line);
  75                         while ( @lines && $#v < $#header ) {
  76                                 $line = $lines[0];
  77                                 $line =~ s/\^//g;
  78                                 chomp $line;
  79                                 my @more_v = split(/\|/, $line);
  80                                 if ( $#v + $#more_v > $#header ) {
  81                                         warn "short line: ",dump( @v );
  82                                         last;
  83                                 }
  84                                 shift @lines;
  85                                 $v[ $#v ] .= shift @more_v if @more_v;
  86                                 push @v, @more_v if @more_v;
  87
  88                                 if ( $#v > $#header ) {
  89                                         die "# splice $#header ", dump( @v );
  90                                         @v = splice @v, 0, $#header;
  91                                 }
  92                         }
  93                         my $item;
  94                         $item->{ $header[$_] || "f_$_" } = [ $v[$_] ] foreach ( 0 .. $#v );
  95                         push @{ $data->{items} }, $item;
  96                 }
  97         } else {
  98                 warn "file format unknown $path";
  99         }
 100
 101         my $stats;
 102
 103         foreach my $e ( @{ $data->{items} } ) {
 104                 foreach my $n ( keys %$e ) {
 105                         $stats->{$n}->{count}++;
 106                         my @v;
 107                         if ( ref $e->{$n} eq 'ARRAY' ) {
 108                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 109                                 @v = @{ $e->{$n} };
 110                         } else {
 111                                 @v = ( $e->{$n} );
 112                         }
 113
 114                         foreach my $x ( @v ) {
 115                                 $stats->{$n}->{numeric}++
 116                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 117                                 $stats->{$n}->{empty}++
 118                                         if $x =~ m/^\s*$/;
 119                         }
 120
 121                 }
 122         }
 123
 124         foreach my $n ( keys %$stats ) {
 125                 next unless defined $stats->{$n}->{array};
 126                 delete $stats->{$n}->{array}
 127                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 128         }
 129
 130         @header =
 131                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 132                 grep { defined $stats->{$_}->{count} } keys %$stats
 133                 unless @header;
 134
 135         warn dump($stats);
 136
 137         $loaded->{ $path } = {
 138                 header => [ @header ],
 139                 stats  => $stats,
 140                 full_path => $full_path,
 141                 size => -s $full_path,
 142                 data => $data,
 143         };
 144
 145 }
 146
 147
 148 sub load {
 149         my $self = shift;
 150
 151         my @paths = $self->param('paths');
 152         warn "# paths ", dump @paths;
 153         $self->_load_path( $_ ) foreach @paths;
 154
 155         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 156         warn "# path $path\n";
 157         $self->session('path' => $path);
 158         $self->_load_path( $path );
 159
 160         $self->session( 'header' => $loaded->{$path}->{header} );
 161         if ( ! defined $loaded->{$path}->{columns} ) {
 162                 $self->session( 'columns' => $loaded->{$path}->{header} );
 163                 $self->redirect_to( '/data/columns' );
 164         } else {
 165                 $self->session( 'columns' => $loaded->{$path}->{columns} );
 166                 $self->redirect_to( '/data/items' );
 167         }
 168
 169 }
 170
 171
 172 sub _loaded {
 173         my ( $self, $name ) = @_;
 174         my $path = $self->session('path');
 175         die "$path $name doesn't exist in loaded ",dump( $loaded )
 176                 unless defined $loaded->{$path}->{$name};
 177         return $loaded->{$path}->{$name};
 178 }
 179
 180
 181 sub _checked {
 182         my $self = shift;
 183         my $checked;
 184         $checked->{$_}++ foreach @_;
 185 #       warn "# _checked ",dump($checked);
 186         return $checked;
 187 }
 188
 189
 190 sub columns {
 191     my $self = shift;
 192
 193         if ( $self->param('columns') ) {
 194                 $self->_perm_array('columns');
 195                 $self->redirect_to('/data/items');
 196         }
 197
 198         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 199
 200         my @columns;
 201         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 202
 203         foreach my $c ( @{ $self->session( 'header' ) } ) {
 204                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 205         }
 206
 207     $self->render(
 208                 message => 'Select columns to display',
 209                 stats => $stats,
 210                 columns => \@columns,
 211                 checked => $self->_checked( $self->_perm_array('columns') ),
 212         );
 213 }
 214
 215 sub _perm_array {
 216     my ($self,$name) = @_;
 217
 218         my @array = $self->param($name);
 219         my $path  = $self->session('path');
 220
 221         if ( @array ) {
 222                 $self->session($name => [ @array ]);
 223                 $loaded->{$path}->{$name} = [ @array ];
 224         } elsif ( my $session = $self->session($name) ) {
 225                 if ( ref $session eq 'ARRAY' ) {
 226                         @array = @$session;
 227                 } else {
 228                         die "$name not array ",dump($session);
 229                 }
 230         }
 231         warn "# $name ",dump @array;
 232         return @array;
 233 }
 234
 235 sub _perm_scalar {
 236     my ($self,$name,$default) = @_;
 237
 238         my $scalar = $self->param($name);
 239
 240         if ( defined $scalar ) {
 241                 $self->session($name => $scalar);
 242         } else {
 243                 $scalar = $self->session($name);
 244         }
 245
 246         if ( ! defined $scalar ) {
 247                 $scalar = $default;
 248                 die "no default for $name" unless defined $scalar;
 249                 $self->session($name => $scalar);
 250         }
 251
 252         warn "# _perm_scalar $name ",dump $scalar;
 253         return $scalar;
 254 }
 255
 256 sub filter {
 257         my $self = shift;
 258
 259         my $name = $self->param('filter_name') || die "name?";
 260         my @vals = $self->param('filter_vals');
 261
 262         warn "# filter $name vals ",dump(@vals);
 263
 264         if ( @vals ) {
 265                 $filters->{$name} = [ @vals ];
 266                 warn "# filter + $name $#vals\n";
 267         } else {
 268                 warn "# filter - $name\n";
 269                 delete $filters->{$name};
 270         }
 271
 272         warn "# filters ",dump($filters);
 273
 274         $self->session( 'offset' => 0 );
 275
 276         $self->redirect_to('/data/items');
 277 }
 278
 279
 280 sub _data_items {
 281         my ( $self, $all ) = @_;
 282         my $data = $self->_loaded( 'data' );
 283
 284         return @{ $data->{items} } if $all == 1;
 285
 286         my $filters = $self->_current_filters;
 287         my $filter_value;
 288         foreach my $f ( keys %$filters ) {
 289                 foreach my $n ( @{ $filters->{$f} } ) {
 290                         $filter_value->{$f}->{$n} = 1;
 291                 }
 292         }
 293         my @items = @{ $data->{items} };
 294         @items = grep {
 295                 my $i = $_;
 296                 my $pass = 1;
 297                 foreach my $n ( keys %$filter_value ) {
 298                         if ( ! exists $i->{$n} ) {
 299                                 if ( defined $filter_value->{$n}->{_missing} ) {
 300                                         $pass = 1;
 301                                         next;
 302                                 } else {
 303                                         $pass = 0;
 304                                         last;
 305                                 }
 306                         }
 307                         # and match any of values in element
 308                         my $have_values = 0;
 309                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 310                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 311                         }
 312                         if ( ! $have_values ) {
 313                                 $pass = 0;
 314                                 last;
 315                         }
 316                 }
 317                 $pass;
 318         } @items if $filter_value;
 319         return @items;
 320 }
 321
 322
 323 sub _current_filters {
 324         my $self = shift;
 325         my $current_filters;
 326         $current_filters->{ $_ } = $filters->{ $_ }
 327                 foreach (
 328                         grep { defined $filters->{ $_ } }
 329                         @{ $self->_loaded('header') }
 330                 );
 331         warn "# current_filters ",dump($current_filters);
 332         return $current_filters;
 333 }
 334
 335 sub _data_sorted_by {
 336         my ( $self, $order ) = @_;
 337
 338         my $path = $self->session('path');
 339
 340         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 341                 return $loaded->{$path}->{sorted}->{$order};
 342         }
 343
 344         my $data = $self->_loaded( 'data' );
 345         my $numeric = $self->_is_numeric($order);
 346         my $missing = $numeric ? 0 : '';
 347         no warnings qw(numeric);
 348         my $nr = 0;
 349         my @sorted = map {
 350                 $_->[0]
 351         } sort {
 352                 if ( $numeric ) {
 353                         $a->[1] <=> $b->[1]
 354                 } else {
 355                         $a->[1] cmp $b->[1]
 356                 }
 357         } map {
 358                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 359         } @{ $data->{items} }
 360         ;
 361
 362         warn "sorted $order"; # ,dump( @sorted );
 363
 364         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 365 }
 366
 367
 368 sub items {
 369         my $self = shift;
 370
 371         my $path = $self->session('path');
 372         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 373
 374         my @columns = $self->_perm_array('columns');
 375         $self->redirect_to('/data/columns') unless @columns;
 376         my $order   = $self->_perm_scalar('order', $columns[0]);
 377         my $sort    = $self->_perm_scalar('sort', 'a');
 378         my $offset  = $self->_perm_scalar('offset', 0);
 379         my $limit   = $self->_perm_scalar('limit', 20);
 380         $self->_perm_scalar('show', 'table');
 381
 382         # fix offset when changing limit
 383         $offset = int( $offset / $limit ) * $limit;
 384
 385         my $sorted = $self->_data_sorted_by( $order );
 386
 387         my $rows = $#$sorted + 1;
 388
 389         my @sorted;
 390         foreach my $i ( 0 .. $limit ) {
 391                 my $pos = $sort eq 'a' ? ( $i + $offset ) : ( $#$sorted - $i - $offset );
 392                 last unless defined $sorted->[$pos];
 393                 push @sorted, $loaded->{$path}->{data}->{items}->[ $sorted->[$pos] ];
 394         }
 395
 396 #       warn "# sorted ", dump $sorted;
 397
 398         $self->render(
 399                 order => $order,
 400                 offset => $offset,
 401                 limit => $limit,
 402                 sorted => [ @sorted ],
 403                 columns => [ @columns ],
 404                 rows => $rows,
 405                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 406                 filters => $self->_current_filters,
 407         );
 408
 409 }
 410
 411
 412 sub order {
 413         my $self = shift;
 414         $self->session('order', $self->param('order'));
 415         $self->session('sort', $self->param('sort'));
 416         $self->redirect_to('/data/items');
 417 }
 418
 419 sub _is_numeric {
 420         my ( $self, $name ) = @_;
 421
 422         my $stats = $self->_loaded( 'stats' );
 423
 424         # sort facet numerically if more >50% elements are numeric
 425         my $count = $stats->{$name}->{count};
 426         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 427         defined $stats->{$name}->{numeric} &&
 428                 $stats->{$name}->{numeric} > $count / 2;
 429 }
 430
 431 sub facet {
 432         my $self = shift;
 433
 434         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 435
 436         if ( my $remove = $self->param('remove') ) {
 437                 delete $filters->{$remove};
 438                 $self->redirect_to( '/data/items' );
 439         }
 440
 441         my $facet;
 442         my $name = $self->param('name') || die "no name";
 443
 444         my $all = $self->_perm_scalar('all', 1);
 445
 446         foreach my $i ( $self->_data_items($all) ) {
 447                 if ( ! exists $i->{$name} ) {
 448                         $facet->{ _missing }++;
 449                 } elsif ( ref $i->{$name} eq 'ARRAY' ) {
 450                         $facet->{$_}++ foreach @{ $i->{$name} };
 451                 } else {
 452                         $facet->{ $i->{$name} }++;
 453                 }
 454         }
 455
 456 #       warn "# facet $name ",dump $facet;
 457
 458         my $checked;
 459         my @facet_names =
 460                   $all                      ? keys %$facet
 461                 : defined $filters->{$name} ? @{ $filters->{$name} }
 462                 : keys %$facet;
 463
 464         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 465
 466         my $sort = $self->param('sort') || 'c';
 467
 468         # sort facet numerically if more >50% elements are numeric
 469         my $numeric = $self->_is_numeric($name);
 470
 471         @facet_names = sort {
 472                 if ( $sort =~ m/a/i ) {
 473                         $numeric ? $a <=> $b : lc $a cmp lc $b;
 474                 } elsif ( $sort =~ m/d/i ) {
 475                         $numeric ? $b <=> $a : lc $b cmp lc $a;
 476                 } elsif ( $sort =~ m/c/i ) {
 477                         $facet->{$b} <=> $facet->{$a};
 478                 } else {
 479                         warn "unknown sort: $sort";
 480                         $a cmp $b;
 481                 }
 482         } @facet_names;
 483
 484         $self->render( name => $name, facet => $facet, checked => $checked,
 485                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 486         );
 487 }
 488
 489 sub edit {
 490         my $self = shift;
 491         my $content = $self->param('content');
 492
 493         $self->render(
 494                 content => $content
 495         );
 496 }
 497
 498 1;