lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14
  15 our $loaded;
  16 our $filters;
  17
  18 sub index {
  19         my $self = shift;
  20
  21         my $path = $self->app->home->rel_dir('data');
  22         die "no data dir $path" unless -d $path;
  23
  24         my @files;
  25         find( sub {
  26                 my $file = $File::Find::name;
  27                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  28                         $file =~ s/$path\/*//;
  29                         push @files, $file;
  30                 } else {
  31                         warn "IGNORE: $file\n";
  32                 }
  33         }, $path);
  34
  35         @files = sort { lc $a cmp lc $b } @files;
  36         my $size;
  37         $size->{$_} = -s "$path/$_" foreach @files;
  38
  39         $self->render(
  40                 files => [ @files ],
  41                 size => $size,
  42                 loaded => $loaded,
  43                 filters => $filters,
  44         );
  45 }
  46
  47 sub _load_path {
  48         my ( $self, $path ) = @_;
  49
  50         return if defined $loaded->{$path}->{data};
  51
  52         my $full_path = $self->app->home->rel_file( 'data/' . $path );
  53         die "$full_path $!" unless -r $full_path;
  54
  55         # we could use Mojo::JSON here, but it's too slow
  56 #       $data = from_json read_file $path;
  57         my $data = read_file $full_path;
  58         warn "# data snippet: ", substr($data,0,200);
  59         my @header;
  60         if ( $path =~ m/\.js/ ) {
  61                 Encode::_utf8_on($data);
  62                 $data = from_json $data;
  63         } elsif ( $path =~ m/\.txt/ ) {
  64                 my @lines = split(/\r?\n/, $data);
  65                 $data = { items => [] };
  66
  67                 my $header_line = shift @lines;
  68                 my $multiline = $header_line =~ s/\^//g;
  69                 @header = split(/\|/, $header_line );
  70                 warn "# header ", dump( @header );
  71                 while ( my $line = shift @lines ) {
  72                         $line =~ s/\^//g;
  73                         chomp $line;
  74                         my @v = split(/\|/, $line);
  75                         while ( @lines && $#v < $#header ) {
  76                                 $line = $lines[0];
  77                                 $line =~ s/\^//g;
  78                                 chomp $line;
  79                                 my @more_v = split(/\|/, $line);
  80                                 if ( $#v + $#more_v > $#header ) {
  81                                         warn "short line: ",dump( @v );
  82                                         last;
  83                                 }
  84                                 shift @lines;
  85                                 $v[ $#v ] .= shift @more_v if @more_v;
  86                                 push @v, @more_v if @more_v;
  87
  88                                 if ( $#v > $#header ) {
  89                                         die "# splice $#header ", dump( @v );
  90                                         @v = splice @v, 0, $#header;
  91                                 }
  92                         }
  93                         my $item;
  94                         $item->{ $header[$_] || "f_$_" } = [ $v[$_] ] foreach ( 0 .. $#v );
  95                         push @{ $data->{items} }, $item;
  96                 }
  97         } else {
  98                 warn "file format unknown $path";
  99         }
 100
 101         my $stats;
 102
 103         foreach my $e ( @{ $data->{items} } ) {
 104                 foreach my $n ( keys %$e ) {
 105                         $stats->{$n}->{count}++;
 106                         my @v;
 107                         if ( ref $e->{$n} eq 'ARRAY' ) {
 108                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 109                                 @v = @{ $e->{$n} };
 110                         } else {
 111                                 @v = ( $e->{$n} );
 112                         }
 113
 114                         foreach my $x ( @v ) {
 115                                 $stats->{$n}->{numeric}++
 116                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 117                                 $stats->{$n}->{empty}++
 118                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 119                         }
 120
 121                 }
 122         }
 123
 124         foreach my $n ( keys %$stats ) {
 125                 next unless defined $stats->{$n}->{array};
 126                 delete $stats->{$n}->{array}
 127                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 128         }
 129
 130         if ( ! @header ) {
 131                 if ( defined $data->{header} ) {
 132                         if ( ref $data->{header} eq 'ARRAY' ) {
 133                                 @header = @{ $data->{header} };
 134                         } else {
 135                                 warn "header not array ", dump( $data->{header} );
 136                         }
 137                 }
 138         }
 139
 140         @header =
 141                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 142                 grep { defined $stats->{$_}->{count} } keys %$stats
 143                 unless @header;
 144
 145         warn dump($stats);
 146
 147         $loaded->{ $path } = {
 148                 header => [ @header ],
 149                 stats  => $stats,
 150                 full_path => $full_path,
 151                 size => -s $full_path,
 152                 data => $data,
 153         };
 154
 155 }
 156
 157
 158 sub load {
 159         my $self = shift;
 160
 161         my @paths = $self->param('paths');
 162         warn "# paths ", dump @paths;
 163         $self->_load_path( $_ ) foreach @paths;
 164
 165         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 166         warn "# path $path\n";
 167         $self->session('path' => $path);
 168         $self->_load_path( $path );
 169
 170         $self->session( 'header' => $loaded->{$path}->{header} );
 171         if ( ! defined $loaded->{$path}->{columns} ) {
 172                 $self->session( 'columns' => $loaded->{$path}->{header} );
 173                 $self->session( 'order'   => $loaded->{$path}->{header}->[0] );
 174                 $self->redirect_to( '/data/columns' );
 175         } else {
 176                 $self->session( 'columns' => $loaded->{$path}->{columns} );
 177                 $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 178                 $self->redirect_to( '/data/items' );
 179         }
 180 }
 181
 182
 183 sub _loaded {
 184         my ( $self, $name ) = @_;
 185         my $path = $self->session('path');
 186         die "$path $name doesn't exist in loaded ",dump( $loaded )
 187                 unless defined $loaded->{$path}->{$name};
 188         return $loaded->{$path}->{$name};
 189 }
 190
 191
 192 sub _checked {
 193         my $self = shift;
 194         my $checked;
 195         $checked->{$_}++ foreach @_;
 196 #       warn "# _checked ",dump($checked);
 197         return $checked;
 198 }
 199
 200
 201 sub columns {
 202     my $self = shift;
 203
 204         if ( $self->param('columns') ) {
 205                 $self->_perm_array('columns');
 206                 $self->redirect_to('/data/items');
 207         }
 208
 209         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 210
 211         my @columns;
 212         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 213
 214         foreach my $c ( @{ $self->session( 'header' ) } ) {
 215                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 216         }
 217
 218     $self->render(
 219                 message => 'Select columns to display',
 220                 stats => $stats,
 221                 columns => \@columns,
 222                 checked => $self->_checked( $self->_perm_array('columns') ),
 223         );
 224 }
 225
 226 sub _perm_array {
 227     my ($self,$name) = @_;
 228
 229         my @array = $self->param($name);
 230         my $path  = $self->session('path');
 231
 232         if ( @array ) {
 233                 $self->session($name => [ @array ]);
 234                 $loaded->{$path}->{$name} = [ @array ];
 235         } elsif ( my $session = $self->session($name) ) {
 236                 if ( ref $session eq 'ARRAY' ) {
 237                         @array = @$session;
 238                 } else {
 239                         die "$name not array ",dump($session);
 240                 }
 241         }
 242         #warn "# $name ",dump @array;
 243         return @array;
 244 }
 245
 246 sub _perm_scalar {
 247     my ($self,$name,$default) = @_;
 248
 249         my $scalar = $self->param($name);
 250
 251         if ( defined $scalar ) {
 252                 $self->session($name => $scalar);
 253         } else {
 254                 $scalar = $self->session($name);
 255         }
 256
 257         if ( ! defined $scalar ) {
 258                 $scalar = $default;
 259                 die "no default for $name" unless defined $scalar;
 260                 $self->session($name => $scalar);
 261         }
 262
 263         warn "# _perm_scalar $name ",dump $scalar;
 264         return $scalar;
 265 }
 266
 267 sub filter {
 268         my $self = shift;
 269
 270         my $name = $self->param('filter_name') || die "name?";
 271         my @vals = $self->param('filter_vals');
 272
 273         $self->_remove_filter( $name );
 274         $self->_filter_on_data( $name, @vals ) if @vals;
 275
 276         $self->session( 'offset' => 0 );
 277
 278         $self->redirect_to('/data/items');
 279 }
 280
 281 sub _filter_on_data {
 282         my ( $self, $name, @vals ) = @_;
 283
 284         my $path = $self->session('path');
 285
 286         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 287                 warn "filter $name not found in data set";
 288                 return;
 289         }
 290
 291         $filters->{$name} = [ @vals ];
 292         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 293
 294         my $filter_hash;
 295         $filter_hash->{$_}++ foreach @vals;
 296
 297         #warn "# filter_hash ",dump( $filter_hash );
 298
 299         my $items = $self->_loaded('data')->{items};
 300
 301         my $include_missing = defined $filter_hash->{_missing};
 302         my $filtered_items;
 303
 304         foreach my $i ( 0 .. $#$items ) {
 305
 306                 if ( defined $items->[$i]->{$name} ) {
 307                         foreach my $v ( @{ $items->[$i]->{$name} } ) {
 308                                 if ( defined $filter_hash->{ $v } ) {
 309                                         $filtered_items->{$i}++;
 310                                 }
 311                         }
 312                 } elsif ( $include_missing ) {
 313                         $filtered_items->{$i}++;
 314                 }
 315         }
 316
 317         #warn "# filter $name ",dump($filtered_items);
 318
 319         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 320         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 321 }
 322
 323 sub _data_items {
 324         my ( $self, $all ) = @_;
 325         my $data = $self->_loaded( 'data' );
 326
 327         return @{ $data->{items} } if $all == 1;
 328
 329         my $filters = $self->_current_filters;
 330         my $filter_value;
 331         foreach my $f ( keys %$filters ) {
 332                 foreach my $n ( @{ $filters->{$f} } ) {
 333                         $filter_value->{$f}->{$n} = 1;
 334                 }
 335         }
 336         my @items = @{ $data->{items} };
 337         @items = grep {
 338                 my $i = $_;
 339                 my $pass = 1;
 340                 foreach my $n ( keys %$filter_value ) {
 341                         if ( ! exists $i->{$n} ) {
 342                                 if ( defined $filter_value->{$n}->{_missing} ) {
 343                                         $pass = 1;
 344                                         next;
 345                                 } else {
 346                                         $pass = 0;
 347                                         last;
 348                                 }
 349                         }
 350                         # and match any of values in element
 351                         my $have_values = 0;
 352                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 353                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 354                         }
 355                         if ( ! $have_values ) {
 356                                 $pass = 0;
 357                                 last;
 358                         }
 359                 }
 360                 $pass;
 361         } @items if $filter_value;
 362         return @items;
 363 }
 364
 365
 366 sub _current_filters {
 367         my $self = shift;
 368         my $current_filters;
 369         $current_filters->{ $_ } = $filters->{ $_ }
 370                 foreach (
 371                         grep { defined $filters->{ $_ } }
 372                         @{ $self->_loaded('header') }
 373                 );
 374         #warn "# current_filters ",dump($current_filters);
 375         return $current_filters;
 376 }
 377
 378 sub _data_sorted_by {
 379         my ( $self, $order ) = @_;
 380
 381         my $path = $self->session('path');
 382
 383         warn "_data_sorted_by $order from $path";
 384
 385         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 386                 return $loaded->{$path}->{sorted}->{$order};
 387         }
 388
 389         my $data = $self->_loaded( 'data' );
 390         my $numeric = $self->_is_numeric($order);
 391         my $missing = $numeric ? 0 : '';
 392         no warnings qw(numeric);
 393         my $nr = 0;
 394         my @sorted = map {
 395                 $_->[0]
 396         } sort {
 397                 if ( $numeric ) {
 398                         $a->[1] <=> $b->[1]
 399                 } else {
 400                         $a->[1] cmp $b->[1]
 401                 }
 402         } map {
 403                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 404         } @{ $data->{items} }
 405         ;
 406
 407         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 408         #warn "# sorted ",dump( @sorted );
 409
 410         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 411 }
 412
 413
 414 sub items {
 415         my $self = shift;
 416
 417         my $path = $self->session('path');
 418         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 419
 420         my @columns = $self->_perm_array('columns');
 421         $self->redirect_to('/data/columns') unless @columns;
 422         my $order   = $self->_perm_scalar('order', $columns[0]);
 423         my $sort    = $self->_perm_scalar('sort', 'a');
 424         my $offset  = $self->_perm_scalar('offset', 0);
 425         my $limit   = $self->_perm_scalar('limit', 20);
 426         $self->_perm_scalar('show', 'table');
 427
 428         # fix offset when changing limit
 429         $offset = int( $offset / $limit ) * $limit;
 430
 431         my $sorted = $self->_data_sorted_by( $order );
 432
 433         my @filter_names;
 434         if ( $filters ) {
 435                 foreach my $name ( keys %$filters ) {
 436                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 437                                 warn "skip filter $name not found in $path\n";
 438                                 next;
 439                         }
 440                         push @filter_names, $name;
 441                 }
 442                 warn "filter_names ",dump( @filter_names );
 443                 foreach my $name ( @filter_names ) {
 444                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 445                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 446                 }
 447         }
 448
 449         my $all_filters = join(' ',sort @filter_names,'order:',$order);
 450
 451 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 452
 453         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 454
 455                 my $path_filters = $loaded->{$path}->{filters};
 456
 457                 warn "create combined filter for $all_filters\n";
 458
 459                 my @filtered;
 460                 foreach my $i ( 0 .. $#$sorted ) {
 461                         my $pos = $sorted->[$i];
 462
 463                         if ( $#filter_names == -1 ) {
 464                                 push @filtered, $pos;
 465                                 next;
 466                         }
 467
 468                         my $skip = 0;
 469                         foreach ( @filter_names ) {
 470                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 471                         }
 472                         next if $skip;
 473
 474                         push @filtered, $pos;
 475                 }
 476
 477                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 478         }
 479
 480         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 481                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 482
 483         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 484
 485         my $sorted_items;
 486         my $data = $self->_loaded('data');
 487         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 488         foreach ( 0 .. $limit ) {
 489                 my $i = $_ + $offset;
 490                 last unless defined $filtered->[$i];
 491                 $i = $from_end - $i if $from_end;
 492                 push @$sorted_items, $data->{items}->[ $filtered->[$i] ];
 493         }
 494
 495         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 496
 497         $self->render(
 498                 order => $order,
 499                 offset => $offset,
 500                 limit => $limit,
 501                 sorted => $sorted_items,
 502                 columns => [ @columns ],
 503                 rows => $#$filtered + 1,
 504                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 505                 filters => $self->_current_filters,
 506         );
 507
 508 }
 509
 510
 511 sub order {
 512         my $self = shift;
 513         $self->session('order', $self->param('order'));
 514         $self->session('sort', $self->param('sort'));
 515         $self->redirect_to('/data/items');
 516 }
 517
 518 sub _is_numeric {
 519         my ( $self, $name ) = @_;
 520
 521         my $stats = $self->_loaded( 'stats' );
 522
 523         # sort facet numerically if more >50% elements are numeric
 524         my $count = $stats->{$name}->{count};
 525         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 526         defined $stats->{$name}->{numeric} &&
 527                 $stats->{$name}->{numeric} > $count / 2;
 528 }
 529
 530 sub _remove_filter {
 531         my ($self,$name) = @_;
 532         warn "_remove_filter $name\n";
 533
 534         my $path = $self->session('path');
 535
 536         delete $filters->{$name};
 537         delete $loaded->{$path}->{filters}->{$name};
 538         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 539
 540         foreach (
 541                         grep { /\b$name\b/ }
 542                         keys %{ $loaded->{$path}->{filtered} }
 543         ) {
 544                 delete $loaded->{$path}->{filtered}->{$_};
 545                 warn "remove filtered cache $_";
 546         }
 547 }
 548
 549 sub facet {
 550         my $self = shift;
 551
 552         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 553
 554         if ( my $name = $self->param('remove') ) {
 555                 $self->_remove_filter( $name );
 556                 $self->redirect_to( '/data/items' );
 557         }
 558
 559         my $facet;
 560         my $name = $self->param('name') || die "no name";
 561
 562         my $all = $self->_perm_scalar('all', 1);
 563         my $data = $self->_loaded('data');
 564
 565         my $filters = $self->_current_filters;
 566         my $all_filters = join(' ',sort keys %$filters,'order:',$self->session('order'));
 567         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 568                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 569
 570         if ( ! $filtered || $all ) {
 571                 $filtered = [ 0 .. $#{ $data->{items} } ];
 572                 warn "filter all values\n";
 573         } else {
 574                 warn "filter using $all_filters\n";
 575         }
 576
 577         foreach my $i ( @$filtered ) {
 578                 my $item = $data->{items}->[$i];
 579                 if ( ! exists $item->{$name} ) {
 580                         $facet->{ _missing }++;
 581                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 582                         $facet->{$_}++ foreach @{ $item->{$name} };
 583                 } else {
 584                         $facet->{ $item->{$name} }++;
 585                 }
 586         }
 587
 588 #       warn "# facet $name ",dump $facet;
 589
 590         my $checked;
 591         my @facet_names =
 592                   $all                      ? keys %$facet
 593                 : defined $filters->{$name} ? @{ $filters->{$name} }
 594                 : keys %$facet;
 595
 596         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 597
 598         my $numeric = $self->_is_numeric($name);
 599
 600         my $sort = $self->param('sort');
 601         $sort ||= $numeric ? 'a' : 'c';
 602
 603         @facet_names = sort {
 604                 if ( $sort =~ m/a/i ) {
 605                         $numeric ? $a <=> $b : lc $a cmp lc $b;
 606                 } elsif ( $sort =~ m/d/i ) {
 607                         $numeric ? $b <=> $a : lc $b cmp lc $a;
 608                 } elsif ( $sort =~ m/c/i ) {
 609                         ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 610                 } else {
 611                         warn "unknown sort: $sort";
 612                         $a cmp $b;
 613                 }
 614         } @facet_names;
 615
 616         $self->render( name => $name, facet => $facet, checked => $checked,
 617                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 618         );
 619 }
 620
 621 sub edit {
 622         my $self = shift;
 623         my $content = $self->param('content');
 624
 625         $self->render(
 626                 content => $content
 627         );
 628 }
 629
 630 1;