C4/SIP/ILS/Item.pm

   1 #
   2 # ILS::Item.pm
   3 #
   4 # A Class for hiding the ILS's concept of the item from OpenSIP
   5 #
   6
   7 package ILS::Item;
   8
   9 use strict;
  10 use warnings;
  11
  12 use Sys::Syslog qw(syslog);
  13 use Carp;
  14
  15 use ILS::Transaction;
  16
  17 use C4::Debug;
  18 use C4::Context;
  19 use C4::Biblio;
  20 use C4::Items;
  21 use C4::Circulation;
  22 use C4::Members;
  23 use C4::Reserves;
  24
  25 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK);
  26
  27 BEGIN {
  28     $VERSION = 3.07.00.049;
  29         require Exporter;
  30         @ISA = qw(Exporter);
  31         @EXPORT_OK = qw();
  32 }
  33
  34 =head1 EXAMPLE
  35
  36  our %item_db = (
  37     '1565921879' => {
  38         title => "Perl 5 desktop reference",
  39         id => '1565921879',
  40         sip_media_type => '001',
  41         magnetic_media => 0,
  42         hold_queue => [],
  43     },
  44     '0440242746' => {
  45         title => "The deep blue alibi",
  46         id => '0440242746',
  47         sip_media_type => '001',
  48         magnetic_media => 0,
  49         hold_queue => [
  50             {
  51             itemnumber => '823',
  52             priority => '1',
  53             reservenotes => undef,
  54             constrainttype => 'a',
  55             reservedate => '2008-10-09',
  56             found => undef,
  57             rtimestamp => '2008-10-09 11:15:06',
  58             biblionumber => '406',
  59             borrowernumber => '756',
  60             branchcode => 'CPL'
  61             }
  62         ],
  63     },
  64     '660' => {
  65         title => "Harry Potter y el cáliz de fuego",
  66         id => '660',
  67         sip_media_type => '001',
  68         magnetic_media => 0,
  69         hold_queue => [],
  70     },
  71 );
  72 =cut
  73
  74 sub priority_sort {
  75     defined $a->{priority} or return -1;
  76     defined $b->{priority} or return 1;
  77     return $a->{priority} <=> $b->{priority};
  78 }
  79
  80 sub new {
  81         my ($class, $item_id) = @_;
  82         my $type = ref($class) || $class;
  83         my $self;
  84     my $itemnumber = GetItemnumberFromBarcode($item_id);
  85         my $item = GetBiblioFromItemNumber($itemnumber);    # actually biblio.*, biblioitems.* AND items.*  (overkill)
  86         if (! $item) {
  87                 syslog("LOG_DEBUG", "new ILS::Item('%s'): not found", $item_id);
  88                 warn "new ILS::Item($item_id) : No item '$item_id'.";
  89                 return undef;
  90         }
  91     $item->{  'itemnumber'   } = $itemnumber;
  92     $item->{      'id'       } = $item->{barcode};     # to SIP, the barcode IS the id.
  93     $item->{permanent_location}= $item->{homebranch};
  94     $item->{'collection_code'} = $item->{ccode};
  95     $item->{  'call_number'  } = $item->{itemcallnumber};
  96     # $item->{'destination_loc'}  =  ?
  97
  98         # check if its on issue and if so get the borrower
  99         my $issue = GetItemIssue($item->{'itemnumber'});
 100     if ($issue) {
 101         $item->{due_date} = $issue->{date_due};
 102     }
 103         my $borrower = GetMember(borrowernumber=>$issue->{'borrowernumber'});
 104         $item->{patron} = $borrower->{'cardnumber'};
 105     my ($whatever, $arrayref) = GetReservesFromBiblionumber($item->{biblionumber});
 106         $item->{hold_queue} = [ sort priority_sort @$arrayref ];
 107         $item->{hold_shelf}    = [( grep {   defined $_->{found}  and $_->{found} eq 'W' } @{$item->{hold_queue}} )];
 108         $item->{pending_queue} = [( grep {(! defined $_->{found}) or  $_->{found} ne 'W' } @{$item->{hold_queue}} )];
 109         $self = $item;
 110         bless $self, $type;
 111
 112     syslog("LOG_DEBUG", "new ILS::Item('%s'): found with title '%s'",
 113            $item_id, $self->{title});
 114
 115     return $self;
 116 }
 117
 118 # 0 means read-only
 119 # 1 means read/write
 120
 121 my %fields = (
 122     id                  => 0,
 123     sip_media_type      => 0,
 124     sip_item_properties => 0,
 125     magnetic_media      => 0,
 126     permanent_location  => 0,
 127     current_location    => 0,
 128     print_line          => 1,
 129     screen_msg          => 1,
 130     itemnumber          => 0,
 131     biblionumber        => 0,
 132     barcode             => 0,
 133     onloan              => 0,
 134     collection_code     => 0,
 135     call_number         => 0,
 136     enumchron           => 0,
 137     location            => 0,
 138     author              => 0,
 139     title               => 0,
 140 );
 141
 142 sub next_hold {
 143     my $self = shift or return;
 144     # use Data::Dumper; warn "next_hold() hold_shelf: " . Dumper($self->{hold_shelf}); warn "next_hold() pending_queue: " . $self->{pending_queue};
 145     foreach (@{$self->hold_shelf}) {    # If this item was taken from the hold shelf, then that reserve still governs
 146         next unless ($_->{itemnumber} and $_->{itemnumber} == $self->{itemnumber});
 147         return $_;
 148     }
 149     if (scalar @{$self->{pending_queue}}) {    # Otherwise, if there is at least one hold, the first (best priority) gets it
 150         return  $self->{pending_queue}->[0];
 151     }
 152     return;
 153 }
 154
 155 # hold_patron_id is NOT the barcode.  It's the borrowernumber.
 156 # If a return triggers capture for a hold the borrowernumber is passed
 157 # and saved so that other hold info can be retrieved
 158 sub hold_patron_id {
 159     my $self = shift;
 160     my $id   = shift;
 161     if ($id) {
 162         $self->{hold}->{borrowernumber} = $id;
 163     }
 164     if ($self->{hold} ) {
 165         return $self->{hold}->{borrowernumber};
 166     }
 167     return;
 168
 169 }
 170 sub hold_patron_name {
 171     my $self = shift or return;
 172     my $borrowernumber = (@_ ? shift: $self->hold_patron_id()) or return;
 173     my $holder = GetMember(borrowernumber=>$borrowernumber);
 174     unless ($holder) {
 175         syslog("LOG_ERR", "While checking hold, GetMember failed for borrowernumber '$borrowernumber'");
 176         return;
 177     }
 178     my $email = $holder->{email} || '';
 179     my $phone = $holder->{phone} || '';
 180     my $extra = ($email and $phone) ? " ($email, $phone)" :  # both populated, employ comma
 181                 ($email or  $phone) ? " ($email$phone)"   :  # only 1 populated, we don't care which: no comma
 182                 "" ;                                         # neither populated, empty string
 183     my $name = $holder->{firstname} ? $holder->{firstname} . ' ' : '';
 184     $name .= $holder->{surname} . $extra;
 185     return $name;
 186 }
 187
 188 sub hold_patron_bcode {
 189     my $self = shift or return;
 190     my $borrowernumber = (@_ ? shift: $self->hold_patron_id()) or return;
 191     my $holder = GetMember(borrowernumber => $borrowernumber);
 192     if ($holder) {
 193         if ($holder->{cardnumber}) {
 194             return $holder->{cardnumber};
 195         }
 196     }
 197     return;
 198 }
 199
 200 sub destination_loc {
 201     my $self = shift;
 202     my $set_loc = shift;
 203     if ($set_loc) {
 204         $self->{dest_loc} = $set_loc;
 205     }
 206     if ($self->{dest_loc} ) {
 207         return $self->{dest_loc};
 208     }
 209     return q{};
 210 }
 211
 212 our $AUTOLOAD;
 213
 214 sub DESTROY { } # keeps AUTOLOAD from catching inherent DESTROY calls
 215
 216 sub AUTOLOAD {
 217     my $self = shift;
 218     my $class = ref($self) or croak "$self is not an object";
 219     my $name = $AUTOLOAD;
 220
 221     $name =~ s/.*://;
 222
 223     unless (exists $fields{$name}) {
 224                 croak "Cannot access '$name' field of class '$class'";
 225     }
 226
 227         if (@_) {
 228         $fields{$name} or croak "Field '$name' of class '$class' is READ ONLY.";
 229                 return $self->{$name} = shift;
 230         } else {
 231                 return $self->{$name};
 232         }
 233 }
 234
 235 sub status_update {     # FIXME: this looks unimplemented
 236     my ($self, $props) = @_;
 237     my $status = new ILS::Transaction;
 238     $self->{sip_item_properties} = $props;
 239     $status->{ok} = 1;
 240     return $status;
 241 }
 242
 243 sub title_id {
 244     my $self = shift;
 245     return $self->{title};
 246 }
 247
 248 sub sip_circulation_status {
 249     my $self = shift;
 250     if ($self->{patron}) {
 251                 return '04';    # charged
 252     } elsif (scalar @{$self->{hold_queue}}) {
 253                 return '08';    # waiting on hold shelf
 254     } else {
 255                 return '03';    # available
 256     }                   # FIXME: 01-13 enumerated in spec.
 257 }
 258
 259 sub sip_security_marker {
 260     return '02';        # FIXME? 00-other; 01-None; 02-Tattle-Tape Security Strip (3M); 03-Whisper Tape (3M)
 261 }
 262 sub sip_fee_type {
 263     return '01';    # FIXME? 01-09 enumerated in spec.  We just use O1-other/unknown.
 264 }
 265
 266 sub fee {
 267     my $self = shift;
 268     return $self->{fee} || 0;
 269 }
 270 sub fee_currency {
 271     my $self = shift;
 272     return $self->{currency} || 'USD';
 273 }
 274 sub owner {
 275     my $self = shift;
 276     return $self->{homebranch};
 277 }
 278 sub hold_queue {
 279     my $self = shift;
 280         (defined $self->{hold_queue}) or return [];
 281     return $self->{hold_queue};
 282 }
 283 sub pending_queue {
 284     my $self = shift;
 285         (defined $self->{pending_queue}) or return [];
 286     return $self->{pending_queue};
 287 }
 288 sub hold_shelf {
 289     my $self = shift;
 290         (defined $self->{hold_shelf}) or return [];
 291     return $self->{hold_shelf};
 292 }
 293
 294 sub hold_queue_position {
 295         my ($self, $patron_id) = @_;
 296         ($self->{hold_queue}) or return 0;
 297         my $i = 0;
 298         foreach (@{$self->{hold_queue}}) {
 299                 $i++;
 300                 $_->{patron_id} or next;
 301                 if ($self->barcode_is_borrowernumber($patron_id, $_->{borrowernumber})) {
 302                         return $i;  # maybe should return $_->{priority}
 303                 }
 304         }
 305     return 0;
 306 }
 307
 308 sub due_date {
 309     my $self = shift;
 310     return $self->{due_date} || 0;
 311 }
 312 sub recall_date {
 313     my $self = shift;
 314     return $self->{recall_date} || 0;
 315 }
 316 sub hold_pickup_date {
 317     my $self = shift;
 318     return $self->{hold_pickup_date} || 0;
 319 }
 320
 321 # This is a partial check of "availability".  It is not supposed to check everything here.
 322 # An item is available for a patron if it is:
 323 # 1) checked out to the same patron
 324 #    AND no pending (i.e. non-W) hold queue
 325 # OR
 326 # 2) not checked out
 327 #    AND (not on hold_shelf OR is on hold_shelf for patron)
 328 #
 329 # What this means is we are consciously allowing the patron to checkout (but not renew) an item that DOES
 330 # have non-W holds on it, but has not been "picked" from the stacks.  That is to say, the
 331 # patron has retrieved the item before the librarian.
 332 #
 333 # We don't check if the patron is at the front of the pending queue in the first case, because
 334 # they should not be able to place a hold on an item they already have.
 335
 336 sub available {
 337         my ($self, $for_patron) = @_;
 338         my $count  = (defined $self->{pending_queue}) ? scalar @{$self->{pending_queue}} : 0;
 339         my $count2 = (defined $self->{hold_shelf}   ) ? scalar @{$self->{hold_shelf}   } : 0;
 340         $debug and print STDERR "availability check: pending_queue size $count, hold_shelf size $count2\n";
 341     if (defined($self->{patron_id})) {
 342                 ($self->{patron_id} eq $for_patron) or return 0;
 343                 return ($count ? 0 : 1);
 344         } else {        # not checked out
 345         ($count2) and return $self->barcode_is_borrowernumber($for_patron, $self->{hold_shelf}[0]->{borrowernumber});
 346         }
 347         return 0;
 348 }
 349
 350 sub _barcode_to_borrowernumber ($) {
 351     my $known = shift;
 352     (defined($known)) or return undef;
 353     my $member = GetMember(cardnumber=>$known) or return undef;
 354     return $member->{borrowernumber};
 355 }
 356 sub barcode_is_borrowernumber ($$$) {    # because hold_queue only has borrowernumber...
 357     my $self = shift;   # not really used
 358     my $barcode = shift;
 359     my $number  = shift or return undef;    # can't be zero
 360     (defined($barcode)) or return undef;    # might be 0 or 000 or 000000
 361     my $converted = _barcode_to_borrowernumber($barcode) or return undef;
 362     return ($number eq $converted); # even though both *should* be numbers, eq is safer.
 363 }
 364 sub fill_reserve ($$) {
 365     my $self = shift;
 366     my $hold = shift or return undef;
 367     foreach (qw(biblionumber borrowernumber reservedate)) {
 368         $hold->{$_} or return undef;
 369     }
 370     return ModReserveFill($hold);
 371 }
 372 1;
 373 __END__
 374