lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14 use Storable;
  15
  16 our $loaded;
  17 our $filters;
  18
  19 sub index {
  20         my $self = shift;
  21
  22         my $path = $self->app->home->rel_dir('data');
  23         die "no data dir $path" unless -d $path;
  24
  25         my @files;
  26         find( sub {
  27                 my $file = $File::Find::name;
  28                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  29                         $file =~ s/$path\/*//;
  30                         push @files, $file;
  31                 } else {
  32                         warn "IGNORE: $file\n";
  33                 }
  34         }, $path);
  35
  36         @files = sort { lc $a cmp lc $b } @files;
  37         my $size;
  38         $size->{$_} = -s "$path/$_" foreach @files;
  39
  40         $self->render(
  41                 files => [ @files ],
  42                 size => $size,
  43                 loaded => $loaded,
  44                 filters => $filters,
  45         );
  46 }
  47
  48 sub _save {
  49         my ( $self, $path ) = @_;
  50
  51         my $name = $path;
  52         my $dir = $self->app->home->rel_dir('data');
  53         $name =~ s/^$dir//;
  54         $name =~ s/\/+/_/g;
  55         my $dump_path = '/tmp/mojo_facets.' . $name . '.storable';
  56
  57         warn "save loaded to $dump_path";
  58         my $info = $loaded->{$path};
  59         store $info, $dump_path;
  60
  61         # sync timestamp
  62         my $mtime = $loaded->{$path}->{mtime};
  63         utime $mtime, $mtime, $dump_path;
  64
  65         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  66 }
  67
  68 sub _load_path {
  69         my ( $self, $path ) = @_;
  70
  71         my $full_path = $self->app->home->rel_file( 'data/' . $path );
  72         die "$full_path $!" unless -r $full_path;
  73
  74         if ( defined $loaded->{$path}->{data} ) {
  75                 my $mtime = (stat($full_path))[9];
  76                 return if $loaded->{$path}->{mtime} == $mtime;
  77                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
  78         }
  79
  80         # we could use Mojo::JSON here, but it's too slow
  81 #       $data = from_json read_file $path;
  82         my $data = read_file $full_path;
  83         warn "# data snippet: ", substr($data,0,200);
  84         my @header;
  85         if ( $path =~ m/\.js/ ) {
  86                 Encode::_utf8_on($data);
  87                 $data = from_json $data;
  88         } elsif ( $path =~ m/\.txt/ ) {
  89                 my @lines = split(/\r?\n/, $data);
  90                 $data = { items => [] };
  91
  92                 my $header_line = shift @lines;
  93                 my $multiline = $header_line =~ s/\^//g;
  94                 @header = split(/\|/, $header_line );
  95                 warn "# header ", dump( @header );
  96                 while ( my $line = shift @lines ) {
  97                         $line =~ s/\^//g;
  98                         chomp $line;
  99                         my @v = split(/\|/, $line);
 100                         while ( @lines && $#v < $#header ) {
 101                                 $line = $lines[0];
 102                                 $line =~ s/\^//g;
 103                                 chomp $line;
 104                                 my @more_v = split(/\|/, $line);
 105                                 if ( $#v + $#more_v > $#header ) {
 106                                         warn "short line: ",dump( @v );
 107                                         last;
 108                                 }
 109                                 shift @lines;
 110                                 $v[ $#v ] .= shift @more_v if @more_v;
 111                                 push @v, @more_v if @more_v;
 112
 113                                 if ( $#v > $#header ) {
 114                                         die "# splice $#header ", dump( @v );
 115                                         @v = splice @v, 0, $#header;
 116                                 }
 117                         }
 118                         my $item;
 119                         foreach my $i ( 0 .. $#v ) {
 120                                 $item->{ $header[$i] || "f_$i" } = [ $v[$i] ];
 121                         }
 122                         push @{ $data->{items} }, $item;
 123                 }
 124         } else {
 125                 warn "file format unknown $path";
 126         }
 127
 128         my $stats;
 129
 130         foreach my $e ( @{ $data->{items} } ) {
 131                 foreach my $n ( keys %$e ) {
 132                         $stats->{$n}->{count}++;
 133                         my @v;
 134                         if ( ref $e->{$n} eq 'ARRAY' ) {
 135                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 136                                 @v = @{ $e->{$n} };
 137                         } else {
 138                                 @v = ( $e->{$n} );
 139                         }
 140
 141                         foreach my $x ( @v ) {
 142                                 $stats->{$n}->{numeric}++
 143                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 144                                 $stats->{$n}->{empty}++
 145                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 146                         }
 147
 148                 }
 149         }
 150
 151         foreach my $n ( keys %$stats ) {
 152                 next unless defined $stats->{$n}->{array};
 153                 delete $stats->{$n}->{array}
 154                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 155         }
 156
 157         if ( ! @header ) {
 158                 if ( defined $data->{header} ) {
 159                         if ( ref $data->{header} eq 'ARRAY' ) {
 160                                 @header = @{ $data->{header} };
 161                         } else {
 162                                 warn "header not array ", dump( $data->{header} );
 163                         }
 164                 }
 165         }
 166
 167         @header =
 168                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 169                 grep { defined $stats->{$_}->{count} } keys %$stats
 170                 unless @header;
 171
 172         warn dump($stats);
 173
 174         my $info = {
 175                 header => [ @header ],
 176                 stats  => $stats,
 177                 full_path => $full_path,
 178                 size => -s $full_path,
 179                 mtime => (stat($full_path))[9],
 180                 data => $data,
 181         };
 182
 183         $loaded->{ $path } = $info;
 184         $self->_save( $path );
 185
 186 }
 187
 188
 189 sub load {
 190         my $self = shift;
 191
 192         my @paths = $self->param('paths');
 193         warn "# paths ", dump @paths;
 194         $self->_load_path( $_ ) foreach @paths;
 195
 196         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 197         warn "# path $path\n";
 198         $self->session('path' => $path);
 199         $self->_load_path( $path );
 200
 201         $self->session( 'header' => $loaded->{$path}->{header} );
 202         if ( ! defined $loaded->{$path}->{columns} ) {
 203                 $self->session( 'columns' => $loaded->{$path}->{header} );
 204                 $self->session( 'order'   => $loaded->{$path}->{header}->[0] );
 205                 $self->redirect_to( '/data/columns' );
 206         } else {
 207                 $self->session( 'columns' => $loaded->{$path}->{columns} );
 208                 $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 209                 $self->redirect_to( '/data/items' );
 210         }
 211 }
 212
 213
 214 sub _loaded {
 215         my ( $self, $name ) = @_;
 216         my $path = $self->session('path');
 217         if ( ! defined $loaded->{$path}->{$name} ) {
 218                 warn "$path $name doesn't exist in loaded ",dump( $loaded );
 219                 $self->redirect_to('/data/index');
 220         }
 221         return $loaded->{$path}->{$name};
 222 }
 223
 224
 225 sub _checked {
 226         my $self = shift;
 227         my $checked;
 228         $checked->{$_}++ foreach @_;
 229 #       warn "# _checked ",dump($checked);
 230         return $checked;
 231 }
 232
 233
 234 sub columns {
 235     my $self = shift;
 236
 237         if ( $self->param('columns') ) {
 238                 $self->_perm_array('columns');
 239                 $self->redirect_to('/data/items');
 240         }
 241
 242         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 243
 244         my @columns;
 245         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 246
 247         foreach my $c ( @{ $self->session( 'header' ) } ) {
 248                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 249         }
 250
 251     $self->render(
 252                 message => 'Select columns to display',
 253                 stats => $stats,
 254                 columns => \@columns,
 255                 checked => $self->_checked( $self->_perm_array('columns') ),
 256         );
 257 }
 258
 259 sub _perm_array {
 260     my ($self,$name) = @_;
 261
 262         my @array = $self->param($name);
 263         my $path  = $self->session('path');
 264
 265         if ( @array ) {
 266                 $self->session($name => [ @array ]);
 267                 $loaded->{$path}->{$name} = [ @array ];
 268         } elsif ( my $session = $self->session($name) ) {
 269                 if ( ref $session eq 'ARRAY' ) {
 270                         @array = @$session;
 271                 } else {
 272                         die "$name not array ",dump($session);
 273                 }
 274         }
 275         #warn "# $name ",dump @array;
 276         return @array;
 277 }
 278
 279 sub _perm_scalar {
 280     my ($self,$name,$default) = @_;
 281
 282         my $scalar = $self->param($name);
 283
 284         if ( defined $scalar ) {
 285                 $self->session($name => $scalar);
 286         } else {
 287                 $scalar = $self->session($name);
 288         }
 289
 290         if ( ! defined $scalar ) {
 291                 $scalar = $default;
 292                 die "no default for $name" unless defined $scalar;
 293                 $self->session($name => $scalar);
 294         }
 295
 296         warn "# _perm_scalar $name ",dump $scalar;
 297         return $scalar;
 298 }
 299
 300 sub filter {
 301         my $self = shift;
 302
 303         my $name = $self->param('filter_name') || die "name?";
 304         my @vals = $self->param('filter_vals');
 305
 306         $self->_remove_filter( $name );
 307         $self->_filter_on_data( $name, @vals ) if @vals;
 308
 309         $self->session( 'offset' => 0 );
 310
 311         $self->redirect_to('/data/items');
 312 }
 313
 314 sub _filter_on_data {
 315         my ( $self, $name, @vals ) = @_;
 316
 317         my $path = $self->session('path');
 318
 319         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 320                 warn "filter $name not found in data set";
 321                 return;
 322         }
 323
 324         $filters->{$name} = [ @vals ];
 325         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 326
 327         my $filter_hash;
 328         $filter_hash->{$_}++ foreach @vals;
 329
 330         #warn "# filter_hash ",dump( $filter_hash );
 331
 332         my $items = $self->_loaded('data')->{items};
 333
 334         my $include_missing = defined $filter_hash->{_missing};
 335         my $filtered_items;
 336
 337         foreach my $i ( 0 .. $#$items ) {
 338
 339                 if ( defined $items->[$i]->{$name} ) {
 340                         foreach my $v ( @{ $items->[$i]->{$name} } ) {
 341                                 if ( defined $filter_hash->{ $v } ) {
 342                                         $filtered_items->{$i}++;
 343                                 }
 344                         }
 345                 } elsif ( $include_missing ) {
 346                         $filtered_items->{$i}++;
 347                 }
 348         }
 349
 350         #warn "# filter $name ",dump($filtered_items);
 351
 352         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 353         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 354 }
 355
 356 sub _data_items {
 357         my ( $self, $all ) = @_;
 358         my $data = $self->_loaded( 'data' );
 359
 360         return @{ $data->{items} } if $all == 1;
 361
 362         my $filters = $self->_current_filters;
 363         my $filter_value;
 364         foreach my $f ( keys %$filters ) {
 365                 foreach my $n ( @{ $filters->{$f} } ) {
 366                         $filter_value->{$f}->{$n} = 1;
 367                 }
 368         }
 369         my @items = @{ $data->{items} };
 370         @items = grep {
 371                 my $i = $_;
 372                 my $pass = 1;
 373                 foreach my $n ( keys %$filter_value ) {
 374                         if ( ! exists $i->{$n} ) {
 375                                 if ( defined $filter_value->{$n}->{_missing} ) {
 376                                         $pass = 1;
 377                                         next;
 378                                 } else {
 379                                         $pass = 0;
 380                                         last;
 381                                 }
 382                         }
 383                         # and match any of values in element
 384                         my $have_values = 0;
 385                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 386                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 387                         }
 388                         if ( ! $have_values ) {
 389                                 $pass = 0;
 390                                 last;
 391                         }
 392                 }
 393                 $pass;
 394         } @items if $filter_value;
 395         return @items;
 396 }
 397
 398
 399 sub _current_filters {
 400         my $self = shift;
 401         my $current_filters;
 402         $current_filters->{ $_ } = $filters->{ $_ }
 403                 foreach (
 404                         grep { defined $filters->{ $_ } }
 405                         @{ $self->_loaded('header') }
 406                 );
 407         #warn "# current_filters ",dump($current_filters);
 408         return $current_filters;
 409 }
 410
 411 sub _data_sorted_by {
 412         my ( $self, $order ) = @_;
 413
 414         my $path = $self->session('path');
 415
 416         warn "_data_sorted_by $order from $path";
 417
 418         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 419                 return $loaded->{$path}->{sorted}->{$order};
 420         }
 421
 422         my $data = $self->_loaded( 'data' );
 423         my $numeric = $self->_is_numeric($order);
 424         my $missing = $numeric ? 0 : '';
 425         no warnings qw(numeric);
 426         my $nr = 0;
 427         my @sorted = map {
 428                 $_->[0]
 429         } sort {
 430                 if ( $numeric ) {
 431                         $a->[1] <=> $b->[1]
 432                 } else {
 433                         $a->[1] cmp $b->[1]
 434                 }
 435         } map {
 436                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 437         } @{ $data->{items} }
 438         ;
 439
 440         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 441         #warn "# sorted ",dump( @sorted );
 442
 443         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 444 }
 445
 446
 447 sub items {
 448         my $self = shift;
 449
 450         my $path = $self->session('path');
 451         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 452
 453         my @columns = $self->_perm_array('columns');
 454         $self->redirect_to('/data/columns') unless @columns;
 455         my $order   = $self->_perm_scalar('order', $columns[0]);
 456         my $sort    = $self->_perm_scalar('sort', 'a');
 457         my $offset  = $self->_perm_scalar('offset', 0);
 458         my $limit   = $self->_perm_scalar('limit', 20);
 459         $self->_perm_scalar('show', 'table');
 460
 461         # fix offset when changing limit
 462         $offset = int( $offset / $limit ) * $limit;
 463
 464         my $sorted = $self->_data_sorted_by( $order );
 465
 466         my @filter_names;
 467         if ( $filters ) {
 468                 foreach my $name ( keys %$filters ) {
 469                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 470                                 warn "skip filter $name not found in $path\n";
 471                                 next;
 472                         }
 473                         push @filter_names, $name;
 474                 }
 475                 warn "filter_names ",dump( @filter_names );
 476                 foreach my $name ( @filter_names ) {
 477                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 478                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 479                 }
 480         }
 481
 482         my $all_filters = join(' ',sort @filter_names,'order:',$order);
 483
 484 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 485
 486         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 487
 488                 my $path_filters = $loaded->{$path}->{filters};
 489
 490                 warn "create combined filter for $all_filters\n";
 491
 492                 my @filtered;
 493                 foreach my $i ( 0 .. $#$sorted ) {
 494                         my $pos = $sorted->[$i];
 495
 496                         if ( $#filter_names == -1 ) {
 497                                 push @filtered, $pos;
 498                                 next;
 499                         }
 500
 501                         my $skip = 0;
 502                         foreach ( @filter_names ) {
 503                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 504                         }
 505                         next if $skip;
 506
 507                         push @filtered, $pos;
 508                 }
 509
 510                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 511         }
 512
 513         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 514                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 515
 516         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 517
 518         my $sorted_items;
 519         my $data = $self->_loaded('data');
 520         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 521         foreach ( 0 .. $limit ) {
 522                 my $i = $_ + $offset;
 523                 last unless defined $filtered->[$i];
 524                 $i = $from_end - $i if $from_end;
 525                 my $id = $filtered->[$i];
 526                 push @$sorted_items,
 527                 my $item = $data->{items}->[ $id ];
 528                 $item->{_row_id} ||= $id;
 529         }
 530
 531         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 532
 533         $self->render(
 534                 order => $order,
 535                 offset => $offset,
 536                 limit => $limit,
 537                 sorted => $sorted_items,
 538                 columns => [ @columns ],
 539                 rows => $#$filtered + 1,
 540                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 541                 filters => $self->_current_filters,
 542         );
 543
 544 }
 545
 546
 547 sub order {
 548         my $self = shift;
 549         $self->session('order', $self->param('order'));
 550         $self->session('sort', $self->param('sort'));
 551         $self->redirect_to('/data/items');
 552 }
 553
 554 sub _is_numeric {
 555         my ( $self, $name ) = @_;
 556
 557         my $stats = $self->_loaded( 'stats' );
 558
 559         # sort facet numerically if more >50% elements are numeric
 560         my $count = $stats->{$name}->{count};
 561         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 562         defined $stats->{$name}->{numeric} &&
 563                 $stats->{$name}->{numeric} > $count / 2;
 564 }
 565
 566 sub _remove_filter {
 567         my ($self,$name) = @_;
 568         warn "_remove_filter $name\n";
 569
 570         my $path = $self->session('path');
 571
 572         delete $filters->{$name};
 573         delete $loaded->{$path}->{filters}->{$name};
 574         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 575
 576         foreach (
 577                         grep { /\b$name\b/ }
 578                         keys %{ $loaded->{$path}->{filtered} }
 579         ) {
 580                 delete $loaded->{$path}->{filtered}->{$_};
 581                 warn "remove filtered cache $_";
 582         }
 583 }
 584
 585 sub facet {
 586         my $self = shift;
 587
 588         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 589
 590         if ( my $name = $self->param('remove') ) {
 591                 $self->_remove_filter( $name );
 592                 $self->redirect_to( '/data/items' );
 593         }
 594
 595         my $facet;
 596         my $name = $self->param('name') || die "no name";
 597
 598         my $all = $self->_perm_scalar('all', 1);
 599         my $data = $self->_loaded('data');
 600
 601         my $filters = $self->_current_filters;
 602         my $all_filters = join(' ',sort keys %$filters,'order:',$self->session('order'));
 603         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 604                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 605
 606         if ( ! $filtered || $all ) {
 607                 $filtered = [ 0 .. $#{ $data->{items} } ];
 608                 warn "filter all values\n";
 609         } else {
 610                 warn "filter using $all_filters\n";
 611         }
 612
 613         foreach my $i ( @$filtered ) {
 614                 my $item = $data->{items}->[$i];
 615                 if ( ! exists $item->{$name} ) {
 616                         $facet->{ _missing }++;
 617                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 618                         $facet->{$_}++ foreach @{ $item->{$name} };
 619                 } else {
 620                         $facet->{ $item->{$name} }++;
 621                 }
 622         }
 623
 624 #       warn "# facet $name ",dump $facet;
 625
 626         my $checked;
 627         my @facet_names =
 628                   $all                      ? keys %$facet
 629                 : defined $filters->{$name} ? @{ $filters->{$name} }
 630                 : keys %$facet;
 631
 632         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 633
 634         my $numeric = $self->_is_numeric($name);
 635
 636         my $sort = $self->param('sort');
 637         # sort numeric facets with more than 5 values ascending
 638         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 639
 640         @facet_names = sort {
 641                 my $result;
 642                 if ( $sort eq 'a' ) {
 643                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 644                 } elsif ( $sort eq 'd' ) {
 645                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 646                 } elsif ( $sort eq 'c' ) {
 647                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 648                 } else {
 649                         warn "unknown sort: $sort";
 650                         $result = $a cmp $b;
 651                 }
 652                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 653                 $result;
 654         } @facet_names;
 655
 656         $self->render( name => $name, facet => $facet, checked => $checked,
 657                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 658         );
 659 }
 660
 661 sub edit {
 662         my $self = shift;
 663         my $content = $self->param('content');
 664
 665         my $i = $self->param('_row_id') || die "no _row_id";
 666         my $path = $self->param('path') || die "no path";
 667         my $name = $self->param('name') || die "no name";
 668
 669         if ( defined $loaded->{$path}->{data}->{items}->[$i]->{$name} ) {
 670                 $content =~ s/^\s+//s;
 671                 $content =~ s/\s+$//s;
 672                 if ( $content =~ /\xB6/ ) {     # para
 673                         $content = [ split(/\s*\xB6\s*/, $content) ];
 674                 } else {
 675                         $content = [ $content ];
 676                 }
 677
 678                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
 679                 my $new = dump $content;
 680                 if ( $old ne $new ) {
 681                         warn "# update $path $i $old -> $new\n";
 682                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $content;
 683
 684                         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
 685                             delete $loaded->{$path}->{sorted}->{$name};
 686                                 warn "# invalidate $path sorted $name\n";
 687                         }
 688
 689                         foreach ( grep { m/$name/ } keys %{ $loaded->{$path}->{filtered} } ) {
 690                             delete $loaded->{$path}->{filtered}->{$_};
 691                                 warn "# invalidate $path filtered $_\n";
 692                         }
 693
 694                 } else {
 695                         warn "# unchanged $path $i $old\n";
 696                 }
 697         } else {
 698                 $content = "$path $i $name doesn't exist\n";
 699                 warn "# $content\n";
 700         }
 701
 702         $self->render(
 703                 content => $content
 704         );
 705 }
 706
 707 1;