admin/preferences.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2009 Jesse Weaver and the Koha Dev Team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI;
  24 use C4::Auth;
  25 use C4::Context;
  26 use C4::Koha;
  27 use C4::Languages qw(getTranslatedLanguages);
  28 use C4::ClassSource;
  29 use C4::Log;
  30 use C4::Output;
  31 use C4::Templates;
  32 use C4::Budgets qw(GetCurrency);
  33 use File::Spec;
  34 use IO::File;
  35 use YAML::Syck qw();
  36 use List::MoreUtils qw(any);
  37 $YAML::Syck::ImplicitTyping = 1;
  38 our $lang;
  39
  40 # use Smart::Comments;
  41 #
  42
  43 sub GetTab {
  44     my ( $input, $tab ) = @_;
  45
  46     my $tab_template = C4::Templates::gettemplate( 'admin/preferences/' . $tab . '.pref', 'intranet', $input );
  47
  48     my $active_currency = GetCurrency();
  49     my $local_currency;
  50     if ($active_currency) {
  51         $local_currency = $active_currency->{currency};
  52     }
  53     $tab_template->param(
  54         local_currency => $local_currency, # currency code is used, because we do not know how a given currency is formatted.
  55     );
  56
  57     return YAML::Syck::Load( $tab_template->output() );
  58 }
  59
  60 sub _get_chunk {
  61     my ( $value, %options ) = @_;
  62
  63     my $name = $options{'pref'};
  64     my $chunk = { name => $name, value => $value, type => $options{'type'} || 'input', class => $options{'class'} };
  65
  66     if ( $options{'class'} && $options{'class'} eq 'password' ) {
  67         $chunk->{'input_type'} = 'password';
  68     } elsif ( $options{'class'} && $options{'class'} eq 'date' ) {
  69         $chunk->{'dateinput'} = 1;
  70     } elsif ( $options{'type'} && ( $options{'type'} eq 'opac-languages' || $options{'type'} eq 'staff-languages' ) ) {
  71         my $current_languages = { map { +$_, 1 } split( /\s*,\s*/, $value ) };
  72
  73         my $theme;
  74         my $interface;
  75         if ( $options{'type'} eq 'opac-languages' ) {
  76             # this is the OPAC
  77             $interface = 'opac';
  78             $theme     = C4::Context->preference('opacthemes');
  79         } else {
  80             # this is the staff client
  81             $interface = 'intranet';
  82             $theme     = C4::Context->preference('template');
  83         }
  84         $chunk->{'languages'} = getTranslatedLanguages( $interface, $theme, $lang, $current_languages );
  85         $chunk->{'type'} = 'languages';
  86     } elsif ( $options{ 'choices' } ) {
  87         if ( $options{'choices'} && ref( $options{ 'choices' } ) eq '' ) {
  88             if ( $options{'choices'} eq 'class-sources' ) {
  89                 my $sources = GetClassSources();
  90                 $options{'choices'} = { map { $_ => $sources->{$_}->{'description'} } keys %$sources };
  91             } elsif ( $options{'choices'} eq 'opac-templates' ) {
  92                 $options{'choices'} = { map { $_ => $_ } getallthemes( 'opac' ) }
  93             } elsif ( $options{'choices'} eq 'staff-templates' ) {
  94                 $options{'choices'} = { map { $_ => $_ } getallthemes( 'intranet' ) }
  95             } else {
  96                 die 'Unrecognized source of preference values: ' . $options{'choices'};
  97             }
  98         }
  99
 100         $value ||= 0;
 101
 102         $chunk->{'type'} = 'select';
 103         $chunk->{'CHOICES'} = [
 104             sort { $a->{'text'} cmp $b->{'text'} }
 105             map { { text => $options{'choices'}->{$_}, value => $_, selected => ( $_ eq $value || ( $_ eq '' && ( $value eq '0' || !$value ) ) ) } }
 106             keys %{ $options{'choices'} }
 107         ];
 108     }
 109
 110     $chunk->{ 'type_' . $chunk->{'type'} } = 1;
 111
 112     return $chunk;
 113 }
 114
 115 sub TransformPrefsToHTML {
 116     my ( $data, $searchfield ) = @_;
 117
 118     my @lines;
 119     my $dbh = C4::Context->dbh;
 120     my $title = ( keys( %$data ) )[0];
 121     my $tab = $data->{ $title };
 122     $tab = { '' => $tab } if ( ref( $tab ) eq 'ARRAY' );
 123
 124     my @override_syspref_names = split( /,/, $ENV{"OVERRIDE_SYSPREF_NAMES"} );
 125
 126     foreach my $group ( sort keys %$tab ) {
 127         if ( $group ) {
 128             push @lines, { is_group_title => 1, title => $group };
 129         }
 130
 131         foreach my $line ( @{ $tab->{ $group } } ) {
 132             my @chunks;
 133             my @names;
 134
 135             foreach my $piece ( @$line ) {
 136                 if ( ref ( $piece ) eq 'HASH' ) {
 137                     my $name = $piece->{'pref'};
 138
 139                     if ( $name ) {
 140                         my $row = $dbh->selectrow_hashref( "SELECT value, type FROM systempreferences WHERE variable = ?", {}, $name );
 141                         my $value;
 142                         if ( ( !defined( $row ) || ( !defined( $row->{'value'} ) && $row->{'type'} ne 'YesNo' ) ) && defined( $piece->{'default'} ) ) {
 143                             $value = $piece->{'default'};
 144                         } else {
 145                             $value = $row->{'value'};
 146                         }
 147                         my $chunk = _get_chunk( $value, %$piece );
 148
 149                         # No highlighting of inputs yet, but would be useful
 150                         $chunk->{'highlighted'} = 1 if ( $searchfield && $name =~ /^$searchfield$/i );
 151
 152                         push @chunks, $chunk;
 153
 154                         my $name_entry = { name => $name };
 155                         if ( $searchfield ) {
 156                             if ( $name =~ /^$searchfield$/i ) {
 157                                 $name_entry->{'jumped'} = 1;
 158                             } elsif ( $name =~ /$searchfield/i ) {
 159                                 $name_entry->{'highlighted'} = 1;
 160                             }
 161                         }
 162                         $name_entry->{'overridden'} = 1 if ( any { $name eq $_ } @override_syspref_names );
 163                         push @names, $name_entry;
 164                     } else {
 165                         push @chunks, $piece;
 166                     }
 167                 } else {
 168                     push @chunks, { type_text => 1, contents => $piece };
 169                 }
 170             }
 171             push @lines, { CHUNKS => \@chunks, NAMES => \@names, is_group_title => 0 };
 172         }
 173     }
 174
 175     return $title, \@lines;
 176 }
 177
 178 sub _get_pref_files {
 179     my ( $input, $open_files ) = @_;
 180
 181     my ( $htdocs, $theme, $lang, undef ) = C4::Templates::_get_template_file( 'admin/preferences/admin.pref', 'intranet', $input );
 182
 183     my %results;
 184
 185     foreach my $file ( glob( "$htdocs/$theme/$lang/modules/admin/preferences/*.pref" ) ) {
 186         my ( $tab ) = ( $file =~ /([a-z0-9_-]+)\.pref$/ );
 187
 188         $results{$tab} = $open_files ? new IO::File( $file, 'r' ) : '';
 189     }
 190
 191     return %results;
 192 }
 193
 194 sub SearchPrefs {
 195     my ( $input, $searchfield ) = @_;
 196     my @tabs;
 197
 198     my %tab_files = _get_pref_files( $input );
 199     our @terms = split( /\s+/, $searchfield );
 200
 201     foreach my $tab_name ( keys %tab_files ) {
 202         my $data = GetTab( $input, $tab_name );
 203         my $title = ( keys( %$data ) )[0];
 204         my $tab = $data->{ $title };
 205         $tab = { '' => $tab } if ( ref( $tab ) eq 'ARRAY' );
 206
 207         my $matched_groups;
 208
 209         while ( my ( $group_title, $contents ) = each %$tab ) {
 210             if ( matches( $group_title, \@terms ) ) {
 211                 $matched_groups->{$group_title} = $contents;
 212                 next;
 213             }
 214
 215             my @new_contents;
 216
 217             foreach my $line ( @$contents ) {
 218                 my $matched;
 219
 220                 foreach my $piece ( @$line ) {
 221                     if ( ref( $piece ) eq 'HASH' ) {
 222                         if ( !$piece->{'pref'} ){
 223                             next;
 224                         }
 225                         if ( matches( $piece->{'pref'}, \@terms) ) {
 226                             $matched = 1;
 227                         } elsif ( ref( $piece->{'choices'} ) eq 'HASH' && grep( { $_ && matches( $_, \@terms ) } values( %{ $piece->{'choices'} } ) ) ) {
 228                             $matched = 1;
 229                         }
 230                     } elsif ( matches( $piece, \@terms ) ) {
 231                         $matched = 1;
 232                     }
 233                     last if ( $matched );
 234                 }
 235
 236                 push @new_contents, $line if ( $matched );
 237             }
 238
 239             $matched_groups->{$group_title} = \@new_contents if ( @new_contents );
 240         }
 241
 242         if ( $matched_groups ) {
 243             my ( $title, $LINES ) = TransformPrefsToHTML( { $title => $matched_groups }, $searchfield );
 244
 245             push @tabs, { tab => $tab, tab_title => $title, LINES => $LINES, };
 246         }
 247     }
 248
 249     return @tabs;
 250 }
 251
 252 sub matches {
 253     my ( $text, $terms ) = @_;
 254     if ( $text ) { return !grep( { $text !~ /$_/i } @$terms ); }
 255 }
 256
 257 my $dbh = C4::Context->dbh;
 258 our $input = new CGI;
 259
 260 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 261     {   template_name   => "admin/preferences.tmpl",
 262         query           => $input,
 263         type            => "intranet",
 264         authnotrequired => 0,
 265         flagsrequired   => { parameters => 'parameters_remaining_permissions' },
 266         debug           => 1,
 267     }
 268 );
 269
 270 $lang = $template->param( 'lang' );
 271 my $op = $input->param( 'op' ) || '';
 272 my $tab = $input->param( 'tab' );
 273 $tab ||= 'acquisitions'; # Ideally this should be "local-use" but preferences.pl
 274                          # does not presently support local use preferences
 275
 276 my $highlighted;
 277
 278 if ( $op eq 'save' ) {
 279     unless ( C4::Context->config( 'demo' ) ) {
 280         foreach my $param ( $input->param() ) {
 281             my ( $pref ) = ( $param =~ /pref_(.*)/ );
 282
 283             next if ( !defined( $pref ) );
 284
 285             my $value = join( ',', $input->param( $param ) );
 286
 287             C4::Context->set_preference( $pref, $value );
 288             logaction( 'SYSTEMPREFERENCE', 'MODIFY', undef, $pref . " | " . $value );
 289         }
 290     }
 291
 292     print $input->redirect( '/cgi-bin/koha/admin/preferences.pl?tab=' . $tab );
 293     exit;
 294 }
 295
 296 my @TABS;
 297
 298 if ( $op eq 'search' ) {
 299     my $searchfield = $input->param( 'searchfield' );
 300
 301     $searchfield =~ s/\p{IsC}//g;
 302     $searchfield =~ s/\s+/ /;
 303     $searchfield =~ s/^\s+//;
 304     $searchfield =~ s/\s+$//;
 305
 306     $template->param( searchfield => $searchfield );
 307
 308     @TABS = SearchPrefs( $input, $searchfield );
 309
 310     foreach my $tabh ( @TABS ) {
 311         $template->param(
 312             $tabh->{'tab'} => 1
 313         );
 314     }
 315
 316     if ( @TABS ) {
 317         $tab = ''; # No need to load a particular tab, as we found results
 318         $template->param( search_jumped => 1 ) if ( $TABS[0]->{'search_jumped'} );
 319     } else {
 320         $template->param(
 321             search_not_found => 1,
 322         );
 323     }
 324 }
 325
 326 if ( $tab ) {
 327     my ( $tab_title, $LINES ) = TransformPrefsToHTML( GetTab( $input, $tab ), $highlighted );
 328
 329     push @TABS, { tab_title => $tab_title, LINES => $LINES };
 330     $template->param(
 331         $tab => 1,
 332         tab => $tab,
 333     );
 334 }
 335
 336 $template->param( TABS => \@TABS );
 337
 338 output_html_with_http_headers $input, $cookie, $template->output;