lib/CloudStore/API.pm

   1 package CloudStore::API;
   2 use warnings;
   3 use strict;
   4 use autodie;
   5
   6 use lib 'lib';
   7 use base qw(CloudStore::Gearman CloudStore::MD5sum);
   8
   9 use File::Path qw(make_path remove_tree);
  10 use File::Find;
  11 use Data::Dump qw(dump);
  12 use Carp qw(confess cluck);
  13
  14 sub new {
  15         my ($class,$slice) = @_;
  16
  17         cluck "DEPRICIATED $slice specified" if $slice;
  18
  19         my $self = {
  20                 passwd => '/var/lib/extrausers/passwd',
  21         };
  22         bless $self, $class;
  23
  24         $self->{md5} = $self->user_info("md5") || die "can't find user md5";
  25 =for removed
  26         $self->{md5}->{dir} = "$dir/md5";
  27         if ( ! -e $self->{md5}->{dir} ) {
  28                 make_path $self->{md5}->{dir}, { uid => $self->{md5}->{uid}, gid => $self->{md5}->{gid} };
  29                 warn "## CREATED md5pool $self->{md5}->{dir}\n";
  30         }
  31 =cut
  32
  33         return $self;
  34 }
  35
  36 sub slice_dir_port {
  37         my ($self,$slice) = @_;
  38         my ( undef, $dir, $port, undef ) = getgrnam($slice);
  39         die "getgrnam $slice: $!" if $!;
  40         warn "# slice_dir_port $slice = $dir $port\n";
  41         return ( $dir, $port );
  42 }
  43
  44 sub dir2gearman {
  45         my $self = shift;
  46         my $dir  = shift;
  47         $dir =~ s/\W+/_/g;
  48         $dir =~ s/^_+//;
  49         $dir =~ s{_\d+$}{};
  50         return join('_', $dir, @_);
  51 }
  52
  53 sub user_info {
  54         my ($self,$login) = @_;
  55
  56         confess "need login" unless $login;
  57
  58         my @n = qw/ login passwd uid gid quota comment gecos dir shell expire /;
  59         my @p = $login =~ m/^\d+$/ ? getpwuid $login : getpwnam $login;
  60         die "user_info $login: $@" if $@;
  61         my $user;
  62         $user->{$_} = shift @p foreach @n;
  63         return $user;
  64 }
  65
  66 sub create_user {
  67         my ( $self, $new_email, $new_passwd, $new_quota ) = @_;
  68
  69         my $max_uid = 0;
  70         my $found = 0;
  71
  72         open(my $fh, '<', $self->{passwd});
  73         while(<$fh>) {
  74                 my ( $login, $passwd, $uid, $gid, $email, $dir, $shell ) = split(/:/,$_);
  75                 $max_uid = $uid if $uid > $max_uid;
  76                 $found = $uid if $email eq $new_email;
  77         }
  78         close($fh);
  79
  80         my $slice = $ENV{SLICE} || 's1';
  81         $slice =~ s{/.+/(\w+)$}{$1};
  82         my ( $dir, $port ) = $self->slice_dir_port( $slice );
  83
  84         $dir ||= $ENV{SLICE};
  85         $port ||= 6501;
  86
  87         if ( ! $found ) {
  88                 $max_uid++;
  89                 $dir .= "/$max_uid";
  90                 warn "# create_user $slice $new_email $new_quota = $max_uid $dir";
  91                 open(my $fh, '>>', $self->{passwd});
  92                 print $fh "u$max_uid:$new_passwd:$max_uid:$port:$new_email:$dir:/bin/true\n";
  93                 close($fh);
  94                 $found = $max_uid;
  95
  96                 mkdir $dir;
  97                 chown $max_uid, $port, $dir;
  98
  99                 my $path = "$dir/.meta/secrets";
 100                 $self->mkbasepath($path);
 101                 open($fh, '>', $path);
 102                 print $fh "u$max_uid:$new_passwd\n";
 103                 close $fh;
 104         }
 105
 106         # FIXME update quota only on create?
 107         $self->gearman_do( $self->dir2gearman( $dir, 'quota', 'set' ) => "$found $new_quota" );
 108
 109         return 'u' . $found;
 110 }
 111
 112 sub mkbasepath {
 113         my ($self,$path,$opts) = @_;
 114         $path =~ s{/[^/]+$}{};
 115         make_path $path unless -d $path;
 116 }
 117
 118 sub user_dir {
 119         my ( $self,$user, $dir ) = @_;
 120         $user = $self->user_info($user) unless ref $user eq 'HASH';
 121         my $path;
 122         if ( exists $user->{dir} ) {
 123                 $path = $user->{dir} . '/.meta/' . $dir;
 124         } else {
 125                 die "no dir in ", dump $user;
 126         }
 127         $path =~ s{//+}{/}g;
 128
 129         if ( ! -e $path ) {
 130                 $self->mkbasepath( $path, { uid => $user->{uid} } );
 131                 open(my $fh, '>', $path);
 132                 close $fh;
 133                 chown $user->{uid}, $user->{gid}, $path;
 134                 warn "# user_dir created $path\n";
 135         }
 136
 137         #warn "### user_dir $path";
 138         return $path;
 139 }
 140
 141 sub append {
 142         my $self = shift @_;
 143         $self->append_meta( 'usage', @_ );
 144 }
 145
 146 sub append_meta {
 147         my $self = shift @_;
 148         my $log  = shift @_;
 149         my $user = shift @_;
 150         my $path = $self->user_dir( $user => $log );
 151         my $delimiter = '#';
 152            $delimiter = '  ' if $log =~ m/md5sum$/;
 153         my $line = join($delimiter,@_);
 154         open(my $fh, '>>', $path);
 155         print $fh "$line\n";
 156         close $fh;
 157         warn "## $path $line\n";
 158 }
 159
 160 sub usage {
 161         my ( $self, $user ) = @_;
 162         $user = $self->user_info($user) unless ref $user eq 'HASH';
 163         my $path = $self->user_dir( $user => 'usage');
 164         my $sum;
 165         open(my $fh, '<', $path);
 166         while(<$fh>) {
 167                 chomp;
 168                 my @v = split(/#/,$_);
 169                 $sum->{ $v[0] } += $v[1];
 170                 $sum->{_usage}  += $v[1];
 171         }
 172         my ( $usage, $quota ) = split(/ /,
 173                 $self->gearman_do( $self->dir2gearman( $user->{dir}, 'quota', 'get' ) => $user->{uid} )
 174         );
 175         $sum->{_usage} += $usage;
 176         $sum->{_quota} = $quota;
 177         warn "## usage ",dump($user, $sum), $/;
 178         return $sum;
 179 }
 180
 181 sub send_file {
 182         my ( $self, $f_uid,$f_path, $t_uid,$t_path ) = @_;
 183
 184         my $f = $self->user_info($f_uid);
 185         die "FIXME not on current slice" if $f->{dir} !~ m/^$ENV{SLICE}/;
 186         my $t = $self->user_info($t_uid);
 187
 188         my $f_full = "$f->{dir}/$f_path";
 189         my $t_full = "$t->{dir}/$t_path";
 190
 191         $self->mkbasepath( $t_full, { uid => $t->{uid} } );
 192
 193         my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size, $atime,$mtime,$ctime,$blksize,$blocks) = stat $f_full;
 194         if ( $uid == $f->{uid} ) {
 195                 warn "# send_file - move $f_uid $f_path to pool\n";
 196                 chown $self->{md5}->{uid}, $self->{md5}->{gid}, $f_full;
 197                 chmod oct("0444"), $f_full;
 198                 $self->append( $f, 'sent', -s $f_full, $t->{uid}, $f_path );
 199         } elsif ( $uid == $self->{md5}->{uid} ) {
 200                 warn "# send_file - shared $f_full\n";
 201         }
 202
 203         $self->delete( $t, $t_path ) if -e $t_full;
 204
 205         my $size = -s $f_full;
 206         my $md5;
 207
 208         my $ok;
 209         {
 210                 no autodie qw(link);
 211                 $ok = link $f_full, $t_full
 212         };
 213         if ( ! $ok || $! =~ m/cross-link/ ) {
 214                 $ok = symlink $f_full, $t_full;
 215         } else {
 216                 $size = -s $t_full;
 217
 218                 if ( $f->{uid} == $self->{md5}->{uid} ) {
 219                         $md5 = $f_path; # we don't have local md5sum db for md5 user!
 220                 } else {
 221                         $md5 = $self->md5_get($f_full);
 222                 }
 223
 224         }
 225
 226         if ( $ok ) {
 227                 $self->append( $t, 'recv', $size, $f->{uid}, $t_path );
 228                 $self->append_meta('md5sum', $t, $md5 => $t_path ) if $md5; # md5sum for received files! FIXME -- cross-slice md5
 229                 $self->refresh_file_list( $t );
 230         }
 231
 232         return $size;
 233 }
 234
 235 sub rename_file {
 236         my ( $self, $user, $from, $to ) = @_;
 237         $user = $self->user_info($user) unless ref $user eq 'HASH';
 238
 239         my $f_full = "$user->{dir}/$from";
 240         my $t_full = "$user->{dir}/$to";
 241
 242         $self->mkbasepath( $t_full, { uid => $user->{uid}, gid => $user->{gid} } );
 243         my $ok = rename $f_full, $t_full;
 244
 245         my $md5 = $self->md5_get($t_full);
 246         if ( ! $md5 ) {
 247                 warn "ERROR: no md5sum for $from";
 248                 return $ok; # XXX our internal error
 249         }
 250
 251         $self->append_meta('md5sum', $user, 'rename' => $from );
 252         $self->append_meta('md5sum', $user, $md5 => $from );
 253
 254         $self->refresh_file_list( $user );
 255
 256         return $ok;
 257 }
 258
 259
 260 sub delete {
 261         my ( $self, $user, $path ) = @_;
 262         $user = $self->user_info($user) unless ref $user eq 'HASH';
 263
 264         my $deleted_size = 0;
 265         my $full_path = "$user->{dir}/$path";
 266
 267         if ( -d $full_path ) {
 268
 269                 find({
 270                 no_chdir => 1,
 271                 wanted => sub {
 272                         return if -d $_;
 273                         my ($uid,$size) = (stat($_))[4,7];
 274                         warn "## find $uid $size $_\n";
 275                         if ( $uid == $self->{md5}->{uid} ) {
 276                                 $deleted_size += $size;
 277                         }
 278                 }}, $full_path);
 279
 280                 remove_tree $full_path;
 281         } else {
 282                 $deleted_size += -s $full_path;
 283                 unlink $full_path;
 284         }
 285
 286         warn "delete $deleted_size bytes shared\n";
 287
 288         $self->append( $user, 'delete', -$deleted_size, $user->{uid}, $path );
 289         $self->append_meta('md5sum', $user, 'delete', $path );
 290
 291         $self->refresh_file_list( $user );
 292
 293         return $full_path;
 294 }
 295
 296 sub file_size {
 297         my ( $self, $user, $path ) = @_;
 298         $user = $self->user_info($user) unless ref $user eq 'HASH';
 299
 300         my $full_path = "$user->{dir}/$path";
 301         return -s $full_path;
 302 }
 303
 304 sub refresh_file_list {
 305         my ( $self, $user ) = @_;
 306         $user = $self->user_info($user) unless ref $user eq 'HASH';
 307         my $full_path = "$user->{dir}/.meta/files";
 308         if ( -e $full_path ) {
 309                 warn "## refresh_file_list $full_path";
 310                 unlink $full_path;
 311         }
 312 }
 313
 314 1;