lib/CWMP/Request.pm

   1 package CWMP::Request;
   2
   3 use warnings;
   4 use strict;
   5
   6 use XML::Rules;
   7 use CWMP::Tree;
   8 use Data::Dump qw/dump/;
   9 use Carp qw/confess cluck/;
  10 use Class::Trigger;
  11
  12 =head1 NAME
  13
  14 CWMP::Request - parse SOAP request metods
  15
  16 =head1 CPE metods
  17
  18 All methods described below call triggers with same name
  19
  20 =cut
  21
  22 my $tree = CWMP::Tree->new({ debug => 0 });
  23
  24 our $state;     # FIXME check this!
  25
  26 my $rules =  [
  27                 #_default => 'content trim',
  28                 x_default => sub {
  29                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
  30                         warn dump( $tag_name, $tag_hash, $context );
  31                 },
  32                 'ID' => sub {
  33                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
  34                         $state->{ID} = $tag_hash->{_content};
  35                 },
  36
  37                 'DeviceId' => sub {
  38                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
  39                         foreach my $name ( keys %$tag_hash ) {
  40                                 next if $name eq '_content';
  41                                 my $key = $name;
  42                                 $key =~ s/^\w+://;      # stip namespace
  43                                 $state->{DeviceID}->{ $key } = _tag( $tag_hash, $name, '_content' );
  44                         }
  45                 },
  46                 'EventStruct' => sub {
  47                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
  48                         push @{ $state->{EventStruct} }, $tag_hash->{EventCode}->{_content};
  49                 },
  50                 qr/(MaxEnvelopes|CurrentTime|RetryCount)/ => sub {
  51                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
  52                         $state->{$tag_name} = $tag_hash->{_content};
  53                 },
  54                 'ParameterValueStruct' => sub {
  55                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
  56                         # Name/Value tags must be case insnesitive
  57                         my $value = (grep( /value/i, keys %$tag_hash ))[0];
  58                         $state->{Parameter}->{ _tag($tag_hash, 'Name', '_content') } = _tag($tag_hash, 'Value', '_content' );
  59                 },
  60
  61 ];
  62
  63 =head2 Inform
  64
  65 Generate InformResponse to CPE
  66
  67 =cut
  68
  69 push @$rules,
  70         'Inform' => sub {
  71                 $state->{_dispatch} = 'InformResponse';         # what reponse to call
  72                 $state->{_trigger} = 'Inform';
  73         };
  74
  75 =head2 GetRPCMethodsResponse
  76
  77 =cut
  78
  79 push @$rules,
  80                 qr/^(?:^\w+:)*string$/ => 'content array',
  81                 'MethodList' => sub {
  82                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
  83                         $state->{MethodList} = _tag( $tag_hash, 'string' );
  84                         $state->{_trigger} = 'GetRPCMethodsResponse';
  85                 };
  86
  87 =head2 GetParameterNamesResponse
  88
  89 =cut
  90
  91 push @$rules,
  92                 'ParameterInfoStruct' => sub {
  93                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
  94                         my $name = _tag($tag_hash, 'Name', '_content');
  95                         my $writable = _tag($tag_hash, 'Writable', '_content' );
  96
  97                         confess "need state" unless ( $state ); # don't remove!
  98
  99                         # XXX dragons ahead: convert name to tree rewriting it into perl
 100                         my $s = '$state->{ParameterInfo}->' . $tree->name2perl( $name ) . "->{writable} = $writable;";
 101                         eval "$s";
 102                         confess "can't eval $s : $@" if ($@);
 103
 104                         #warn "## state = dump( $state ), "\n";
 105
 106                         $state->{_trigger} = 'GetParameterNamesResponse';
 107                 };
 108
 109 =head2 Fault
 110
 111 =cut
 112
 113 push @$rules,
 114                 'Fault' => sub {
 115                         my ($tag_name, $tag_hash, $context, $parent_data) = @_;
 116                         $state->{Fault} = {
 117                                 FaultCode => _tag( $tag_hash, 'FaultCode', '_content' ),
 118                                 FaultString => _tag( $tag_hash, 'FaultString', '_content' ),
 119                         };
 120                         warn "FAULT: ", $state->{Fault}->{FaultCode}, " ", $state->{Fault}->{FaultString}, "\n";
 121                         $state->{_trigger} = 'Fault';
 122                 };
 123
 124 my $parser = XML::Rules->new(
 125 #       start_rules => [
 126 #               '^division_name,fax' => 'skip',
 127 #       ],
 128         namespaces => {
 129                 'http://schemas.xmlsoap.org/soap/envelope/' => 'soapenv',
 130                 'http://schemas.xmlsoap.org/soap/encoding/' => 'soap',
 131                 'http://www.w3.org/2001/XMLSchema' => 'xsd',
 132                 'http://www.w3.org/2001/XMLSchema-instance' => 'xsi',
 133                 'urn:dslforum-org:cwmp-1-0' => '',
 134         },
 135         rules => $rules,
 136 );
 137
 138 =head1 METHODS
 139
 140 =head2 parse
 141
 142   my $state = CWMP::Request->parse( "<soap>request</soap>" );
 143
 144 =cut
 145
 146 sub parse {
 147         my $self = shift;
 148
 149         my $xml = shift || confess "no xml?";
 150
 151         $state = {};
 152         $parser->parsestring( $xml );
 153         if ( my $trigger = $state->{_trigger} ) {
 154                 __PACKAGE__->call_trigger( $trigger, $state );
 155         }
 156         # XXX don't propagate _trigger (useful?)
 157         delete( $state->{_trigger} );
 158         return $state;
 159 }
 160
 161 =head2 _tag
 162
 163 Get value of tag. Tag name is case insensitive (don't ask why),
 164 we ignore namespaces and can take optional C<sub_key>
 165 (usually C<_content>).
 166
 167   _tag( $tag_hash, $name, $sub_key )
 168
 169 =cut
 170
 171 sub _tag {
 172         my ( $tag_hash, $name, $sub_key ) = @_;
 173         confess "need hash as first argument" unless ( ref $tag_hash eq 'HASH' );
 174         $name = (grep { m/^(?:\w+:)*$name$/i } keys %$tag_hash )[0];
 175 #       $name =~ s/^\w+://;
 176         if ( defined $tag_hash->{$name} ) {
 177                 if ( ! defined $sub_key ) {
 178                         return $tag_hash->{$name};
 179                 } elsif ( defined $tag_hash->{$name}->{$sub_key} ) {
 180                         return $tag_hash->{$name}->{$sub_key};
 181                 } else {
 182                         return if ( $name =~ m/^value$/i );
 183                         warn "can't find '$name/$sub_key' in ", dump( $tag_hash );
 184                         return;
 185                 }
 186         } else {
 187                 warn "can't find '$name' in ", dump( $tag_hash );
 188                 return;
 189         }
 190 }
 191
 192 1;