lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use Encode;
  11 use locale;
  12 use File::Find;
  13 use Storable;
  14 use Time::HiRes qw(time);
  15 use File::Path qw(mkpath);
  16 use Text::Unaccent::PurePerl;
  17
  18 use MojoFacets::Import::File;
  19 use MojoFacets::Import::HTMLTable;
  20 use MojoFacets::Import::CSV;
  21
  22 our $loaded;
  23 our $filters;
  24
  25 sub index {
  26         my $self = shift;
  27
  28         my $data_dir = $self->app->home->rel_dir('data');
  29         die "no data dir $data_dir" unless -d $data_dir;
  30
  31         my @files;
  32         my $changes;
  33         find( sub {
  34                 my $file = $File::Find::name;
  35                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  36                         $file =~ s/$data_dir\/*//;
  37                         push @files, $file;
  38                 } elsif ( -f $file && $file =~ m/([^\/]+)\.changes\/(\d+\.\d+.+)/ ) {
  39                         push @{ $changes->{$1} }, $2
  40                 } elsif ( -d $file && $file =~ m/\.html$/ ) {
  41                         $file =~ s/$data_dir\/*//;
  42                         push @files, $file;
  43                 } elsif ( -f $file && $file =~ m/\.csv$/i ) {
  44                         $file =~ s/$data_dir\/*//;
  45                         push @files, $file;
  46                 } elsif ( -f $file && $file =~ m/\.storable/i ) {
  47                         $file =~ s/$data_dir\/*//;
  48                         push @files, $file;
  49                 } else {
  50                         #warn "IGNORE: $file\n";
  51                 }
  52         }, $data_dir);
  53
  54         no warnings qw(uninitialized); # mtime
  55         @files = sort { $loaded->{$b}->{mtime} <=> $loaded->{$a}->{mtime} || lc $a cmp lc $b } @files,
  56                         grep { defined $loaded->{$_}->{generated} } keys %$loaded;
  57         my $size;
  58         $size->{$_} = -s "$data_dir/$_" foreach @files;
  59
  60         $self->render(
  61                 files => [ @files ],
  62                 size => $size,
  63                 loaded => $loaded,
  64                 filters => $filters,
  65                 dump_path => { map { $_ => $self->_dump_path($_) } @files },
  66                 changes => $changes,
  67         );
  68 }
  69
  70 sub _dump_path {
  71         my ( $self, $name ) = @_;
  72         my $dir = $self->app->home->rel_dir('data');
  73         $name =~ s/^$dir//;
  74         $name =~ s/\/+/_/g;
  75         return '/tmp/mojo_facets.' . $name . '.storable';
  76 }
  77
  78 sub _save {
  79         my ( $self, $path ) = @_;
  80
  81         my $dump_path = $self->_dump_path( $path );
  82         my $first_load = ! -e $dump_path;
  83         warn "save loaded to $dump_path";
  84         my $info = $loaded->{$path};
  85         store $info, $dump_path;
  86
  87         if ( $first_load ) {
  88                 my $mtime = $loaded->{$path}->{mtime};
  89                 utime $mtime, $mtime, $dump_path;
  90                 warn "sync time to $path at $mtime\n";
  91         }
  92
  93         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  94         return $dump_path;
  95 }
  96
  97
  98 sub __stats {
  99
 100         my $stats;
 101
 102         my $nr_items = $#{ $_[0] } + 1;
 103
 104         warn "__stats $nr_items\n";
 105
 106         foreach my $e ( @{ $_[0] } ) {
 107                 foreach my $n ( keys %$e ) {
 108                         $stats->{$n}->{count}++;
 109                         my @v;
 110                         if ( ref $e->{$n} eq 'ARRAY' ) {
 111                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 112                                 @v = @{ $e->{$n} };
 113                         } else {
 114                                 @v = ( $e->{$n} );
 115                         }
 116
 117                         foreach my $x ( @v ) {
 118                                 $stats->{$n}->{numeric}++
 119                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 120                                 $stats->{$n}->{empty}++
 121                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 122                         }
 123
 124                 }
 125         }
 126
 127         foreach my $n ( keys %$stats ) {
 128                 my $s = $stats->{$n};
 129                 next unless defined $s->{array};
 130                 if ( $s->{array} == $s->{count} ) {
 131                         delete $s->{array};
 132                         if ( $s->{count} == $nr_items ) {
 133                                 warn "check $n for uniqeness\n";
 134                                 my $unique;
 135                                 foreach my $e ( @{ $_[0] } ) {
 136                                         if ( ++$unique->{ $e->{$n}->[0] } == 2 ) {
 137                                                 $unique = 0;
 138                                                 last;
 139                                         }
 140                                 }
 141                                 if ( $unique ) {
 142                                         $stats->{$n}->{unique} = 1;
 143                                         #warn "# $n unique ",dump( $unique );
 144                                 }
 145                         }
 146                 }
 147         }
 148
 149         warn "# __stats ",dump($stats);
 150
 151         return $stats;
 152 }
 153
 154 sub _param_or_session {
 155         $_[0]->param( $_[1] ) || $_[0]->session( $_[1] )
 156 }
 157
 158 sub stats {
 159         my $self = shift;
 160         my $path = $self->_param_or_session('path');
 161         warn "stats $path\n";
 162         delete $loaded->{$path}->{stats};
 163         $self->redirect_to( '/data/columns' );
 164 }
 165
 166
 167 sub _load_path {
 168         my ( $self, $path ) = @_;
 169
 170         return if defined $loaded->{$path}->{'generated'};
 171
 172         my $full_path = $self->app->home->rel_file( 'data/' . $path );
 173         $self->redirect_to('/data/index') unless -r $full_path;
 174
 175         my $dump_path = $self->_dump_path( $path );
 176
 177         if ( defined $loaded->{$path}->{data} ) {
 178                 my $mtime = (stat($full_path))[9];
 179                 return if $loaded->{$path}->{mtime} == $mtime;
 180                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
 181         } elsif ( -e $dump_path ) {
 182                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
 183                 my $info = retrieve $dump_path;
 184                 $loaded->{ $path } = $info;
 185                 return;
 186         }
 187
 188         my $data;
 189         if ( -f $full_path ) {
 190                 if ( $full_path =~ m/.csv/i ) {
 191                         $data = MojoFacets::Import::CSV->new( full_path => $full_path )->data;
 192                 } elsif ( $full_path =~ m/.storable/ ) {
 193                         warn "open $full_path ", -s $full_path, " bytes";
 194                         open(my $pipe, "<", $full_path) || die $!;
 195                         while ( my $o = eval { Storable::fd_retrieve $pipe } ) {
 196                                 if ( defined $o->{item} ) {
 197                                         push @{ $data->{items} }, $o->{item};
 198                                 } else {
 199                                         warn "SKIP ",dump($o);
 200                                 }
 201                         }
 202                         close($pipe);
 203                         warn "loaded ", $#{ $data->{items} } + 1, " items from $full_path\n";
 204                 } else {
 205                         $data = MojoFacets::Import::File->new( full_path => $full_path, path => $path )->data;
 206                 }
 207         } elsif ( -d $full_path && $full_path =~ m/.html/ ) {
 208                 $data = MojoFacets::Import::HTMLTable->new( dir => $full_path )->data;
 209         } else {
 210                 die "can't load $full_path";
 211         }
 212
 213         my @header;
 214
 215         if ( defined $data->{header} ) {
 216                 if ( ref $data->{header} eq 'ARRAY' ) {
 217                         @header = @{ $data->{header} };
 218                 } else {
 219                         warn "header not array ", dump( $data->{header} );
 220                 }
 221         }
 222
 223         my $stats = __stats( $data->{items} );
 224
 225         @header =
 226                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 227                 grep { defined $stats->{$_}->{count} } keys %$stats
 228                 unless @header;
 229
 230         my $info = {
 231                 header => [ @header ],
 232                 stats  => $stats,
 233                 full_path => $full_path,
 234                 size => -s $full_path,
 235                 mtime => (stat($full_path))[9],
 236                 data => $data,
 237         };
 238
 239         $loaded->{ $path } = $info;
 240         $self->_save( $path );
 241
 242 }
 243
 244
 245 sub load {
 246         my $self = shift;
 247
 248         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 249
 250         my @paths = $self->param('paths');
 251         warn "# paths ", dump @paths;
 252
 253         foreach my $p ( keys %$loaded ) {
 254                 next if grep { /^\Q$p\E$/ } @paths;
 255                 warn "remove $p from memory\n";
 256                 delete $loaded->{$p};
 257         }
 258
 259         $self->_load_path( $_ ) foreach @paths;
 260
 261         warn "# path $path\n";
 262         $self->_load_path( $path );
 263
 264         $self->session( 'path' => $path );
 265
 266         my $redirect_to = '/data/items';
 267
 268         $self->session( 'header' => $loaded->{$path}->{header} );
 269         if ( ! defined $loaded->{$path}->{columns} ) {
 270                 my $columns_path = $self->_permanent_path( 'columns' );
 271                 if ( -e $columns_path ) {
 272                         my @columns = map { s/[\r\n]+$//; $_ } read_file $columns_path, binmode => ':utf8';
 273                         $loaded->{$path}->{columns} = [ @columns ];
 274                         warn "# columns_path $columns_path ",dump(@columns);
 275                 } else {
 276                         $loaded->{$path}->{columns} = $loaded->{$path}->{header}
 277                 }
 278
 279                 $redirect_to = '/data/columns';
 280         }
 281         $self->session( 'columns' => $loaded->{$path}->{columns} );
 282         $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 283         $self->redirect_to( $redirect_to );
 284 }
 285
 286
 287 sub _loaded {
 288         my ( $self, $name ) = @_;
 289         my $path = $self->session('path') || $self->param('path');
 290         $self->redirect_to('/data/index') unless $path;
 291
 292         if ( defined $loaded->{$path}->{modified} && $loaded->{$path}->{modified} > 1 ) {
 293                 my $caller = (caller(1))[3];
 294                 if ( $caller =~ m/::edit/ ) {
 295                         warn "rebuild stats for $path ignored caller $caller\n";
 296                 } else {
 297                         warn "rebuild stats for $path FORCED by modified caller $caller\n";
 298 #                       $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 299                         $loaded->{$path}->{rebuild_stats} = 1;
 300                         $loaded->{$path}->{modified} = 1;
 301                 }
 302         }
 303
 304         if ( defined $loaded->{$path}->{rebuild_stats} ) {
 305                 warn "rebuild_stats $path";
 306                 $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 307                 delete $loaded->{$path}->{rebuild_stats};
 308         }
 309
 310         if ( ! defined $loaded->{$path}->{$name} ) {
 311                 warn "$path $name isn't loaded\n";
 312                 $self->_load_path( $path );
 313                 if ( ! defined $loaded->{$path}->{stats} ) {
 314                         warn "rebuild stats for $path\n";
 315                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 316                 }
 317                 if ( ! defined $loaded->{$path}->{$name} ) {
 318                         warn "MISSING $name for $path\n";
 319                         $self->redirect_to('/data/index')
 320                 }
 321         }
 322
 323         $self->session( 'modified' => $loaded->{$path}->{modified} );
 324
 325         return $loaded->{$path}->{$name};
 326 }
 327
 328
 329 sub _checked {
 330         my $self = shift;
 331         my $checked;
 332         $checked->{$_}++ foreach @_;
 333 #       warn "# _checked ",dump($checked);
 334         return $checked;
 335 }
 336
 337 sub _permanent_path {
 338         my $self = shift;
 339         my $path = $self->_param_or_session('path');
 340         $self->app->home->rel_dir('data') . '/' . join('.', $path, @_);
 341 }
 342
 343 sub __unac {
 344         my $n = shift;
 345         $n = unac_string($n);
 346         $n =~ s/\W+/_/g;
 347         return $n;
 348 }
 349
 350 sub _column_from_unac {
 351         my ($self,$name) = @_;
 352
 353         my $stats = $self->_loaded('stats');
 354         my $cols_norm = { map { __unac( $_ ) => $_ } keys %$stats };
 355
 356         $cols_norm->{$name} || die "can't find column $name in ", dump($cols_norm);
 357 }
 358
 359 sub _export_path {
 360         my $self = shift;
 361         my $path = $self->_param_or_session('path');
 362         if ( ! $path ) {
 363                 warn "no path in param or session";
 364                 return;
 365         }
 366         my $dir = $self->app->home->rel_dir('public') . "/export/$path";
 367         mkpath $dir unless -e $dir;
 368         my $name = join('.', map { __unac($_) } @_ );
 369         my $full = $dir . '/' . $name;
 370         $full =~ s/\/+$// if -d $full; # strip trailing slash for dirs
 371         return $full;
 372 }
 373
 374 sub columns {
 375     my $self = shift;
 376
 377         if ( $self->param('columns') ) {
 378                 my @columns = $self->_param_array('columns');
 379                 write_file( $self->_permanent_path( 'columns' ), { binmode => ':utf8' }, map { "$_\n" } @columns );
 380                 $self->redirect_to('/data/items');
 381         }
 382
 383         my $stats = $self->_loaded( 'stats' );
 384
 385         my @columns;
 386         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 387
 388         foreach my $c ( @{ $self->session( 'header' ) } ) {
 389                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 390         }
 391
 392     $self->render(
 393                 message => 'Select columns to display',
 394                 stats => $stats,
 395                 columns => \@columns,
 396                 checked => $self->_checked( $self->_param_array('columns') ),
 397         );
 398 }
 399
 400 sub _param_array {
 401     my ($self,$name) = @_;
 402
 403         my @array = $self->param($name);
 404         my $path  = $self->session('path');
 405
 406         if ( @array ) {
 407                 $self->session($name => [ @array ]);
 408                 $loaded->{$path}->{$name} = [ @array ];
 409         } elsif ( my $session = $self->session($name) ) {
 410                 if ( ref $session eq 'ARRAY' ) {
 411                         @array = @$session;
 412                 } else {
 413                         die "$name not array ",dump($session);
 414                 }
 415         }
 416         #warn "# $name ",dump @array;
 417         return @array;
 418 }
 419
 420 sub _param_scalar {
 421     my ($self,$name,$default) = @_;
 422
 423         my $scalar = $self->param($name);
 424
 425         if ( defined $scalar ) {
 426                 $self->session($name => $scalar);
 427         } else {
 428                 $scalar = $self->session($name);
 429         }
 430
 431         if ( ! defined $scalar ) {
 432                 $scalar = $default;
 433                 die "no default for $name" unless defined $scalar;
 434                 $self->session($name => $scalar);
 435         }
 436
 437         warn "# _param_scalar $name ",dump $scalar;
 438         return $scalar;
 439 }
 440
 441 sub filter {
 442         my $self = shift;
 443
 444         my $name = $self->param('filter_name') || die "name?";
 445         my @vals = $self->param('filter_vals');
 446
 447         $self->_remove_filter( $name );
 448         if ( @vals ) {
 449                 $self->_filter_on_data( $name, @vals );
 450                 if ( my $permanent = $self->param('_permanent') ) {
 451                         my $permanent_path = $self->_export_path( 'filter', $name, $permanent );
 452                         write_file $permanent_path, { binmode => ':utf8' }, map { "$_\n" } @vals;
 453                         warn "permanent filter $permanent_path ", -s $permanent_path;
 454                 }
 455         }
 456
 457         $self->session( 'offset' => 0 );
 458
 459         $self->redirect_to('/data/items');
 460 }
 461
 462 sub _filter_on_data {
 463         my ( $self, $name, @vals ) = @_;
 464
 465         my $path = $self->session('path');
 466
 467         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 468                 warn "filter $name not found in data set";
 469                 return;
 470         }
 471
 472         $filters->{$name} = [ @vals ];
 473         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 474
 475         my $filter_hash;
 476         $filter_hash->{$_}++ foreach @vals;
 477
 478         #warn "# filter_hash ",dump( $filter_hash );
 479
 480         my $items = $self->_loaded('data')->{items};
 481
 482         my $include_missing = defined $filter_hash->{_missing};
 483         my $filtered_items;
 484
 485         foreach my $i ( 0 .. $#$items ) {
 486
 487                 if ( defined $items->[$i]->{$name} ) {
 488                         my $row = $items->[$i]->{$name};
 489                         $row = [ $row ] unless ref $row eq 'ARRAY'; # FIXME probably wrong place
 490                         foreach my $v ( @$row ) {
 491                                 if ( defined $filter_hash->{ $v } ) {
 492                                         $filtered_items->{$i}++;
 493                                 }
 494                         }
 495                 } elsif ( $include_missing ) {
 496                         $filtered_items->{$i}++;
 497                 }
 498         }
 499
 500         #warn "# filter $name ",dump($filtered_items);
 501
 502         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 503         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 504 }
 505
 506
 507 sub _current_filters {
 508         my $self = shift;
 509         my $current_filters;
 510         my $stats = $self->_loaded('stats');
 511
 512         $current_filters->{ $_ } = $filters->{ $_ }
 513                 foreach ( grep { defined $filters->{ $_ } } keys %$stats )
 514         ;
 515         warn "# _current_filters ",dump( keys %$current_filters );
 516         return $current_filters;
 517 }
 518
 519 sub _data_sorted_by {
 520         my ( $self, $order ) = @_;
 521
 522         my $path = $self->session('path');
 523
 524         warn "_data_sorted_by $order from $path";
 525
 526         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 527                 return $loaded->{$path}->{sorted}->{$order};
 528         }
 529
 530         my $data = $self->_loaded( 'data' );
 531         my $numeric = $self->_is_numeric($order);
 532         my $missing = $numeric ? 0 : '';
 533         no warnings qw(numeric);
 534         my $nr = 0;
 535         my @sorted = map {
 536                 $_->[0]
 537         } sort {
 538                 if ( $numeric ) {
 539                         $a->[1] <=> $b->[1]
 540                 } else {
 541                         $a->[1] cmp $b->[1]
 542                 }
 543         } map {
 544                 my $v;
 545                 if ( ! exists $_->{$order} ) {
 546                         $v = $missing;
 547                 } elsif ( ref $_->{$order} eq 'ARRAY' ) {
 548                         $v = join('', @{$_->{$order}});
 549                 } else {
 550                         $v = $_->{$order};
 551                 }
 552                 [ $nr++, $v ]
 553         } @{ $data->{items} }
 554         ;
 555
 556         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 557         #warn "# sorted ",dump( @sorted );
 558
 559         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 560 }
 561
 562
 563 sub __all_filters {
 564         my $order = pop @_;
 565         join(',', sort(@_), 'order', $order);
 566 }
 567
 568 our ($out, $key,$value);
 569
 570 sub __commit_path_code {
 571         my ( $path, $i, $code, $commit_changed ) = @_;
 572
 573         my $items = $loaded->{$path}->{data}->{items} || die "no items for $path";
 574         my $row = $items->[$i];
 575         my $update;
 576         eval $code;
 577         foreach ( keys %$update ) {
 578                 $$commit_changed->{$_}++;
 579                 $loaded->{$path}->{data}->{items}->[$i]->{$_} = $update->{$_};
 580         }
 581         #warn "__commit_path_code $path $i ",dump( $update );
 582 }
 583
 584 sub items {
 585         my $self = shift;
 586
 587         if ( my $show = $self->param('id') ) {
 588                 $self->param('show', $show);
 589                 warn "show $show\n";
 590         }
 591
 592         my $path = $self->session('path');
 593
 594         my @columns = $self->_param_array('columns');
 595         $self->redirect_to('/data/columns') unless @columns;
 596         my $order   = $self->_param_scalar('order', $columns[0]);
 597         my $sort    = $self->_param_scalar('sort', 'a');
 598         my $offset  = $self->_param_scalar('offset', 0);
 599         my $limit   = $self->_param_scalar('limit', 20);
 600         $self->_param_scalar('show', 'table');
 601
 602         # fix offset when changing limit
 603         $offset = int( $offset / $limit ) * $limit;
 604
 605         if ( ! grep { /^\Q$order\E$/ } @columns ) {
 606                 $order = $columns[0];
 607                 $self->session( order => $order );
 608         }
 609         my $sorted = $self->_data_sorted_by( $order );
 610
 611         my @filter_names;
 612         if ( $filters ) {
 613                 foreach my $name ( keys %$filters ) {
 614                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 615                                 warn "skip filter $name not found in $path\n";
 616                                 next;
 617                         }
 618                         push @filter_names, $name;
 619                 }
 620                 warn "filter_names ",dump( @filter_names );
 621                 foreach my $name ( @filter_names ) {
 622                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 623                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 624                 }
 625         }
 626
 627         my $all_filters = __all_filters( @filter_names,$order );
 628
 629 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 630
 631         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 632
 633                 my $path_filters = $loaded->{$path}->{filters};
 634
 635                 warn "create combined filter for $all_filters from ", $#$sorted + 1, " items\n";
 636
 637                 my @filtered;
 638                 foreach my $i ( 0 .. $#$sorted ) {
 639                         my $pos = $sorted->[$i];
 640
 641                         if ( $#filter_names == -1 ) {
 642                                 push @filtered, $pos;
 643                                 next;
 644                         }
 645
 646                         my $skip = 0;
 647                         foreach ( @filter_names ) {
 648                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 649                         }
 650                         next if $skip;
 651
 652                         push @filtered, $pos;
 653                 }
 654
 655                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 656         }
 657
 658         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 659                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 660
 661         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 662
 663         my $data = $self->_loaded('data');
 664
 665         my $code = $self->_param_scalar('code','');
 666         $code =~ s{\r}{}gs;
 667         $code =~ s{\n+$}{\n}s;
 668
 669         my $commit = $self->param('commit');
 670         my $test = $self->param('test');
 671
 672         my $commit_changed;
 673
 674         if ( $code && ( $test || $commit ) ) {
 675                 # XXX find columns used in code snippet and show them to user
 676                 my $order = 0;
 677                 foreach my $column ( $code =~ m/\$row->{([^}]+)}/g ) {
 678                         if ( $column =~ s/^(['"])// ) {
 679                                 $column =~ s/$1$//;
 680                         }
 681                         next if $column =~ m/\$/; # hide columns with vars in them
 682                         $commit_changed->{$column} = 0;
 683                 }
 684         }
 685
 686         my $code_path = $self->app->home->rel_dir('public') . "/code";
 687         if ( $commit ) {
 688
 689                 warn "# commit on ", $#$filtered + 1, " items:\n$code\n";
 690                 ( $key, $value, $out ) = ( 'key', 'value' );
 691                 foreach ( 0 .. $#$filtered ) {
 692                         my $i = $filtered->[$_];
 693                         __commit_path_code( $path, $i, $code, \$commit_changed );
 694                 }
 695
 696                 $self->_save_change({
 697                         path => $path,
 698                         time => $self->param('time') || time(),
 699                         user => $self->param('user') || $ENV{'LOGNAME'},
 700                         code => $code,
 701                         commit_changed => $commit_changed,
 702                 });
 703
 704                 if ( my $description = $self->param('code_description') ) {
 705                         my $depends = $self->param('code_depends') || die "no code_depends?";
 706                         my $path = "$code_path/$depends.$description.pl";
 707                         if ( -e $path && ! $self->param('overwrite') ) {
 708                                 warn "# code $path not saved\n";
 709                         } else {
 710                                 write_file(  $path, { binmode => ':utf8' }, "$code\n" );
 711                                 warn "code $path ", -s $path, " bytes saved\n";
 712                         }
 713                 }
 714
 715                 # remove console
 716                 $code = '';
 717                 if ( $out ) {
 718                         my $commit_dataset = join('.'
 719                                 , $self->param('code_depends')
 720                                 , $self->param('code_description')
 721                                 , time()
 722                         );
 723                         $key ||= 'key';
 724                         $value ||= 'value';
 725                         warn "key $key value $value";
 726                         my $items;
 727                         foreach my $n ( keys %$out ) {
 728                                 my $i = { $key => [ $n ] };
 729                                 my $ref = ref $out->{$n};
 730                                 if ( $ref eq 'HASH' ) {
 731                                         $i->{$_} = [ $out->{$n}->{$_} ] foreach keys %{ $out->{$n} };
 732                                 } elsif ( $ref eq 'ARRAY' ) {
 733                                         $i->{$_} = $out->{$n};
 734                                 } elsif ( ! $ref ) {
 735                                         $i->{$value} = [ $out->{$n} ];
 736                                 } else {
 737                                         $i->{_error} = [ dump($out->{$n}) ];
 738                                 }
 739                                 push @$items, $i;
 740                         };
 741                         undef $out;
 742                         my $stats = __stats( $items );
 743                         my @columns = grep { ! m/^\Q$key\E$/ } sort keys %$stats;
 744                         unshift @columns, $key;
 745
 746                         $loaded->{$commit_dataset} = {
 747                                 header => [ @columns ],
 748                                 columns => [ @columns ],
 749                                 mtime => time(),
 750                                 data => { items => $items },
 751                                 stats => $stats,
 752                                 generated => 1,
 753                         };
 754                         warn "# loaded out ", dump( $loaded->{$commit_dataset} );
 755                         $self->session('path', $commit_dataset);
 756                         $self->session('columns', [ @columns ]);
 757                         $self->session('order', $key);
 758                         $self->redirect_to('/data/items');
 759                         return; # FIXME needed to correctly show columns
 760                 }
 761
 762                 # this might move before $out to recalculate stats on source dataset?
 763                 __path_rebuild_stats( $path );
 764                 my $c = { map { $_ => 1 } @columns };
 765                 my @added_columns = sort grep { ! $c->{$_} } keys %$commit_changed;
 766                 warn "# added_columns ",dump( @added_columns );
 767                 unshift @columns, @added_columns;
 768
 769                 $self->session('columns', [ @columns ]);
 770                 $loaded->{$path}->{columns} = [ @columns ];
 771                 warn "# new columns ",dump( @columns );
 772
 773                 __invalidate_path_column( $path, $_ ) foreach keys %$commit_changed;
 774         }
 775
 776         my $sorted_items;
 777         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 778         my $test_changed;
 779         my ( $key, $value, $out ) = ( 'key', 'value' ); # XXX make local
 780         foreach ( 0 .. $limit ) {
 781                 my $i = $_ + $offset;
 782                 last unless defined $filtered->[$i];
 783                 $i = $from_end - $i if $from_end;
 784                 my $id = $filtered->[$i];
 785                 my $row = Storable::dclone $data->{items}->[ $id ];
 786                 if ( $code && $test ) {
 787                         my $update;
 788                         eval $code;
 789                         if ( $@ ) {
 790                                 warn "ERROR evaling $@", dump($code);
 791                                 $self->stash('eval_error', $@) if $@;
 792                         } else {
 793                                 warn "EVAL ",dump($update);
 794                                 foreach ( keys %$update ) {
 795                                         $test_changed->{$_}++;
 796                                         $row->{$_} = $update->{$_};
 797                                 }
 798                         }
 799                 }
 800                 $row->{_row_id} ||= $id;
 801                 push @$sorted_items, $row;
 802         }
 803
 804         if ( $self->param('export') ) {
 805                 my $export_path = $self->_export_path( 'items', @columns);
 806                 open(my $fh, '>', $export_path) || warn "ERROR: can't open $export_path: $!";
 807                 foreach my $f ( 0 .. $#$filtered ) {
 808                         print $fh join("\t", map {
 809                                 my $i = $data->{items}->[ $filtered->[$f] ];
 810                                 my $v = '\N';
 811                                 if ( ! defined $i->{$_} ) {
 812                                         # nop
 813                                 } elsif ( ref $i->{$_} eq 'ARRAY' ) {
 814                                         $v =join(',', @{ $i->{$_} });
 815                                         $v = '\N' if length($v) == 0;
 816                                 } else {
 817                                         $v = dump $i->{$_};
 818                                 }
 819                                 $v;
 820                         } @columns),"\n";
 821                 }
 822                 close($fh);
 823                 warn "export $export_path ", -s $export_path, " bytes\n";
 824         }
 825
 826         warn "# test_changed ",dump( $test_changed );
 827         my $c = { map { $_ => 1 } @columns };
 828         my @added_columns = sort grep { ! $c->{$_} } keys %$test_changed;
 829         unshift @columns, @added_columns;
 830
 831         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 832
 833         my $code_depends = $self->param('code_depends')||
 834         join(',', sort grep { $test_changed->{$_} == 0 } keys %$test_changed );
 835         my $code_description = $self->param('code_description') ||
 836         join(',', @added_columns);
 837
 838         $code_depends ||= $code_description; # self-modifing
 839         if ( ! $code_depends && $out ) {
 840                 $code_depends = $key;
 841                 $code_description = $value;
 842         }
 843
 844         warn "# test_changed ",dump( $test_changed, $code_depends, $code_description );
 845
 846         $self->render(
 847                 order => $order,
 848                 offset => $offset,
 849                 limit => $limit,
 850                 sorted => $sorted_items,
 851                 columns => [ @columns ],
 852                 rows => $#$filtered + 1,
 853                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 854                 unique  => { map { $_, $self->_is_unique( $_) } @columns },
 855                 filters => $self->_current_filters,
 856                 code => $code,
 857                 cols_changed => $commit ? $commit_changed : $test_changed,
 858                 code_depends => $code_depends,
 859                 code_description => $code_description,
 860                 code_path => $code_path,
 861                 out => $out,
 862         );
 863
 864 }
 865
 866
 867 sub order {
 868         my $self = shift;
 869         $self->session('order', $self->param('order'));
 870         $self->session('sort', $self->param('sort'));
 871         $self->redirect_to('/data/items');
 872 }
 873
 874 sub _is_numeric {
 875         my ( $self, $name ) = @_;
 876
 877         my $stats = $self->_loaded( 'stats' );
 878
 879         # sort facet numerically if more >50% elements are numeric
 880         my $count = $stats->{$name}->{count};
 881         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 882         defined $stats->{$name}->{numeric} &&
 883                 $stats->{$name}->{numeric} > $count / 2;
 884 }
 885
 886 sub _is_unique {
 887         my ( $self, $name ) = @_;
 888         my $stats = $self->_loaded( 'stats' );
 889         defined $stats->{$name}->{unique};
 890 }
 891
 892 sub _remove_filter {
 893         my ($self,$name) = @_;
 894         warn "_remove_filter $name\n";
 895
 896         my $path = $self->session('path');
 897
 898         delete $filters->{$name};
 899         delete $loaded->{$path}->{filters}->{$name};
 900         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 901
 902         foreach (
 903                         grep { /\Q$name\E/ }
 904                         keys %{ $loaded->{$path}->{filtered} }
 905         ) {
 906                 delete $loaded->{$path}->{filtered}->{$_};
 907                 warn "remove filtered cache $_";
 908         }
 909 }
 910
 911 sub facet {
 912         my $self = shift;
 913
 914         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 915
 916         if ( my $name = $self->param('remove') ) {
 917                 $self->_remove_filter( $name );
 918                 $self->redirect_to( '/data/items' );
 919         }
 920
 921         my $facet;
 922         my $name = $self->param('name') || die "no name";
 923
 924         my $all = $self->_param_scalar('all', 1);
 925         my $data = $self->_loaded('data');
 926
 927         my $filters = $self->_current_filters;
 928         my $all_filters = __all_filters( keys %$filters,$self->session('order') );
 929         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 930                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 931
 932         if ( ! $filtered || $all ) {
 933                 $filtered = [ 0 .. $#{ $data->{items} } ];
 934                 warn "filter all values\n";
 935         } else {
 936                 warn "filter using $all_filters\n";
 937         }
 938
 939         foreach my $i ( @$filtered ) {
 940                 my $item = $data->{items}->[$i];
 941                 if ( ! exists $item->{$name} ) {
 942                         $facet->{ _missing }++;
 943                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 944                         $facet->{$_}++ foreach @{ $item->{$name} };
 945                 } else {
 946                         $facet->{ $item->{$name} }++;
 947                 }
 948         }
 949
 950         if ( my $code = $self->param('code') ) {
 951                 my $out;
 952                 foreach my $v ( keys %$facet ) {
 953                         my $c = $facet->{$v};
 954                         eval $code;
 955                         if ( $@ ) {
 956                                 $out = $@;
 957                                 warn "ERROR: $@\n$code\n";
 958                                 last;
 959                         }
 960                 }
 961                 warn "out ",dump( $out );
 962                 $self->stash( out => $out );
 963         }
 964
 965 #       warn "# facet $name ",dump $facet;
 966
 967         my $checked;
 968         my @facet_names =
 969                   $all                      ? keys %$facet
 970                 : defined $filters->{$name} ? @{ $filters->{$name} }
 971                 : keys %$facet;
 972
 973         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 974
 975         my $numeric = $self->_is_numeric($name);
 976
 977         my $sort = $self->param('sort');
 978         # sort numeric facets with more than 5 values ascending
 979         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 980
 981         @facet_names = sort {
 982                 my $result;
 983                 if ( $sort eq 'a' ) {
 984                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 985                 } elsif ( $sort eq 'd' ) {
 986                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 987                 } elsif ( $sort eq 'c' ) {
 988                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 989                 } else {
 990                         warn "unknown sort: $sort";
 991                         $result = $a cmp $b;
 992                 }
 993                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 994                 $result;
 995         } @facet_names;
 996
 997         $self->render( name => $name, facet => $facet, checked => $checked,
 998                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 999         );
1000 }
1001
1002
1003 sub __invalidate_path_column {
1004         my ( $path, $name ) = @_;
1005
1006         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
1007                 delete $loaded->{$path}->{sorted}->{$name};
1008                 warn "# invalidate $path sorted $name\n";
1009         }
1010
1011         foreach ( grep { m/\Q$name\E/ } keys %{ $loaded->{$path}->{filtered} } ) {
1012                 delete $loaded->{$path}->{filtered}->{$_};
1013                 warn "# invalidate $path filtered $_\n";
1014         }
1015 }
1016
1017 sub __path_modified {
1018         my ( $path, $value ) = @_;
1019         $value = 1 unless defined $value;
1020
1021         $loaded->{$path}->{modified}  = $value;
1022
1023         warn "# __path_modified $path $value\n";
1024 }
1025
1026 sub __path_rebuild_stats { $loaded->{ $_[0] }->{rebuild_stats} = 1 };
1027
1028 sub _save_change {
1029         my ($self,$change) = @_;
1030
1031         my $change_path = $self->_permanent_path( 'changes' );
1032         mkdir $change_path unless -d $change_path;
1033         $change_path .= '/' . $change->{time};
1034         store $change, $change_path;
1035         utime $change->{time}, $change->{time}, $change_path;
1036         warn "_save_change $change_path ", dump($change);
1037 }
1038
1039 sub edit {
1040         my $self = shift;
1041         my $new_content = $self->param('new_content');
1042         $new_content  ||= $self->param('content'); # backward compatibility with old actions
1043
1044         my $i = $self->param('_row_id');
1045         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
1046         my $path = $self->param('path') || die "no path";
1047         my $name = $self->param('name') || die "no name";
1048         my $status = 200; # 200 = OK, 201 = Created
1049
1050         my $data = $self->_loaded('data');
1051
1052         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
1053                 $new_content =~ s/^\s+//s;
1054                 $new_content =~ s/\s+$//s;
1055                 my $v;
1056                 if ( $new_content =~ /\xB6/ ) { # para
1057                         $v = [ split(/\s*\xB6\s*/, $new_content) ];
1058                 } else {
1059                         $v = [ $new_content ];
1060                 }
1061
1062                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
1063                 my $new = dump $v;
1064                 if ( $old ne $new
1065                         && ! ( $old eq 'undef' && length($new_content) == 0 ) # new value empty, previous undef
1066                 ) {
1067                         $self->_save_change({
1068                                 path => $path,
1069                                 column => $name,
1070                                 pos => $i,
1071                                 old => $loaded->{$path}->{data}->{items}->[$i]->{$name},
1072                                 new => $v,
1073                                 time => $self->param('time') || time(),
1074                                 user => $self->param('user') || $ENV{'LOGNAME'},
1075                                 unique => {
1076                                         map { $_ => $loaded->{$path}->{data}->{items}->[$i]->{$_}->[0] }
1077                                         grep { defined $loaded->{$path}->{stats}->{$_}->{unique} }
1078                                         keys %{ $loaded->{$path}->{stats} }
1079                                 },
1080                         });
1081
1082                         warn "# change $path $i $old -> $new\n";
1083                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
1084
1085                         __invalidate_path_column( $path, $name );
1086
1087                         $status = 201; # created
1088                         __path_rebuild_stats( $path );
1089
1090                         $new_content = join("\xB6",@$v);
1091
1092                 } else {
1093                         warn "# unchanged $path $i $old\n";
1094                         $status = 304;
1095                 }
1096         } else {
1097                 $new_content = "$path $i $name doesn't exist\n";
1098                 $status = 404;
1099         }
1100
1101         warn "# edit $status ", dump $new_content;
1102
1103         $self->render(
1104                 status => $status,
1105                 new_content => scalar $new_content,
1106         );
1107 }
1108
1109
1110 sub save {
1111         my $self = shift;
1112         my $path = $self->_param_or_session('path');
1113         my $dump_path = $self->_save( $path );
1114         __path_modified( $path, 0 );
1115
1116         $self->redirect_to( '/data/items' );
1117 }
1118
1119 sub export {
1120         my $self = shift;
1121
1122         my $dir = $self->app->home->rel_dir('public');
1123
1124         if ( my $import = $self->param('import') ) {
1125
1126                 if ( $import =~ m{/filter\.(.+?)\..+} ) {
1127                         my $name = $self->_column_from_unac( $1 );
1128
1129                         my @vals = map { chomp; $_ }
1130                                 read_file "$dir/export/$import", binmode => ':utf8';
1131
1132                         $self->_remove_filter( $name );
1133                         $self->_filter_on_data( $name, @vals );
1134                         $self->session( 'offset' => 0 );
1135                         $self->redirect_to('/data/items');
1136                 } else {
1137                         warn "UNKNOWN IMPORT $import";
1138                 }
1139         }
1140
1141         if ( my $remove = $self->param('remove') ) {
1142                 my $path = "$dir/export/$remove";
1143                 unlink $path if -e $path;
1144                 $path .= '.png';
1145                 unlink $path if -e $path;
1146         }
1147
1148         my $path = $self->_export_path || $self->redirect_to('/data/index');
1149
1150         my @files = grep { ! /\.png$/ } glob "$path/*";
1151         my $mtime = { map { $_ => (stat($_))[9] } @files };
1152         @files = sort { $mtime->{$b} <=> $mtime->{$a} } @files;
1153         $self->render( export => [ @files ] );
1154 }
1155
1156 sub __loaded_paths {
1157         return
1158                 grep { defined $loaded->{$_}->{data} }
1159                 keys %$loaded;
1160 }
1161
1162 1;