Koha/Plugins/Base.pm

   1 package Koha::Plugins::Base;
   2
   3 # Copyright 2012 Kyle Hall
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use Module::Pluggable require => 1;
  23
  24 use base qw{Module::Bundled::Files};
  25
  26 use C4::Context;
  27 use C4::Auth;
  28
  29 =head1 NAME
  30
  31 C4::Plugins::Base - Base Module for plugins
  32
  33 =cut
  34
  35 sub new {
  36     my ( $class, $args ) = @_;
  37
  38     return unless ( C4::Context->config("enable_plugins") || $args->{'enable_plugins'} );
  39
  40     $args->{'class'} = $class;
  41     $args->{'template'} = Template->new( { ABSOLUTE => 1 } );
  42
  43     my $self = bless( $args, $class );
  44
  45     ## Run the installation method if it exists and hasn't been run before
  46     if ( $self->can('install') && !$self->retrieve_data('__INSTALLED__') ) {
  47         if ( $self->install() ) {
  48             $self->store_data( { '__INSTALLED__' => 1 } );
  49         } else {
  50             warn "Plugin $class failed during installation!";
  51         }
  52     }
  53
  54     return $self;
  55 }
  56
  57 =head2 store_data
  58
  59 store_data allows a plugin to store key value pairs in the database for future use.
  60
  61 usage: $self->store_data({ param1 => 'param1val', param2 => 'param2value' })
  62
  63 =cut
  64
  65 sub store_data {
  66     my ( $self, $data ) = @_;
  67
  68     my $dbh = C4::Context->dbh;
  69     my $sql = "REPLACE INTO plugin_data SET plugin_class = ?, plugin_key = ?, plugin_value = ?";
  70     my $sth = $dbh->prepare($sql);
  71
  72     foreach my $key ( keys %$data ) {
  73         $sth->execute( $self->{'class'}, $key, $data->{$key} );
  74     }
  75 }
  76
  77 =head2 retrieve_data
  78
  79 retrieve_data allows a plugin to read the values that were previously saved with store_data
  80
  81 usage: my $value = $self->retrieve_data( $key );
  82
  83 =cut
  84
  85 sub retrieve_data {
  86     my ( $self, $key ) = @_;
  87
  88     my $dbh = C4::Context->dbh;
  89     my $sql = "SELECT plugin_value FROM plugin_data WHERE plugin_class = ? AND plugin_key = ?";
  90     my $sth = $dbh->prepare($sql);
  91     $sth->execute( $self->{'class'}, $key );
  92     my $row = $sth->fetchrow_hashref();
  93
  94     return $row->{'plugin_value'};
  95 }
  96
  97 =head2 get_template
  98
  99 get_template returns a Template object. Eventually this will probably be calling
 100 C4:Template, but at the moment, it does not.
 101
 102 =cut
 103
 104 sub get_template {
 105     my ( $self, $args ) = @_;
 106
 107     my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 108         {   template_name   => $self->mbf_path( $args->{'file'} ),
 109             query           => $self->{'cgi'},
 110             type            => "intranet",
 111             authnotrequired => 1,
 112 #           flagsrequired   => { tools => '*' },
 113             is_plugin       => 1,
 114         }
 115     );
 116
 117     $template->param(
 118         CLASS       => $self->{'class'},
 119         METHOD      => $self->{'cgi'}->param('method'),
 120         PLUGIN_PATH => $self->get_plugin_http_path(),
 121     );
 122
 123     return $template;
 124 }
 125
 126 sub get_metadata {
 127     my ( $self, $args ) = @_;
 128
 129     return $self->{'metadata'};
 130 }
 131
 132 =head2 get_qualified_table_name
 133
 134 To avoid naming conflict, each plugins tables should use a fully qualified namespace.
 135 To avoid hardcoding and make plugins more flexible, this method will return the proper
 136 fully qualified table name.
 137
 138 usage: my $table = $self->get_qualified_table_name( 'myTable' );
 139
 140 =cut
 141
 142 sub get_qualified_table_name {
 143     my ( $self, $table_name ) = @_;
 144
 145     return lc( join( '_', split( '::', $self->{'class'} ), $table_name ) );
 146 }
 147
 148 =head2 get_plugin_http_path
 149
 150 To access a plugin's own resources ( images, js files, css files, etc... )
 151 a plugin will need to know what path to use in the template files. This
 152 method returns that path.
 153
 154 usage: my $path = $self->get_plugin_http_path();
 155
 156 =cut
 157
 158 sub get_plugin_http_path {
 159     my ($self) = @_;
 160
 161     return "/plugin/" . join( '/', split( '::', $self->{'class'} ) );
 162 }
 163
 164 =head2 go_home
 165
 166    go_home is a quick redirect to the Koha plugins home page
 167
 168 =cut
 169
 170 sub go_home {
 171     my ( $self, $params ) = @_;
 172
 173     print $self->{'cgi'}->redirect("/cgi-bin/koha/plugins/plugins-home.pl");
 174 }
 175
 176 1;
 177 __END__
 178
 179 =head1 AUTHOR
 180
 181 Kyle M Hall <kyle.m.hall@gmail.com>
 182
 183 =cut